configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.13.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25 AC_PROG_CXX
  26 RW_PROG_CXX_WORKS
  27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  28
  29 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  30 #
  31 # Pass -Werror as an extra flag during the test: this is needed to make the
  32 # -Wunknown-warning-option diagnostic fatal with clang.
  33 AX_APPEND_COMPILE_FLAGS([ dnl
  34                 -Wall dnl
  35                 dnl We currently get this warning when building with Clang:
  36                 dnl
  37                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  38                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  39                 dnl            ^
  40                 -Wno-incomplete-setjmp-declaration dnl
  41                 -Wdiscarded-qualifiers dnl
  42                 -Wmissing-declarations dnl
  43                 -Wmissing-prototypes dnl
  44                 -Wmissing-parameter-type dnl
  45                 -Wold-style-definition dnl
  46                 -Wstrict-prototypes dnl
  47         ],
  48         [WARN_CFLAGS],
  49         [-Werror])
  50
  51 # When given, add -Werror to WARN_CFLAGS.
  52 AC_ARG_ENABLE([Werror],
  53         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  54 )
  55 AS_IF([test "x$enable_Werror" = "xyes"],
  56         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  57 )
  58
  59 # Checks for programs.
  60 AC_PROG_GREP
  61 AC_PROG_MAKE_SET
  62 AC_PROG_SED
  63 AC_PATH_PROG([report_fold], [fold])
  64 LT_INIT
  65
  66 # Check for objcopy, required by the base address statedump and dynamic linker tests
  67 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  68 AS_IF([test "x$OBJCOPY" = "xno"],
  69         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  70 )
  71 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  72
  73 # check for pgrep
  74 AC_PATH_PROG([PGREP], [pgrep], [no])
  75 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  76
  77 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  78 # is not distributed in tarballs
  79 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  80 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  81
  82 # check for bison
  83 AC_PROG_YACC
  84 BISON=$YACC
  85 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  86
  87 AS_IF([test "x$have_bison" != "xyes"], [
  88   AS_IF([test "x$in_git_repo" = "xyes"], [
  89     AC_MSG_FAILURE([
  90 Bison >= 2.4 is required when building from the Git repository. You can
  91 set the YACC variable to override automatic detection.
  92     ])
  93   ], [
  94     AC_MSG_WARN([
  95 Missing Bison >= 2.4. Note that the parser files are already built in
  96 this distribution tarball, so Bison is only needed if you intend to
  97 modify their sources. You can set the YACC variable to override automatic
  98 detection.
  99     ])
 100   ])
 101 ])
 102 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 103
 104 # check for flex
 105 AC_PROG_LEX
 106 FLEX=$LEX
 107 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 108
 109 AS_IF([test "x$have_flex" != "xyes"], [
 110   AS_IF([test "x$in_git_repo" = "xyes"], [
 111     AC_MSG_FAILURE([
 112 Flex >= 2.5.35 is required when building from the Git repository. You can
 113 set the LEX variable to override automatic detection.
 114     ])
 115   ], [
 116     AC_MSG_WARN([
 117 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 118 this distribution tarball, so Flex is only needed if you intend to
 119 modify their sources. You can set the LEX variable to override automatic
 120 detection.
 121     ])
 122   ])
 123 ])
 124 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 125
 126
 127 # Checks for typedefs, structures, and compiler characteristics.
 128 AC_C_INLINE
 129 AC_TYPE_INT32_T
 130 AC_TYPE_INT64_T
 131 AC_TYPE_MODE_T
 132 AC_TYPE_OFF_T
 133 AC_TYPE_PID_T
 134 AC_TYPE_SIZE_T
 135 AC_TYPE_SSIZE_T
 136 AC_TYPE_UID_T
 137 AC_TYPE_UINT16_T
 138 AC_TYPE_UINT32_T
 139 AC_TYPE_UINT64_T
 140 AC_TYPE_UINT8_T
 141
 142 AX_C___ATTRIBUTE__
 143 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 144         [:],
 145         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 146
 147 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 148
 149 # Check if linker has the -no-pie option.
 150 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 151 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 152
 153 AX_LIB_SOCKET_NSL
 154
 155 LT_NO_UNDEFINED=""
 156 AS_CASE([$host_os],
 157   [cygwin*],
 158     [
 159       LT_NO_UNDEFINED="-no-undefined"
 160     ],
 161   [cygwin*|darwin*|mingw*|solaris*],
 162     [
 163       # On platforms where we only support the relayd, disable the other binaries by default
 164       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 165       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 166       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 167       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 168       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 169       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 170     ]
 171 )
 172
 173 AC_SUBST(LT_NO_UNDEFINED)
 174
 175 # Compute minor/major/patchlevel version numbers
 176 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 177 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 178 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 179
 180 AC_SUBST([MAJOR_VERSION], [$major_version])
 181 AC_SUBST([MINOR_VERSION], [$minor_version])
 182 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 183 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 184 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 185 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 186
 187 version_name="N-Beer"
 188 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 189 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 190
 191 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 192 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 193
 194 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 195 AC_ARG_ENABLE(libtool-linkdep-fixup,
 196         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 197                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 198         libtool_fixup=$enableval,
 199         libtool_fixup=yes)
 200
 201 AS_IF([test "x$libtool_fixup" = "xyes"],
 202             [
 203             libtool_m4="$srcdir/m4/libtool.m4"
 204             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 205             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 206             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 207             AS_IF([test $libtool_flag_pattern_count -ne 0],
 208             [
 209                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 210                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 211                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 212                   ],
 213                   [
 214                   AC_MSG_RESULT([none])
 215                   ])
 216             ])
 217
 218 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 219
 220 AC_CHECK_HEADERS([ \
 221         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 222         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 223         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 224         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 225         sys/mount.h sys/param.h sys/time.h elf.h
 226 ])
 227
 228 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 229
 230 # Basic functions check
 231 AC_CHECK_FUNCS([ \
 232         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 233         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 234         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 235         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 236         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 237         sched_getcpu sysconf sync_file_range
 238 ])
 239
 240 # Check for pthread_setname_np and its signature
 241 LTTNG_PTHREAD_SETNAME_NP
 242
 243 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 244 # add -lrt to LIBS
 245 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 246
 247 # Checks for dl.
 248 AC_CHECK_LIB([dl], [dlopen], [
 249         have_libdl=yes
 250         libdl_name=dl
 251         DL_LIBS="-ldl"
 252 ], [
 253         # libdl not found, check for dlopen in libc.
 254         AC_CHECK_LIB([c], [dlopen], [
 255                 have_libc_dl=yes
 256                 libdl_name=c
 257                 DL_LIBS="-lc"
 258         ], [
 259                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 260         ])
 261 ])
 262 AC_SUBST(DL_LIBS)
 263
 264 # Check if libdl has dlmopen support.
 265 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 266 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 267         AC_DEFINE([HAVE_DLMOPEN], [1])
 268         HAVE_DLMOPEN=1
 269 ], [
 270         HAVE_DLMOPEN=0
 271 ])
 272 AC_SUBST(HAVE_DLMOPEN)
 273
 274 # Babeltrace viewer check
 275 AC_ARG_WITH([babeltrace-bin],
 276         AS_HELP_STRING([--with-babeltrace-bin],
 277         [Location of the babeltrace viewer executable (including the filename)]),
 278         [BABELTRACE_BIN="$withval"],
 279         [BABELTRACE_BIN=''])
 280 AC_SUBST([BABELTRACE_BIN])
 281
 282 AC_ARG_WITH([babeltrace2-bin],
 283         AS_HELP_STRING([--with-babeltrace2-bin],
 284         [Location of the babeltrace2 viewer executable (including the filename)]),
 285         [BABELTRACE2_BIN="$withval"],
 286         [BABELTRACE2_BIN=''])
 287 AC_SUBST([BABELTRACE2_BIN])
 288
 289 AC_ARG_WITH([consumerd32-bin],
 290         AS_HELP_STRING([--with-consumerd32-bin],
 291         [Location of the 32-bit consumerd executable (including the filename)]),
 292         [CONSUMERD32_BIN="$withval"],
 293         [CONSUMERD32_BIN=''])
 294 AC_SUBST([CONSUMERD32_BIN])
 295
 296 AC_ARG_WITH([consumerd64-bin],
 297         AS_HELP_STRING([--with-consumerd64-bin],
 298         [Location of the 64-bit consumerd executable (including the filename)]),
 299         [CONSUMERD64_BIN="$withval"],
 300         [CONSUMERD64_BIN=''])
 301 AC_SUBST([CONSUMERD64_BIN])
 302
 303 AC_ARG_WITH([consumerd32-libdir],
 304         AS_HELP_STRING([--with-consumerd32-libdir],
 305         [Directory containing the 32-bit consumerd libraries]),
 306         [CONSUMERD32_LIBDIR="$withval"],
 307         [CONSUMERD32_LIBDIR=''])
 308 AC_SUBST([CONSUMERD32_LIBDIR])
 309
 310 AC_ARG_WITH([consumerd64-libdir],
 311         AS_HELP_STRING([--with-consumerd64-libdir],
 312         [Directory containing the 64-bit consumerd libraries]),
 313         [CONSUMERD64_LIBDIR="$withval"],
 314         [CONSUMERD64_LIBDIR=''])
 315 AC_SUBST([CONSUMERD64_LIBDIR])
 316
 317 AC_ARG_WITH([sessiond-bin],
 318         AS_HELP_STRING([--with-sessiond-bin],
 319         [Location of the sessiond executable (including the filename)]),
 320         [SESSIOND_BIN="$withval"],
 321         [SESSIOND_BIN=''])
 322 AC_SUBST([SESSIOND_BIN])
 323
 324 AC_ARG_WITH([lttng-system-rundir],
 325         AS_HELP_STRING([--with-lttng-system-rundir],
 326         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 327         [LTTNG_SYSTEM_RUNDIR="$withval"],
 328         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 329 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 330
 331 AC_ARG_ENABLE([test-java-agent-jul],
 332         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 333         [test_java_agent_jul=$enableval],
 334         [test_java_agent_jul=no]
 335 )
 336
 337 AC_ARG_ENABLE([test-java-agent-log4j],
 338         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 339         [test_java_agent_log4j=$enableval],
 340         [test_java_agent_log4j=no]
 341 )
 342
 343 AC_ARG_ENABLE([test-java-agent-all],
 344         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 345         [test_java_agent_jul=$enableval
 346          test_java_agent_log4j=$enableval],
 347         [:]
 348 )
 349
 350 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 351 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 352 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 353 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 354 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 355 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 356 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 357 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 358
 359 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 360         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 361         $1="$2"
 362         AC_SUBST([$1])
 363 ])
 364
 365 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 366         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 367         $1="$2"
 368         AC_SUBST([$1])
 369 ])
 370
 371 # Default values
 372 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 373 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 374 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 375 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 376 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 377 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 378 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 415 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 416 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 417 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 418 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 419 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 420 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 421
 422 # Command short descriptions
 423 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 424 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 425 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 426 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 450
 451 if test "x$prefix" = "xNONE"; then
 452         prefix=$ac_default_prefix
 453 fi
 454 CONFDIR=`eval echo $sysconfdir`
 455 AC_SUBST(CONFDIR)
 456 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 457
 458 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 459
 460 # Check libpopt
 461 PKG_CHECK_MODULES([POPT], [popt],
 462   [
 463     dnl PKG_CHECK_MODULES defines POPT_LIBS
 464   ],
 465   [
 466     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 467     AC_MSG_WARN([Finding libpopt without pkg-config.])
 468     AC_CHECK_LIB([popt],
 469       [poptGetContext],
 470       [POPT_LIBS="-lpopt"],
 471       [
 472         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 473       ]
 474     )
 475   ]
 476 )
 477 AC_SUBST(POPT_LIBS)
 478
 479 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 480
 481 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 482
 483 # URCU library version needed or newer
 484 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 485
 486 # Check liburcu needed function calls
 487 AC_CHECK_DECL([cds_list_add], [],
 488         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 489 AC_CHECK_DECL([cds_wfcq_init], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 491 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 492         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 493 AC_CHECK_DECL([futex_async], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 495 AC_CHECK_DECL([rcu_thread_offline], [],
 496         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 497 AC_CHECK_DECL([rcu_thread_online], [],
 498         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 499 AC_CHECK_DECL([caa_likely], [],
 500         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 501 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 502         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 503
 504 #Function added in urcu 0.7.0
 505 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 506         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 507 )
 508
 509 #Function added in urcu 0.9.0
 510 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 511         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 512 )
 513
 514 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 515 # it can be explicitly disabled with --without-kmod
 516 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 517 AC_ARG_WITH([kmod],
 518   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 519   [],
 520   [with_kmod=check]
 521 )
 522
 523 AS_IF([test "x$with_kmod" != "xno"],
 524   [
 525     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 526       [
 527         AC_DEFINE([HAVE_KMOD], [1])
 528         KMOD_LIBS="-lkmod"
 529       ],
 530       [
 531         if test "x$with_kmod" != xcheck; then
 532           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 533         else
 534           with_kmod=no
 535         fi
 536       ]
 537     )
 538   ]
 539 )
 540 AC_SUBST(KMOD_LIBS)
 541
 542 # Check for liblttng-ust-ctl, fail if it's not found,
 543 # it can be explicitly disabled with --without-lttng-ust
 544 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 545 AC_ARG_WITH([lttng-ust],
 546   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 547   [],
 548   [with_lttng_ust=yes]
 549 )
 550
 551 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 552   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 553
 554   # Check for liblttng-ust
 555   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 556
 557   # Check for liblttng-ust-ctl
 558   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 559
 560   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 561 ])
 562
 563 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 564
 565
 566 # Check for fmemopen
 567 AC_CHECK_LIB([c], [fmemopen],
 568 [
 569         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 570 ]
 571 )
 572
 573 # check for libpfm
 574 AC_CHECK_LIB([pfm], [pfm_initialize],
 575              [
 576               have_libpfm=yes
 577               ])
 578 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 579
 580 # For Python
 581 # SWIG version needed or newer:
 582 swig_version=2.0.0
 583
 584 AC_ARG_ENABLE([python-bindings],
 585               [AC_HELP_STRING([--enable-python-bindings],
 586                               [compile Python bindings])],
 587               [enable_python_binding=$enableval], [enable_python_binding=no])
 588
 589 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 590
 591 if test "x$enable_python_binding" = xyes; then
 592   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 593   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 594   AM_PATH_PYTHON([3.0])
 595
 596   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 597   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 598   AS_IF([test -z "$PYTHON_INCLUDE"], [
 599     AS_IF([test -z "$PYTHON_CONFIG"], [
 600       AC_PATH_PROGS([PYTHON_CONFIG],
 601                     [python$PYTHON_VERSION-config python-config],
 602                     [no],
 603                     [`dirname $PYTHON`])
 604       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 605     ])
 606     AC_MSG_CHECKING([python include flags])
 607     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 608     AC_MSG_RESULT([$PYTHON_INCLUDE])
 609   ])
 610
 611 else
 612     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 613 [if you want Python bindings.])
 614
 615 fi
 616
 617 # Epoll check. If not present, the build will fallback on poll() API
 618 AX_HAVE_EPOLL(
 619         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 620         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 621 )
 622 AX_CONFIG_FEATURE(
 623         [epoll], [This platform supports epoll(7)],
 624         [HAVE_EPOLL], [This platform supports epoll(7).],
 625         [enable_epoll="yes"], [enable_epoll="no"]
 626 )
 627 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 628
 629 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 630         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 631         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 632 )
 633 AX_CONFIG_FEATURE(
 634         [dirfd], [Use directory file descriptors],
 635         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 636 )
 637
 638 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 639 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 640
 641 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 642         AX_JAVA_OPTIONS
 643         AX_PROG_JAVAC
 644         AX_PROG_JAVA
 645         AX_PROG_JAR
 646
 647         AX_CHECK_CLASSPATH
 648
 649         # Check for Java UST agent common class first
 650         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 651         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 652                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 653         fi
 654
 655         if test "x$test_java_agent_jul" = "xyes"; then
 656                 # Check for JUL agent class
 657                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 658                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 659                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 660                 fi
 661         fi
 662
 663         if test "x$test_java_agent_log4j" = "xyes"; then
 664                 # Check for Log4j agent class
 665                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 666                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 667                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 668                 fi
 669
 670                 # Check for Log4j class
 671                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 672                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 673                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 674                 fi
 675         fi
 676 fi
 677
 678 # enable building man pages (user's intention)
 679 AC_ARG_ENABLE(
 680         man-pages,
 681         AS_HELP_STRING(
 682                 [--disable-man-pages],
 683                 [Do not build and install man pages (already built in a distributed tarball)]
 684         ),
 685         [man_pages_opt=$enableval],
 686         [man_pages_opt=yes]
 687 )
 688
 689 # check for asciidoc and xmlto if we enabled building the man pages
 690 have_asciidoc_xmlto=no
 691 warn_prebuilt_man_pages=no
 692
 693 AS_IF([test "x$man_pages_opt" = "xyes"], [
 694         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 695         AC_PATH_PROG([XMLTO], [xmlto], [no])
 696
 697         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 698                 AS_IF([test "x$in_git_repo" = "xyes"], [
 699                         # this is an error because we're in the Git repo, which
 700                         # means the man pages are not already generated for us,
 701                         # thus asciidoc/xmlto are required because we were asked
 702                         # to build the man pages
 703                         AC_MSG_ERROR([
 704 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 705 --disable-man-pages to disable building the man pages, in which case
 706 they will not be installed.
 707                         ])
 708                 ], [
 709                         # only warn here: since we're in the tarball, the man
 710                         # pages should already be generated at this point, thus
 711                         # asciidoc/xmlto are not strictly required
 712                         warn_prebuilt_man_pages=yes
 713                 ])
 714         ], [
 715                 have_asciidoc_xmlto=yes
 716         ])
 717 ])
 718
 719 # export man page build condition: build the man pages if the user
 720 # asked for it, and if the tools are available
 721 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 722 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 723
 724 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 725
 726 # embedded --help message
 727 AC_ARG_ENABLE(
 728         [embedded-help],
 729         AS_HELP_STRING(
 730                 [--enable-embedded-help],
 731                 [Embed the --help messages in the executable files]
 732         ),
 733         [embedded_help=$enableval],
 734         [embedded_help=no]
 735 )
 736 AS_IF([test "x$embedded_help" = "xyes"], [
 737         AS_IF([test "x$man_pages_opt" = "xno"], [
 738                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 739         ])
 740         AC_PATH_PROG([man_prog_path], [man], [no])
 741         AS_IF([test "x$man_prog_path" = "xno"], [
 742                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 743         ])
 744         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 745         AC_SUBST([MANPROG], [$man_prog_path])
 746 ])
 747 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 748
 749 # Python agent test
 750 UST_PYTHON_AGENT="lttngust"
 751
 752 AC_ARG_ENABLE(test-python2-agent,
 753         AS_HELP_STRING([--enable-test-python2-agent],
 754                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 755         ),[:],[test_python2_agent_autodetect=yes]
 756 )
 757
 758 AC_ARG_ENABLE(test-python3-agent,
 759         AS_HELP_STRING([--enable-test-python3-agent],
 760                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 761         ),[:],[test_python3_agent_autodetect=yes]
 762 )
 763
 764 AC_ARG_ENABLE(test-python-agent-all,
 765         AS_HELP_STRING([--enable-test-python-agent-all],
 766                 [enable test for all python{2/3} agent.]
 767         ),
 768 )
 769
 770 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 771        unset test_python2_agent_autodetect
 772        unset test_python3_agent_autodetect
 773 ])
 774
 775 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 776        enable_test_python2_agent=yes
 777        enable_test_python3_agent=yes
 778 ])
 779
 780 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 781        enable_test_python2_agent=no
 782        enable_test_python3_agent=no
 783 ])
 784
 785
 786 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 787         AS_IF([test -z "$PYTHON2"], [
 788                         PYTHON2=python2
 789                 ], [
 790                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 791         ])
 792
 793         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 794         AS_IF([test -z "$PYTHON2_BIN"], [
 795                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 796                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 797                 ])
 798         ], [
 799                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 800                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 801                         PYTHON2_AGENT=$PYTHON2_BIN
 802                         AC_MSG_RESULT([yes])
 803                         RUN_PYTHON_AGENT_TEST=yes
 804                 ], [
 805                         AC_MSG_RESULT([no])
 806                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 807                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 808                         ])
 809                 ])
 810
 811         ])
 812
 813 ])
 814
 815 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 816         AS_IF([test -z "$PYTHON3"], [
 817                 PYTHON3=python3
 818         ], [
 819                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 820         ])
 821
 822         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 823         AS_IF([test -z "$PYTHON3_BIN"], [
 824                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 825                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 826                 ])
 827         ], [
 828                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 829                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 830                         PYTHON3_AGENT=$PYTHON3_BIN
 831                         AC_MSG_RESULT([yes])
 832                         RUN_PYTHON_AGENT_TEST=yes
 833                 ], [
 834                         AC_MSG_RESULT([no])
 835                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 836                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 837                         ])
 838                 ])
 839
 840         ])
 841 ])
 842 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 843 AC_SUBST([PYTHON2_AGENT])
 844 AC_SUBST([PYTHON3_AGENT])
 845
 846 AC_ARG_ENABLE([test-sdt-uprobe],
 847   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 848   [test_sdt_uprobe="$enableval"],
 849   [test_sdt_uprobe=autodetect]
 850 )
 851
 852 AS_IF([test "$test_sdt_uprobe" != "no"], [
 853   LTTNG_CHECK_SDT_WORKS
 854   AC_PATH_PROG([DTRACE], [dtrace])
 855 ])
 856
 857 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 858   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 859     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 860   ])
 861   AS_IF([test "x$DTRACE" = "x"], [
 862     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 863   ])
 864 ])
 865
 866 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 867   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 868     AS_IF([test "x$DTRACE" != "x"], [
 869       test_sdt_uprobe=yes
 870     ])
 871   ])
 872 ])
 873
 874 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 875
 876 # Arguments for binaries build exclusion
 877 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 878 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 879               [Disable the build of lttng-consumerd binaries]))
 880 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 881 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 882               [Disable the build of lttng-relayd binaries]))
 883 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 884               [Disable the build of lttng-sessiond binaries]))
 885 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 886               [Disable the build of the extra components]))
 887
 888
 889 # Always build libconfig since it a dependency of libcommon
 890 build_lib_config=yes
 891
 892 build_lib_compat=no
 893 build_lib_consumer=no
 894 build_lib_hashtable=no
 895 build_lib_health=no
 896 build_lib_index=no
 897 build_lib_kernel_consumer=no
 898 build_lib_kernel_ctl=no
 899 build_lib_lttng_ctl=no
 900 build_lib_relayd=no
 901 build_lib_fd_tracker=no
 902 build_lib_sessiond_comm=no
 903 build_lib_testpoint=no
 904 build_lib_ust_consumer=no
 905
 906 # There is an overlap for enabled dependencies, but this makes everything
 907 # simpler. libcommon and libconfig are always compiled so they are not repeated
 908 # here.
 909
 910 # Enable binary dependencies.
 911 AS_IF([test x$enable_bin_lttng != xno],
 912       [
 913        build_lib_lttng_ctl=yes
 914       ]
 915 )
 916
 917 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 918       [
 919        build_lib_consumer=yes
 920        build_lib_sessiond_comm=yes
 921        build_lib_index=yes
 922        build_lib_health=yes
 923        build_lib_testpoint=yes
 924       ]
 925 )
 926
 927 AS_IF([test x$enable_bin_lttng_crash != xno],
 928       # Do nothing since libconfig and libcommon are built by default.
 929       []
 930 )
 931
 932 AS_IF([test x$enable_bin_lttng_relayd != xno],
 933       [
 934        build_lib_lttng_ctl=yes
 935        build_lib_sessiond_comm=yes
 936        build_lib_hashtable=yes
 937        build_lib_compat=yes
 938        build_lib_index=yes
 939        build_lib_health=yes
 940        build_lib_testpoint=yes
 941        build_lib_fd_tracker=yes
 942       ]
 943 )
 944 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 945       [
 946        build_lib_lttng_ctl=yes
 947        build_lib_sessiond_comm=yes
 948        build_lib_kernel_ctl=yes
 949        build_lib_hashtable=yes
 950        build_lib_compat=yes
 951        build_lib_relayd=yes
 952        build_lib_testpoint=yes
 953        build_lib_health=yes
 954       ]
 955 )
 956
 957 # Libraries dependencies enabling
 958 AS_IF([test x$build_lib_lttng_ctl = xyes],
 959       [
 960        build_lib_sessiond_comm=yes
 961        build_lib_hashtable=yes
 962       ]
 963 )
 964
 965 AS_IF([test x$build_lib_consumer = xyes],
 966       [
 967        build_lib_sessiond_comm=yes
 968        build_lib_kernel_consumer=yes
 969        build_lib_hashtable=yes
 970        build_lib_compat=yes
 971        build_lib_relayd=yes
 972        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 973       ]
 974 )
 975
 976 AS_IF([test x$build_lib_kernel_consumer = xyes],
 977       [
 978        build_lib_kernel_ctl=yes
 979        build_lib_relayd=yes
 980       ]
 981 )
 982
 983 AS_IF([test x$build_lib_relayd = xyes],
 984       [
 985        build_lib_sessiond_comm=yes
 986       ]
 987 )
 988
 989 # Find arch type
 990 AS_CASE([$host_cpu],
 991         [k1om], [ARCHTYPE="x86"],
 992         [i386], [ARCHTYPE="x86"],
 993         [i486], [ARCHTYPE="x86"],
 994         [i586], [ARCHTYPE="x86"],
 995         [i686], [ARCHTYPE="x86"],
 996         [amd64], [ARCHTYPE="x86"],
 997         [x86_64], [ARCHTYPE="x86"],
 998         [powerpc], [ARCHTYPE="ppc"],
 999         [ppc64], [ARCHTYPE="ppc"],
1000         [powerpc64], [ARCHTYPE="ppc"],
1001         [powerpc64le], [ARCHTYPE="ppc"],
1002         [ppc], [ARCHTYPE="ppc"],
1003         [s390], [ARCHTYPE="s390"],
1004         [s390x], [ARCHTYPE="s390"],
1005         [sparc], [ARCHTYPE="sparc64"],
1006         [sparc64], [ARCHTYPE="sparc64"],
1007         [alpha*], [ARCHTYPE="alpha"],
1008         [ia64], [ARCHTYPE="ia64"],
1009         [arm*], [ARCHTYPE="arm"],
1010         [aarch64*], [ARCHTYPE="aarch64"],
1011         [mips*], [ARCHTYPE="mips"],
1012         [nios2*], [ARCHTYPE="nios2"],
1013         [tile*], [ARCHTYPE="tile"],
1014         [hppa*], [ARCHTYPE="hppa"],
1015         [m68k], [ARCHTYPE="m68k"],
1016         [riscv*], [ARCHTYPE="riscv"],
1017         [ARCHTYPE="unknown"]
1018 )
1019
1020 AC_SUBST(ARCHTYPE)
1021
1022 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1023 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1024 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1025         # Userspace callstack capture is only supported by the Linux kernel on x86.
1026         AC_MSG_RESULT([yes])
1027         have_modules_userspace_callstack_context=yes
1028         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1029 ], [
1030         AC_MSG_RESULT([no])
1031         have_modules_userspace_callstack_context=no
1032 ])
1033 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1034
1035 # Export binaries build conditions.
1036 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1037 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1038 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1039 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1040 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1041
1042 # Export the tests and extras build conditions.
1043 AS_IF([\
1044 test "x$enable_bin_lttng" != "xno" && \
1045 test "x$enable_bin_lttng_consumerd" != "xno" && \
1046 test "x$enable_bin_lttng_crash" != "xno" && \
1047 test "x$enable_bin_lttng_relayd" != "xno" && \
1048 test "x$enable_bin_lttng_sessiond" != "xno"],
1049 [build_tests=yes],
1050 [build_tests=no]
1051 )
1052
1053 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1054 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1055
1056 # Export libraries build conditions.
1057 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1058 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1059 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1060 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1061 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1062 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1063 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1064 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1065 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1066 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1067 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1068 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1069 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1070 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1071
1072 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1073 AC_SUBST(AM_CFLAGS)
1074
1075 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1076 AM_LDFLAGS=""
1077 AC_SUBST(AM_LDFLAGS)
1078
1079 # The order in which the include folders are searched is important.
1080 # The top_builddir should always be searched first in the event that a build
1081 # time generated file is included. An example of this is the "version.i" file.
1082 # In a scenario where lttng-tools is built from a distribution tarball and in a
1083 # out-of-tree manner, the generated "version.i" has priority on the one from
1084 # the source (distribution tarball) and must be found first.
1085 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1086 AC_SUBST(AM_CPPFLAGS)
1087
1088 lttngincludedir="${includedir}/lttng"
1089 AC_SUBST(lttngincludedir)
1090
1091 lttngactionincludedir="${includedir}/lttng/action"
1092 AC_SUBST(lttngactionincludedir)
1093
1094 lttngconditionincludedir="${includedir}/lttng/condition"
1095 AC_SUBST(lttngconditionincludedir)
1096
1097 lttngnotificationincludedir="${includedir}/lttng/notification"
1098 AC_SUBST(lttngnotificationincludedir)
1099
1100 lttngtriggerincludedir="${includedir}/lttng/trigger"
1101 AC_SUBST(lttngtriggerincludedir)
1102
1103 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1104 AC_SUBST(lttngeventruleincludedir)
1105
1106 lttnglibexecdir="${libdir}/lttng/libexec"
1107 AC_SUBST(lttnglibexecdir)
1108
1109 AC_CONFIG_FILES([
1110         Makefile
1111         doc/Makefile
1112         doc/man/Makefile
1113         doc/man/asciidoc-attrs.conf
1114         include/Makefile
1115         extras/Makefile
1116         extras/bindings/Makefile
1117         extras/bindings/swig/Makefile
1118         extras/bindings/swig/python/Makefile
1119         extras/core-handler/Makefile
1120         src/Makefile
1121         src/common/Makefile
1122         src/common/kernel-ctl/Makefile
1123         src/common/kernel-consumer/Makefile
1124         src/common/consumer/Makefile
1125         src/common/ust-consumer/Makefile
1126         src/common/hashtable/Makefile
1127         src/common/sessiond-comm/Makefile
1128         src/common/compat/Makefile
1129         src/common/relayd/Makefile
1130         src/common/testpoint/Makefile
1131         src/common/index/Makefile
1132         src/common/health/Makefile
1133         src/common/config/Makefile
1134         src/common/string-utils/Makefile
1135         src/common/fd-tracker/Makefile
1136         src/common/filter/Makefile
1137         src/lib/Makefile
1138         src/lib/lttng-ctl/Makefile
1139         src/lib/lttng-ctl/lttng-ctl.pc
1140         src/bin/Makefile
1141         src/bin/lttng-consumerd/Makefile
1142         src/bin/lttng-sessiond/Makefile
1143         src/bin/lttng-relayd/Makefile
1144         src/bin/lttng/Makefile
1145         src/bin/lttng-crash/Makefile
1146         tests/Makefile
1147         tests/destructive/Makefile
1148         tests/regression/Makefile
1149         tests/regression/kernel/Makefile
1150         tests/regression/tools/Makefile
1151         tests/regression/tools/streaming/Makefile
1152         tests/regression/tools/filtering/Makefile
1153         tests/regression/tools/health/Makefile
1154         tests/regression/tools/tracefile-limits/Makefile
1155         tests/regression/tools/snapshots/Makefile
1156         tests/regression/tools/live/Makefile
1157         tests/regression/tools/exclusion/Makefile
1158         tests/regression/tools/save-load/Makefile
1159         tests/regression/tools/save-load/configuration/Makefile
1160         tests/regression/tools/mi/Makefile
1161         tests/regression/tools/wildcard/Makefile
1162         tests/regression/tools/crash/Makefile
1163         tests/regression/tools/regen-metadata/Makefile
1164         tests/regression/tools/regen-statedump/Makefile
1165         tests/regression/tools/notification/Makefile
1166         tests/regression/tools/rotation/Makefile
1167         tests/regression/tools/base-path/Makefile
1168         tests/regression/tools/metadata/Makefile
1169         tests/regression/tools/tracker/Makefile
1170         tests/regression/tools/working-directory/Makefile
1171         tests/regression/tools/relayd-grouping/Makefile
1172         tests/regression/tools/clear/Makefile
1173         tests/regression/ust/Makefile
1174         tests/regression/ust/nprocesses/Makefile
1175         tests/regression/ust/high-throughput/Makefile
1176         tests/regression/ust/low-throughput/Makefile
1177         tests/regression/ust/before-after/Makefile
1178         tests/regression/ust/buffers-pid/Makefile
1179         tests/regression/ust/periodical-metadata-flush/Makefile
1180         tests/regression/ust/multi-session/Makefile
1181         tests/regression/ust/multi-lib/Makefile
1182         tests/regression/ust/overlap/Makefile
1183         tests/regression/ust/overlap/demo/Makefile
1184         tests/regression/ust/linking/Makefile
1185         tests/regression/ust/daemon/Makefile
1186         tests/regression/ust/exit-fast/Makefile
1187         tests/regression/ust/fork/Makefile
1188         tests/regression/ust/libc-wrapper/Makefile
1189         tests/regression/ust/baddr-statedump/Makefile
1190         tests/regression/ust/ust-dl/Makefile
1191         tests/regression/ust/java-jul/Makefile
1192         tests/regression/ust/java-log4j/Makefile
1193         tests/regression/ust/python-logging/Makefile
1194         tests/regression/ust/getcpu-override/Makefile
1195         tests/regression/ust/clock-override/Makefile
1196         tests/regression/ust/type-declarations/Makefile
1197         tests/regression/ust/rotation-destroy-flush/Makefile
1198         tests/regression/ust/blocking/Makefile
1199         tests/regression/ust/namespaces/Makefile
1200         tests/stress/Makefile
1201         tests/unit/Makefile
1202         tests/unit/ini_config/Makefile
1203         tests/perf/Makefile
1204         tests/utils/Makefile
1205         tests/utils/tap/Makefile
1206         tests/utils/testapp/Makefile
1207         tests/utils/testapp/gen-ns-events/Makefile
1208         tests/utils/testapp/gen-kernel-test-events/Makefile
1209         tests/utils/testapp/gen-ust-events/Makefile
1210         tests/utils/testapp/gen-ust-events-ns/Makefile
1211         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1212         tests/utils/testapp/gen-ust-nevents/Makefile
1213         tests/utils/testapp/gen-ust-nevents-str/Makefile
1214         tests/utils/testapp/gen-syscall-events/Makefile
1215         tests/utils/testapp/gen-ust-tracef/Makefile
1216         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1217         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1218         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1219 ])
1220
1221 # Inject variable into python test script.
1222 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1223 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1224 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1225 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1226
1227 AC_OUTPUT
1228
1229 #
1230 # Mini-report on what will be built.
1231 #
1232
1233 PPRINT_INIT
1234 PPRINT_SET_INDENT(1)
1235 PPRINT_SET_TS(38)
1236
1237 AS_ECHO
1238 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1239 AS_ECHO
1240
1241 AS_IF([test -n "$report_fold"], [
1242         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1243 ], [
1244         AS_ECHO("$version_description")
1245 ])
1246
1247 AS_ECHO
1248 PPRINT_SUBTITLE([Features])
1249
1250 # Target architecture we're building for.
1251 target_arch=$host_cpu
1252 [
1253 for f in $CFLAGS; do
1254         if test $f = "-m32"; then
1255                         target_arch="32-bit"
1256         elif test $f = "-m64"; then
1257                         target_arch="64-bit"
1258         fi
1259 done
1260 ]
1261 PPRINT_PROP_STRING([Target architecture], $target_arch)
1262
1263 # kmod enabled/disabled
1264 test "x$with_kmod" != "xno" && value=1 || value=0
1265 PPRINT_PROP_BOOL([libkmod support], $value)
1266
1267 # LTTng-UST enabled/disabled
1268 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1269 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1270
1271 AS_ECHO
1272 PPRINT_SUBTITLE([Binaries])
1273
1274 # List binaries to be built
1275 test x$enable_bin_lttng != xno && value=1 || value=0
1276 PPRINT_PROP_BOOL([lttng], $value)
1277
1278 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1279 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1280
1281 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1282 PPRINT_PROP_BOOL([lttng-crash], $value)
1283
1284 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1285 PPRINT_PROP_BOOL([lttng-relayd], $value)
1286
1287 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1288 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1289
1290 # Extras
1291 test x$enable_extras != xno && value=1 || value=0
1292 AS_ECHO
1293 PPRINT_SET_INDENT(0)
1294 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1295 PPRINT_SET_INDENT(1)
1296
1297 AS_ECHO
1298 PPRINT_SUBTITLE([Tests])
1299
1300 # Print clear message that tests won't be built
1301 AS_IF([test "x$build_tests" = "xno"],[
1302         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1303 ])
1304
1305 # LTTng UST Java agent JUL tests enabled/disabled
1306 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1307 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1308
1309 # LTTng UST Java agent Log4j tests enabled/disabled
1310 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1311 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1312
1313 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1314 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1315
1316 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1317 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1318
1319 # LTTng UST Java agent Log4j tests enabled/disabled
1320 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1321 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1322
1323 #Python binding enabled/disabled
1324 test "x$enable_python_binding" = xyes && value=1 || value=0
1325 AS_ECHO
1326 PPRINT_SET_INDENT(0)
1327 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1328
1329 # man pages build enabled/disabled
1330 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1331
1332 AS_IF([test "x$man_pages_opt" != "xno"], [
1333         AS_IF([test "x$in_git_repo" = "xyes"], [
1334                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1335         ], [
1336                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1337                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1338                 ], [
1339                         PPRINT_PROP_STRING([build_man_pages_msg],
1340                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1341                                 $PPRINT_COLOR_SUBTITLE)
1342                 ])
1343         ])
1344 ], [
1345         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1346 ])
1347
1348 m4_popdef([build_man_pages_msg])
1349
1350 test "x$embedded_help" = xyes && value=1 || value=0
1351 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1352
1353 PPRINT_SET_INDENT(1)
1354
1355 report_bindir="`eval eval echo $bindir`"
1356 report_libdir="`eval eval echo $libdir`"
1357
1358 # Print the bindir and libdir this `make install' will install into.
1359 AS_ECHO
1360 PPRINT_SUBTITLE([Install directories])
1361 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1362 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1363
1364 AS_ECHO
1365 PPRINT_SUBTITLE([Search directories])
1366
1367 # If we build the sessiond, print the paths it will use
1368 AS_IF([test "$SESSIOND_BIN" = ""],[
1369         path="$report_bindir/lttng-sessiond"
1370 ],[
1371         path="$SESSIOND_BIN"
1372 ])
1373 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1374
1375 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1376         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1377 ],[
1378         path="$CONSUMERD32_BIN"
1379 ])
1380 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1381
1382 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1383         path="`eval eval echo $libdir`"
1384 ],[
1385         path="$CONSUMERD32_LIBDIR"
1386 ])
1387 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1388
1389 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1390         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1391 ],[
1392         path="$CONSUMERD64_BIN"
1393 ])
1394 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1395
1396 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1397         path="`eval eval echo $libdir`"
1398 ],[
1399         path="$CONSUMERD64_LIBDIR"
1400 ])
1401 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1402 PPRINT_SET_INDENT(0)
1403
1404 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1405         AS_ECHO
1406         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1407
1408 Note that the man pages are already built in this distribution tarball,
1409 therefore asciidoc and xmlto are only needed if you intend to modify
1410 their sources.
1411
1412 Also note that the installed man pages will contain the project's
1413 default command-line option and environment variable values.
1414
1415 Use --disable-man-pages to completely disable building and installing
1416 the man pages.])
1417 ])