configure: use AX_APPEND_COMPILE_FLAGS to detect supported warning flags
[lttng-tools.git] / configure.ac
1 dnl SPDX-License-Identifier: GPL-2.0-only
2 AC_PREREQ([2.64])
3 AC_INIT([lttng-tools],[2.12.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
4
5 AC_CONFIG_HEADERS([include/config.h])
6 AC_CONFIG_AUX_DIR([config])
7 AC_CONFIG_MACRO_DIR([m4])
8
9 AC_CANONICAL_TARGET
10 AC_CANONICAL_HOST
11
12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
13 AM_MAINTAINER_MODE([enable])
14
15 # Enable silent rules if available (Introduced in AM 1.11)
16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
19
20 # Checks for C compiler
21 AC_USE_SYSTEM_EXTENSIONS
22 AC_SYS_LARGEFILE
23 AC_PROG_CC
24 AC_PROG_CC_STDC
25 AC_PROG_CXX
26 RW_PROG_CXX_WORKS
27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
28
29 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
30 #
31 # Pass -Werror as an extra flag during the test: this is needed to make the
32 # -Wunknown-warning-option diagnostic fatal with clang.
33 AX_APPEND_COMPILE_FLAGS([ dnl
34 -Wall dnl
35 ],
36 [WARN_CFLAGS],
37 [-Werror])
38
39 # Checks for programs.
40 AC_PROG_GREP
41 AC_PROG_MAKE_SET
42 AC_PROG_SED
43 AC_PATH_PROG([report_fold], [fold])
44 LT_INIT
45
46 # Check for objcopy, required by the base address statedump and dynamic linker tests
47 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
48 AS_IF([test "x$OBJCOPY" = "xno"],
49 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
50 )
51 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
52
53 # check for pgrep
54 AC_PATH_PROG([PGREP], [pgrep], [no])
55 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
56
57 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
58 # is not distributed in tarballs
59 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
60 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
61
62 # check for bison
63 AC_PROG_YACC
64 BISON=$YACC
65 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
66
67 AS_IF([test "x$have_bison" != "xyes"], [
68 AS_IF([test "x$in_git_repo" = "xyes"], [
69 AC_MSG_FAILURE([
70 Bison >= 2.4 is required when building from the Git repository. You can
71 set the YACC variable to override automatic detection.
72 ])
73 ], [
74 AC_MSG_WARN([
75 Missing Bison >= 2.4. Note that the parser files are already built in
76 this distribution tarball, so Bison is only needed if you intend to
77 modify their sources. You can set the YACC variable to override automatic
78 detection.
79 ])
80 ])
81 ])
82 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
83
84 # check for flex
85 AC_PROG_LEX
86 FLEX=$LEX
87 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
88
89 AS_IF([test "x$have_flex" != "xyes"], [
90 AS_IF([test "x$in_git_repo" = "xyes"], [
91 AC_MSG_FAILURE([
92 Flex >= 2.5.35 is required when building from the Git repository. You can
93 set the LEX variable to override automatic detection.
94 ])
95 ], [
96 AC_MSG_WARN([
97 Missing Flex >= 2.5.35. Note that the lexer files are already built in
98 this distribution tarball, so Flex is only needed if you intend to
99 modify their sources. You can set the LEX variable to override automatic
100 detection.
101 ])
102 ])
103 ])
104 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
105
106
107 # Checks for typedefs, structures, and compiler characteristics.
108 AC_C_INLINE
109 AC_TYPE_INT32_T
110 AC_TYPE_INT64_T
111 AC_TYPE_MODE_T
112 AC_TYPE_OFF_T
113 AC_TYPE_PID_T
114 AC_TYPE_SIZE_T
115 AC_TYPE_SSIZE_T
116 AC_TYPE_UID_T
117 AC_TYPE_UINT16_T
118 AC_TYPE_UINT32_T
119 AC_TYPE_UINT64_T
120 AC_TYPE_UINT8_T
121
122 AX_C___ATTRIBUTE__
123 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
124 [:],
125 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
126
127 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
128
129 # Check if linker has the -no-pie option.
130 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
131 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
132
133 AX_LIB_SOCKET_NSL
134
135 LT_NO_UNDEFINED=""
136 AS_CASE([$host_os],
137 [cygwin*],
138 [
139 LT_NO_UNDEFINED="-no-undefined"
140 ],
141 [cygwin*|darwin*|mingw*|solaris*],
142 [
143 # On platforms where we only support the relayd, disable the other binaries by default
144 AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
145 AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
146 AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
147 AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
148 AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
149 AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
150 ]
151 )
152
153 AC_SUBST(LT_NO_UNDEFINED)
154
155 # Compute minor/major/patchlevel version numbers
156 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
157 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
158 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
159
160 AC_SUBST([MAJOR_VERSION], [$major_version])
161 AC_SUBST([MINOR_VERSION], [$minor_version])
162 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
163 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
164 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
165 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
166
167 version_name="(Ta) Meilleure"
168 version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness."
169 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
170
171 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
172 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
173
174 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
175 AC_ARG_ENABLE(libtool-linkdep-fixup,
176 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
177 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
178 libtool_fixup=$enableval,
179 libtool_fixup=yes)
180
181 AS_IF([test "x$libtool_fixup" = "xyes"],
182 [
183 libtool_m4="$srcdir/m4/libtool.m4"
184 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
185 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
186 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
187 AS_IF([test $libtool_flag_pattern_count -ne 0],
188 [
189 AC_MSG_RESULT([$libtool_flag_pattern_count])
190 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
191 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
192 ],
193 [
194 AC_MSG_RESULT([none])
195 ])
196 ])
197
198 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
199
200 AC_CHECK_HEADERS([ \
201 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
202 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
203 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
204 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
205 sys/mount.h sys/param.h sys/time.h elf.h
206 ])
207
208 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
209
210 # Basic functions check
211 AC_CHECK_FUNCS([ \
212 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
213 gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
214 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
215 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
216 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
217 sched_getcpu sysconf sync_file_range
218 ])
219
220 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
221 # add -lrt to LIBS
222 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
223
224 # Checks for dl.
225 AC_CHECK_LIB([dl], [dlopen], [
226 have_libdl=yes
227 libdl_name=dl
228 DL_LIBS="-ldl"
229 ], [
230 # libdl not found, check for dlopen in libc.
231 AC_CHECK_LIB([c], [dlopen], [
232 have_libc_dl=yes
233 libdl_name=c
234 DL_LIBS="-lc"
235 ], [
236 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
237 ])
238 ])
239 AC_SUBST(DL_LIBS)
240
241 # Check if libdl has dlmopen support.
242 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
243 AC_CHECK_LIB([$libdl_name], [dlmopen], [
244 AC_DEFINE([HAVE_DLMOPEN], [1])
245 HAVE_DLMOPEN=1
246 ], [
247 HAVE_DLMOPEN=0
248 ])
249 AC_SUBST(HAVE_DLMOPEN)
250
251 # Babeltrace viewer check
252 AC_ARG_WITH([babeltrace-bin],
253 AS_HELP_STRING([--with-babeltrace-bin],
254 [Location of the babeltrace viewer executable (including the filename)]),
255 [BABELTRACE_BIN="$withval"],
256 [BABELTRACE_BIN=''])
257 AC_SUBST([BABELTRACE_BIN])
258
259 AC_ARG_WITH([babeltrace2-bin],
260 AS_HELP_STRING([--with-babeltrace2-bin],
261 [Location of the babeltrace2 viewer executable (including the filename)]),
262 [BABELTRACE2_BIN="$withval"],
263 [BABELTRACE2_BIN=''])
264 AC_SUBST([BABELTRACE2_BIN])
265
266 AC_ARG_WITH([consumerd32-bin],
267 AS_HELP_STRING([--with-consumerd32-bin],
268 [Location of the 32-bit consumerd executable (including the filename)]),
269 [CONSUMERD32_BIN="$withval"],
270 [CONSUMERD32_BIN=''])
271 AC_SUBST([CONSUMERD32_BIN])
272
273 AC_ARG_WITH([consumerd64-bin],
274 AS_HELP_STRING([--with-consumerd64-bin],
275 [Location of the 64-bit consumerd executable (including the filename)]),
276 [CONSUMERD64_BIN="$withval"],
277 [CONSUMERD64_BIN=''])
278 AC_SUBST([CONSUMERD64_BIN])
279
280 AC_ARG_WITH([consumerd32-libdir],
281 AS_HELP_STRING([--with-consumerd32-libdir],
282 [Directory containing the 32-bit consumerd libraries]),
283 [CONSUMERD32_LIBDIR="$withval"],
284 [CONSUMERD32_LIBDIR=''])
285 AC_SUBST([CONSUMERD32_LIBDIR])
286
287 AC_ARG_WITH([consumerd64-libdir],
288 AS_HELP_STRING([--with-consumerd64-libdir],
289 [Directory containing the 64-bit consumerd libraries]),
290 [CONSUMERD64_LIBDIR="$withval"],
291 [CONSUMERD64_LIBDIR=''])
292 AC_SUBST([CONSUMERD64_LIBDIR])
293
294 AC_ARG_WITH([sessiond-bin],
295 AS_HELP_STRING([--with-sessiond-bin],
296 [Location of the sessiond executable (including the filename)]),
297 [SESSIOND_BIN="$withval"],
298 [SESSIOND_BIN=''])
299 AC_SUBST([SESSIOND_BIN])
300
301 AC_ARG_WITH([lttng-system-rundir],
302 AS_HELP_STRING([--with-lttng-system-rundir],
303 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
304 [LTTNG_SYSTEM_RUNDIR="$withval"],
305 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
306 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
307
308 AC_ARG_ENABLE([test-java-agent-jul],
309 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
310 [test_java_agent_jul=$enableval],
311 [test_java_agent_jul=no]
312 )
313
314 AC_ARG_ENABLE([test-java-agent-log4j],
315 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
316 [test_java_agent_log4j=$enableval],
317 [test_java_agent_log4j=no]
318 )
319
320 AC_ARG_ENABLE([test-java-agent-all],
321 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
322 [test_java_agent_jul=$enableval
323 test_java_agent_log4j=$enableval],
324 [:]
325 )
326
327 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
328 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
329 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
330 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
331 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
332 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
333 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
334 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
335
336 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
337 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
338 $1="$2"
339 AC_SUBST([$1])
340 ])
341
342 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
343 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
344 $1="$2"
345 AC_SUBST([$1])
346 ])
347
348 # Default values
349 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
350 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
351 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
352 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
353 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
354 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
355 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
356 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
357 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
358 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
359 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
360 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
361 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
362 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
363 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
364 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
365 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
366 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
367 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
368 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
369 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
370 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
371 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
372 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
373 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
374 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
375 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
376 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
377 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
382 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
383 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
384 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
385 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
386 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
387 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
388 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
389 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
390 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
391 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
392 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
393 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
394 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
395 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
396 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
397 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
398
399 # Command short descriptions
400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
417 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
418 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
419 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
420 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
421 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
422 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
423 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
424 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
425 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
426 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
427
428 if test "x$prefix" = "xNONE"; then
429 prefix=$ac_default_prefix
430 fi
431 CONFDIR=`eval echo $sysconfdir`
432 AC_SUBST(CONFDIR)
433 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
434
435 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
436
437 # Check libpopt
438 PKG_CHECK_MODULES([POPT], [popt],
439 [
440 dnl PKG_CHECK_MODULES defines POPT_LIBS
441 ],
442 [
443 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
444 AC_MSG_WARN([Finding libpopt without pkg-config.])
445 AC_CHECK_LIB([popt],
446 [poptGetContext],
447 [POPT_LIBS="-lpopt"],
448 [
449 AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
450 ]
451 )
452 ]
453 )
454 AC_SUBST(POPT_LIBS)
455
456 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
457
458 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
459
460 # URCU library version needed or newer
461 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
462
463 # Check liburcu needed function calls
464 AC_CHECK_DECL([cds_list_add], [],
465 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
466 AC_CHECK_DECL([cds_wfcq_init], [],
467 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
468 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
469 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
470 AC_CHECK_DECL([futex_async], [],
471 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
472 AC_CHECK_DECL([rcu_thread_offline], [],
473 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
474 AC_CHECK_DECL([rcu_thread_online], [],
475 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
476 AC_CHECK_DECL([caa_likely], [],
477 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
478 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
479 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
480
481 #Function added in urcu 0.7.0
482 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
483 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
484 )
485
486 #Function added in urcu 0.9.0
487 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
488 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
489 )
490
491 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
492 # it can be explicitly disabled with --without-kmod
493 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
494 AC_ARG_WITH([kmod],
495 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
496 [],
497 [with_kmod=check]
498 )
499
500 AS_IF([test "x$with_kmod" != "xno"],
501 [
502 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
503 [
504 AC_DEFINE([HAVE_KMOD], [1])
505 KMOD_LIBS="-lkmod"
506 ],
507 [
508 if test "x$with_kmod" != xcheck; then
509 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
510 else
511 with_kmod=no
512 fi
513 ]
514 )
515 ]
516 )
517 AC_SUBST(KMOD_LIBS)
518
519 # Check for liblttng-ust-ctl, fail if it's not found,
520 # it can be explicitly disabled with --without-lttng-ust
521 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
522 AC_ARG_WITH([lttng-ust],
523 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
524 [],
525 [with_lttng_ust=yes]
526 )
527
528 AS_IF([test "x$with_lttng_ust" = "xyes"], [
529 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
530
531 # Check for liblttng-ust
532 PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
533
534 # Check for liblttng-ust-ctl
535 PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
536
537 AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
538 ])
539
540 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
541
542
543 # Check for fmemopen
544 AC_CHECK_LIB([c], [fmemopen],
545 [
546 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
547 ]
548 )
549
550 # check for libpfm
551 AC_CHECK_LIB([pfm], [pfm_initialize],
552 [
553 have_libpfm=yes
554 ])
555 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
556
557 # For Python
558 # SWIG version needed or newer:
559 swig_version=2.0.0
560
561 AC_ARG_ENABLE([python-bindings],
562 [AC_HELP_STRING([--enable-python-bindings],
563 [compile Python bindings])],
564 [enable_python_binding=$enableval], [enable_python_binding=no])
565
566 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
567
568 if test "x$enable_python_binding" = xyes; then
569 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
570 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
571 AM_PATH_PYTHON([3.0])
572
573 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
574 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
575 AS_IF([test -z "$PYTHON_INCLUDE"], [
576 AS_IF([test -z "$PYTHON_CONFIG"], [
577 AC_PATH_PROGS([PYTHON_CONFIG],
578 [python$PYTHON_VERSION-config python-config],
579 [no],
580 [`dirname $PYTHON`])
581 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
582 ])
583 AC_MSG_CHECKING([python include flags])
584 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
585 AC_MSG_RESULT([$PYTHON_INCLUDE])
586 ])
587
588 else
589 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
590 [if you want Python bindings.])
591
592 fi
593
594 # Epoll check. If not present, the build will fallback on poll() API
595 AX_HAVE_EPOLL(
596 [AX_CONFIG_FEATURE_ENABLE(epoll)],
597 [AX_CONFIG_FEATURE_DISABLE(epoll)]
598 )
599 AX_CONFIG_FEATURE(
600 [epoll], [This platform supports epoll(7)],
601 [HAVE_EPOLL], [This platform supports epoll(7).],
602 [enable_epoll="yes"], [enable_epoll="no"]
603 )
604 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
605
606 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
607 [AX_CONFIG_FEATURE_ENABLE(dirfd)],
608 [AX_CONFIG_FEATURE_DISABLE(dirfd)]
609 )
610 AX_CONFIG_FEATURE(
611 [dirfd], [Use directory file descriptors],
612 [COMPAT_DIRFD], [This platform supports directory file descriptors.],
613 [enable_dirfd="yes"], [enable_dirfd="no"]
614 )
615 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
616
617 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
618 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
619
620 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
621 AX_JAVA_OPTIONS
622 AX_PROG_JAVAC
623 AX_PROG_JAVA
624 AX_PROG_JAR
625
626 AX_CHECK_CLASSPATH
627
628 # Check for Java UST agent common class first
629 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
630 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
631 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
632 fi
633
634 if test "x$test_java_agent_jul" = "xyes"; then
635 # Check for JUL agent class
636 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
637 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
638 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
639 fi
640 fi
641
642 if test "x$test_java_agent_log4j" = "xyes"; then
643 # Check for Log4j agent class
644 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
645 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
646 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
647 fi
648
649 # Check for Log4j class
650 AX_CHECK_CLASS(org.apache.log4j.Logger)
651 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
652 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
653 fi
654 fi
655 fi
656
657 # enable building man pages (user's intention)
658 AC_ARG_ENABLE(
659 man-pages,
660 AS_HELP_STRING(
661 [--disable-man-pages],
662 [Do not build and install man pages (already built in a distributed tarball)]
663 ),
664 [man_pages_opt=$enableval],
665 [man_pages_opt=yes]
666 )
667
668 # check for asciidoc and xmlto if we enabled building the man pages
669 have_asciidoc_xmlto=no
670 warn_prebuilt_man_pages=no
671
672 AS_IF([test "x$man_pages_opt" = "xyes"], [
673 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
674 AC_PATH_PROG([XMLTO], [xmlto], [no])
675
676 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
677 AS_IF([test "x$in_git_repo" = "xyes"], [
678 # this is an error because we're in the Git repo, which
679 # means the man pages are not already generated for us,
680 # thus asciidoc/xmlto are required because we were asked
681 # to build the man pages
682 AC_MSG_ERROR([
683 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
684 --disable-man-pages to disable building the man pages, in which case
685 they will not be installed.
686 ])
687 ], [
688 # only warn here: since we're in the tarball, the man
689 # pages should already be generated at this point, thus
690 # asciidoc/xmlto are not strictly required
691 warn_prebuilt_man_pages=yes
692 ])
693 ], [
694 have_asciidoc_xmlto=yes
695 ])
696 ])
697
698 # export man page build condition: build the man pages if the user
699 # asked for it, and if the tools are available
700 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
701 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
702
703 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
704
705 # embedded --help message
706 AC_ARG_ENABLE(
707 [embedded-help],
708 AS_HELP_STRING(
709 [--enable-embedded-help],
710 [Embed the --help messages in the executable files]
711 ),
712 [embedded_help=$enableval],
713 [embedded_help=no]
714 )
715 AS_IF([test "x$embedded_help" = "xyes"], [
716 AS_IF([test "x$man_pages_opt" = "xno"], [
717 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
718 ])
719 AC_PATH_PROG([man_prog_path], [man], [no])
720 AS_IF([test "x$man_prog_path" = "xno"], [
721 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
722 ])
723 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
724 AC_SUBST([MANPROG], [$man_prog_path])
725 ])
726 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
727
728 # Python agent test
729 UST_PYTHON_AGENT="lttngust"
730
731 AC_ARG_ENABLE(test-python2-agent,
732 AS_HELP_STRING([--enable-test-python2-agent],
733 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
734 ),[:],[test_python2_agent_autodetect=yes]
735 )
736
737 AC_ARG_ENABLE(test-python3-agent,
738 AS_HELP_STRING([--enable-test-python3-agent],
739 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
740 ),[:],[test_python3_agent_autodetect=yes]
741 )
742
743 AC_ARG_ENABLE(test-python-agent-all,
744 AS_HELP_STRING([--enable-test-python-agent-all],
745 [enable test for all python{2/3} agent.]
746 ),
747 )
748
749 AS_IF([test ! -z "$enable_test_python_agent_all"], [
750 unset test_python2_agent_autodetect
751 unset test_python3_agent_autodetect
752 ])
753
754 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
755 enable_test_python2_agent=yes
756 enable_test_python3_agent=yes
757 ])
758
759 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
760 enable_test_python2_agent=no
761 enable_test_python3_agent=no
762 ])
763
764
765 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
766 AS_IF([test -z "$PYTHON2"], [
767 PYTHON2=python2
768 ], [
769 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
770 ])
771
772 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
773 AS_IF([test -z "$PYTHON2_BIN"], [
774 AS_IF([test -z "$test_python2_agent_autodetect"],[
775 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
776 ])
777 ], [
778 AC_MSG_CHECKING([for python2 lttng-ust agent])
779 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
780 PYTHON2_AGENT=$PYTHON2_BIN
781 AC_MSG_RESULT([yes])
782 RUN_PYTHON_AGENT_TEST=yes
783 ], [
784 AC_MSG_RESULT([no])
785 AS_IF([test -z "$test_python2_agent_autodetect"],[
786 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
787 ])
788 ])
789
790 ])
791
792 ])
793
794 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
795 AS_IF([test -z "$PYTHON3"], [
796 PYTHON3=python3
797 ], [
798 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
799 ])
800
801 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
802 AS_IF([test -z "$PYTHON3_BIN"], [
803 AS_IF([test -z "$test_python3_agent_autodetect"],[
804 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
805 ])
806 ], [
807 AC_MSG_CHECKING([for python3 lttng-ust agent])
808 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
809 PYTHON3_AGENT=$PYTHON3_BIN
810 AC_MSG_RESULT([yes])
811 RUN_PYTHON_AGENT_TEST=yes
812 ], [
813 AC_MSG_RESULT([no])
814 AS_IF([test -z "$test_python3_agent_autodetect"],[
815 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
816 ])
817 ])
818
819 ])
820 ])
821 AC_SUBST([RUN_PYTHON_AGENT_TEST])
822 AC_SUBST([PYTHON2_AGENT])
823 AC_SUBST([PYTHON3_AGENT])
824
825 AC_ARG_ENABLE([test-sdt-uprobe],
826 [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
827 [test_sdt_uprobe="$enableval"],
828 [test_sdt_uprobe=autodetect]
829 )
830
831 AS_IF([test "$test_sdt_uprobe" != "no"], [
832 LTTNG_CHECK_SDT_WORKS
833 AC_PATH_PROG([DTRACE], [dtrace])
834 ])
835
836 AS_IF([test "$test_sdt_uprobe" = "yes"], [
837 AS_IF([test "$lttng_cv_sdt_works" = "no"], [
838 AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
839 ])
840 AS_IF([test "x$DTRACE" = "x"], [
841 AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
842 ])
843 ])
844
845 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
846 AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
847 AS_IF([test "x$DTRACE" != "x"], [
848 test_sdt_uprobe=yes
849 ])
850 ])
851 ])
852
853 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
854
855 # Arguments for binaries build exclusion
856 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
857 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
858 [Disable the build of lttng-consumerd binaries]))
859 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
860 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
861 [Disable the build of lttng-relayd binaries]))
862 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
863 [Disable the build of lttng-sessiond binaries]))
864 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
865 [Disable the build of the extra components]))
866
867
868 # Always build libconfig since it a dependency of libcommon
869 build_lib_config=yes
870
871 build_lib_compat=no
872 build_lib_consumer=no
873 build_lib_hashtable=no
874 build_lib_health=no
875 build_lib_index=no
876 build_lib_kernel_consumer=no
877 build_lib_kernel_ctl=no
878 build_lib_lttng_ctl=no
879 build_lib_relayd=no
880 build_lib_fd_tracker=no
881 build_lib_sessiond_comm=no
882 build_lib_testpoint=no
883 build_lib_ust_consumer=no
884
885 # There is an overlap for enabled dependencies, but this makes everything
886 # simpler. libcommon and libconfig are always compiled so they are not repeated
887 # here.
888
889 # Enable binary dependencies.
890 AS_IF([test x$enable_bin_lttng != xno],
891 [
892 build_lib_lttng_ctl=yes
893 ]
894 )
895
896 AS_IF([test x$enable_bin_lttng_consumerd != xno],
897 [
898 build_lib_consumer=yes
899 build_lib_sessiond_comm=yes
900 build_lib_index=yes
901 build_lib_health=yes
902 build_lib_testpoint=yes
903 ]
904 )
905
906 AS_IF([test x$enable_bin_lttng_crash != xno],
907 # Do nothing since libconfig and libcommon are built by default.
908 []
909 )
910
911 AS_IF([test x$enable_bin_lttng_relayd != xno],
912 [
913 build_lib_lttng_ctl=yes
914 build_lib_sessiond_comm=yes
915 build_lib_hashtable=yes
916 build_lib_compat=yes
917 build_lib_index=yes
918 build_lib_health=yes
919 build_lib_testpoint=yes
920 build_lib_fd_tracker=yes
921 ]
922 )
923 AS_IF([test x$enable_bin_lttng_sessiond != xno],
924 [
925 build_lib_lttng_ctl=yes
926 build_lib_sessiond_comm=yes
927 build_lib_kernel_ctl=yes
928 build_lib_hashtable=yes
929 build_lib_compat=yes
930 build_lib_relayd=yes
931 build_lib_testpoint=yes
932 build_lib_health=yes
933 ]
934 )
935
936 # Libraries dependencies enabling
937 AS_IF([test x$build_lib_lttng_ctl = xyes],
938 [
939 build_lib_sessiond_comm=yes
940 build_lib_hashtable=yes
941 ]
942 )
943
944 AS_IF([test x$build_lib_consumer = xyes],
945 [
946 build_lib_sessiond_comm=yes
947 build_lib_kernel_consumer=yes
948 build_lib_hashtable=yes
949 build_lib_compat=yes
950 build_lib_relayd=yes
951 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
952 ]
953 )
954
955 AS_IF([test x$build_lib_kernel_consumer = xyes],
956 [
957 build_lib_kernel_ctl=yes
958 build_lib_relayd=yes
959 ]
960 )
961
962 AS_IF([test x$build_lib_relayd = xyes],
963 [
964 build_lib_sessiond_comm=yes
965 ]
966 )
967
968 # Find arch type
969 AS_CASE([$host_cpu],
970 [k1om], [ARCHTYPE="x86"],
971 [i386], [ARCHTYPE="x86"],
972 [i486], [ARCHTYPE="x86"],
973 [i586], [ARCHTYPE="x86"],
974 [i686], [ARCHTYPE="x86"],
975 [amd64], [ARCHTYPE="x86"],
976 [x86_64], [ARCHTYPE="x86"],
977 [powerpc], [ARCHTYPE="ppc"],
978 [ppc64], [ARCHTYPE="ppc"],
979 [powerpc64], [ARCHTYPE="ppc"],
980 [powerpc64le], [ARCHTYPE="ppc"],
981 [ppc], [ARCHTYPE="ppc"],
982 [s390], [ARCHTYPE="s390"],
983 [s390x], [ARCHTYPE="s390"],
984 [sparc], [ARCHTYPE="sparc64"],
985 [sparc64], [ARCHTYPE="sparc64"],
986 [alpha*], [ARCHTYPE="alpha"],
987 [ia64], [ARCHTYPE="ia64"],
988 [arm*], [ARCHTYPE="arm"],
989 [aarch64*], [ARCHTYPE="aarch64"],
990 [mips*], [ARCHTYPE="mips"],
991 [nios2*], [ARCHTYPE="nios2"],
992 [tile*], [ARCHTYPE="tile"],
993 [hppa*], [ARCHTYPE="hppa"],
994 [m68k], [ARCHTYPE="m68k"],
995 [riscv*], [ARCHTYPE="riscv"],
996 [ARCHTYPE="unknown"]
997 )
998
999 AC_SUBST(ARCHTYPE)
1000
1001 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1002 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1003 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1004 # Userspace callstack capture is only supported by the Linux kernel on x86.
1005 AC_MSG_RESULT([yes])
1006 have_modules_userspace_callstack_context=yes
1007 AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1008 ], [
1009 AC_MSG_RESULT([no])
1010 have_modules_userspace_callstack_context=no
1011 ])
1012 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1013
1014 # Export binaries build conditions.
1015 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1016 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1017 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1018 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1019 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1020
1021 # Export the tests and extras build conditions.
1022 AS_IF([\
1023 test "x$enable_bin_lttng" != "xno" && \
1024 test "x$enable_bin_lttng_consumerd" != "xno" && \
1025 test "x$enable_bin_lttng_crash" != "xno" && \
1026 test "x$enable_bin_lttng_relayd" != "xno" && \
1027 test "x$enable_bin_lttng_sessiond" != "xno"],
1028 [build_tests=yes],
1029 [build_tests=no]
1030 )
1031
1032 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1033 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1034
1035 # Export libraries build conditions.
1036 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1039 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1040 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1041 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1042 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1043 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1044 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1050
1051 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1052 AC_SUBST(AM_CFLAGS)
1053
1054 # The order in which the include folders are searched is important.
1055 # The top_builddir should always be searched first in the event that a build
1056 # time generated file is included. An example of this is the "version.i" file.
1057 # In a scenario where lttng-tools is built from a distribution tarball and in a
1058 # out-of-tree manner, the generated "version.i" has priority on the one from
1059 # the source (distribution tarball) and must be found first.
1060 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1061 AC_SUBST(AM_CPPFLAGS)
1062
1063 lttngincludedir="${includedir}/lttng"
1064 AC_SUBST(lttngincludedir)
1065
1066 lttngactionincludedir="${includedir}/lttng/action"
1067 AC_SUBST(lttngactionincludedir)
1068
1069 lttngconditionincludedir="${includedir}/lttng/condition"
1070 AC_SUBST(lttngconditionincludedir)
1071
1072 lttngnotificationincludedir="${includedir}/lttng/notification"
1073 AC_SUBST(lttngnotificationincludedir)
1074
1075 lttngtriggerincludedir="${includedir}/lttng/trigger"
1076 AC_SUBST(lttngtriggerincludedir)
1077
1078 lttnglibexecdir="${libdir}/lttng/libexec"
1079 AC_SUBST(lttnglibexecdir)
1080
1081 AC_CONFIG_FILES([
1082 Makefile
1083 doc/Makefile
1084 doc/man/Makefile
1085 doc/man/asciidoc-attrs.conf
1086 include/Makefile
1087 extras/Makefile
1088 extras/bindings/Makefile
1089 extras/bindings/swig/Makefile
1090 extras/bindings/swig/python/Makefile
1091 extras/core-handler/Makefile
1092 src/Makefile
1093 src/common/Makefile
1094 src/common/kernel-ctl/Makefile
1095 src/common/kernel-consumer/Makefile
1096 src/common/consumer/Makefile
1097 src/common/ust-consumer/Makefile
1098 src/common/hashtable/Makefile
1099 src/common/sessiond-comm/Makefile
1100 src/common/compat/Makefile
1101 src/common/relayd/Makefile
1102 src/common/testpoint/Makefile
1103 src/common/index/Makefile
1104 src/common/health/Makefile
1105 src/common/config/Makefile
1106 src/common/string-utils/Makefile
1107 src/common/fd-tracker/Makefile
1108 src/lib/Makefile
1109 src/lib/lttng-ctl/Makefile
1110 src/lib/lttng-ctl/filter/Makefile
1111 src/lib/lttng-ctl/lttng-ctl.pc
1112 src/bin/Makefile
1113 src/bin/lttng-consumerd/Makefile
1114 src/bin/lttng-sessiond/Makefile
1115 src/bin/lttng-relayd/Makefile
1116 src/bin/lttng/Makefile
1117 src/bin/lttng-crash/Makefile
1118 tests/Makefile
1119 tests/destructive/Makefile
1120 tests/regression/Makefile
1121 tests/regression/kernel/Makefile
1122 tests/regression/tools/Makefile
1123 tests/regression/tools/streaming/Makefile
1124 tests/regression/tools/filtering/Makefile
1125 tests/regression/tools/health/Makefile
1126 tests/regression/tools/tracefile-limits/Makefile
1127 tests/regression/tools/snapshots/Makefile
1128 tests/regression/tools/live/Makefile
1129 tests/regression/tools/exclusion/Makefile
1130 tests/regression/tools/save-load/Makefile
1131 tests/regression/tools/save-load/configuration/Makefile
1132 tests/regression/tools/mi/Makefile
1133 tests/regression/tools/wildcard/Makefile
1134 tests/regression/tools/crash/Makefile
1135 tests/regression/tools/regen-metadata/Makefile
1136 tests/regression/tools/regen-statedump/Makefile
1137 tests/regression/tools/notification/Makefile
1138 tests/regression/tools/rotation/Makefile
1139 tests/regression/tools/base-path/Makefile
1140 tests/regression/tools/metadata/Makefile
1141 tests/regression/tools/tracker/Makefile
1142 tests/regression/tools/working-directory/Makefile
1143 tests/regression/tools/relayd-grouping/Makefile
1144 tests/regression/tools/clear/Makefile
1145 tests/regression/ust/Makefile
1146 tests/regression/ust/nprocesses/Makefile
1147 tests/regression/ust/high-throughput/Makefile
1148 tests/regression/ust/low-throughput/Makefile
1149 tests/regression/ust/before-after/Makefile
1150 tests/regression/ust/buffers-pid/Makefile
1151 tests/regression/ust/periodical-metadata-flush/Makefile
1152 tests/regression/ust/multi-session/Makefile
1153 tests/regression/ust/multi-lib/Makefile
1154 tests/regression/ust/overlap/Makefile
1155 tests/regression/ust/overlap/demo/Makefile
1156 tests/regression/ust/linking/Makefile
1157 tests/regression/ust/daemon/Makefile
1158 tests/regression/ust/exit-fast/Makefile
1159 tests/regression/ust/fork/Makefile
1160 tests/regression/ust/libc-wrapper/Makefile
1161 tests/regression/ust/baddr-statedump/Makefile
1162 tests/regression/ust/ust-dl/Makefile
1163 tests/regression/ust/java-jul/Makefile
1164 tests/regression/ust/java-log4j/Makefile
1165 tests/regression/ust/python-logging/Makefile
1166 tests/regression/ust/getcpu-override/Makefile
1167 tests/regression/ust/clock-override/Makefile
1168 tests/regression/ust/type-declarations/Makefile
1169 tests/regression/ust/rotation-destroy-flush/Makefile
1170 tests/regression/ust/blocking/Makefile
1171 tests/regression/ust/namespaces/Makefile
1172 tests/stress/Makefile
1173 tests/unit/Makefile
1174 tests/unit/ini_config/Makefile
1175 tests/perf/Makefile
1176 tests/utils/Makefile
1177 tests/utils/tap/Makefile
1178 tests/utils/testapp/Makefile
1179 tests/utils/testapp/gen-ns-events/Makefile
1180 tests/utils/testapp/gen-kernel-test-events/Makefile
1181 tests/utils/testapp/gen-ust-events/Makefile
1182 tests/utils/testapp/gen-ust-events-ns/Makefile
1183 tests/utils/testapp/gen-syscall-events-callstack/Makefile
1184 tests/utils/testapp/gen-ust-nevents/Makefile
1185 tests/utils/testapp/gen-ust-nevents-str/Makefile
1186 tests/utils/testapp/gen-syscall-events/Makefile
1187 tests/utils/testapp/gen-ust-tracef/Makefile
1188 tests/utils/testapp/userspace-probe-elf-binary/Makefile
1189 tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1190 tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1191 ])
1192
1193 # Inject variable into python test script.
1194 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1195 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1196 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1197 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1198
1199 AC_OUTPUT
1200
1201 #
1202 # Mini-report on what will be built.
1203 #
1204
1205 PPRINT_INIT
1206 PPRINT_SET_INDENT(1)
1207 PPRINT_SET_TS(38)
1208
1209 AS_ECHO
1210 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1211 AS_ECHO
1212
1213 AS_IF([test -n "$report_fold"], [
1214 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1215 ], [
1216 AS_ECHO("$version_description")
1217 ])
1218
1219 AS_ECHO
1220 PPRINT_SUBTITLE([Features])
1221
1222 # Target architecture we're building for.
1223 target_arch=$host_cpu
1224 [
1225 for f in $CFLAGS; do
1226 if test $f = "-m32"; then
1227 target_arch="32-bit"
1228 elif test $f = "-m64"; then
1229 target_arch="64-bit"
1230 fi
1231 done
1232 ]
1233 PPRINT_PROP_STRING([Target architecture], $target_arch)
1234
1235 # kmod enabled/disabled
1236 test "x$with_kmod" != "xno" && value=1 || value=0
1237 PPRINT_PROP_BOOL([libkmod support], $value)
1238
1239 # LTTng-UST enabled/disabled
1240 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1241 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1242
1243 AS_ECHO
1244 PPRINT_SUBTITLE([Binaries])
1245
1246 # List binaries to be built
1247 test x$enable_bin_lttng != xno && value=1 || value=0
1248 PPRINT_PROP_BOOL([lttng], $value)
1249
1250 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1251 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1252
1253 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1254 PPRINT_PROP_BOOL([lttng-crash], $value)
1255
1256 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1257 PPRINT_PROP_BOOL([lttng-relayd], $value)
1258
1259 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1260 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1261
1262 # Extras
1263 test x$enable_extras != xno && value=1 || value=0
1264 AS_ECHO
1265 PPRINT_SET_INDENT(0)
1266 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1267 PPRINT_SET_INDENT(1)
1268
1269 AS_ECHO
1270 PPRINT_SUBTITLE([Tests])
1271
1272 # Print clear message that tests won't be built
1273 AS_IF([test "x$build_tests" = "xno"],[
1274 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1275 ])
1276
1277 # LTTng UST Java agent JUL tests enabled/disabled
1278 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1279 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1280
1281 # LTTng UST Java agent Log4j tests enabled/disabled
1282 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1283 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1284
1285 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1286 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1287
1288 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1289 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1290
1291 # LTTng UST Java agent Log4j tests enabled/disabled
1292 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1293 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1294
1295 #Python binding enabled/disabled
1296 test "x$enable_python_binding" = xyes && value=1 || value=0
1297 AS_ECHO
1298 PPRINT_SET_INDENT(0)
1299 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1300
1301 # man pages build enabled/disabled
1302 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1303
1304 AS_IF([test "x$man_pages_opt" != "xno"], [
1305 AS_IF([test "x$in_git_repo" = "xyes"], [
1306 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1307 ], [
1308 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1309 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1310 ], [
1311 PPRINT_PROP_STRING([build_man_pages_msg],
1312 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1313 $PPRINT_COLOR_SUBTITLE)
1314 ])
1315 ])
1316 ], [
1317 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1318 ])
1319
1320 m4_popdef([build_man_pages_msg])
1321
1322 test "x$embedded_help" = xyes && value=1 || value=0
1323 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1324
1325 PPRINT_SET_INDENT(1)
1326
1327 report_bindir="`eval eval echo $bindir`"
1328 report_libdir="`eval eval echo $libdir`"
1329
1330 # Print the bindir and libdir this `make install' will install into.
1331 AS_ECHO
1332 PPRINT_SUBTITLE([Install directories])
1333 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1334 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1335
1336 AS_ECHO
1337 PPRINT_SUBTITLE([Search directories])
1338
1339 # If we build the sessiond, print the paths it will use
1340 AS_IF([test "$SESSIOND_BIN" = ""],[
1341 path="$report_bindir/lttng-sessiond"
1342 ],[
1343 path="$SESSIOND_BIN"
1344 ])
1345 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1346
1347 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1348 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1349 ],[
1350 path="$CONSUMERD32_BIN"
1351 ])
1352 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1353
1354 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1355 path="`eval eval echo $libdir`"
1356 ],[
1357 path="$CONSUMERD32_LIBDIR"
1358 ])
1359 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1360
1361 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1362 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1363 ],[
1364 path="$CONSUMERD64_BIN"
1365 ])
1366 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1367
1368 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1369 path="`eval eval echo $libdir`"
1370 ],[
1371 path="$CONSUMERD64_LIBDIR"
1372 ])
1373 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1374 PPRINT_SET_INDENT(0)
1375
1376 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1377 AS_ECHO
1378 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1379
1380 Note that the man pages are already built in this distribution tarball,
1381 therefore asciidoc and xmlto are only needed if you intend to modify
1382 their sources.
1383
1384 Also note that the installed man pages will contain the project's
1385 default command-line option and environment variable values.
1386
1387 Use --disable-man-pages to completely disable building and installing
1388 the man pages.])
1389 ])
This page took 0.096244 seconds and 6 git commands to generate.