Remove calibrate documentation
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_LEX
28 AC_PROG_MAKE_SET
29 AC_PROG_SED
30 AC_PROG_YACC
31 AC_PATH_PROG(report_fold, fold)
32 LT_INIT
33
34 # Check for objcopy, required by the base address statedump and dynamic linker tests
35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
36 AS_IF([test "x$OBJCOPY" = xno],
37 [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
38 )
39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
40
41 # Checks for typedefs, structures, and compiler characteristics.
42 AC_C_INLINE
43 AC_TYPE_INT32_T
44 AC_TYPE_INT64_T
45 AC_TYPE_MODE_T
46 AC_TYPE_OFF_T
47 AC_TYPE_PID_T
48 AC_TYPE_SIZE_T
49 AC_TYPE_SSIZE_T
50 AC_TYPE_UID_T
51 AC_TYPE_UINT16_T
52 AC_TYPE_UINT32_T
53 AC_TYPE_UINT64_T
54 AC_TYPE_UINT8_T
55
56 AX_C___ATTRIBUTE__
57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
58 [:],
59 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
60
61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
62 LIBS="$PTHREAD_LIBS $LIBS"
63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
64 CC="$PTHREAD_CC"
65
66 AX_LIB_SOCKET_NSL
67
68 # Compute minor/major/patchlevel version numbers
69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
72
73 AC_SUBST([MAJOR_VERSION], [$major_version])
74 AC_SUBST([MINOR_VERSION], [$minor_version])
75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
79
80 version_name="Codename TBD"
81 version_description='Description TBD'
82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
83
84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
86
87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
88 AC_ARG_ENABLE(libtool-linkdep-fixup,
89 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
90 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
91 libtool_fixup=$enableval,
92 libtool_fixup=yes)
93
94 AS_IF([test "x$libtool_fixup" = "xyes"],
95 [
96 libtool_m4="$srcdir/m4/libtool.m4"
97 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
98 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
99 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
100 AS_IF([test $libtool_flag_pattern_count -ne 0],
101 [
102 AC_MSG_RESULT([$libtool_flag_pattern_count])
103 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
104 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
105 ],
106 [
107 AC_MSG_RESULT([none])
108 ])
109 ])
110
111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
112
113 AC_CHECK_HEADERS([ \
114 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
115 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
116 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
117 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
118 sys/mount.h sys/param.h sys/time.h
119 ])
120
121 # Basic functions check
122 AC_CHECK_FUNCS([ \
123 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
124 gethostbyname gethostname getpagesize localtime_r memchr memset \
125 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
126 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
127 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
128 ])
129
130 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
131 # add -lrt to LIBS
132 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
133
134 # Babeltrace viewer check
135 AC_ARG_WITH([babeltrace-bin],
136 AS_HELP_STRING([--with-babeltrace-bin],
137 [Location of the babeltrace viewer executable (including the filename)]),
138 [BABELTRACE_BIN="$withval"],
139 [BABELTRACE_BIN=''])
140 AC_SUBST([BABELTRACE_BIN])
141
142 # lttv-gui
143 AC_ARG_WITH([lttv-gui-bin],
144 AS_HELP_STRING([--with-lttv-gui-bin],
145 [Location of the lttv GUI viewer executable (including the filename)]),
146 [LTTV_GUI_BIN="$withval"],
147 [LTTV_GUI_BIN=''])
148 AC_SUBST([LTTV_GUI_BIN])
149
150 AC_ARG_WITH([consumerd32-bin],
151 AS_HELP_STRING([--with-consumerd32-bin],
152 [Location of the 32-bit consumerd executable (including the filename)]),
153 [CONSUMERD32_BIN="$withval"],
154 [CONSUMERD32_BIN=''])
155 AC_SUBST([CONSUMERD32_BIN])
156
157 AC_ARG_WITH([consumerd64-bin],
158 AS_HELP_STRING([--with-consumerd64-bin],
159 [Location of the 64-bit consumerd executable (including the filename)]),
160 [CONSUMERD64_BIN="$withval"],
161 [CONSUMERD64_BIN=''])
162 AC_SUBST([CONSUMERD64_BIN])
163
164 AC_ARG_WITH([consumerd32-libdir],
165 AS_HELP_STRING([--with-consumerd32-libdir],
166 [Directory containing the 32-bit consumerd libraries]),
167 [CONSUMERD32_LIBDIR="$withval"],
168 [CONSUMERD32_LIBDIR=''])
169 AC_SUBST([CONSUMERD32_LIBDIR])
170
171 AC_ARG_WITH([consumerd64-libdir],
172 AS_HELP_STRING([--with-consumerd64-libdir],
173 [Directory containing the 64-bit consumerd libraries]),
174 [CONSUMERD64_LIBDIR="$withval"],
175 [CONSUMERD64_LIBDIR=''])
176 AC_SUBST([CONSUMERD64_LIBDIR])
177
178 AC_ARG_WITH([sessiond-bin],
179 AS_HELP_STRING([--with-sessiond-bin],
180 [Location of the sessiond executable (including the filename)]),
181 [SESSIOND_BIN="$withval"],
182 [SESSIOND_BIN=''])
183 AC_SUBST([SESSIOND_BIN])
184
185 AC_ARG_WITH([lttng-system-rundir],
186 AS_HELP_STRING([--with-lttng-system-rundir],
187 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
188 [LTTNG_SYSTEM_RUNDIR="$withval"],
189 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
190 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
191
192 AC_ARG_ENABLE([test-java-agent-jul],
193 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
194 [test_java_agent_jul=$enableval],
195 [test_java_agent_jul=no]
196 )
197
198 AC_ARG_ENABLE([test-java-agent-log4j],
199 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
200 [test_java_agent_log4j=$enableval],
201 [test_java_agent_log4j=no]
202 )
203
204 AC_ARG_ENABLE([test-java-agent-all],
205 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
206 [test_java_agent_jul=$enableval
207 test_java_agent_log4j=$enableval],
208 [:]
209 )
210
211 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
212 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
213 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
214 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
215 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
216 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
217 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
218 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
219
220 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
221 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
222 $1="$2"
223 AC_SUBST([$1])
224 ])
225
226 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
227 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
228 $1="$2"
229 AC_SUBST([$1])
230 ])
231
232 # Default values
233 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
234 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
235 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
236 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
237 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
238 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
239 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
240 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
241 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
242 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
243 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
244 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
245 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
246 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
247 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
248 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
249 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
250 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
251 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
252 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
253 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
254 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
255 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
256 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
257 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
258 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
259 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
260 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
261 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
262 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
263 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
264 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
265 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
266 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
267 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
268 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
269 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
270 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
271
272 # Command short descriptions
273 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
274 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
275 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
276 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
277 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
278 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
279 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
280 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
281 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
282 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
283 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_METADATA], [Manage an LTTng tracing session's metadata generation])
284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
294
295 if test "x$prefix" = "xNONE"; then
296 prefix=$ac_default_prefix
297 fi
298 CONFDIR=`eval echo $sysconfdir`
299 AC_SUBST(CONFDIR)
300 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
301
302 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
303
304 #
305 # Check for pthread
306 AC_CHECK_LIB([pthread], [pthread_create], [],
307 [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
308 )
309
310 # Check libpopt
311 PKG_CHECK_MODULES([POPT], [popt],
312 [LIBS="$LIBS $POPT_LIBS"],
313 [
314 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
315 AC_MSG_WARN([Finding libpopt without pkg-config.])
316 AC_CHECK_LIB([popt],
317 [poptGetContext],
318 [],
319 [
320 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
321 ]
322 )
323 ]
324 )
325
326 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
327
328 # Check for uuid in system libs
329 AC_CHECK_FUNCS([uuid_generate],
330 [
331 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
332 link_with_libuuid=no
333 ],
334 [
335 # First, check the pkg-config module is available, otherwise explicitly check
336 # for libuuid, or uuid support in the C-library.
337 PKG_CHECK_MODULES([UUID], [uuid],
338 [
339 LIBS="$LIBS $UUID_LIBS"
340 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
341 link_with_libuuid=yes
342 ],
343 [
344 # Check for libuuid
345 AC_CHECK_LIB([uuid],
346 [uuid_generate],
347 [
348 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
349 link_with_libuuid=yes
350 ],
351 [
352 # libuuid not found, check for uuid_create in libc.
353 AC_CHECK_LIB([c],
354 [uuid_create],
355 [
356 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
357 link_with_libc_uuid=yes
358 ],
359 [
360 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
361 ]
362 )
363 ]
364 )
365 ])
366 ])
367
368 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
369 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
370
371 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
372
373 # URCU library version needed or newer
374 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
375
376 # Check liburcu needed function calls
377 AC_CHECK_DECL([cds_list_add], [],
378 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
379 AC_CHECK_DECL([cds_wfcq_init], [],
380 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
381 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
382 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
383 AC_CHECK_DECL([futex_async], [],
384 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
385 AC_CHECK_DECL([rcu_thread_offline], [],
386 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
387 AC_CHECK_DECL([rcu_thread_online], [],
388 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
389 AC_CHECK_DECL([caa_likely], [],
390 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
391 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
392 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
393
394 #Function added in urcu 0.7.0
395 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
396 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
397 )
398
399 # Check kmod library
400 AC_ARG_WITH(kmod-prefix,
401 AS_HELP_STRING([--with-kmod-prefix=PATH],
402 [Specify the installation prefix of the kmod library.
403 Headers must be in PATH/include; libraries in PATH/lib.]),
404 [
405 CPPFLAGS="$CPPFLAGS -I${withval}/include"
406 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
407 ])
408
409 AC_ARG_ENABLE(kmod,
410 AS_HELP_STRING([--disable-kmod],[build without kmod support]),
411 kmod_support=$enableval, kmod_support=yes)
412
413 AS_IF([test "x$kmod_support" = "xyes"], [
414 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
415 [
416 AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
417 LIBS="$LIBS -lkmod"
418 kmod_found=yes
419 ],
420 kmod_found=no
421 )
422 ])
423 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
424
425 AC_ARG_WITH(lttng-ust-prefix,
426 AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
427 [Specify the installation prefix of the lttng-ust library.
428 Headers must be in PATH/include; libraries in PATH/lib.]),
429 [
430 CPPFLAGS="$CPPFLAGS -I${withval}/include"
431 LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
432 ])
433
434 # Check liblttng-ust-ctl library
435 AC_ARG_WITH(lttng-ust,
436 AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
437 lttng_ust_support=$withval, lttng_ust_support=yes)
438
439 AS_IF([test "x$lttng_ust_support" = "xyes"], [
440 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
441 [
442 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
443 lttng_ust_ctl_found=yes
444 ],
445 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
446 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
447 )
448 ])
449 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
450 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
451
452 # check for dlopen
453 AC_CHECK_LIB([dl], [dlopen],
454 [
455 have_libdl=yes
456 ],
457 [
458 #libdl not found, check for dlopen in libc.
459 AC_CHECK_LIB([c], [dlopen],
460 [
461 have_libc_dl=yes
462 ],
463 [
464 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
465 ])
466 ])
467 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
468 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
469
470 # Check for fmemopen
471 AC_CHECK_LIB([c], [fmemopen],
472 [
473 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
474 ]
475 )
476
477 # Check for open_memstream
478 AC_CHECK_LIB([c], [open_memstream],
479 [
480 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
481 ]
482 )
483
484 AC_ARG_ENABLE([git-version],
485 [AC_HELP_STRING([--disable-git-version],
486 [Do not use the git version for the build])],
487 [have_git_version=$enableval], [have_git_version=yes]
488 )
489
490 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
491 [test "x${have_git_version}" = "xyes"])
492
493 # For Python
494 # SWIG version needed or newer:
495 swig_version=2.0.0
496
497 AC_ARG_ENABLE([python-bindings],
498 [AC_HELP_STRING([--enable-python-bindings],
499 [compile Python bindings])],
500 [enable_python_binding=$enableval], [enable_python_binding=no])
501
502 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
503
504 if test "x$enable_python_binding" = xyes; then
505 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
506 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
507 AM_PATH_PYTHON([3.0])
508
509 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
510 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
511 AS_IF([test -z "$PYTHON_INCLUDE"], [
512 AS_IF([test -z "$PYTHON_CONFIG"], [
513 AC_PATH_PROGS([PYTHON_CONFIG],
514 [python$PYTHON_VERSION-config python-config],
515 [no],
516 [`dirname $PYTHON`])
517 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
518 ])
519 AC_MSG_CHECKING([python include flags])
520 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
521 AC_MSG_RESULT([$PYTHON_INCLUDE])
522 ])
523
524 else
525 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
526 [if you want Python bindings.])
527
528 fi
529
530 # Epoll check. If not present, the build will fallback on poll() API
531 AX_HAVE_EPOLL(
532 [AX_CONFIG_FEATURE_ENABLE(epoll)],
533 [AX_CONFIG_FEATURE_DISABLE(epoll)]
534 )
535 AX_CONFIG_FEATURE(
536 [epoll], [This platform supports epoll(7)],
537 [HAVE_EPOLL], [This platform supports epoll(7).],
538 [enable_epoll="yes"], [enable_epoll="no"]
539 )
540 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
541
542 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
543 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
544
545 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
546 AX_JAVA_OPTIONS
547 AX_PROG_JAVAC
548 AX_PROG_JAVA
549 AX_PROG_JAR
550
551 AX_CHECK_CLASSPATH
552
553 # Check for Java UST agent common class first
554 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
555 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
556 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
557 fi
558
559 if test "x$test_java_agent_jul" = "xyes"; then
560 # Check for JUL agent class
561 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
562 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
563 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
564 fi
565 fi
566
567 if test "x$test_java_agent_log4j" = "xyes"; then
568 # Check for Log4j agent class
569 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
570 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
571 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
572 fi
573
574 # Check for Log4j class
575 AX_CHECK_CLASS(org.apache.log4j.Logger)
576 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
577 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
578 fi
579 fi
580 fi
581
582 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
583 # is not distributed in tarballs
584 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
585 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
586
587 # enable building man pages (user's intention)
588 AC_ARG_ENABLE(
589 man-pages,
590 AS_HELP_STRING(
591 [--disable-man-pages],
592 [Do not build and install man pages (already built in a distributed tarball)]
593 ),
594 [man_pages_opt=$enableval],
595 [man_pages_opt=yes]
596 )
597
598 # check for asciidoc and xmlto if we enabled building the man pages
599 have_asciidoc_xmlto=no
600
601 AS_IF([test "x$man_pages_opt" = "xyes"], [
602 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
603 AC_PATH_PROG([XMLTO], [xmlto], [no])
604
605 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
606 AS_IF([test "x$in_git_repo" = "xyes"], [
607 # this is an error because we're in the Git repo, which
608 # means the man pages are not already generated for us,
609 # thus asciidoc/xmlto are required because we were asked
610 # to build the man pages
611 AC_MSG_ERROR([
612 Both asciidoc and xmlto are needed to build the LTTng man pages. Use
613 --disable-man-pages to disable building the man pages, in which case
614 they will not be installed.
615 ])
616 ], [
617 # only warn here: since we're in the tarball, the man
618 # pages should already be generated at this point, thus
619 # asciidoc/xmlto are not strictly required
620 AC_MSG_WARN([
621 Both asciidoc and xmlto are needed to build the LTTng man pages. Note
622 that the man pages are already built in this distribution tarball, so
623 asciidoc and xmlto are only needed if you intend to modify their
624 sources. Use --disable-man-pages to completely disable building
625 and installing the man pages.
626 ])
627 ])
628 ], [
629 have_asciidoc_xmlto=yes
630 ])
631 ])
632
633 # export man page build condition: build the man pages if the user
634 # asked for it, and if the tools are available
635 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
636 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
637
638 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
639
640 # Python agent test
641 UST_PYTHON_AGENT="lttngust"
642
643 AC_ARG_ENABLE(test-python2-agent,
644 AS_HELP_STRING([--enable-test-python2-agent],
645 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
646 ),[:],[test_python2_agent_autodetect=yes]
647 )
648
649 AC_ARG_ENABLE(test-python3-agent,
650 AS_HELP_STRING([--enable-test-python3-agent],
651 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
652 ),[:],[test_python3_agent_autodetect=yes]
653 )
654
655 AC_ARG_ENABLE(test-python-agent-all,
656 AS_HELP_STRING([--enable-test-python-agent-all],
657 [enable test for all python{2/3} agent.]
658 ),
659 )
660
661 AS_IF([test ! -z "$enable_test_python_agent_all"], [
662 unset test_python2_agent_autodetect
663 unset test_python3_agent_autodetect
664 ])
665
666 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
667 enable_test_python2_agent=yes
668 enable_test_python3_agent=yes
669 ])
670
671 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
672 enable_test_python2_agent=no
673 enable_test_python3_agent=no
674 ])
675
676
677 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
678 AS_IF([test -z "$PYTHON2"], [
679 PYTHON2=python2
680 ], [
681 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
682 ])
683
684 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
685 AS_IF([test -z "$PYTHON2_BIN"], [
686 AS_IF([test -z "$test_python2_agent_autodetect"],[
687 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
688 ])
689 ], [
690 AC_MSG_CHECKING([for python2 lttng-ust agent])
691 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
692 PYTHON2_AGENT=$PYTHON2_BIN
693 AC_MSG_RESULT([yes])
694 RUN_PYTHON_AGENT_TEST=yes
695 ], [
696 AC_MSG_RESULT([no])
697 AS_IF([test -z "$test_python2_agent_autodetect"],[
698 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
699 ])
700 ])
701
702 ])
703
704 ])
705
706 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
707 AS_IF([test -z "$PYTHON3"], [
708 PYTHON3=python3
709 ], [
710 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
711 ])
712
713 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
714 AS_IF([test -z "$PYTHON3_BIN"], [
715 AS_IF([test -z "$test_python3_agent_autodetect"],[
716 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
717 ])
718 ], [
719 AC_MSG_CHECKING([for python3 lttng-ust agent])
720 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
721 PYTHON3_AGENT=$PYTHON3_BIN
722 AC_MSG_RESULT([yes])
723 RUN_PYTHON_AGENT_TEST=yes
724 ], [
725 AC_MSG_RESULT([no])
726 AS_IF([test -z "$test_python3_agent_autodetect"],[
727 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
728 ])
729 ])
730
731 ])
732 ])
733 AC_SUBST([RUN_PYTHON_AGENT_TEST])
734 AC_SUBST([PYTHON2_AGENT])
735 AC_SUBST([PYTHON3_AGENT])
736
737 # Arguments for binaries build exclusion
738 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
739 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
740 [Disable the build of lttng-consumerd binaries]))
741 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
742 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
743 [Disable the build of lttng-relayd binaries]))
744 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
745 [Disable the build of lttng-sessiond binaries]))
746 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
747 [Disable the build of the extra components]))
748
749
750 # Always build libconfig since it a dependency of libcommon
751 build_lib_config=yes
752
753 build_lib_compat=no
754 build_lib_consumer=no
755 build_lib_hashtable=no
756 build_lib_health=no
757 build_lib_index=no
758 build_lib_kernel_consumer=no
759 build_lib_kernel_ctl=no
760 build_lib_lttng_ctl=no
761 build_lib_relayd=no
762 build_lib_sessiond_comm=no
763 build_lib_testpoint=no
764 build_lib_ust_consumer=no
765
766 # There is an overlap for enabled dependencies, but this makes everything
767 # simpler. libcommon and libconfig are always compiled so they are not repeated
768 # here.
769
770 # Enable binary dependencies.
771 AS_IF([test x$enable_bin_lttng != xno],
772 [
773 build_lib_lttng_ctl=yes
774 ]
775 )
776
777 AS_IF([test x$enable_bin_lttng_consumerd != xno],
778 [
779 build_lib_consumer=yes
780 build_lib_sessiond_comm=yes
781 build_lib_index=yes
782 build_lib_health=yes
783 build_lib_testpoint=yes
784 ]
785 )
786
787 AS_IF([test x$enable_bin_lttng_crash != xno],
788 # Do nothing since libconfig and libcommon are built by default.
789 []
790 )
791
792 AS_IF([test x$enable_bin_lttng_relayd != xno],
793 [
794 build_lib_lttng_ctl=yes
795 build_lib_sessiond_comm=yes
796 build_lib_hashtable=yes
797 build_lib_compat=yes
798 build_lib_index=yes
799 build_lib_health=yes
800 build_lib_testpoint=yes
801 ]
802 )
803 AS_IF([test x$enable_bin_lttng_sessiond != xno],
804 [
805 build_lib_lttng_ctl=yes
806 build_lib_sessiond_comm=yes
807 build_lib_kernel_ctl=yes
808 build_lib_hashtable=yes
809 build_lib_compat=yes
810 build_lib_relayd=yes
811 build_lib_testpoint=yes
812 build_lib_health=yes
813 build_lib_health=yes
814 ]
815 )
816
817 # Libraries dependencies enabling
818 AS_IF([test x$build_lib_lttng_ctl = xyes],
819 [
820 build_lib_sessiond_comm=yes
821 build_lib_hashtable=yes
822 ]
823 )
824
825 AS_IF([test x$build_lib_consumer = xyes],
826 [
827 build_lib_sessiond_comm=yes
828 build_lib_kernel_consumer=yes
829 build_lib_hashtable=yes
830 build_lib_compat=yes
831 build_lib_relayd=yes
832 AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
833 ]
834 )
835
836 AS_IF([test x$build_lib_kernel_consumer = xyes],
837 [
838 build_lib_kernel_ctl=yes
839 build_lib_relayd=yes
840 ]
841 )
842
843 AS_IF([test x$build_lib_relayd = xyes],
844 [
845 build_lib_sessiond_comm=yes
846 ]
847 )
848
849
850 # Export binaries build conditions.
851 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
852 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
853 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
854 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
855 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
856
857 # Export the tests and extras build conditions.
858 AS_IF([\
859 test "x$enable_bin_lttng" != "xno" && \
860 test "x$enable_bin_lttng_consumerd" != "xno" && \
861 test "x$enable_bin_lttng_crash" != "xno" && \
862 test "x$enable_bin_lttng_relayd" != "xno" && \
863 test "x$enable_bin_lttng_sessiond" != "xno"],
864 [build_tests=yes],
865 [build_tests=no]
866 )
867
868 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
869 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
870
871 # Export libraries build conditions.
872 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
873 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
874 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
875 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
876 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
877 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
878 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
879 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
880 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
881 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
882 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
883 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
884 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
885
886 # check for pgrep
887 AC_PATH_PROG([PGREP], [pgrep], [no])
888 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
889
890 # check for bison
891 have_bison=yes
892
893 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
894 AC_PATH_PROG([BISON], [bison])
895 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
896
897 AS_IF([test "x$have_bison" = "xno"], [
898 AS_IF([test "x$in_git_repo" = "xyes"], [
899 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
900 ], [
901 AC_MSG_WARN([
902 Missing Bison >= 2.4. Note that the parser files are already built in
903 this distribution tarball, so Bison is only needed if you intend to
904 modify their sources.
905 ])
906 ])
907 ])
908
909 # export bison condition
910 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
911
912 # check for flex
913 have_flex=yes
914
915 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
916 AC_PATH_PROG([FLEX], [flex])
917 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
918
919 AS_IF([test "x$have_flex" = "xno"], [
920 AS_IF([test "x$in_git_repo" = "xyes"], [
921 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
922 ], [
923 AC_MSG_WARN([
924 Missing Flex >= 2.5.35. Note that the lexer files are already built in
925 this distribution tarball, so Flex is only needed if you intend to
926 modify their sources.
927 ])
928 ])
929 ])
930
931 # export flex condition
932 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
933
934 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
935
936 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
937
938 lttngincludedir="${includedir}/lttng"
939
940 AC_SUBST(lttngincludedir)
941 AC_SUBST(DEFAULT_INCLUDES)
942
943 lttnglibexecdir="${libdir}/lttng/libexec"
944 AC_SUBST(lttnglibexecdir)
945
946 AC_CONFIG_FILES([
947 Makefile
948 doc/Makefile
949 doc/man/Makefile
950 doc/man/asciidoc-attrs.conf
951 include/Makefile
952 extras/Makefile
953 extras/bindings/Makefile
954 extras/bindings/swig/Makefile
955 extras/bindings/swig/python/Makefile
956 extras/core-handler/Makefile
957 src/Makefile
958 src/common/Makefile
959 src/common/kernel-ctl/Makefile
960 src/common/kernel-consumer/Makefile
961 src/common/consumer/Makefile
962 src/common/ust-consumer/Makefile
963 src/common/hashtable/Makefile
964 src/common/sessiond-comm/Makefile
965 src/common/compat/Makefile
966 src/common/relayd/Makefile
967 src/common/testpoint/Makefile
968 src/common/index/Makefile
969 src/common/health/Makefile
970 src/common/config/Makefile
971 src/lib/Makefile
972 src/lib/lttng-ctl/Makefile
973 src/lib/lttng-ctl/filter/Makefile
974 src/lib/lttng-ctl/lttng-ctl.pc
975 src/bin/Makefile
976 src/bin/lttng-consumerd/Makefile
977 src/bin/lttng-sessiond/Makefile
978 src/bin/lttng-relayd/Makefile
979 src/bin/lttng/Makefile
980 src/bin/lttng-crash/Makefile
981 tests/Makefile
982 tests/destructive/Makefile
983 tests/regression/Makefile
984 tests/regression/kernel/Makefile
985 tests/regression/tools/Makefile
986 tests/regression/tools/streaming/Makefile
987 tests/regression/tools/filtering/Makefile
988 tests/regression/tools/health/Makefile
989 tests/regression/tools/tracefile-limits/Makefile
990 tests/regression/tools/snapshots/Makefile
991 tests/regression/tools/live/Makefile
992 tests/regression/tools/exclusion/Makefile
993 tests/regression/tools/save-load/Makefile
994 tests/regression/tools/save-load/configuration/Makefile
995 tests/regression/tools/mi/Makefile
996 tests/regression/tools/wildcard/Makefile
997 tests/regression/tools/crash/Makefile
998 tests/regression/tools/regen-metadata/Makefile
999 tests/regression/tools/regen-statedump/Makefile
1000 tests/regression/ust/Makefile
1001 tests/regression/ust/nprocesses/Makefile
1002 tests/regression/ust/high-throughput/Makefile
1003 tests/regression/ust/low-throughput/Makefile
1004 tests/regression/ust/before-after/Makefile
1005 tests/regression/ust/buffers-pid/Makefile
1006 tests/regression/ust/periodical-metadata-flush/Makefile
1007 tests/regression/ust/multi-session/Makefile
1008 tests/regression/ust/overlap/Makefile
1009 tests/regression/ust/overlap/demo/Makefile
1010 tests/regression/ust/linking/Makefile
1011 tests/regression/ust/daemon/Makefile
1012 tests/regression/ust/exit-fast/Makefile
1013 tests/regression/ust/fork/Makefile
1014 tests/regression/ust/libc-wrapper/Makefile
1015 tests/regression/ust/baddr-statedump/Makefile
1016 tests/regression/ust/ust-dl/Makefile
1017 tests/regression/ust/java-jul/Makefile
1018 tests/regression/ust/java-log4j/Makefile
1019 tests/regression/ust/python-logging/Makefile
1020 tests/regression/ust/getcpu-override/Makefile
1021 tests/regression/ust/clock-override/Makefile
1022 tests/regression/ust/type-declarations/Makefile
1023 tests/regression/ust/rotation-destroy-flush/Makefile
1024 tests/stress/Makefile
1025 tests/unit/Makefile
1026 tests/unit/ini_config/Makefile
1027 tests/utils/Makefile
1028 tests/utils/tap/Makefile
1029 tests/utils/testapp/Makefile
1030 tests/utils/testapp/gen-ust-events/Makefile
1031 tests/utils/testapp/gen-ust-nevents/Makefile
1032 tests/utils/testapp/gen-ust-tracef/Makefile
1033 ])
1034
1035 # Inject variable into python test script.
1036 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1037
1038 AC_OUTPUT
1039
1040 #
1041 # Mini-report on what will be built.
1042 #
1043
1044 PPRINT_INIT
1045 PPRINT_SET_INDENT(1)
1046 PPRINT_SET_TS(38)
1047
1048 AS_ECHO
1049 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1050 AS_ECHO
1051
1052 AS_IF([test -n "$report_fold"], [
1053 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1054 ], [
1055 AS_ECHO("$version_description")
1056 ])
1057
1058 AS_ECHO
1059 PPRINT_SUBTITLE([Features])
1060
1061 # Target architecture we're building for.
1062 target_arch=$host_cpu
1063 [
1064 for f in $CFLAGS; do
1065 if test $f = "-m32"; then
1066 target_arch="32-bit"
1067 elif test $f = "-m64"; then
1068 target_arch="64-bit"
1069 fi
1070 done
1071 ]
1072 PPRINT_PROP_STRING([Target architecture], $target_arch)
1073
1074 # kmod enabled/disabled
1075 test "x$kmod_found" = "xyes" && value=1 || value=0
1076 PPRINT_PROP_BOOL([libkmod support], $value)
1077
1078 # LTTng-UST enabled/disabled
1079 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1080 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1081
1082 AS_ECHO
1083 PPRINT_SUBTITLE([Binaries])
1084
1085 # List binaries to be built
1086 test x$enable_bin_lttng != xno && value=1 || value=0
1087 PPRINT_PROP_BOOL([lttng], $value)
1088
1089 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1090 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1091
1092 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1093 PPRINT_PROP_BOOL([lttng-crash], $value)
1094
1095 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1096 PPRINT_PROP_BOOL([lttng-relayd], $value)
1097
1098 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1099 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1100
1101 # Extras
1102 test x$enable_extras != xno && value=1 || value=0
1103 AS_ECHO
1104 PPRINT_SET_INDENT(0)
1105 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1106 PPRINT_SET_INDENT(1)
1107
1108 AS_ECHO
1109 PPRINT_SUBTITLE([Tests])
1110
1111 # Print clear message that tests won't be built
1112 AS_IF([test "x$build_tests" = "xno"],[
1113 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1114 ])
1115
1116 # LTTng UST Java agent JUL tests enabled/disabled
1117 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1118 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1119
1120 # LTTng UST Java agent Log4j tests enabled/disabled
1121 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1122 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1123
1124 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1125 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1126
1127 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1128 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1129
1130 #Python binding enabled/disabled
1131 test "x$enable_python_binding" = xyes && value=1 || value=0
1132 AS_ECHO
1133 PPRINT_SET_INDENT(0)
1134 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1135
1136 # man pages build enabled/disabled
1137 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1138
1139 AS_IF([test "x$man_pages_opt" != "xno"], [
1140 AS_IF([test "x$in_git_repo" = "xyes"], [
1141 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1142 ], [
1143 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1144 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1145 ], [
1146 PPRINT_PROP_STRING([build_man_pages_msg],
1147 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1148 $PPRINT_COLOR_SUBTITLE)
1149 ])
1150 ])
1151 ], [
1152 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1153 ])
1154
1155 m4_popdef([build_man_pages_msg])
1156
1157 PPRINT_SET_INDENT(1)
1158
1159 report_bindir="`eval eval echo $bindir`"
1160 report_libdir="`eval eval echo $libdir`"
1161
1162 # Print the bindir and libdir this `make install' will install into.
1163 AS_ECHO
1164 PPRINT_SUBTITLE([Install directories])
1165 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1166 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1167
1168 AS_ECHO
1169 PPRINT_SUBTITLE([Search directories])
1170
1171 # If we build the sessiond, print the paths it will use
1172 AS_IF([test "$SESSIOND_BIN" = ""],[
1173 path="$report_bindir/lttng-sessiond"
1174 ],[
1175 path="$SESSIOND_BIN"
1176 ])
1177 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1178
1179 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1180 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1181 ],[
1182 path="$CONSUMERD32_BIN"
1183 ])
1184 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1185
1186 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1187 path="`eval eval echo $libdir`"
1188 ],[
1189 path="$CONSUMERD32_LIBDIR"
1190 ])
1191 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1192
1193 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1194 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1195 ],[
1196 path="$CONSUMERD64_BIN"
1197 ])
1198 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1199
1200 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1201 path="`eval eval echo $libdir`"
1202 ],[
1203 path="$CONSUMERD64_LIBDIR"
1204 ])
1205 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
This page took 0.090121 seconds and 6 git commands to generate.