Port: Add OSX libuuid compat
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_LEX
28 AC_PROG_MAKE_SET
29 AC_PROG_SED
30 AC_PROG_YACC
31 AC_PATH_PROG(report_fold, fold)
32 LT_INIT
33
34 # Check for objcopy, required by the base address statedump and dynamic linker tests
35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36 AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38 )
39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41 # Checks for typedefs, structures, and compiler characteristics.
42 AC_C_INLINE
43 AC_TYPE_INT32_T
44 AC_TYPE_INT64_T
45 AC_TYPE_MODE_T
46 AC_TYPE_OFF_T
47 AC_TYPE_PID_T
48 AC_TYPE_SIZE_T
49 AC_TYPE_SSIZE_T
50 AC_TYPE_UID_T
51 AC_TYPE_UINT16_T
52 AC_TYPE_UINT32_T
53 AC_TYPE_UINT64_T
54 AC_TYPE_UINT8_T
55
56 AX_C___ATTRIBUTE__
57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62 LIBS="$PTHREAD_LIBS $LIBS"
63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
64 CC="$PTHREAD_CC"
65
66 AX_LIB_SOCKET_NSL
67
68 # Compute minor/major/patchlevel version numbers
69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
72
73 AC_SUBST([MAJOR_VERSION], [$major_version])
74 AC_SUBST([MINOR_VERSION], [$minor_version])
75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
79
80 version_name="Codename TBD"
81 version_description='Description TBD'
82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
83
84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
86
87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
88 AC_ARG_ENABLE(libtool-linkdep-fixup,
89 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
90 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
91 libtool_fixup=$enableval,
92 libtool_fixup=yes)
93
94 AS_IF([test "x$libtool_fixup" = "xyes"],
95 [
96 libtool_m4="$srcdir/m4/libtool.m4"
97 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
98 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
99 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
100 AS_IF([test $libtool_flag_pattern_count -ne 0],
101 [
102 AC_MSG_RESULT([$libtool_flag_pattern_count])
103 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
104 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
105 ],
106 [
107 AC_MSG_RESULT([none])
108 ])
109 ])
110
111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
112
113 AC_CHECK_HEADERS([ \
114 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
115 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
116 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
117 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
118 sys/mount.h sys/param.h sys/time.h
119 ])
120
121 # Basic functions check
122 AC_CHECK_FUNCS([ \
123 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
124 gethostbyname gethostname getpagesize localtime_r memchr memset \
125 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
126 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
127 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
128 ])
129
130 # Babeltrace viewer check
131 AC_ARG_WITH([babeltrace-bin],
132 AS_HELP_STRING([--with-babeltrace-bin],
133 [Location of the babeltrace viewer executable (including the filename)]),
134 [BABELTRACE_BIN="$withval"],
135 [BABELTRACE_BIN=''])
136 AC_SUBST([BABELTRACE_BIN])
137
138 # lttv-gui
139 AC_ARG_WITH([lttv-gui-bin],
140 AS_HELP_STRING([--with-lttv-gui-bin],
141 [Location of the lttv GUI viewer executable (including the filename)]),
142 [LTTV_GUI_BIN="$withval"],
143 [LTTV_GUI_BIN=''])
144 AC_SUBST([LTTV_GUI_BIN])
145
146 AC_ARG_WITH([consumerd32-bin],
147 AS_HELP_STRING([--with-consumerd32-bin],
148 [Location of the 32-bit consumerd executable (including the filename)]),
149 [CONSUMERD32_BIN="$withval"],
150 [CONSUMERD32_BIN=''])
151 AC_SUBST([CONSUMERD32_BIN])
152
153 AC_ARG_WITH([consumerd64-bin],
154 AS_HELP_STRING([--with-consumerd64-bin],
155 [Location of the 64-bit consumerd executable (including the filename)]),
156 [CONSUMERD64_BIN="$withval"],
157 [CONSUMERD64_BIN=''])
158 AC_SUBST([CONSUMERD64_BIN])
159
160 AC_ARG_WITH([consumerd32-libdir],
161 AS_HELP_STRING([--with-consumerd32-libdir],
162 [Directory containing the 32-bit consumerd libraries]),
163 [CONSUMERD32_LIBDIR="$withval"],
164 [CONSUMERD32_LIBDIR=''])
165 AC_SUBST([CONSUMERD32_LIBDIR])
166
167 AC_ARG_WITH([consumerd64-libdir],
168 AS_HELP_STRING([--with-consumerd64-libdir],
169 [Directory containing the 64-bit consumerd libraries]),
170 [CONSUMERD64_LIBDIR="$withval"],
171 [CONSUMERD64_LIBDIR=''])
172 AC_SUBST([CONSUMERD64_LIBDIR])
173
174 AC_ARG_WITH([sessiond-bin],
175 AS_HELP_STRING([--with-sessiond-bin],
176 [Location of the sessiond executable (including the filename)]),
177 [SESSIOND_BIN="$withval"],
178 [SESSIOND_BIN=''])
179 AC_SUBST([SESSIOND_BIN])
180
181 AC_ARG_WITH([lttng-system-rundir],
182 AS_HELP_STRING([--with-lttng-system-rundir],
183 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
184 [LTTNG_SYSTEM_RUNDIR="$withval"],
185 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
186 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
187
188 AC_ARG_ENABLE([test-java-agent-jul],
189 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
190 [test_java_agent_jul=$enableval],
191 [test_java_agent_jul=no]
192 )
193
194 AC_ARG_ENABLE([test-java-agent-log4j],
195 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
196 [test_java_agent_log4j=$enableval],
197 [test_java_agent_log4j=no]
198 )
199
200 AC_ARG_ENABLE([test-java-agent-all],
201 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
202 [test_java_agent_jul=$enableval
203 test_java_agent_log4j=$enableval],
204 [:]
205 )
206
207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
209 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
210 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
211 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
212 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
213 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
214 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
215
216 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
217 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
218 $1="$2"
219 AC_SUBST([$1])
220 ])
221
222 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
223 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
224 $1="$2"
225 AC_SUBST([$1])
226 ])
227
228 # Default values
229 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
230 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
231 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
232 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
233 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
234 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
235 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
236 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
237 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
238 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
239 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
240 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
241 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
242 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
243 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
244 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
245 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
246 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
247 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
248 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
249 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
250 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
251 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
252 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
253 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
254 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
255 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
256 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
257 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
258 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
259 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
260 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
261 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
262 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
263 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
264 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
265 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
266 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
267
268 # Command short descriptions
269 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
270 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CALIBRATE], [Quantify LTTng overhead])
271 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
272 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
273 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
274 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
275 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
276 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
277 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
278 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
279 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
280 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_METADATA], [Manage an LTTng tracing session's metadata generation])
281 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
282 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
283 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
291
292 if test "x$prefix" = "xNONE"; then
293 prefix=$ac_default_prefix
294 fi
295 CONFDIR=`eval echo $sysconfdir`
296 AC_SUBST(CONFDIR)
297 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
298
299 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
300
301 #
302 # Check for pthread
303 AC_CHECK_LIB([pthread], [pthread_create], [],
304 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
305 )
306
307 # Check libpopt
308 PKG_CHECK_MODULES([POPT], [popt],
309 [LIBS="$LIBS $POPT_LIBS"],
310 [
311 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
312 AC_MSG_WARN([Finding libpopt without pkg-config.])
313 AC_CHECK_LIB([popt],
314 [poptGetContext],
315 [],
316 [
317 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
318 ]
319 )
320 ]
321 )
322
323 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
324
325 # Check for uuid in system libs
326 AC_CHECK_FUNCS([uuid_generate],
327 [
328 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
329 link_with_libuuid=no
330 ],
331 [
332 # First, check the pkg-config module is available, otherwise explicitly check
333 # for libuuid, or uuid support in the C-library.
334 PKG_CHECK_MODULES([UUID], [uuid],
335 [
336 LIBS="$LIBS $UUID_LIBS"
337 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
338 link_with_libuuid=yes
339 ],
340 [
341 # Check for libuuid
342 AC_CHECK_LIB([uuid],
343 [uuid_generate],
344 [
345 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
346 link_with_libuuid=yes
347 ],
348 [
349 # libuuid not found, check for uuid_create in libc.
350 AC_CHECK_LIB([c],
351 [uuid_create],
352 [
353 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
354 link_with_libc_uuid=yes
355 ],
356 [
357 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
358 ]
359 )
360 ]
361 )
362 ])
363 ])
364
365 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
366 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
367
368 # URCU library version needed or newer
369 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
370
371 # Check liburcu needed function calls
372 AC_CHECK_DECL([cds_list_add], [],
373 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
374 AC_CHECK_DECL([cds_wfcq_init], [],
375 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
376 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
377 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
378 AC_CHECK_DECL([futex_async], [],
379 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
380 AC_CHECK_DECL([rcu_thread_offline], [],
381 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
382 AC_CHECK_DECL([rcu_thread_online], [],
383 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
384 AC_CHECK_DECL([caa_likely], [],
385 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
386 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
387 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
388
389 #Function added in urcu 0.7.0
390 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
391 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
392 )
393
394 # Check kmod library
395 AC_ARG_WITH(kmod-prefix,
396 AS_HELP_STRING([--with-kmod-prefix=PATH],
397 [Specify the installation prefix of the kmod library.
398 Headers must be in PATH/include; libraries in PATH/lib.]),
399 [
400 CPPFLAGS="$CPPFLAGS -I${withval}/include"
401 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
402 ])
403
404 AC_ARG_ENABLE(kmod,
405 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
406 kmod_support=$enableval, kmod_support=yes)
407
408 AS_IF([test "x$kmod_support" = "xyes"], [
409 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
410 [
411 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
412 LIBS="$LIBS -lkmod"
413 kmod_found=yes
414 ],
415 kmod_found=no
416 )
417 ])
418 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
419
420 AC_ARG_WITH(lttng-ust-prefix,
421 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
422 [Specify the installation prefix of the lttng-ust library.
423 Headers must be in PATH/include; libraries in PATH/lib.]),
424 [
425 CPPFLAGS="$CPPFLAGS -I${withval}/include"
426 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
427 ])
428
429 # Check liblttng-ust-ctl library
430 AC_ARG_WITH(lttng-ust,
431 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
432 lttng_ust_support=$withval, lttng_ust_support=yes)
433
434 AS_IF([test "x$lttng_ust_support" = "xyes"], [
435 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
436 [
437 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
438 lttng_ust_ctl_found=yes
439 ],
440 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
441 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
442 )
443 ])
444 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
445 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
446
447 # check for dlopen
448 AC_CHECK_LIB([dl], [dlopen],
449 [
450 have_libdl=yes
451 ],
452 [
453 #libdl not found, check for dlopen in libc.
454 AC_CHECK_LIB([c], [dlopen],
455 [
456 have_libc_dl=yes
457 ],
458 [
459 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
460 ])
461 ])
462 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
463 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
464
465 # Check for fmemopen
466 AC_CHECK_LIB([c], [fmemopen],
467 [
468 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
469 ]
470 )
471
472 # Check for open_memstream
473 AC_CHECK_LIB([c], [open_memstream],
474 [
475 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
476 ]
477 )
478
479 AC_ARG_ENABLE([git-version],
480 [AC_HELP_STRING([--disable-git-version],
481 [Do not use the git version for the build])],
482 [have_git_version=$enableval], [have_git_version=yes]
483 )
484
485 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
486 [test "x${have_git_version}" = "xyes"])
487
488 # For Python
489 # SWIG version needed or newer:
490 swig_version=2.0.0
491
492 AC_ARG_ENABLE([python-bindings],
493 [AC_HELP_STRING([--enable-python-bindings],
494 [compile Python bindings])],
495 [enable_python_binding=$enableval], [enable_python_binding=no])
496
497 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
498
499 if test "x$enable_python_binding" = xyes; then
500 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
501 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
502 AM_PATH_PYTHON([3.0])
503
504 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
505 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
506 AS_IF([test -z "$PYTHON_INCLUDE"], [
507 AS_IF([test -z "$PYTHON_CONFIG"], [
508 AC_PATH_PROGS([PYTHON_CONFIG],
509 [python$PYTHON_VERSION-config python-config],
510 [no],
511 [`dirname $PYTHON`])
512 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
513 ])
514 AC_MSG_CHECKING([python include flags])
515 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
516 AC_MSG_RESULT([$PYTHON_INCLUDE])
517 ])
518
519 else
520 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
521 [if you want Python bindings.])
522
523 fi
524
525 # Epoll check. If not present, the build will fallback on poll() API
526 AX_HAVE_EPOLL(
527 [AX_CONFIG_FEATURE_ENABLE(epoll)],
528 [AX_CONFIG_FEATURE_DISABLE(epoll)]
529 )
530 AX_CONFIG_FEATURE(
531 [epoll], [This platform supports epoll(7)],
532 [HAVE_EPOLL], [This platform supports epoll(7).],
533 [enable_epoll="yes"], [enable_epoll="no"]
534 )
535 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
536
537 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
538 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
539
540 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
541 AX_JAVA_OPTIONS
542 AX_PROG_JAVAC
543 AX_PROG_JAVA
544 AX_PROG_JAR
545
546 AX_CHECK_CLASSPATH
547
548 # Check for Java UST agent common class first
549 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
550 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
551 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
552 fi
553
554 if test "x$test_java_agent_jul" = "xyes"; then
555 # Check for JUL agent class
556 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
557 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
558 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
559 fi
560 fi
561
562 if test "x$test_java_agent_log4j" = "xyes"; then
563 # Check for Log4j agent class
564 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
565 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
566 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
567 fi
568
569 # Check for Log4j class
570 AX_CHECK_CLASS(org.apache.log4j.Logger)
571 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
572 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
573 fi
574 fi
575 fi
576
577 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
578 # is not distributed in tarballs
579 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
580 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
581
582 # enable building man pages (user's intention)
583 AC_ARG_ENABLE(
584 man-pages,
585 AS_HELP_STRING(
586 [--disable-man-pages],
587 [Do not build and install man pages (already built in a distributed tarball)]
588 ),
589 [man_pages_opt=$enableval],
590 [man_pages_opt=yes]
591 )
592
593 # check for asciidoc and xmlto if we enabled building the man pages
594 have_asciidoc_xmlto=no
595
596 AS_IF([test "x$man_pages_opt" = "xyes"], [
597 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
598 AC_PATH_PROG([XMLTO], [xmlto], [no])
599
600 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
601 AS_IF([test "x$in_git_repo" = "xyes"], [
602 # this is an error because we're in the Git repo, which
603 # means the man pages are not already generated for us,
604 # thus asciidoc/xmlto are required because we were asked
605 # to build the man pages
606 AC_MSG_ERROR([
607 Both asciidoc and xmlto are needed to build the LTTng man pages. Use
608 --disable-man-pages to disable building the man pages, in which case
609 they will not be installed.
610 ])
611 ], [
612 # only warn here: since we're in the tarball, the man
613 # pages should already be generated at this point, thus
614 # asciidoc/xmlto are not strictly required
615 AC_MSG_WARN([
616 Both asciidoc and xmlto are needed to build the LTTng man pages. Note
617 that the man pages are already built in this distribution tarball, so
618 asciidoc and xmlto are only needed if you intend to modify their
619 sources. Use --disable-man-pages to completely disable building
620 and installing the man pages.
621 ])
622 ])
623 ], [
624 have_asciidoc_xmlto=yes
625 ])
626 ])
627
628 # export man page build condition: build the man pages if the user
629 # asked for it, and if the tools are available
630 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
631 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
632
633 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
634
635 # Python agent test
636 UST_PYTHON_AGENT="lttngust"
637
638 AC_ARG_ENABLE(test-python2-agent,
639 AS_HELP_STRING([--enable-test-python2-agent],
640 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
641 ),[:],[test_python2_agent_autodetect=yes]
642 )
643
644 AC_ARG_ENABLE(test-python3-agent,
645 AS_HELP_STRING([--enable-test-python3-agent],
646 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
647 ),[:],[test_python3_agent_autodetect=yes]
648 )
649
650 AC_ARG_ENABLE(test-python-agent-all,
651 AS_HELP_STRING([--enable-test-python-agent-all],
652 [enable test for all python{2/3} agent.]
653 ),
654 )
655
656 AS_IF([test ! -z "$enable_test_python_agent_all"], [
657 unset test_python2_agent_autodetect
658 unset test_python3_agent_autodetect
659 ])
660
661 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
662 enable_test_python2_agent=yes
663 enable_test_python3_agent=yes
664 ])
665
666 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
667 enable_test_python2_agent=no
668 enable_test_python3_agent=no
669 ])
670
671
672 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
673 AS_IF([test -z "$PYTHON2"], [
674 PYTHON2=python2
675 ], [
676 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
677 ])
678
679 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
680 AS_IF([test -z "$PYTHON2_BIN"], [
681 AS_IF([test -z "$test_python2_agent_autodetect"],[
682 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
683 ])
684 ], [
685 AC_MSG_CHECKING([for python2 lttng-ust agent])
686 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
687 PYTHON2_AGENT=$PYTHON2_BIN
688 AC_MSG_RESULT([yes])
689 RUN_PYTHON_AGENT_TEST=yes
690 ], [
691 AC_MSG_RESULT([no])
692 AS_IF([test -z "$test_python2_agent_autodetect"],[
693 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
694 ])
695 ])
696
697 ])
698
699 ])
700
701 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
702 AS_IF([test -z "$PYTHON3"], [
703 PYTHON3=python3
704 ], [
705 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
706 ])
707
708 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
709 AS_IF([test -z "$PYTHON3_BIN"], [
710 AS_IF([test -z "$test_python3_agent_autodetect"],[
711 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
712 ])
713 ], [
714 AC_MSG_CHECKING([for python3 lttng-ust agent])
715 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
716 PYTHON3_AGENT=$PYTHON3_BIN
717 AC_MSG_RESULT([yes])
718 RUN_PYTHON_AGENT_TEST=yes
719 ], [
720 AC_MSG_RESULT([no])
721 AS_IF([test -z "$test_python3_agent_autodetect"],[
722 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
723 ])
724 ])
725
726 ])
727 ])
728 AC_SUBST([RUN_PYTHON_AGENT_TEST])
729 AC_SUBST([PYTHON2_AGENT])
730 AC_SUBST([PYTHON3_AGENT])
731
732 # Arguments for binaries build exclusion
733 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
734 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
735 [Disable the build of lttng-consumerd binaries]))
736 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
737 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
738 [Disable the build of lttng-relayd binaries]))
739 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
740 [Disable the build of lttng-sessiond binaries]))
741 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
742 [Disable the build of the extra components]))
743
744
745 # Always build libconfig since it a dependency of libcommon
746 build_lib_config=yes
747
748 build_lib_compat=no
749 build_lib_consumer=no
750 build_lib_hashtable=no
751 build_lib_health=no
752 build_lib_index=no
753 build_lib_kernel_consumer=no
754 build_lib_kernel_ctl=no
755 build_lib_lttng_ctl=no
756 build_lib_relayd=no
757 build_lib_sessiond_comm=no
758 build_lib_testpoint=no
759 build_lib_ust_consumer=no
760
761 # There is an overlap for enabled dependencies, but this makes everything
762 # simpler. libcommon and libconfig are always compiled so they are not repeated
763 # here.
764
765 # Enable binary dependencies.
766 AS_IF([test x$enable_bin_lttng != xno],
767 [
768 build_lib_lttng_ctl=yes
769 ]
770 )
771
772 AS_IF([test x$enable_bin_lttng_consumerd != xno],
773 [
774 build_lib_consumer=yes
775 build_lib_sessiond_comm=yes
776 build_lib_index=yes
777 build_lib_health=yes
778 build_lib_testpoint=yes
779 ]
780 )
781
782 AS_IF([test x$enable_bin_lttng_crash != xno],
783 # Do nothing since libconfig and libcommon are built by default.
784 []
785 )
786
787 AS_IF([test x$enable_bin_lttng_relayd != xno],
788 [
789 build_lib_lttng_ctl=yes
790 build_lib_sessiond_comm=yes
791 build_lib_hashtable=yes
792 build_lib_compat=yes
793 build_lib_index=yes
794 build_lib_health=yes
795 build_lib_testpoint=yes
796 ]
797 )
798 AS_IF([test x$enable_bin_lttng_sessiond != xno],
799 [
800 build_lib_lttng_ctl=yes
801 build_lib_sessiond_comm=yes
802 build_lib_kernel_ctl=yes
803 build_lib_hashtable=yes
804 build_lib_compat=yes
805 build_lib_relayd=yes
806 build_lib_testpoint=yes
807 build_lib_health=yes
808 build_lib_health=yes
809 ]
810 )
811
812 # Libraries dependencies enabling
813 AS_IF([test x$build_lib_lttng_ctl = xyes],
814 [
815 build_lib_sessiond_comm=yes
816 build_lib_hashtable=yes
817 ]
818 )
819
820 AS_IF([test x$build_lib_consumer = xyes],
821 [
822 build_lib_sessiond_comm=yes
823 build_lib_kernel_consumer=yes
824 build_lib_hashtable=yes
825 build_lib_compat=yes
826 build_lib_relayd=yes
827 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
828 ]
829 )
830
831 AS_IF([test x$build_lib_kernel_consumer = xyes],
832 [
833 build_lib_kernel_ctl=yes
834 build_lib_relayd=yes
835 ]
836 )
837
838 AS_IF([test x$build_lib_relayd = xyes],
839 [
840 build_lib_sessiond_comm=yes
841 ]
842 )
843
844
845 # Export binaries build conditions.
846 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
847 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
848 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
849 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
850 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
851
852 # Export the tests and extras build conditions.
853 AS_IF([\
854 test "x$enable_bin_lttng" != "xno" && \
855 test "x$enable_bin_lttng_consumerd" != "xno" && \
856 test "x$enable_bin_lttng_crash" != "xno" && \
857 test "x$enable_bin_lttng_relayd" != "xno" && \
858 test "x$enable_bin_lttng_sessiond" != "xno"],
859 [build_tests=yes],
860 [build_tests=no]
861 )
862
863 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
864 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
865
866 # Export libraries build conditions.
867 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
868 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
869 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
870 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
871 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
872 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
873 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
874 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
875 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
876 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
877 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
878 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
879 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
880
881 # check for pgrep
882 AC_PATH_PROG([PGREP], [pgrep], [no])
883 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
884
885 # check for bison
886 have_bison=yes
887
888 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
889 AC_PATH_PROG([BISON], [bison])
890 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
891
892 AS_IF([test "x$have_bison" = "xno"], [
893 AS_IF([test "x$in_git_repo" = "xyes"], [
894 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
895 ], [
896 AC_MSG_WARN([
897 Missing Bison >= 2.4. Note that the parser files are already built in
898 this distribution tarball, so Bison is only needed if you intend to
899 modify their sources.
900 ])
901 ])
902 ])
903
904 # export bison condition
905 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
906
907 # check for flex
908 have_flex=yes
909
910 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
911 AC_PATH_PROG([FLEX], [flex])
912 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
913
914 AS_IF([test "x$have_flex" = "xno"], [
915 AS_IF([test "x$in_git_repo" = "xyes"], [
916 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
917 ], [
918 AC_MSG_WARN([
919 Missing Flex >= 2.5.35. Note that the lexer files are already built in
920 this distribution tarball, so Flex is only needed if you intend to
921 modify their sources.
922 ])
923 ])
924 ])
925
926 # export flex condition
927 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
928
929 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
930
931 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
932
933 lttngincludedir="${includedir}/lttng"
934
935 AC_SUBST(lttngincludedir)
936 AC_SUBST(DEFAULT_INCLUDES)
937
938 lttnglibexecdir="${libdir}/lttng/libexec"
939 AC_SUBST(lttnglibexecdir)
940
941 AC_CONFIG_FILES([
942 Makefile
943 doc/Makefile
944 doc/man/Makefile
945 doc/man/asciidoc-attrs.conf
946 include/Makefile
947 extras/Makefile
948 extras/bindings/Makefile
949 extras/bindings/swig/Makefile
950 extras/bindings/swig/python/Makefile
951 extras/core-handler/Makefile
952 src/Makefile
953 src/common/Makefile
954 src/common/kernel-ctl/Makefile
955 src/common/kernel-consumer/Makefile
956 src/common/consumer/Makefile
957 src/common/ust-consumer/Makefile
958 src/common/hashtable/Makefile
959 src/common/sessiond-comm/Makefile
960 src/common/compat/Makefile
961 src/common/relayd/Makefile
962 src/common/testpoint/Makefile
963 src/common/index/Makefile
964 src/common/health/Makefile
965 src/common/config/Makefile
966 src/lib/Makefile
967 src/lib/lttng-ctl/Makefile
968 src/lib/lttng-ctl/filter/Makefile
969 src/lib/lttng-ctl/lttng-ctl.pc
970 src/bin/Makefile
971 src/bin/lttng-consumerd/Makefile
972 src/bin/lttng-sessiond/Makefile
973 src/bin/lttng-relayd/Makefile
974 src/bin/lttng/Makefile
975 src/bin/lttng-crash/Makefile
976 tests/Makefile
977 tests/destructive/Makefile
978 tests/regression/Makefile
979 tests/regression/kernel/Makefile
980 tests/regression/tools/Makefile
981 tests/regression/tools/streaming/Makefile
982 tests/regression/tools/filtering/Makefile
983 tests/regression/tools/health/Makefile
984 tests/regression/tools/tracefile-limits/Makefile
985 tests/regression/tools/snapshots/Makefile
986 tests/regression/tools/live/Makefile
987 tests/regression/tools/exclusion/Makefile
988 tests/regression/tools/save-load/Makefile
989 tests/regression/tools/mi/Makefile
990 tests/regression/tools/wildcard/Makefile
991 tests/regression/tools/crash/Makefile
992 tests/regression/tools/regen-metadata/Makefile
993 tests/regression/tools/regen-statedump/Makefile
994 tests/regression/ust/Makefile
995 tests/regression/ust/nprocesses/Makefile
996 tests/regression/ust/high-throughput/Makefile
997 tests/regression/ust/low-throughput/Makefile
998 tests/regression/ust/before-after/Makefile
999 tests/regression/ust/buffers-pid/Makefile
1000 tests/regression/ust/periodical-metadata-flush/Makefile
1001 tests/regression/ust/multi-session/Makefile
1002 tests/regression/ust/overlap/Makefile
1003 tests/regression/ust/overlap/demo/Makefile
1004 tests/regression/ust/linking/Makefile
1005 tests/regression/ust/daemon/Makefile
1006 tests/regression/ust/exit-fast/Makefile
1007 tests/regression/ust/fork/Makefile
1008 tests/regression/ust/libc-wrapper/Makefile
1009 tests/regression/ust/baddr-statedump/Makefile
1010 tests/regression/ust/ust-dl/Makefile
1011 tests/regression/ust/java-jul/Makefile
1012 tests/regression/ust/java-log4j/Makefile
1013 tests/regression/ust/python-logging/Makefile
1014 tests/regression/ust/getcpu-override/Makefile
1015 tests/regression/ust/clock-override/Makefile
1016 tests/regression/ust/type-declarations/Makefile
1017 tests/regression/ust/rotation-destroy-flush/Makefile
1018 tests/stress/Makefile
1019 tests/unit/Makefile
1020 tests/unit/ini_config/Makefile
1021 tests/utils/Makefile
1022 tests/utils/tap/Makefile
1023 tests/utils/testapp/Makefile
1024 tests/utils/testapp/gen-ust-events/Makefile
1025 tests/utils/testapp/gen-ust-nevents/Makefile
1026 tests/utils/testapp/gen-ust-tracef/Makefile
1027 ])
1028
1029 # Inject variable into python test script.
1030 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1031
1032 AC_OUTPUT
1033
1034 #
1035 # Mini-report on what will be built.
1036 #
1037
1038 PPRINT_INIT
1039 PPRINT_SET_INDENT(1)
1040 PPRINT_SET_TS(38)
1041
1042 AS_ECHO
1043 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1044 AS_ECHO
1045
1046 AS_IF([test -n "$report_fold"], [
1047 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1048 ], [
1049 AS_ECHO("$version_description")
1050 ])
1051
1052 AS_ECHO
1053 PPRINT_SUBTITLE([Features])
1054
1055 # Target architecture we're building for.
1056 target_arch=$host_cpu
1057 [
1058 for f in $CFLAGS; do
1059 if test $f = "-m32"; then
1060 target_arch="32-bit"
1061 elif test $f = "-m64"; then
1062 target_arch="64-bit"
1063 fi
1064 done
1065 ]
1066 PPRINT_PROP_STRING([Target architecture], $target_arch)
1067
1068 # kmod enabled/disabled
1069 test "x$kmod_found" = "xyes" && value=1 || value=0
1070 PPRINT_PROP_BOOL([libkmod support], $value)
1071
1072 # LTTng-UST enabled/disabled
1073 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1074 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1075
1076 AS_ECHO
1077 PPRINT_SUBTITLE([Binaries])
1078
1079 # List binaries to be built
1080 test x$enable_bin_lttng != xno && value=1 || value=0
1081 PPRINT_PROP_BOOL([lttng], $value)
1082
1083 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1084 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1085
1086 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1087 PPRINT_PROP_BOOL([lttng-crash], $value)
1088
1089 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1090 PPRINT_PROP_BOOL([lttng-relayd], $value)
1091
1092 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1093 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1094
1095 # Extras
1096 test x$enable_extras != xno && value=1 || value=0
1097 AS_ECHO
1098 PPRINT_SET_INDENT(0)
1099 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1100 PPRINT_SET_INDENT(1)
1101
1102 AS_ECHO
1103 PPRINT_SUBTITLE([Tests])
1104
1105 # Print clear message that tests won't be built
1106 AS_IF([test "x$build_tests" = "xno"],[
1107 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1108 ])
1109
1110 # LTTng UST Java agent JUL tests enabled/disabled
1111 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1112 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1113
1114 # LTTng UST Java agent Log4j tests enabled/disabled
1115 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1116 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1117
1118 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1119 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1120
1121 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1122 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1123
1124 #Python binding enabled/disabled
1125 test "x$enable_python_binding" = xyes && value=1 || value=0
1126 AS_ECHO
1127 PPRINT_SET_INDENT(0)
1128 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1129
1130 # man pages build enabled/disabled
1131 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1132
1133 AS_IF([test "x$man_pages_opt" != "xno"], [
1134 AS_IF([test "x$in_git_repo" = "xyes"], [
1135 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1136 ], [
1137 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1138 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1139 ], [
1140 PPRINT_PROP_STRING([build_man_pages_msg],
1141 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1142 $PPRINT_COLOR_SUBTITLE)
1143 ])
1144 ])
1145 ], [
1146 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1147 ])
1148
1149 m4_popdef([build_man_pages_msg])
1150
1151 PPRINT_SET_INDENT(1)
1152
1153 report_bindir="`eval eval echo $bindir`"
1154 report_libdir="`eval eval echo $libdir`"
1155
1156 # Print the bindir and libdir this `make install' will install into.
1157 AS_ECHO
1158 PPRINT_SUBTITLE([Install directories])
1159 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1160 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1161
1162 AS_ECHO
1163 PPRINT_SUBTITLE([Search directories])
1164
1165 # If we build the sessiond, print the paths it will use
1166 AS_IF([test "$SESSIOND_BIN" = ""],[
1167 path="$report_bindir/lttng-sessiond"
1168 ],[
1169 path="$SESSIOND_BIN"
1170 ])
1171 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1172
1173 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1174 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1175 ],[
1176 path="$CONSUMERD32_BIN"
1177 ])
1178 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1179
1180 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1181 path="`eval eval echo $libdir`"
1182 ],[
1183 path="$CONSUMERD32_LIBDIR"
1184 ])
1185 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1186
1187 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1188 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1189 ],[
1190 path="$CONSUMERD64_BIN"
1191 ])
1192 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1193
1194 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1195 path="`eval eval echo $libdir`"
1196 ],[
1197 path="$CONSUMERD64_LIBDIR"
1198 ])
1199 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
This page took 0.053798 seconds and 6 git commands to generate.