configure.ac

   1 AC_INIT([lttng-tools],[2.4.0-rc2],[dgoulet@efficios.com],[],[http://lttng.org])
   2 AC_CONFIG_AUX_DIR([config])
   3 AC_CANONICAL_TARGET
   4 AC_CANONICAL_HOST
   5 AC_CONFIG_MACRO_DIR([config])
   6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 # Compute minor/major/patchlevel version numbers
  10 AC_PROG_SED
  11 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  12 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  13 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  14 AC_SUBST([MAJOR_VERSION], [$major_version])
  15 AC_SUBST([MINOR_VERSION], [$minor_version])
  16 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  17 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  18 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  19 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  20
  21 version_name="Époque Opaque"
  22 version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
  23
  24 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  25 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  26
  27 AC_CONFIG_HEADERS([include/config.h])
  28
  29 AC_PROG_GREP
  30 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  31 AC_ARG_ENABLE(libtool-linkdep-fixup,
  32         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  33                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  34         libtool_fixup=$enableval,
  35         libtool_fixup=yes)
  36
  37 AS_IF([test "x$libtool_fixup" = "xyes"],
  38             [
  39             libtool_m4="$srcdir/config/libtool.m4"
  40             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  41             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  42             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  43             AS_IF([test $libtool_flag_pattern_count -ne 0],
  44             [
  45                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  46                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  47                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  48                   ],
  49                   [
  50                   AC_MSG_RESULT([none])
  51                   ])
  52             ])
  53
  54 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  55
  56 AC_CHECK_HEADERS([ \
  57         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  58         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  59         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  60 ])
  61
  62 # Babeltrace viewer check
  63 AC_ARG_WITH([babeltrace-bin],
  64         AS_HELP_STRING([--with-babeltrace-bin],
  65         [Location of the babeltrace viewer executable (including the filename)]),
  66         [BABELTRACE_BIN="$withval"],
  67         [BABELTRACE_BIN=''])
  68 AC_SUBST([BABELTRACE_BIN])
  69
  70 # lttv-gui
  71 AC_ARG_WITH([lttv-gui-bin],
  72         AS_HELP_STRING([--with-lttv-gui-bin],
  73    [Location of the lttv GUI viewer executable (including the filename)]),
  74    [LTTV_GUI_BIN="$withval"],
  75    [LTTV_GUI_BIN=''])
  76 AC_SUBST([LTTV_GUI_BIN])
  77
  78 AC_ARG_WITH([consumerd32-bin],
  79         AS_HELP_STRING([--with-consumerd32-bin],
  80         [Location of the 32-bit consumerd executable (including the filename)]),
  81         [CONSUMERD32_BIN="$withval"],
  82         [CONSUMERD32_BIN=''])
  83 AC_SUBST([CONSUMERD32_BIN])
  84
  85 AC_ARG_WITH([consumerd64-bin],
  86         AS_HELP_STRING([--with-consumerd64-bin],
  87         [Location of the 64-bit consumerd executable (including the filename)]),
  88         [CONSUMERD64_BIN="$withval"],
  89         [CONSUMERD64_BIN=''])
  90 AC_SUBST([CONSUMERD64_BIN])
  91
  92 AC_ARG_WITH([consumerd32-libdir],
  93         AS_HELP_STRING([--with-consumerd32-libdir],
  94         [Directory containing the 32-bit consumerd libraries]),
  95         [CONSUMERD32_LIBDIR="$withval"],
  96         [CONSUMERD32_LIBDIR=''])
  97 AC_SUBST([CONSUMERD32_LIBDIR])
  98
  99 AC_ARG_WITH([consumerd64-libdir],
 100         AS_HELP_STRING([--with-consumerd64-libdir],
 101         [Directory containing the 64-bit consumerd libraries]),
 102         [CONSUMERD64_LIBDIR="$withval"],
 103         [CONSUMERD64_LIBDIR=''])
 104 AC_SUBST([CONSUMERD64_LIBDIR])
 105
 106 AC_ARG_WITH([sessiond-bin],
 107         AS_HELP_STRING([--with-sessiond-bin],
 108         [Location of the sessiond executable (including the filename)]),
 109         [SESSIOND_BIN="$withval"],
 110         [SESSIOND_BIN=''])
 111 AC_SUBST([SESSIOND_BIN])
 112
 113 AC_ARG_WITH([lttng-system-rundir],
 114         AS_HELP_STRING([--with-lttng-system-rundir],
 115         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 116         [LTTNG_SYSTEM_RUNDIR="$withval"],
 117         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 118 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 119
 120 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 121 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 124 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 125 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 126 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 127 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 128
 129 if test "x$prefix" = "xNONE"; then
 130         prefix=$ac_default_prefix
 131 fi
 132 CONFDIR=`eval echo $sysconfdir`
 133 AC_SUBST(CONFDIR)
 134 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 135
 136 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 137
 138 #
 139 # Check for pthread
 140 AC_CHECK_LIB([pthread], [pthread_create], [],
 141         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 142 )
 143
 144 # Check libpopt
 145 AC_CHECK_LIB([popt], [poptGetContext], [],
 146         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 147 )
 148
 149 AM_PATH_XML2(2.7.6, 1, AC_MSG_ERROR(No supported version of libxml2 found.))
 150
 151 # Check for libuuid
 152 AC_CHECK_LIB([uuid], [uuid_generate],
 153 [
 154         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 155         have_libuuid=yes
 156 ],
 157 [
 158         # libuuid not found, check for uuid_create in libc.
 159         AC_CHECK_LIB([c], [uuid_create],
 160         [
 161                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 162                 have_libc_uuid=yes
 163         ],
 164         [
 165                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 166         ])
 167 ]
 168 )
 169 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 170 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 171
 172 # URCU library version needed or newer
 173 liburcu_version=">= 0.7.2"
 174
 175 # Check liburcu needed function calls
 176 AC_CHECK_DECL([cds_list_add], [],
 177         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 178 )
 179 AC_CHECK_DECL([cds_wfq_init], [],
 180         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 181 )
 182 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
 183     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 184 )
 185 AC_CHECK_DECL([futex_async], [],
 186         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 187 )
 188 AC_CHECK_DECL([rcu_thread_offline], [],
 189         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 190 )
 191 AC_CHECK_DECL([rcu_thread_online], [],
 192         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 193 )
 194 AC_CHECK_DECL([caa_likely], [],
 195         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 196 )
 197 #Function added in urcu 0.7.0
 198 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 199         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 200 )
 201
 202 AC_ARG_WITH(lttng-ust-prefix,
 203   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 204                  [Specify the installation prefix of the lttng-ust library.
 205                   Headers must be in PATH/include; libraries in PATH/lib.]),
 206                   [
 207                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 208                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 209                   ])
 210
 211 # Check liblttng-ust-ctl library
 212 AC_ARG_ENABLE(lttng-ust,
 213         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 214         lttng_ust_support=$enableval, lttng_ust_support=yes)
 215
 216 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 217         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 218                 [
 219                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 220                         lttng_ust_ctl_found=yes
 221                 ],
 222                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 223                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 224         )
 225 ])
 226 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 227 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 228
 229 # check for dlopen
 230 AC_CHECK_LIB([dl], [dlopen],
 231 [
 232         have_libdl=yes
 233 ],
 234 [
 235         #libdl not found, check for dlopen in libc.
 236         AC_CHECK_LIB([c], [dlopen],
 237         [
 238                 have_libc_dl=yes
 239         ],
 240         [
 241                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 242         ])
 243 ])
 244 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 245 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 246
 247 # Check for fmemopen
 248 AC_CHECK_LIB([c], [fmemopen],
 249 [
 250         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 251 ]
 252 )
 253
 254 # Check for open_memstream
 255 AC_CHECK_LIB([c], [open_memstream],
 256 [
 257         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 258 ]
 259 )
 260
 261 # For Python
 262 # SWIG version needed or newer:
 263 swig_version=2.0.0
 264
 265 AC_ARG_ENABLE([python-bindings],
 266               [AC_HELP_STRING([--enable-python-bindings],
 267                               [compile Python bindings])],
 268               [enable_python=yes], [enable_python=no])
 269
 270 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 271
 272 if test "x${enable_python:-yes}" = xyes; then
 273   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 274   AM_PATH_PYTHON
 275
 276   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 277   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 278   AS_IF([test -z "$PYTHON_INCLUDE"], [
 279     AS_IF([test -z "$PYTHON_CONFIG"], [
 280       AC_PATH_PROGS([PYTHON_CONFIG],
 281                     [python$PYTHON_VERSION-config python-config],
 282                     [no],
 283                     [`dirname $PYTHON`])
 284       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 285     ])
 286     AC_MSG_CHECKING([python include flags])
 287     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 288     AC_MSG_RESULT([$PYTHON_INCLUDE])
 289   ])
 290
 291 else
 292     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 293 [if you want Python bindings.])
 294
 295 fi
 296
 297 # Option to only build the consumer daemon and its libraries
 298 AC_ARG_WITH([consumerd-only],
 299         AS_HELP_STRING([--with-consumerd-only],[Only build the consumer daemon [default=no]]),
 300         [consumerd_only=$withval],
 301         [consumerd_only=no])
 302 AM_CONDITIONAL([BUILD_CONSUMERD_ONLY], [test "x$consumerd_only" = "xyes"])
 303
 304 # Epoll check. If not present, the build will fallback on poll() API
 305 AX_HAVE_EPOLL(
 306         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 307         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 308 )
 309 AX_CONFIG_FEATURE(
 310         [epoll], [This platform supports epoll(7)],
 311         [HAVE_EPOLL], [This platform supports epoll(7).],
 312         [enable_epoll="yes"], [enable_epoll="no"]
 313 )
 314 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 315
 316 # Set compile flags to java include files if given. This is only used to
 317 # compile JUL tests.
 318 AC_ARG_WITH([java-jdk],
 319         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 320         [JAVA_JDK=$withval],
 321         [JAVA_JDK=""]
 322 )
 323 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 324 AC_SUBST([JAVA_JDK])
 325
 326 AS_IF([test $JAVA_JDK],[
 327         AS_IF([test -d $JAVA_JDK],
 328                 [
 329                         AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 330                         SUBDIRS=`find $JAVA_JDK/include -type d`
 331                         CPPFLAGS+=" "
 332                         CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 333                         CPPFLAGS+=" "
 334         ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
 335         )
 336 ])
 337
 338 # Check for the UST JUL jar file in the system. Hardcoded path is added here
 339 # since we have *no* idea where this could be installed. Note that this is only
 340 # used for JUL testing.
 341 AC_MSG_CHECKING(Java JUL UST jar file)
 342 java_jul_jar_path="/usr/local/lib/lttng/java/liblttng-ust-jul.jar"
 343 if test -f $java_jul_jar_path; then
 344         build_java_jul=yes
 345         AC_MSG_RESULT(found)
 346 else
 347         build_java_jul=no
 348         AC_MSG_RESULT(not found)
 349 fi
 350 AM_CONDITIONAL([BUILD_JAVA_JUL], [test "x$build_java_jul" = "xyes"])
 351 AC_SUBST([java_jul_jar_path])
 352
 353 AC_SYS_LARGEFILE
 354 AC_PROG_CC
 355 LT_INIT
 356 AC_PROG_YACC
 357 AC_PROG_LEX
 358
 359 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 360         if test x"$YACC" != "xbison -y"; then
 361                 AC_MSG_ERROR([[bison not found and is required when building from git.
 362                 Please install bison]])
 363         fi
 364 fi
 365
 366 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 367         if test x"$LEX" != "xflex"; then
 368                 AC_MSG_ERROR([[flex not found and is required when building from git.
 369                 Please install flex]])
 370         fi
 371 fi
 372
 373 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 374
 375 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 376
 377 lttngincludedir="${includedir}/lttng"
 378
 379 AC_SUBST(lttngincludedir)
 380 AC_SUBST(DEFAULT_INCLUDES)
 381
 382 lttnglibexecdir="${libdir}/lttng/libexec"
 383 AC_SUBST(lttnglibexecdir)
 384
 385 AC_CONFIG_FILES([
 386         Makefile
 387         doc/Makefile
 388         doc/man/Makefile
 389         include/Makefile
 390         extras/Makefile
 391         extras/bindings/Makefile
 392         extras/bindings/swig/Makefile
 393         extras/bindings/swig/python/Makefile
 394         extras/core-handler/Makefile
 395         src/Makefile
 396         src/common/Makefile
 397         src/common/kernel-ctl/Makefile
 398         src/common/kernel-consumer/Makefile
 399         src/common/ust-consumer/Makefile
 400         src/common/hashtable/Makefile
 401         src/common/sessiond-comm/Makefile
 402         src/common/compat/Makefile
 403         src/common/relayd/Makefile
 404         src/common/testpoint/Makefile
 405         src/common/index/Makefile
 406         src/common/health/Makefile
 407         src/common/config/Makefile
 408         src/lib/Makefile
 409         src/lib/lttng-ctl/Makefile
 410         src/lib/lttng-ctl/filter/Makefile
 411         src/lib/lttng-ctl/lttng-ctl.pc
 412         src/bin/Makefile
 413         src/bin/lttng-consumerd/Makefile
 414         src/bin/lttng-sessiond/Makefile
 415         src/bin/lttng-relayd/Makefile
 416         src/bin/lttng/Makefile
 417         tests/Makefile
 418         tests/regression/Makefile
 419         tests/regression/kernel/Makefile
 420         tests/regression/tools/Makefile
 421         tests/regression/tools/streaming/Makefile
 422         tests/regression/tools/filtering/Makefile
 423         tests/regression/tools/health/Makefile
 424         tests/regression/tools/tracefile-limits/Makefile
 425         tests/regression/tools/snapshots/Makefile
 426         tests/regression/tools/live/Makefile
 427         tests/regression/tools/exclusion/Makefile
 428         tests/regression/ust/Makefile
 429         tests/regression/ust/nprocesses/Makefile
 430         tests/regression/ust/high-throughput/Makefile
 431         tests/regression/ust/low-throughput/Makefile
 432         tests/regression/ust/before-after/Makefile
 433         tests/regression/ust/buffers-pid/Makefile
 434         tests/regression/ust/periodical-metadata-flush/Makefile
 435         tests/regression/ust/multi-session/Makefile
 436         tests/regression/ust/overlap/Makefile
 437         tests/regression/ust/overlap/demo/Makefile
 438         tests/regression/ust/linking/Makefile
 439         tests/regression/ust/daemon/Makefile
 440         tests/regression/ust/exit-fast/Makefile
 441         tests/regression/ust/fork/Makefile
 442         tests/regression/ust/libc-wrapper/Makefile
 443         tests/regression/ust/java-jul/Makefile
 444         tests/stress/Makefile
 445         tests/unit/Makefile
 446         tests/unit/ini_config/Makefile
 447         tests/utils/Makefile
 448         tests/utils/tap/Makefile
 449         tests/utils/testapp/Makefile
 450         tests/utils/testapp/gen-ust-events/Makefile
 451         tests/utils/testapp/gen-ust-nevents/Makefile
 452 ])
 453
 454 AC_OUTPUT
 455
 456 #
 457 # Mini-report on what will be built
 458 #
 459 AS_ECHO()
 460
 461 AS_ECHO("Version name: $version_name")
 462 AS_ECHO("$version_description")
 463
 464 AS_ECHO()
 465
 466 # Target architecture we're building for
 467 target_arch=$host_cpu
 468 [
 469 for f in $CFLAGS; do
 470         if test $f = "-m32"; then
 471                         target_arch="32-bit"
 472         elif test $f = "-m64"; then
 473                         target_arch="64-bit"
 474         fi
 475 done
 476 ]
 477 AS_ECHO_N("Target architecture: ")
 478 AS_ECHO($target_arch)
 479
 480 # LTTng-UST enabled/disabled
 481 AS_ECHO_N("Lttng-UST support: ")
 482 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 483         AS_ECHO("Enabled")
 484 ],[
 485         AS_ECHO("Disabled")
 486 ])
 487
 488 #Python binding enabled/disabled
 489 AS_ECHO_N("Python binding: ")
 490 AS_IF([test "x${enable_python:-yes}" = xyes], [
 491         AS_ECHO("Enabled")
 492 ],[
 493         AS_ECHO("Disabled")
 494 ])
 495
 496 # Do we build only the consumerd, or everything
 497 AS_IF([test "x$consumerd_only" = "xyes"],[
 498         AS_ECHO("Only the consumerd daemon will be built.")
 499 ],[
 500         AS_ECHO("All binaries will be built.")
 501 ])
 502
 503 # Print the bindir and libdir this `make install' will install into.
 504 AS_ECHO()
 505 AS_ECHO_N("Binaries will be installed in:  ")
 506 AS_ECHO("`eval eval echo $bindir`")
 507 AS_ECHO_N("Libraries will be installed in: ")
 508 AS_ECHO("`eval eval echo $libdir`")
 509
 510 # If we build the sessiond, print the paths it will use
 511 AS_IF([test "x$consumerd_only" = "xno"],[
 512         AS_ECHO()
 513         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 514         AS_IF([test "$SESSIOND_BIN" = ""],[
 515                 AS_ECHO_N("`eval eval echo $bindir`")
 516                 AS_ECHO("/lttng-sessiond")
 517         ],[
 518                 AS_ECHO("$SESSIOND_BIN")
 519         ])
 520
 521         AS_ECHO()
 522         AS_ECHO("The sessiond daemon will look in the following directories: ")
 523         AS_ECHO_N("32-bit consumerd executable at: ")
 524         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 525                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 526                 AS_ECHO("/lttng-consumerd")
 527         ],[
 528                 AS_ECHO("$CONSUMERD32_BIN")
 529         ])
 530
 531         AS_ECHO_N("32-bit consumer libraries in:   ")
 532         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 533                 AS_ECHO("`eval eval echo $libdir`")
 534         ],[
 535                 AS_ECHO("$CONSUMERD32_LIBDIR")
 536         ])
 537
 538         AS_ECHO_N("64-bit consumerd executable at: ")
 539         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 540                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 541                 AS_ECHO("/lttng-consumerd")
 542         ],[
 543                 AS_ECHO("$CONSUMERD64_BIN")
 544         ])
 545
 546         AS_ECHO_N("64-bit consumer libraries in:   ")
 547         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 548                 AS_ECHO("`eval eval echo $libdir`")
 549         ],[
 550                 AS_ECHO("$CONSUMERD64_LIBDIR")
 551         ])
 552 ])
 553
 554 AS_ECHO()
 555