configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 # Compute minor/major/patchlevel version numbers
  69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  72
  73 AC_SUBST([MAJOR_VERSION], [$major_version])
  74 AC_SUBST([MINOR_VERSION], [$minor_version])
  75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  79
  80 version_name="Codename TBD"
  81 version_description='Description TBD'
  82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  83
  84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  86
  87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  88 AC_ARG_ENABLE(libtool-linkdep-fixup,
  89         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  90                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  91         libtool_fixup=$enableval,
  92         libtool_fixup=yes)
  93
  94 AS_IF([test "x$libtool_fixup" = "xyes"],
  95             [
  96             libtool_m4="$srcdir/m4/libtool.m4"
  97             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  98             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  99             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 100             AS_IF([test $libtool_flag_pattern_count -ne 0],
 101             [
 102                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 103                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 104                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 105                   ],
 106                   [
 107                   AC_MSG_RESULT([none])
 108                   ])
 109             ])
 110
 111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 112
 113 AC_CHECK_HEADERS([ \
 114         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 115         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 116         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 117         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 118         sys/mount.h sys/param.h sys/time.h
 119 ])
 120
 121 # Basic functions check
 122 AC_CHECK_FUNCS([ \
 123         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 124         gethostbyname gethostname getpagesize localtime_r memchr memset \
 125         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 126         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 127         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 128 ])
 129
 130 # Babeltrace viewer check
 131 AC_ARG_WITH([babeltrace-bin],
 132         AS_HELP_STRING([--with-babeltrace-bin],
 133         [Location of the babeltrace viewer executable (including the filename)]),
 134         [BABELTRACE_BIN="$withval"],
 135         [BABELTRACE_BIN=''])
 136 AC_SUBST([BABELTRACE_BIN])
 137
 138 # lttv-gui
 139 AC_ARG_WITH([lttv-gui-bin],
 140         AS_HELP_STRING([--with-lttv-gui-bin],
 141    [Location of the lttv GUI viewer executable (including the filename)]),
 142    [LTTV_GUI_BIN="$withval"],
 143    [LTTV_GUI_BIN=''])
 144 AC_SUBST([LTTV_GUI_BIN])
 145
 146 AC_ARG_WITH([consumerd32-bin],
 147         AS_HELP_STRING([--with-consumerd32-bin],
 148         [Location of the 32-bit consumerd executable (including the filename)]),
 149         [CONSUMERD32_BIN="$withval"],
 150         [CONSUMERD32_BIN=''])
 151 AC_SUBST([CONSUMERD32_BIN])
 152
 153 AC_ARG_WITH([consumerd64-bin],
 154         AS_HELP_STRING([--with-consumerd64-bin],
 155         [Location of the 64-bit consumerd executable (including the filename)]),
 156         [CONSUMERD64_BIN="$withval"],
 157         [CONSUMERD64_BIN=''])
 158 AC_SUBST([CONSUMERD64_BIN])
 159
 160 AC_ARG_WITH([consumerd32-libdir],
 161         AS_HELP_STRING([--with-consumerd32-libdir],
 162         [Directory containing the 32-bit consumerd libraries]),
 163         [CONSUMERD32_LIBDIR="$withval"],
 164         [CONSUMERD32_LIBDIR=''])
 165 AC_SUBST([CONSUMERD32_LIBDIR])
 166
 167 AC_ARG_WITH([consumerd64-libdir],
 168         AS_HELP_STRING([--with-consumerd64-libdir],
 169         [Directory containing the 64-bit consumerd libraries]),
 170         [CONSUMERD64_LIBDIR="$withval"],
 171         [CONSUMERD64_LIBDIR=''])
 172 AC_SUBST([CONSUMERD64_LIBDIR])
 173
 174 AC_ARG_WITH([sessiond-bin],
 175         AS_HELP_STRING([--with-sessiond-bin],
 176         [Location of the sessiond executable (including the filename)]),
 177         [SESSIOND_BIN="$withval"],
 178         [SESSIOND_BIN=''])
 179 AC_SUBST([SESSIOND_BIN])
 180
 181 AC_ARG_WITH([lttng-system-rundir],
 182         AS_HELP_STRING([--with-lttng-system-rundir],
 183         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 184         [LTTNG_SYSTEM_RUNDIR="$withval"],
 185         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 186 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 187
 188 AC_ARG_ENABLE([test-java-agent-jul],
 189         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 190         [test_java_agent_jul=$enableval],
 191         [test_java_agent_jul=no]
 192 )
 193
 194 AC_ARG_ENABLE([test-java-agent-log4j],
 195         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 196         [test_java_agent_log4j=$enableval],
 197         [test_java_agent_log4j=no]
 198 )
 199
 200 AC_ARG_ENABLE([test-java-agent-all],
 201         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 202         [test_java_agent_jul=$enableval
 203          test_java_agent_log4j=$enableval],
 204         [:]
 205 )
 206
 207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 209 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 210 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 211 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 212 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 213 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 214 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 215
 216 if test "x$prefix" = "xNONE"; then
 217         prefix=$ac_default_prefix
 218 fi
 219 CONFDIR=`eval echo $sysconfdir`
 220 AC_SUBST(CONFDIR)
 221 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 222
 223 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 224
 225 #
 226 # Check for pthread
 227 AC_CHECK_LIB([pthread], [pthread_create], [],
 228         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 229 )
 230
 231 # Check libpopt
 232 PKG_CHECK_MODULES([POPT], [popt],
 233         [LIBS="$LIBS $POPT_LIBS"],
 234         [
 235                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 236                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 237                 AC_CHECK_LIB([popt],
 238                         [poptGetContext],
 239                         [],
 240                         [
 241                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 242                         ]
 243                 )
 244         ]
 245 )
 246
 247 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 248
 249 # Check for libuuid
 250 PKG_CHECK_MODULES([UUID], [uuid],
 251 [
 252         LIBS="$LIBS $UUID_LIBS"
 253         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 254         have_libuuid=yes
 255 ],
 256 [
 257         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 258         AC_MSG_WARN([Finding libuuid without pkg-config.])
 259         AC_CHECK_LIB([uuid],
 260                 [uuid_generate],
 261                 [
 262                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 263                         have_libuuid=yes
 264                 ],
 265                 [
 266                         # libuuid not found, check for uuid_create in libc.
 267                         AC_CHECK_LIB([c],
 268                                 [uuid_create],
 269                                 [
 270                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 271                                         have_libc_uuid=yes
 272                                 ],
 273                                 [
 274                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 275                                 ]
 276                         )
 277                 ]
 278         )
 279 ])
 280 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 281 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 282
 283 # URCU library version needed or newer
 284 liburcu_version=">= 0.8.0"
 285
 286 # Check liburcu needed function calls
 287 AC_CHECK_DECL([cds_list_add], [],
 288         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 289 )
 290 AC_CHECK_DECL([cds_wfcq_init], [],
 291         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 292 )
 293 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 294     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 295 )
 296 AC_CHECK_DECL([futex_async], [],
 297         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 298 )
 299 AC_CHECK_DECL([rcu_thread_offline], [],
 300         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 301 )
 302 AC_CHECK_DECL([rcu_thread_online], [],
 303         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 304 )
 305 AC_CHECK_DECL([caa_likely], [],
 306         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 307 )
 308 #Function added in urcu 0.7.0
 309 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 310         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 311 )
 312
 313 # Check kmod library
 314 AC_ARG_WITH(kmod-prefix,
 315   AS_HELP_STRING([--with-kmod-prefix=PATH],
 316                 [Specify the installation prefix of the kmod library.
 317                 Headers must be in PATH/include; libraries in PATH/lib.]),
 318                 [
 319                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 320                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 321                 ])
 322
 323 AC_ARG_ENABLE(kmod,
 324         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 325         kmod_support=zz$enableval, kmod_support=yes)
 326
 327 AS_IF([test "x$kmod_support" = "xyes"], [
 328         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 329                 [
 330                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 331                         LIBS="$LIBS -lkmod"
 332                         kmod_found=yes
 333                 ],
 334                 kmod_found=no
 335         )
 336 ])
 337 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 338
 339 AC_ARG_WITH(lttng-ust-prefix,
 340   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 341                  [Specify the installation prefix of the lttng-ust library.
 342                   Headers must be in PATH/include; libraries in PATH/lib.]),
 343                   [
 344                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 345                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 346                   ])
 347
 348 # Check liblttng-ust-ctl library
 349 AC_ARG_WITH(lttng-ust,
 350         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 351         lttng_ust_support=$withval, lttng_ust_support=yes)
 352
 353 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 354         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 355                 [
 356                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 357                         lttng_ust_ctl_found=yes
 358                 ],
 359                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 360                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 361         )
 362 ])
 363 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 364 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 365
 366 # check for dlopen
 367 AC_CHECK_LIB([dl], [dlopen],
 368 [
 369         have_libdl=yes
 370 ],
 371 [
 372         #libdl not found, check for dlopen in libc.
 373         AC_CHECK_LIB([c], [dlopen],
 374         [
 375                 have_libc_dl=yes
 376         ],
 377         [
 378                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 379         ])
 380 ])
 381 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 382 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 383
 384 # Check for fmemopen
 385 AC_CHECK_LIB([c], [fmemopen],
 386 [
 387         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 388 ]
 389 )
 390
 391 # Check for open_memstream
 392 AC_CHECK_LIB([c], [open_memstream],
 393 [
 394         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 395 ]
 396 )
 397
 398 AC_ARG_ENABLE([git-version],
 399               [AC_HELP_STRING([--disable-git-version],
 400                               [Do not use the git version for the build])],
 401               [have_git_version=$enableval], [have_git_version=yes]
 402 )
 403
 404 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 405         [test "x${have_git_version}" = "xyes"])
 406
 407 # For Python
 408 # SWIG version needed or newer:
 409 swig_version=2.0.0
 410
 411 AC_ARG_ENABLE([python-bindings],
 412               [AC_HELP_STRING([--enable-python-bindings],
 413                               [compile Python bindings])],
 414               [enable_python_binding=yes], [enable_python_binding=no])
 415
 416 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 417
 418 if test "x${enable_python_binding:-yes}" = xyes; then
 419   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 420   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 421   AM_PATH_PYTHON([3.0])
 422
 423   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 424   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 425   AS_IF([test -z "$PYTHON_INCLUDE"], [
 426     AS_IF([test -z "$PYTHON_CONFIG"], [
 427       AC_PATH_PROGS([PYTHON_CONFIG],
 428                     [python$PYTHON_VERSION-config python-config],
 429                     [no],
 430                     [`dirname $PYTHON`])
 431       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 432     ])
 433     AC_MSG_CHECKING([python include flags])
 434     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 435     AC_MSG_RESULT([$PYTHON_INCLUDE])
 436   ])
 437
 438 else
 439     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 440 [if you want Python bindings.])
 441
 442 fi
 443
 444 # Epoll check. If not present, the build will fallback on poll() API
 445 AX_HAVE_EPOLL(
 446         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 447         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 448 )
 449 AX_CONFIG_FEATURE(
 450         [epoll], [This platform supports epoll(7)],
 451         [HAVE_EPOLL], [This platform supports epoll(7).],
 452         [enable_epoll="yes"], [enable_epoll="no"]
 453 )
 454 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 455
 456 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 457 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 458
 459 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 460         AX_JAVA_OPTIONS
 461         AX_PROG_JAVAC
 462         AX_PROG_JAVA
 463         AX_PROG_JAR
 464
 465         AX_CHECK_CLASSPATH
 466
 467         # Check for Java UST agent common class first
 468         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 469         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 470                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 471         fi
 472
 473         if test "x$test_java_agent_jul" = "xyes"; then
 474                 # Check for JUL agent class
 475                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 476                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 477                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 478                 fi
 479         fi
 480
 481         if test "x$test_java_agent_log4j" = "xyes"; then
 482                 # Check for Log4j agent class
 483                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 484                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 485                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 486                 fi
 487
 488                 # Check for Log4j class
 489                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 490                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 491                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 492                 fi
 493         fi
 494 fi
 495
 496 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 497 # is not distributed in tarballs
 498 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 499 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 500
 501 # enable building man pages
 502 AC_ARG_ENABLE(
 503         build-man-pages,
 504         AS_HELP_STRING(
 505                 [--disable-build-man-pages],
 506                 [Build man pages (already built in a distributed tarball)]
 507         ),
 508         [build_man_pages=$enableval],
 509         [build_man_pages=yes]
 510 )
 511
 512 # export man page build condition
 513 AM_CONDITIONAL([BUILD_MAN_PAGES], [test "x$build_man_pages" != "xno"])
 514
 515 # check for asciidoc and xmlto if we enabled building the man pages
 516 AS_IF([test "x$build_man_pages" = "xyes"], [
 517         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 518         AC_PATH_PROG([XMLTO], [xmlto], [no])
 519
 520         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 521                 AC_MSG_ERROR([Both asciidoc and xmlto are needed to build the LTTng man pages.])
 522         ])
 523 ])
 524
 525 # Python agent test
 526 UST_PYTHON_AGENT="lttngust"
 527
 528 AC_ARG_ENABLE(test-python2-agent,
 529         AS_HELP_STRING([--enable-test-python2-agent],
 530                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 531         ),[:],[test_python2_agent_autodetect=yes]
 532 )
 533
 534 AC_ARG_ENABLE(test-python3-agent,
 535         AS_HELP_STRING([--enable-test-python3-agent],
 536                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 537         ),[:],[test_python3_agent_autodetect=yes]
 538 )
 539
 540 AC_ARG_ENABLE(test-python-agent-all,
 541         AS_HELP_STRING([--enable-test-python-agent-all],
 542                 [enable test for all python{2/3} agent.]
 543         ),
 544 )
 545
 546 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 547        unset test_python2_agent_autodetect
 548        unset test_python3_agent_autodetect
 549 ])
 550
 551 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 552        enable_test_python2_agent=yes
 553        enable_test_python3_agent=yes
 554 ])
 555
 556 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 557        enable_test_python2_agent=no
 558        enable_test_python3_agent=no
 559 ])
 560
 561
 562 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 563         AS_IF([test -z "$PYTHON2"], [
 564                         PYTHON2=python2
 565                 ], [
 566                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 567         ])
 568
 569         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 570         AS_IF([test -z "$PYTHON2_BIN"], [
 571                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 572                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 573                 ])
 574         ], [
 575                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 576                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 577                         PYTHON2_AGENT=$PYTHON2_BIN
 578                         AC_MSG_RESULT([yes])
 579                         RUN_PYTHON_AGENT_TEST=yes
 580                 ], [
 581                         AC_MSG_RESULT([no])
 582                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 583                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 584                         ])
 585                 ])
 586
 587         ])
 588
 589 ])
 590
 591 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 592         AS_IF([test -z "$PYTHON3"], [
 593                 PYTHON3=python3
 594         ], [
 595                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 596         ])
 597
 598         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 599         AS_IF([test -z "$PYTHON3_BIN"], [
 600                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 601                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 602                 ])
 603         ], [
 604                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 605                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 606                         PYTHON3_AGENT=$PYTHON3_BIN
 607                         AC_MSG_RESULT([yes])
 608                         RUN_PYTHON_AGENT_TEST=yes
 609                 ], [
 610                         AC_MSG_RESULT([no])
 611                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 612                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 613                         ])
 614                 ])
 615
 616         ])
 617 ])
 618 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 619 AC_SUBST([PYTHON2_AGENT])
 620 AC_SUBST([PYTHON3_AGENT])
 621
 622 # Arguments for binaries build exclusion
 623 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 624 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 625               [Disable the build of lttng-consumerd binaries]))
 626 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 627 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 628               [Disable the build of lttng-relayd binaries]))
 629 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 630               [Disable the build of lttng-sessiond binaries]))
 631 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 632               [Disable the build of the extra components]))
 633
 634
 635 # Always build libconfig since it a dependency of libcommon
 636 build_lib_config=yes
 637
 638 build_lib_compat=no
 639 build_lib_consumer=no
 640 build_lib_hashtable=no
 641 build_lib_health=no
 642 build_lib_index=no
 643 build_lib_kernel_consumer=no
 644 build_lib_kernel_ctl=no
 645 build_lib_lttng_ctl=no
 646 build_lib_relayd=no
 647 build_lib_sessiond_comm=no
 648 build_lib_testpoint=no
 649 build_lib_ust_consumer=no
 650
 651 # There is an overlap for enabled dependencies, but this makes everything
 652 # simpler. libcommon and libconfig are always compiled so they are not repeated
 653 # here.
 654
 655 # Enable binary dependencies.
 656 AS_IF([test x$enable_bin_lttng != xno],
 657       [
 658        build_lib_lttng_ctl=yes
 659       ]
 660 )
 661
 662 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 663       [
 664        build_lib_consumer=yes
 665        build_lib_sessiond_comm=yes
 666        build_lib_index=yes
 667        build_lib_health=yes
 668        build_lib_testpoint=yes
 669       ]
 670 )
 671
 672 AS_IF([test x$enable_bin_lttng_crash != xno],
 673       # Do nothing since libconfig and libcommon are built by default.
 674       []
 675 )
 676
 677 AS_IF([test x$enable_bin_lttng_relayd != xno],
 678       [
 679        build_lib_lttng_ctl=yes
 680        build_lib_sessiond_comm=yes
 681        build_lib_hashtable=yes
 682        build_lib_compat=yes
 683        build_lib_index=yes
 684        build_lib_health=yes
 685        build_lib_testpoint=yes
 686       ]
 687 )
 688 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 689       [
 690        build_lib_lttng_ctl=yes
 691        build_lib_sessiond_comm=yes
 692        build_lib_kernel_ctl=yes
 693        build_lib_hashtable=yes
 694        build_lib_compat=yes
 695        build_lib_relayd=yes
 696        build_lib_testpoint=yes
 697        build_lib_health=yes
 698        build_lib_health=yes
 699       ]
 700 )
 701
 702 # Libraries dependencies enabling
 703 AS_IF([test x$build_lib_lttng_ctl = xyes],
 704       [
 705        build_lib_sessiond_comm=yes
 706        build_lib_hashtable=yes
 707       ]
 708 )
 709
 710 AS_IF([test x$build_lib_consumer = xyes],
 711       [
 712        build_lib_sessiond_comm=yes
 713        build_lib_kernel_consumer=yes
 714        build_lib_hashtable=yes
 715        build_lib_compat=yes
 716        build_lib_relayd=yes
 717        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 718       ]
 719 )
 720
 721 AS_IF([test x$build_lib_kernel_consumer = xyes],
 722       [
 723        build_lib_kernel_ctl=yes
 724        build_lib_relayd=yes
 725       ]
 726 )
 727
 728 AS_IF([test x$build_lib_relayd = xyes],
 729       [
 730        build_lib_sessiond_comm=yes
 731       ]
 732 )
 733
 734
 735 # Export binaries build conditions.
 736 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 737 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 738 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 739 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 740 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 741
 742 # Export the tests and extras build conditions.
 743 AS_IF([\
 744 test "x$enable_bin_lttng" != "xno" && \
 745 test "x$enable_bin_lttng_consumerd" != "xno" && \
 746 test "x$enable_bin_lttng_crash" != "xno" && \
 747 test "x$enable_bin_lttng_relayd" != "xno" && \
 748 test "x$enable_bin_lttng_sessiond" != "xno"],
 749 [build_tests=yes],
 750 [build_tests=no]
 751 )
 752
 753 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 754 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 755
 756 # Export libraries build conditions.
 757 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 758 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 759 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 760 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 761 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 762 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 763 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 764 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 765 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 766 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 767 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 768 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 769 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 770
 771 # check for pgrep
 772 AC_PATH_PROG([PGREP], [pgrep], [no])
 773 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 774
 775 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 776         if test x"$(basename "$YACC")" != "xbison -y"; then
 777                 AC_MSG_ERROR([[bison not found and is required when building from git.
 778                 Please install bison]])
 779         fi
 780         AC_PATH_PROG([BISON],[bison])
 781         AX_PROG_BISON_VERSION([2.4], [],[
 782                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 783         ])
 784 fi
 785
 786 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 787         if test x"$LEX" != "xflex"; then
 788                 AC_MSG_ERROR([[flex not found and is required when building from git.
 789                 Please install flex]])
 790         fi
 791         AC_PATH_PROG([FLEX],[flex])
 792         AX_PROG_FLEX_VERSION([2.5.35], [],[
 793                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 794         ])
 795 fi
 796
 797 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 798
 799 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 800
 801 lttngincludedir="${includedir}/lttng"
 802
 803 AC_SUBST(lttngincludedir)
 804 AC_SUBST(DEFAULT_INCLUDES)
 805
 806 lttnglibexecdir="${libdir}/lttng/libexec"
 807 AC_SUBST(lttnglibexecdir)
 808
 809 AC_CONFIG_FILES([
 810         Makefile
 811         doc/Makefile
 812         doc/man/Makefile
 813         include/Makefile
 814         extras/Makefile
 815         extras/bindings/Makefile
 816         extras/bindings/swig/Makefile
 817         extras/bindings/swig/python/Makefile
 818         extras/core-handler/Makefile
 819         src/Makefile
 820         src/common/Makefile
 821         src/common/kernel-ctl/Makefile
 822         src/common/kernel-consumer/Makefile
 823         src/common/consumer/Makefile
 824         src/common/ust-consumer/Makefile
 825         src/common/hashtable/Makefile
 826         src/common/sessiond-comm/Makefile
 827         src/common/compat/Makefile
 828         src/common/relayd/Makefile
 829         src/common/testpoint/Makefile
 830         src/common/index/Makefile
 831         src/common/health/Makefile
 832         src/common/config/Makefile
 833         src/lib/Makefile
 834         src/lib/lttng-ctl/Makefile
 835         src/lib/lttng-ctl/filter/Makefile
 836         src/lib/lttng-ctl/lttng-ctl.pc
 837         src/bin/Makefile
 838         src/bin/lttng-consumerd/Makefile
 839         src/bin/lttng-sessiond/Makefile
 840         src/bin/lttng-relayd/Makefile
 841         src/bin/lttng/Makefile
 842         src/bin/lttng-crash/Makefile
 843         tests/Makefile
 844         tests/destructive/Makefile
 845         tests/regression/Makefile
 846         tests/regression/kernel/Makefile
 847         tests/regression/tools/Makefile
 848         tests/regression/tools/streaming/Makefile
 849         tests/regression/tools/filtering/Makefile
 850         tests/regression/tools/health/Makefile
 851         tests/regression/tools/tracefile-limits/Makefile
 852         tests/regression/tools/snapshots/Makefile
 853         tests/regression/tools/live/Makefile
 854         tests/regression/tools/exclusion/Makefile
 855         tests/regression/tools/save-load/Makefile
 856         tests/regression/tools/mi/Makefile
 857         tests/regression/tools/wildcard/Makefile
 858         tests/regression/tools/crash/Makefile
 859         tests/regression/tools/metadata-regen/Makefile
 860         tests/regression/ust/Makefile
 861         tests/regression/ust/nprocesses/Makefile
 862         tests/regression/ust/high-throughput/Makefile
 863         tests/regression/ust/low-throughput/Makefile
 864         tests/regression/ust/before-after/Makefile
 865         tests/regression/ust/buffers-pid/Makefile
 866         tests/regression/ust/periodical-metadata-flush/Makefile
 867         tests/regression/ust/multi-session/Makefile
 868         tests/regression/ust/overlap/Makefile
 869         tests/regression/ust/overlap/demo/Makefile
 870         tests/regression/ust/linking/Makefile
 871         tests/regression/ust/daemon/Makefile
 872         tests/regression/ust/exit-fast/Makefile
 873         tests/regression/ust/fork/Makefile
 874         tests/regression/ust/libc-wrapper/Makefile
 875         tests/regression/ust/baddr-statedump/Makefile
 876         tests/regression/ust/ust-dl/Makefile
 877         tests/regression/ust/java-jul/Makefile
 878         tests/regression/ust/java-log4j/Makefile
 879         tests/regression/ust/python-logging/Makefile
 880         tests/regression/ust/getcpu-override/Makefile
 881         tests/regression/ust/clock-override/Makefile
 882         tests/regression/ust/type-declarations/Makefile
 883         tests/stress/Makefile
 884         tests/unit/Makefile
 885         tests/unit/ini_config/Makefile
 886         tests/utils/Makefile
 887         tests/utils/tap/Makefile
 888         tests/utils/testapp/Makefile
 889         tests/utils/testapp/gen-ust-events/Makefile
 890         tests/utils/testapp/gen-ust-nevents/Makefile
 891         tests/utils/testapp/gen-ust-tracef/Makefile
 892 ])
 893
 894 # Inject variable into python test script.
 895 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 896
 897 AC_OUTPUT
 898
 899 #
 900 # Mini-report on what will be built.
 901 #
 902
 903 PPRINT_INIT
 904 PPRINT_SET_INDENT(1)
 905 PPRINT_SET_TS(38)
 906
 907 AS_ECHO
 908 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
 909 AS_ECHO
 910
 911 AS_IF([test -n "$report_fold"], [
 912         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
 913 ], [
 914         AS_ECHO("$version_description")
 915 ])
 916
 917 AS_ECHO
 918 PPRINT_SUBTITLE([Features])
 919
 920 # Target architecture we're building for.
 921 target_arch=$host_cpu
 922 [
 923 for f in $CFLAGS; do
 924         if test $f = "-m32"; then
 925                         target_arch="32-bit"
 926         elif test $f = "-m64"; then
 927                         target_arch="64-bit"
 928         fi
 929 done
 930 ]
 931 PPRINT_PROP_STRING([Target architecture], $target_arch)
 932
 933 # kmod enabled/disabled
 934 test "x$kmod_found" = "xyes" && value=1 || value=0
 935 PPRINT_PROP_BOOL([libkmod support], $value)
 936
 937 # LTTng-UST enabled/disabled
 938 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
 939 PPRINT_PROP_BOOL([LTTng-UST support], $value)
 940
 941 AS_ECHO
 942 PPRINT_SUBTITLE([Binaries])
 943
 944 # List binaries to be built
 945 test x$enable_bin_lttng != xno && value=1 || value=0
 946 PPRINT_PROP_BOOL([lttng], $value)
 947
 948 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
 949 PPRINT_PROP_BOOL([lttng-consumerd], $value)
 950
 951 test x$enable_bin_lttng_crash != xno && value=1 || value=0
 952 PPRINT_PROP_BOOL([lttng-crash], $value)
 953
 954 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
 955 PPRINT_PROP_BOOL([lttng-relayd], $value)
 956
 957 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
 958 PPRINT_PROP_BOOL([lttng-sessiond], $value)
 959
 960 # Extras
 961 test x$enable_extras != xno && value=1 || value=0
 962 AS_ECHO
 963 PPRINT_SET_INDENT(0)
 964 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
 965 PPRINT_SET_INDENT(1)
 966
 967 AS_ECHO
 968 PPRINT_SUBTITLE([Tests])
 969
 970 # Print clear message that tests won't be built
 971 AS_IF([test "x$build_tests" = "xno"],[
 972         PPRINT_WARN([Tests won't be built since some binaries were disabled])
 973 ])
 974
 975 # LTTng UST Java agent JUL tests enabled/disabled
 976 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
 977 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
 978
 979 # LTTng UST Java agent Log4j tests enabled/disabled
 980 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
 981 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
 982
 983 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
 984 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
 985
 986 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
 987 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
 988
 989 #Python binding enabled/disabled
 990 test "x${enable_python_binding:-yes}" = xyes && value=1 || value=0
 991 AS_ECHO
 992 PPRINT_SET_INDENT(0)
 993 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
 994 PPRINT_SET_INDENT(1)
 995
 996 AS_ECHO
 997 PPRINT_SUBTITLE([Man pages])
 998
 999 # man pages build enabled/disabled
1000 AS_IF([test "x$build_man_pages" = "xyes"], [
1001         PPRINT_PROP_BOOL([Build man pages], 1)
1002 ], [
1003         AS_IF([test "x$in_git_repo" = "xyes"], [
1004                 PPRINT_PROP_BOOL([Build man pages], 0)
1005         ], [
1006                 PPRINT_PROP_STRING([Build man pages], [${PPRINT_COLOR_BLDGRN}Already built])
1007         ])
1008 ])
1009
1010 # man pages install enabled/disabled (always true in tarball)
1011 test "x$build_man_pages" != "xyes" && test "x$in_git_repo" = "xyes" && value=0 || value=1
1012 PPRINT_PROP_BOOL([Install man pages], $value)
1013
1014 report_bindir="`eval eval echo $bindir`"
1015 report_libdir="`eval eval echo $libdir`"
1016
1017 # Print the bindir and libdir this `make install' will install into.
1018 AS_ECHO
1019 PPRINT_SUBTITLE([Install directories])
1020 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1021 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1022
1023 AS_ECHO
1024 PPRINT_SUBTITLE([Search directories])
1025
1026 # If we build the sessiond, print the paths it will use
1027 AS_IF([test "$SESSIOND_BIN" = ""],[
1028         path="$report_bindir/lttng-sessiond"
1029 ],[
1030         path="$SESSIOND_BIN"
1031 ])
1032 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1033
1034 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1035         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1036 ],[
1037         path="$CONSUMERD32_BIN"
1038 ])
1039 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1040
1041 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1042         path="`eval eval echo $libdir`"
1043 ],[
1044         path="$CONSUMERD32_LIBDIR"
1045 ])
1046 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1047
1048 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1049         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1050 ],[
1051         path="$CONSUMERD64_BIN"
1052 ])
1053 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1054
1055 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1056         path="`eval eval echo $libdir`"
1057 ],[
1058         path="$CONSUMERD64_LIBDIR"
1059 ])
1060 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])