Introduce "--blocking-timeout" channel parameter
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_MAKE_SET
28 AC_PROG_SED
29 AC_PATH_PROG([report_fold], [fold])
30 LT_INIT
31
32 # Check for objcopy, required by the base address statedump and dynamic linker tests
33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
34 AS_IF([test "x$OBJCOPY" = "xno"],
35 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
36 )
37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
38
39 # check for pgrep
40 AC_PATH_PROG([PGREP], [pgrep], [no])
41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
42
43 # check for bison
44 AC_PROG_YACC
45 BISON=$YACC
46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
47
48 AS_IF([test "x$have_bison" != "xyes"], [
49 AS_IF([test "x$in_git_repo" = "xyes"], [
50 AC_MSG_FAILURE([
51 Bison >= 2.4 is required when building from the Git repository. You can
52 set the YACC variable to override automatic detection.
53 ])
54 ], [
55 AC_MSG_WARN([
56 Missing Bison >= 2.4. Note that the parser files are already built in
57 this distribution tarball, so Bison is only needed if you intend to
58 modify their sources. You can set the YACC variable to override automatic
59 detection.
60 ])
61 ])
62 ])
63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
64
65 # check for flex
66 AC_PROG_LEX
67 FLEX=$LEX
68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
69
70 AS_IF([test "x$have_flex" != "xyes"], [
71 AS_IF([test "x$in_git_repo" = "xyes"], [
72 AC_MSG_FAILURE([
73 Flex >= 2.5.35 is required when building from the Git repository. You can
74 set the LEX variable to override automatic detection.
75 ])
76 ], [
77 AC_MSG_WARN([
78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
79 this distribution tarball, so Flex is only needed if you intend to
80 modify their sources. You can set the LEX variable to override automatic
81 detection.
82 ])
83 ])
84 ])
85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
86
87
88 # Checks for typedefs, structures, and compiler characteristics.
89 AC_C_INLINE
90 AC_TYPE_INT32_T
91 AC_TYPE_INT64_T
92 AC_TYPE_MODE_T
93 AC_TYPE_OFF_T
94 AC_TYPE_PID_T
95 AC_TYPE_SIZE_T
96 AC_TYPE_SSIZE_T
97 AC_TYPE_UID_T
98 AC_TYPE_UINT16_T
99 AC_TYPE_UINT32_T
100 AC_TYPE_UINT64_T
101 AC_TYPE_UINT8_T
102
103 AX_C___ATTRIBUTE__
104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
105 [:],
106 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
107
108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
109
110 AX_LIB_SOCKET_NSL
111
112 LT_NO_UNDEFINED=""
113 AS_CASE([$host_os],
114 [cygwin*],
115 [
116 LT_NO_UNDEFINED="-no-undefined"
117 ],
118 [cygwin*|darwin*|mingw*|solaris*],
119 [
120 # On platforms where we only support the relayd, disable the other binaries by default
121 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
122 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
123 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
124 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
125 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
126 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
127 ]
128 )
129
130 AC_SUBST(LT_NO_UNDEFINED)
131
132 # Compute minor/major/patchlevel version numbers
133 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
134 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
135 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
136
137 AC_SUBST([MAJOR_VERSION], [$major_version])
138 AC_SUBST([MINOR_VERSION], [$minor_version])
139 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
140 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
141 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
142 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
143
144 version_name="KeKriek"
145 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
146 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
147
148 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
149 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
150
151 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
152 AC_ARG_ENABLE(libtool-linkdep-fixup,
153 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
154 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
155 libtool_fixup=$enableval,
156 libtool_fixup=yes)
157
158 AS_IF([test "x$libtool_fixup" = "xyes"],
159 [
160 libtool_m4="$srcdir/m4/libtool.m4"
161 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
162 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
163 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
164 AS_IF([test $libtool_flag_pattern_count -ne 0],
165 [
166 AC_MSG_RESULT([$libtool_flag_pattern_count])
167 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
168 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
169 ],
170 [
171 AC_MSG_RESULT([none])
172 ])
173 ])
174
175 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
176
177 AC_CHECK_HEADERS([ \
178 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
179 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
180 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
181 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
182 sys/mount.h sys/param.h sys/time.h
183 ])
184
185 # Basic functions check
186 AC_CHECK_FUNCS([ \
187 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
188 gethostbyname gethostname getpagesize localtime_r memchr memset \
189 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
190 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
191 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
192 sched_getcpu sysconf sync_file_range
193 ])
194
195 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
196 # add -lrt to LIBS
197 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
198
199 # Babeltrace viewer check
200 AC_ARG_WITH([babeltrace-bin],
201 AS_HELP_STRING([--with-babeltrace-bin],
202 [Location of the babeltrace viewer executable (including the filename)]),
203 [BABELTRACE_BIN="$withval"],
204 [BABELTRACE_BIN=''])
205 AC_SUBST([BABELTRACE_BIN])
206
207 # lttv-gui
208 AC_ARG_WITH([lttv-gui-bin],
209 AS_HELP_STRING([--with-lttv-gui-bin],
210 [Location of the lttv GUI viewer executable (including the filename)]),
211 [LTTV_GUI_BIN="$withval"],
212 [LTTV_GUI_BIN=''])
213 AC_SUBST([LTTV_GUI_BIN])
214
215 AC_ARG_WITH([consumerd32-bin],
216 AS_HELP_STRING([--with-consumerd32-bin],
217 [Location of the 32-bit consumerd executable (including the filename)]),
218 [CONSUMERD32_BIN="$withval"],
219 [CONSUMERD32_BIN=''])
220 AC_SUBST([CONSUMERD32_BIN])
221
222 AC_ARG_WITH([consumerd64-bin],
223 AS_HELP_STRING([--with-consumerd64-bin],
224 [Location of the 64-bit consumerd executable (including the filename)]),
225 [CONSUMERD64_BIN="$withval"],
226 [CONSUMERD64_BIN=''])
227 AC_SUBST([CONSUMERD64_BIN])
228
229 AC_ARG_WITH([consumerd32-libdir],
230 AS_HELP_STRING([--with-consumerd32-libdir],
231 [Directory containing the 32-bit consumerd libraries]),
232 [CONSUMERD32_LIBDIR="$withval"],
233 [CONSUMERD32_LIBDIR=''])
234 AC_SUBST([CONSUMERD32_LIBDIR])
235
236 AC_ARG_WITH([consumerd64-libdir],
237 AS_HELP_STRING([--with-consumerd64-libdir],
238 [Directory containing the 64-bit consumerd libraries]),
239 [CONSUMERD64_LIBDIR="$withval"],
240 [CONSUMERD64_LIBDIR=''])
241 AC_SUBST([CONSUMERD64_LIBDIR])
242
243 AC_ARG_WITH([sessiond-bin],
244 AS_HELP_STRING([--with-sessiond-bin],
245 [Location of the sessiond executable (including the filename)]),
246 [SESSIOND_BIN="$withval"],
247 [SESSIOND_BIN=''])
248 AC_SUBST([SESSIOND_BIN])
249
250 AC_ARG_WITH([lttng-system-rundir],
251 AS_HELP_STRING([--with-lttng-system-rundir],
252 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
253 [LTTNG_SYSTEM_RUNDIR="$withval"],
254 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
255 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
256
257 AC_ARG_ENABLE([test-java-agent-jul],
258 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
259 [test_java_agent_jul=$enableval],
260 [test_java_agent_jul=no]
261 )
262
263 AC_ARG_ENABLE([test-java-agent-log4j],
264 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
265 [test_java_agent_log4j=$enableval],
266 [test_java_agent_log4j=no]
267 )
268
269 AC_ARG_ENABLE([test-java-agent-all],
270 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
271 [test_java_agent_jul=$enableval
272 test_java_agent_log4j=$enableval],
273 [:]
274 )
275
276 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
277 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
278 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
279 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
280 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
281 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
282 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
283 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
284
285 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
286 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
287 $1="$2"
288 AC_SUBST([$1])
289 ])
290
291 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
292 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
293 $1="$2"
294 AC_SUBST([$1])
295 ])
296
297 # Default values
298 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
299 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
300 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
301 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
302 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
303 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
304 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
305 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
306 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
307 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
308 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
309 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
310 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
311 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
312 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
313 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
314 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
315 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
316 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
317 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
318 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
319 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
320 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
321 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
322 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
323 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
324 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
325 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
326 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
327 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
328 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
329 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
330 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
331 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
332 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
333 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
334 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
335 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
336 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
337 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
338 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
339 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
340 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
341 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
342 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
343 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
344
345 # Command short descriptions
346 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
347 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
348 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
349 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
350 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
351 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
352 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
353 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
354 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
355 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
356 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
357 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
358 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
359 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
360 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
361 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
362 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
363 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
364 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
365 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
366 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
367
368 if test "x$prefix" = "xNONE"; then
369 prefix=$ac_default_prefix
370 fi
371 CONFDIR=`eval echo $sysconfdir`
372 AC_SUBST(CONFDIR)
373 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
374
375 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
376
377 # Check libpopt
378 PKG_CHECK_MODULES([POPT], [popt],
379 [
380 dnl PKG_CHECK_MODULES defines POPT_LIBS
381 ],
382 [
383 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
384 AC_MSG_WARN([Finding libpopt without pkg-config.])
385 AC_CHECK_LIB([popt],
386 [poptGetContext],
387 [POPT_LIBS="-lpopt"],
388 [
389 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
390 ]
391 )
392 ]
393 )
394 AC_SUBST(POPT_LIBS)
395
396 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
397
398 # First, check for uuid in system libs
399 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
400 AC_CHECK_FUNCS([uuid_generate],
401 [
402 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
403 UUID_LIBS=""
404 ],
405 [
406 # Then, check if the pkg-config module is available, otherwise explicitly check
407 # for libuuid, or uuid support in the C-library.
408 PKG_CHECK_MODULES([UUID], [uuid],
409 [
410 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
411 dnl PKG_CHECK_MODULES defines UUID_LIBS
412 ],
413 [
414 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
415 AC_MSG_WARN([Finding libuuid without pkg-config.])
416 AC_CHECK_LIB([uuid], [uuid_generate],
417 [
418 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
419 UUID_LIBS="-luuid"
420 ],
421 [
422 # libuuid not found, check for uuid_create in libc.
423 AC_CHECK_LIB([c], [uuid_create],
424 [
425 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
426 UUID_LIBS="-lc"
427 ],
428 [
429 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
430 ]
431 )
432 ]
433 )
434 ]
435 )
436 ]
437 )
438 AC_SUBST(UUID_LIBS)
439
440 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
441
442 # URCU library version needed or newer
443 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
444
445 # Check liburcu needed function calls
446 AC_CHECK_DECL([cds_list_add], [],
447 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
448 AC_CHECK_DECL([cds_wfcq_init], [],
449 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
450 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
451 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
452 AC_CHECK_DECL([futex_async], [],
453 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
454 AC_CHECK_DECL([rcu_thread_offline], [],
455 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
456 AC_CHECK_DECL([rcu_thread_online], [],
457 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
458 AC_CHECK_DECL([caa_likely], [],
459 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
460 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
461 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
462
463 #Function added in urcu 0.7.0
464 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
465 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
466 )
467
468 #Function added in urcu 0.9.0
469 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
470 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
471 )
472
473 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
474 # it can be explicitly disabled with --without-kmod
475 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
476 AC_ARG_WITH([kmod],
477 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
478 [],
479 [with_kmod=check]
480 )
481
482 AS_IF([test "x$with_kmod" != "xno"],
483 [
484 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
485 [
486 AC_DEFINE([HAVE_KMOD], [1])
487 KMOD_LIBS="-lkmod"
488 ],
489 [
490 if test "x$with_kmod" != xcheck; then
491 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
492 else
493 with_kmod=no
494 fi
495 ]
496 )
497 ]
498 )
499 AC_SUBST(KMOD_LIBS)
500
501 # Check for liblttng-ust-ctl, fail if it's not found,
502 # it can be explicitly disabled with --without-lttng-ust
503 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
504 AC_ARG_WITH([lttng-ust],
505 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
506 [],
507 [with_lttng_ust=yes]
508 )
509
510 AS_IF([test "x$with_lttng_ust" = "xyes"],
511 [
512 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
513 [
514 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
515 ],
516 [
517 AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
518 ],
519 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
520 )
521 ]
522 )
523 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
524
525
526
527 # check for dlopen
528 AC_CHECK_LIB([dl], [dlopen],
529 [DL_LIBS="-ldl"],
530 [
531 #libdl not found, check for dlopen in libc.
532 AC_CHECK_LIB([c], [dlopen],
533 [DL_LIBS="-lc"],
534 [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
535 )
536 ]
537 )
538 AC_SUBST(DL_LIBS)
539
540 # Check for fmemopen
541 AC_CHECK_LIB([c], [fmemopen],
542 [
543 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
544 ]
545 )
546
547 # Check for open_memstream
548 AC_CHECK_LIB([c], [open_memstream],
549 [
550 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
551 ]
552 )
553
554 # check for libpfm
555 AC_CHECK_LIB([pfm], [pfm_initialize],
556 [
557 have_libpfm=yes
558 ])
559 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
560
561 AC_ARG_ENABLE([git-version],
562 [AC_HELP_STRING([--disable-git-version],
563 [Do not use the git version for the build])],
564 [have_git_version=$enableval], [have_git_version=yes]
565 )
566
567 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
568 [test "x${have_git_version}" = "xyes"])
569
570 # For Python
571 # SWIG version needed or newer:
572 swig_version=2.0.0
573
574 AC_ARG_ENABLE([python-bindings],
575 [AC_HELP_STRING([--enable-python-bindings],
576 [compile Python bindings])],
577 [enable_python_binding=$enableval], [enable_python_binding=no])
578
579 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
580
581 if test "x$enable_python_binding" = xyes; then
582 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
583 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
584 AM_PATH_PYTHON([3.0])
585
586 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
587 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
588 AS_IF([test -z "$PYTHON_INCLUDE"], [
589 AS_IF([test -z "$PYTHON_CONFIG"], [
590 AC_PATH_PROGS([PYTHON_CONFIG],
591 [python$PYTHON_VERSION-config python-config],
592 [no],
593 [`dirname $PYTHON`])
594 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
595 ])
596 AC_MSG_CHECKING([python include flags])
597 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
598 AC_MSG_RESULT([$PYTHON_INCLUDE])
599 ])
600
601 else
602 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
603 [if you want Python bindings.])
604
605 fi
606
607 # Epoll check. If not present, the build will fallback on poll() API
608 AX_HAVE_EPOLL(
609 [AX_CONFIG_FEATURE_ENABLE(epoll)],
610 [AX_CONFIG_FEATURE_DISABLE(epoll)]
611 )
612 AX_CONFIG_FEATURE(
613 [epoll], [This platform supports epoll(7)],
614 [HAVE_EPOLL], [This platform supports epoll(7).],
615 [enable_epoll="yes"], [enable_epoll="no"]
616 )
617 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
618
619 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
620 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
621
622 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
623 AX_JAVA_OPTIONS
624 AX_PROG_JAVAC
625 AX_PROG_JAVA
626 AX_PROG_JAR
627
628 AX_CHECK_CLASSPATH
629
630 # Check for Java UST agent common class first
631 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
632 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
633 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
634 fi
635
636 if test "x$test_java_agent_jul" = "xyes"; then
637 # Check for JUL agent class
638 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
639 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
640 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
641 fi
642 fi
643
644 if test "x$test_java_agent_log4j" = "xyes"; then
645 # Check for Log4j agent class
646 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
647 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
648 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
649 fi
650
651 # Check for Log4j class
652 AX_CHECK_CLASS(org.apache.log4j.Logger)
653 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
654 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
655 fi
656 fi
657 fi
658
659 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
660 # is not distributed in tarballs
661 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
662 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
663
664 # enable building man pages (user's intention)
665 AC_ARG_ENABLE(
666 man-pages,
667 AS_HELP_STRING(
668 [--disable-man-pages],
669 [Do not build and install man pages (already built in a distributed tarball)]
670 ),
671 [man_pages_opt=$enableval],
672 [man_pages_opt=yes]
673 )
674
675 # check for asciidoc and xmlto if we enabled building the man pages
676 have_asciidoc_xmlto=no
677 warn_prebuilt_man_pages=no
678
679 AS_IF([test "x$man_pages_opt" = "xyes"], [
680 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
681 AC_PATH_PROG([XMLTO], [xmlto], [no])
682
683 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
684 AS_IF([test "x$in_git_repo" = "xyes"], [
685 # this is an error because we're in the Git repo, which
686 # means the man pages are not already generated for us,
687 # thus asciidoc/xmlto are required because we were asked
688 # to build the man pages
689 AC_MSG_ERROR([
690 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
691 --disable-man-pages to disable building the man pages, in which case
692 they will not be installed.
693 ])
694 ], [
695 # only warn here: since we're in the tarball, the man
696 # pages should already be generated at this point, thus
697 # asciidoc/xmlto are not strictly required
698 warn_prebuilt_man_pages=yes
699 ])
700 ], [
701 have_asciidoc_xmlto=yes
702 ])
703 ])
704
705 # export man page build condition: build the man pages if the user
706 # asked for it, and if the tools are available
707 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
708 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
709
710 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
711
712 # embedded --help message
713 AC_ARG_ENABLE(
714 [embedded-help],
715 AS_HELP_STRING(
716 [--enable-embedded-help],
717 [Embed the --help messages in the executable files]
718 ),
719 [embedded_help=$enableval],
720 [embedded_help=no]
721 )
722 AS_IF([test "x$embedded_help" = "xyes"], [
723 AS_IF([test "x$man_pages_opt" = "xno"], [
724 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
725 ])
726 AC_PATH_PROG([man_prog_path], [man], [no])
727 AS_IF([test "x$man_prog_path" = "xno"], [
728 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
729 ])
730 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
731 AC_SUBST([MANPROG], [$man_prog_path])
732 ])
733 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
734
735 # Python agent test
736 UST_PYTHON_AGENT="lttngust"
737
738 AC_ARG_ENABLE(test-python2-agent,
739 AS_HELP_STRING([--enable-test-python2-agent],
740 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
741 ),[:],[test_python2_agent_autodetect=yes]
742 )
743
744 AC_ARG_ENABLE(test-python3-agent,
745 AS_HELP_STRING([--enable-test-python3-agent],
746 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
747 ),[:],[test_python3_agent_autodetect=yes]
748 )
749
750 AC_ARG_ENABLE(test-python-agent-all,
751 AS_HELP_STRING([--enable-test-python-agent-all],
752 [enable test for all python{2/3} agent.]
753 ),
754 )
755
756 AS_IF([test ! -z "$enable_test_python_agent_all"], [
757 unset test_python2_agent_autodetect
758 unset test_python3_agent_autodetect
759 ])
760
761 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
762 enable_test_python2_agent=yes
763 enable_test_python3_agent=yes
764 ])
765
766 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
767 enable_test_python2_agent=no
768 enable_test_python3_agent=no
769 ])
770
771
772 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
773 AS_IF([test -z "$PYTHON2"], [
774 PYTHON2=python2
775 ], [
776 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
777 ])
778
779 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
780 AS_IF([test -z "$PYTHON2_BIN"], [
781 AS_IF([test -z "$test_python2_agent_autodetect"],[
782 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
783 ])
784 ], [
785 AC_MSG_CHECKING([for python2 lttng-ust agent])
786 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
787 PYTHON2_AGENT=$PYTHON2_BIN
788 AC_MSG_RESULT([yes])
789 RUN_PYTHON_AGENT_TEST=yes
790 ], [
791 AC_MSG_RESULT([no])
792 AS_IF([test -z "$test_python2_agent_autodetect"],[
793 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
794 ])
795 ])
796
797 ])
798
799 ])
800
801 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
802 AS_IF([test -z "$PYTHON3"], [
803 PYTHON3=python3
804 ], [
805 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
806 ])
807
808 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
809 AS_IF([test -z "$PYTHON3_BIN"], [
810 AS_IF([test -z "$test_python3_agent_autodetect"],[
811 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
812 ])
813 ], [
814 AC_MSG_CHECKING([for python3 lttng-ust agent])
815 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
816 PYTHON3_AGENT=$PYTHON3_BIN
817 AC_MSG_RESULT([yes])
818 RUN_PYTHON_AGENT_TEST=yes
819 ], [
820 AC_MSG_RESULT([no])
821 AS_IF([test -z "$test_python3_agent_autodetect"],[
822 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
823 ])
824 ])
825
826 ])
827 ])
828 AC_SUBST([RUN_PYTHON_AGENT_TEST])
829 AC_SUBST([PYTHON2_AGENT])
830 AC_SUBST([PYTHON3_AGENT])
831
832 # Arguments for binaries build exclusion
833 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
834 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
835 [Disable the build of lttng-consumerd binaries]))
836 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
837 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
838 [Disable the build of lttng-relayd binaries]))
839 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
840 [Disable the build of lttng-sessiond binaries]))
841 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
842 [Disable the build of the extra components]))
843
844
845 # Always build libconfig since it a dependency of libcommon
846 build_lib_config=yes
847
848 build_lib_compat=no
849 build_lib_consumer=no
850 build_lib_hashtable=no
851 build_lib_health=no
852 build_lib_index=no
853 build_lib_kernel_consumer=no
854 build_lib_kernel_ctl=no
855 build_lib_lttng_ctl=no
856 build_lib_relayd=no
857 build_lib_sessiond_comm=no
858 build_lib_testpoint=no
859 build_lib_ust_consumer=no
860
861 # There is an overlap for enabled dependencies, but this makes everything
862 # simpler. libcommon and libconfig are always compiled so they are not repeated
863 # here.
864
865 # Enable binary dependencies.
866 AS_IF([test x$enable_bin_lttng != xno],
867 [
868 build_lib_lttng_ctl=yes
869 ]
870 )
871
872 AS_IF([test x$enable_bin_lttng_consumerd != xno],
873 [
874 build_lib_consumer=yes
875 build_lib_sessiond_comm=yes
876 build_lib_index=yes
877 build_lib_health=yes
878 build_lib_testpoint=yes
879 ]
880 )
881
882 AS_IF([test x$enable_bin_lttng_crash != xno],
883 # Do nothing since libconfig and libcommon are built by default.
884 []
885 )
886
887 AS_IF([test x$enable_bin_lttng_relayd != xno],
888 [
889 build_lib_lttng_ctl=yes
890 build_lib_sessiond_comm=yes
891 build_lib_hashtable=yes
892 build_lib_compat=yes
893 build_lib_index=yes
894 build_lib_health=yes
895 build_lib_testpoint=yes
896 ]
897 )
898 AS_IF([test x$enable_bin_lttng_sessiond != xno],
899 [
900 build_lib_lttng_ctl=yes
901 build_lib_sessiond_comm=yes
902 build_lib_kernel_ctl=yes
903 build_lib_hashtable=yes
904 build_lib_compat=yes
905 build_lib_relayd=yes
906 build_lib_testpoint=yes
907 build_lib_health=yes
908 build_lib_health=yes
909 ]
910 )
911
912 # Libraries dependencies enabling
913 AS_IF([test x$build_lib_lttng_ctl = xyes],
914 [
915 build_lib_sessiond_comm=yes
916 build_lib_hashtable=yes
917 ]
918 )
919
920 AS_IF([test x$build_lib_consumer = xyes],
921 [
922 build_lib_sessiond_comm=yes
923 build_lib_kernel_consumer=yes
924 build_lib_hashtable=yes
925 build_lib_compat=yes
926 build_lib_relayd=yes
927 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
928 ]
929 )
930
931 AS_IF([test x$build_lib_kernel_consumer = xyes],
932 [
933 build_lib_kernel_ctl=yes
934 build_lib_relayd=yes
935 ]
936 )
937
938 AS_IF([test x$build_lib_relayd = xyes],
939 [
940 build_lib_sessiond_comm=yes
941 ]
942 )
943
944
945 # Export binaries build conditions.
946 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
947 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
948 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
949 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
950 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
951
952 # Export the tests and extras build conditions.
953 AS_IF([\
954 test "x$enable_bin_lttng" != "xno" && \
955 test "x$enable_bin_lttng_consumerd" != "xno" && \
956 test "x$enable_bin_lttng_crash" != "xno" && \
957 test "x$enable_bin_lttng_relayd" != "xno" && \
958 test "x$enable_bin_lttng_sessiond" != "xno"],
959 [build_tests=yes],
960 [build_tests=no]
961 )
962
963 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
964 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
965
966 # Export libraries build conditions.
967 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
968 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
969 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
970 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
971 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
972 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
973 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
974 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
975 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
976 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
977 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
978 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
979 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
980
981 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
982 AC_SUBST(AM_CFLAGS)
983
984 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
985 AC_SUBST(AM_CPPFLAGS)
986
987 lttngincludedir="${includedir}/lttng"
988 AC_SUBST(lttngincludedir)
989
990 lttngactionincludedir="${includedir}/lttng/action"
991 AC_SUBST(lttngactionincludedir)
992
993 lttngconditionincludedir="${includedir}/lttng/condition"
994 AC_SUBST(lttngconditionincludedir)
995
996 lttngnotificationincludedir="${includedir}/lttng/notification"
997 AC_SUBST(lttngnotificationincludedir)
998
999 lttngtriggerincludedir="${includedir}/lttng/trigger"
1000 AC_SUBST(lttngtriggerincludedir)
1001
1002 lttnglibexecdir="${libdir}/lttng/libexec"
1003 AC_SUBST(lttnglibexecdir)
1004
1005 AC_CONFIG_FILES([
1006 Makefile
1007 doc/Makefile
1008 doc/man/Makefile
1009 doc/man/asciidoc-attrs.conf
1010 include/Makefile
1011 extras/Makefile
1012 extras/bindings/Makefile
1013 extras/bindings/swig/Makefile
1014 extras/bindings/swig/python/Makefile
1015 extras/core-handler/Makefile
1016 src/Makefile
1017 src/common/Makefile
1018 src/common/kernel-ctl/Makefile
1019 src/common/kernel-consumer/Makefile
1020 src/common/consumer/Makefile
1021 src/common/ust-consumer/Makefile
1022 src/common/hashtable/Makefile
1023 src/common/sessiond-comm/Makefile
1024 src/common/compat/Makefile
1025 src/common/relayd/Makefile
1026 src/common/testpoint/Makefile
1027 src/common/index/Makefile
1028 src/common/health/Makefile
1029 src/common/config/Makefile
1030 src/common/string-utils/Makefile
1031 src/lib/Makefile
1032 src/lib/lttng-ctl/Makefile
1033 src/lib/lttng-ctl/filter/Makefile
1034 src/lib/lttng-ctl/lttng-ctl.pc
1035 src/bin/Makefile
1036 src/bin/lttng-consumerd/Makefile
1037 src/bin/lttng-sessiond/Makefile
1038 src/bin/lttng-relayd/Makefile
1039 src/bin/lttng/Makefile
1040 src/bin/lttng-crash/Makefile
1041 tests/Makefile
1042 tests/destructive/Makefile
1043 tests/regression/Makefile
1044 tests/regression/kernel/Makefile
1045 tests/regression/tools/Makefile
1046 tests/regression/tools/streaming/Makefile
1047 tests/regression/tools/filtering/Makefile
1048 tests/regression/tools/health/Makefile
1049 tests/regression/tools/tracefile-limits/Makefile
1050 tests/regression/tools/snapshots/Makefile
1051 tests/regression/tools/live/Makefile
1052 tests/regression/tools/exclusion/Makefile
1053 tests/regression/tools/save-load/Makefile
1054 tests/regression/tools/save-load/configuration/Makefile
1055 tests/regression/tools/mi/Makefile
1056 tests/regression/tools/wildcard/Makefile
1057 tests/regression/tools/crash/Makefile
1058 tests/regression/tools/regen-metadata/Makefile
1059 tests/regression/tools/regen-statedump/Makefile
1060 tests/regression/tools/notification/Makefile
1061 tests/regression/ust/Makefile
1062 tests/regression/ust/nprocesses/Makefile
1063 tests/regression/ust/high-throughput/Makefile
1064 tests/regression/ust/low-throughput/Makefile
1065 tests/regression/ust/before-after/Makefile
1066 tests/regression/ust/buffers-pid/Makefile
1067 tests/regression/ust/periodical-metadata-flush/Makefile
1068 tests/regression/ust/multi-session/Makefile
1069 tests/regression/ust/overlap/Makefile
1070 tests/regression/ust/overlap/demo/Makefile
1071 tests/regression/ust/linking/Makefile
1072 tests/regression/ust/daemon/Makefile
1073 tests/regression/ust/exit-fast/Makefile
1074 tests/regression/ust/fork/Makefile
1075 tests/regression/ust/libc-wrapper/Makefile
1076 tests/regression/ust/baddr-statedump/Makefile
1077 tests/regression/ust/ust-dl/Makefile
1078 tests/regression/ust/java-jul/Makefile
1079 tests/regression/ust/java-log4j/Makefile
1080 tests/regression/ust/python-logging/Makefile
1081 tests/regression/ust/getcpu-override/Makefile
1082 tests/regression/ust/clock-override/Makefile
1083 tests/regression/ust/type-declarations/Makefile
1084 tests/regression/ust/rotation-destroy-flush/Makefile
1085 tests/regression/ust/blocking/Makefile
1086 tests/stress/Makefile
1087 tests/unit/Makefile
1088 tests/unit/ini_config/Makefile
1089 tests/perf/Makefile
1090 tests/utils/Makefile
1091 tests/utils/tap/Makefile
1092 tests/utils/testapp/Makefile
1093 tests/utils/testapp/gen-ust-events/Makefile
1094 tests/utils/testapp/gen-ust-nevents/Makefile
1095 tests/utils/testapp/gen-ust-nevents-str/Makefile
1096 tests/utils/testapp/gen-ust-tracef/Makefile
1097 ])
1098
1099 # Inject variable into python test script.
1100 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1101 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1102 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1103
1104 AC_OUTPUT
1105
1106 #
1107 # Mini-report on what will be built.
1108 #
1109
1110 PPRINT_INIT
1111 PPRINT_SET_INDENT(1)
1112 PPRINT_SET_TS(38)
1113
1114 AS_ECHO
1115 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1116 AS_ECHO
1117
1118 AS_IF([test -n "$report_fold"], [
1119 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1120 ], [
1121 AS_ECHO("$version_description")
1122 ])
1123
1124 AS_ECHO
1125 PPRINT_SUBTITLE([Features])
1126
1127 # Target architecture we're building for.
1128 target_arch=$host_cpu
1129 [
1130 for f in $CFLAGS; do
1131 if test $f = "-m32"; then
1132 target_arch="32-bit"
1133 elif test $f = "-m64"; then
1134 target_arch="64-bit"
1135 fi
1136 done
1137 ]
1138 PPRINT_PROP_STRING([Target architecture], $target_arch)
1139
1140 # kmod enabled/disabled
1141 test "x$with_kmod" != "xno" && value=1 || value=0
1142 PPRINT_PROP_BOOL([libkmod support], $value)
1143
1144 # LTTng-UST enabled/disabled
1145 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1146 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1147
1148 AS_ECHO
1149 PPRINT_SUBTITLE([Binaries])
1150
1151 # List binaries to be built
1152 test x$enable_bin_lttng != xno && value=1 || value=0
1153 PPRINT_PROP_BOOL([lttng], $value)
1154
1155 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1156 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1157
1158 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1159 PPRINT_PROP_BOOL([lttng-crash], $value)
1160
1161 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1162 PPRINT_PROP_BOOL([lttng-relayd], $value)
1163
1164 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1165 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1166
1167 # Extras
1168 test x$enable_extras != xno && value=1 || value=0
1169 AS_ECHO
1170 PPRINT_SET_INDENT(0)
1171 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1172 PPRINT_SET_INDENT(1)
1173
1174 AS_ECHO
1175 PPRINT_SUBTITLE([Tests])
1176
1177 # Print clear message that tests won't be built
1178 AS_IF([test "x$build_tests" = "xno"],[
1179 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1180 ])
1181
1182 # LTTng UST Java agent JUL tests enabled/disabled
1183 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1184 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1185
1186 # LTTng UST Java agent Log4j tests enabled/disabled
1187 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1188 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1189
1190 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1191 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1192
1193 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1194 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1195
1196 #Python binding enabled/disabled
1197 test "x$enable_python_binding" = xyes && value=1 || value=0
1198 AS_ECHO
1199 PPRINT_SET_INDENT(0)
1200 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1201
1202 # man pages build enabled/disabled
1203 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1204
1205 AS_IF([test "x$man_pages_opt" != "xno"], [
1206 AS_IF([test "x$in_git_repo" = "xyes"], [
1207 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1208 ], [
1209 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1210 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1211 ], [
1212 PPRINT_PROP_STRING([build_man_pages_msg],
1213 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1214 $PPRINT_COLOR_SUBTITLE)
1215 ])
1216 ])
1217 ], [
1218 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1219 ])
1220
1221 m4_popdef([build_man_pages_msg])
1222
1223 test "x$embedded_help" = xyes && value=1 || value=0
1224 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1225
1226 PPRINT_SET_INDENT(1)
1227
1228 report_bindir="`eval eval echo $bindir`"
1229 report_libdir="`eval eval echo $libdir`"
1230
1231 # Print the bindir and libdir this `make install' will install into.
1232 AS_ECHO
1233 PPRINT_SUBTITLE([Install directories])
1234 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1235 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1236
1237 AS_ECHO
1238 PPRINT_SUBTITLE([Search directories])
1239
1240 # If we build the sessiond, print the paths it will use
1241 AS_IF([test "$SESSIOND_BIN" = ""],[
1242 path="$report_bindir/lttng-sessiond"
1243 ],[
1244 path="$SESSIOND_BIN"
1245 ])
1246 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1247
1248 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1249 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1250 ],[
1251 path="$CONSUMERD32_BIN"
1252 ])
1253 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1254
1255 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1256 path="`eval eval echo $libdir`"
1257 ],[
1258 path="$CONSUMERD32_LIBDIR"
1259 ])
1260 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1261
1262 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1263 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1264 ],[
1265 path="$CONSUMERD64_BIN"
1266 ])
1267 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1268
1269 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1270 path="`eval eval echo $libdir`"
1271 ],[
1272 path="$CONSUMERD64_LIBDIR"
1273 ])
1274 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1275 PPRINT_SET_INDENT(0)
1276
1277 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1278 AS_ECHO
1279 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1280
1281 Note that the man pages are already built in this distribution tarball,
1282 therefore asciidoc and xmlto are only needed if you intend to modify
1283 their sources.
1284
1285 Also note that the installed man pages will contain the project's
1286 default command-line option and environment variable values.
1287
1288 Use --disable-man-pages to completely disable building and installing
1289 the man pages.])
1290 ])
This page took 0.093588 seconds and 6 git commands to generate.