Cleanup: remove duplicated pthread detection code
[lttng-tools.git] / configure.ac
1 AC_PREREQ([2.64])
2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
3
4 AC_CONFIG_HEADERS([include/config.h])
5 AC_CONFIG_AUX_DIR([config])
6 AC_CONFIG_MACRO_DIR([m4])
7
8 AC_CANONICAL_TARGET
9 AC_CANONICAL_HOST
10
11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
12 AM_MAINTAINER_MODE([enable])
13
14 # Enable silent rules if available (Introduced in AM 1.11)
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
18
19 # Checks for C compiler
20 AC_USE_SYSTEM_EXTENSIONS
21 AC_SYS_LARGEFILE
22 AC_PROG_CC
23 AC_PROG_CC_STDC
24
25 # Checks for programs.
26 AC_PROG_GREP
27 AC_PROG_MAKE_SET
28 AC_PROG_SED
29 AC_PATH_PROG([report_fold], [fold])
30 LT_INIT
31
32 # Check for objcopy, required by the base address statedump and dynamic linker tests
33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
34 AS_IF([test "x$OBJCOPY" = "xno"],
35 [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
36 )
37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
38
39 # check for pgrep
40 AC_PATH_PROG([PGREP], [pgrep], [no])
41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
42
43 # check for bison
44 AC_PROG_YACC
45 BISON=$YACC
46 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
47
48 AS_IF([test "x$have_bison" != "xyes"], [
49 AS_IF([test "x$in_git_repo" = "xyes"], [
50 AC_MSG_FAILURE([
51 Bison >= 2.4 is required when building from the Git repository. You can
52 set the YACC variable to override automatic detection.
53 ])
54 ], [
55 AC_MSG_WARN([
56 Missing Bison >= 2.4. Note that the parser files are already built in
57 this distribution tarball, so Bison is only needed if you intend to
58 modify their sources. You can set the YACC variable to override automatic
59 detection.
60 ])
61 ])
62 ])
63 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
64
65 # check for flex
66 AC_PROG_LEX
67 FLEX=$LEX
68 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
69
70 AS_IF([test "x$have_flex" != "xyes"], [
71 AS_IF([test "x$in_git_repo" = "xyes"], [
72 AC_MSG_FAILURE([
73 Flex >= 2.5.35 is required when building from the Git repository. You can
74 set the LEX variable to override automatic detection.
75 ])
76 ], [
77 AC_MSG_WARN([
78 Missing Flex >= 2.5.35. Note that the lexer files are already built in
79 this distribution tarball, so Flex is only needed if you intend to
80 modify their sources. You can set the LEX variable to override automatic
81 detection.
82 ])
83 ])
84 ])
85 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
86
87
88 # Checks for typedefs, structures, and compiler characteristics.
89 AC_C_INLINE
90 AC_TYPE_INT32_T
91 AC_TYPE_INT64_T
92 AC_TYPE_MODE_T
93 AC_TYPE_OFF_T
94 AC_TYPE_PID_T
95 AC_TYPE_SIZE_T
96 AC_TYPE_SSIZE_T
97 AC_TYPE_UID_T
98 AC_TYPE_UINT16_T
99 AC_TYPE_UINT32_T
100 AC_TYPE_UINT64_T
101 AC_TYPE_UINT8_T
102
103 AX_C___ATTRIBUTE__
104 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
105 [:],
106 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
107
108 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
109
110 AX_LIB_SOCKET_NSL
111
112 LT_NO_UNDEFINED=""
113 AS_CASE([$host_os],
114 [cygwin*],
115 [
116 LT_NO_UNDEFINED="-no-undefined"
117 ]
118 )
119
120 AC_SUBST(LT_NO_UNDEFINED)
121
122 # Compute minor/major/patchlevel version numbers
123 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
124 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
125 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
126
127 AC_SUBST([MAJOR_VERSION], [$major_version])
128 AC_SUBST([MINOR_VERSION], [$minor_version])
129 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
130 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
131 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
132 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
133
134 version_name="KeKriek"
135 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
136 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
137
138 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
139 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
140
141 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
142 AC_ARG_ENABLE(libtool-linkdep-fixup,
143 AS_HELP_STRING([--disable-libtool-linkdep-fixup],
144 [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
145 libtool_fixup=$enableval,
146 libtool_fixup=yes)
147
148 AS_IF([test "x$libtool_fixup" = "xyes"],
149 [
150 libtool_m4="$srcdir/m4/libtool.m4"
151 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
152 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
153 libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
154 AS_IF([test $libtool_flag_pattern_count -ne 0],
155 [
156 AC_MSG_RESULT([$libtool_flag_pattern_count])
157 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
158 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
159 ],
160 [
161 AC_MSG_RESULT([none])
162 ])
163 ])
164
165 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
166
167 AC_CHECK_HEADERS([ \
168 sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
169 signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
170 getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
171 netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
172 sys/mount.h sys/param.h sys/time.h
173 ])
174
175 # Basic functions check
176 AC_CHECK_FUNCS([ \
177 atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
178 gethostbyname gethostname getpagesize localtime_r memchr memset \
179 mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
180 strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
181 strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
182 sched_getcpu sysconf sync_file_range
183 ])
184
185 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
186 # add -lrt to LIBS
187 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
188
189 # Babeltrace viewer check
190 AC_ARG_WITH([babeltrace-bin],
191 AS_HELP_STRING([--with-babeltrace-bin],
192 [Location of the babeltrace viewer executable (including the filename)]),
193 [BABELTRACE_BIN="$withval"],
194 [BABELTRACE_BIN=''])
195 AC_SUBST([BABELTRACE_BIN])
196
197 # lttv-gui
198 AC_ARG_WITH([lttv-gui-bin],
199 AS_HELP_STRING([--with-lttv-gui-bin],
200 [Location of the lttv GUI viewer executable (including the filename)]),
201 [LTTV_GUI_BIN="$withval"],
202 [LTTV_GUI_BIN=''])
203 AC_SUBST([LTTV_GUI_BIN])
204
205 AC_ARG_WITH([consumerd32-bin],
206 AS_HELP_STRING([--with-consumerd32-bin],
207 [Location of the 32-bit consumerd executable (including the filename)]),
208 [CONSUMERD32_BIN="$withval"],
209 [CONSUMERD32_BIN=''])
210 AC_SUBST([CONSUMERD32_BIN])
211
212 AC_ARG_WITH([consumerd64-bin],
213 AS_HELP_STRING([--with-consumerd64-bin],
214 [Location of the 64-bit consumerd executable (including the filename)]),
215 [CONSUMERD64_BIN="$withval"],
216 [CONSUMERD64_BIN=''])
217 AC_SUBST([CONSUMERD64_BIN])
218
219 AC_ARG_WITH([consumerd32-libdir],
220 AS_HELP_STRING([--with-consumerd32-libdir],
221 [Directory containing the 32-bit consumerd libraries]),
222 [CONSUMERD32_LIBDIR="$withval"],
223 [CONSUMERD32_LIBDIR=''])
224 AC_SUBST([CONSUMERD32_LIBDIR])
225
226 AC_ARG_WITH([consumerd64-libdir],
227 AS_HELP_STRING([--with-consumerd64-libdir],
228 [Directory containing the 64-bit consumerd libraries]),
229 [CONSUMERD64_LIBDIR="$withval"],
230 [CONSUMERD64_LIBDIR=''])
231 AC_SUBST([CONSUMERD64_LIBDIR])
232
233 AC_ARG_WITH([sessiond-bin],
234 AS_HELP_STRING([--with-sessiond-bin],
235 [Location of the sessiond executable (including the filename)]),
236 [SESSIOND_BIN="$withval"],
237 [SESSIOND_BIN=''])
238 AC_SUBST([SESSIOND_BIN])
239
240 AC_ARG_WITH([lttng-system-rundir],
241 AS_HELP_STRING([--with-lttng-system-rundir],
242 [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
243 [LTTNG_SYSTEM_RUNDIR="$withval"],
244 [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
245 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
246
247 AC_ARG_ENABLE([test-java-agent-jul],
248 [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
249 [test_java_agent_jul=$enableval],
250 [test_java_agent_jul=no]
251 )
252
253 AC_ARG_ENABLE([test-java-agent-log4j],
254 [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
255 [test_java_agent_log4j=$enableval],
256 [test_java_agent_log4j=no]
257 )
258
259 AC_ARG_ENABLE([test-java-agent-all],
260 [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
261 [test_java_agent_jul=$enableval
262 test_java_agent_log4j=$enableval],
263 [:]
264 )
265
266 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
267 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
268 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
269 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
270 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
271 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
272 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
273 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
274
275 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
276 AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
277 $1="$2"
278 AC_SUBST([$1])
279 ])
280
281 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
282 AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
283 $1="$2"
284 AC_SUBST([$1])
285 ])
286
287 # Default values
288 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
289 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
290 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
291 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
292 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
293 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
294 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
295 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
296 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
297 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
298 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
299 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
300 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
301 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
302 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
303 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
304 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
305 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
306 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
307 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
308 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
309 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
310 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
311 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
312 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
313 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
314 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
315 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
316 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
317 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
318 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
319 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
320 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
321 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
322 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
323 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
324 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
325 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
326 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
327 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
328 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
329 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
330
331 # Command short descriptions
332 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
333 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
334 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
335 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
336 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
337 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
338 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
339 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
340 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
341 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
342 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
343 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
344 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
345 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
346 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
347 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
348 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
349 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
350 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
351 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
352 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
353
354 if test "x$prefix" = "xNONE"; then
355 prefix=$ac_default_prefix
356 fi
357 CONFDIR=`eval echo $sysconfdir`
358 AC_SUBST(CONFDIR)
359 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
360
361 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
362
363 # Check libpopt
364 PKG_CHECK_MODULES([POPT], [popt],
365 [LIBS="$LIBS $POPT_LIBS"],
366 [
367 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
368 AC_MSG_WARN([Finding libpopt without pkg-config.])
369 AC_CHECK_LIB([popt],
370 [poptGetContext],
371 [],
372 [
373 AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
374 ]
375 )
376 ]
377 )
378
379 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
380
381 # First, check for uuid in system libs
382 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
383 AC_CHECK_FUNCS([uuid_generate],
384 [
385 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
386 UUID_LIBS=""
387 ],
388 [
389 # Then, check if the pkg-config module is available, otherwise explicitly check
390 # for libuuid, or uuid support in the C-library.
391 PKG_CHECK_MODULES([UUID], [uuid],
392 [
393 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
394 dnl PKG_CHECK_MODULES defines UUID_LIBS
395 ],
396 [
397 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
398 AC_MSG_WARN([Finding libuuid without pkg-config.])
399 AC_CHECK_LIB([uuid], [uuid_generate],
400 [
401 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
402 UUID_LIBS="-luuid"
403 ],
404 [
405 # libuuid not found, check for uuid_create in libc.
406 AC_CHECK_LIB([c], [uuid_create],
407 [
408 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
409 UUID_LIBS="-lc"
410 ],
411 [
412 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
413 ]
414 )
415 ]
416 )
417 ]
418 )
419 ]
420 )
421 AC_SUBST(UUID_LIBS)
422
423 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
424
425 # URCU library version needed or newer
426 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
427
428 # Check liburcu needed function calls
429 AC_CHECK_DECL([cds_list_add], [],
430 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
431 AC_CHECK_DECL([cds_wfcq_init], [],
432 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
433 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
434 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
435 AC_CHECK_DECL([futex_async], [],
436 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
437 AC_CHECK_DECL([rcu_thread_offline], [],
438 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
439 AC_CHECK_DECL([rcu_thread_online], [],
440 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
441 AC_CHECK_DECL([caa_likely], [],
442 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
443 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
444 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
445
446 #Function added in urcu 0.7.0
447 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
448 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
449 )
450
451 #Function added in urcu 0.9.0
452 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
453 [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
454 )
455
456 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
457 # it can be explicitly disabled with --without-kmod
458 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
459 AC_ARG_WITH([kmod],
460 [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
461 [],
462 [with_kmod=check]
463 )
464
465 AS_IF([test "x$with_kmod" != "xno"],
466 [
467 AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
468 [
469 AC_DEFINE([HAVE_KMOD], [1])
470 KMOD_LIBS="-lkmod"
471 ],
472 [
473 if test "x$with_kmod" != xcheck; then
474 AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
475 else
476 with_kmod=no
477 fi
478 ]
479 )
480 ]
481 )
482 AC_SUBST(KMOD_LIBS)
483
484 # Check for liblttng-ust-ctl, fail if it's not found,
485 # it can be explicitly disabled with --without-lttng-ust
486 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
487 AC_ARG_WITH([lttng-ust],
488 [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
489 [],
490 [with_lttng_ust=yes]
491 )
492
493 AS_IF([test "x$with_lttng_ust" = "xyes"],
494 [
495 AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
496 [
497 AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
498 ],
499 [
500 AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
501 ],
502 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
503 )
504 ]
505 )
506 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
507
508
509
510 # check for dlopen
511 AC_CHECK_LIB([dl], [dlopen],
512 [DL_LIBS="-ldl"],
513 [
514 #libdl not found, check for dlopen in libc.
515 AC_CHECK_LIB([c], [dlopen],
516 [DL_LIBS="-lc"],
517 [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])]
518 )
519 ]
520 )
521 AC_SUBST(DL_LIBS)
522
523 # Check for fmemopen
524 AC_CHECK_LIB([c], [fmemopen],
525 [
526 AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
527 ]
528 )
529
530 # Check for open_memstream
531 AC_CHECK_LIB([c], [open_memstream],
532 [
533 AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
534 ]
535 )
536
537 # check for libpfm
538 AC_CHECK_LIB([pfm], [pfm_initialize],
539 [
540 have_libpfm=yes
541 ])
542 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
543
544 AC_ARG_ENABLE([git-version],
545 [AC_HELP_STRING([--disable-git-version],
546 [Do not use the git version for the build])],
547 [have_git_version=$enableval], [have_git_version=yes]
548 )
549
550 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
551 [test "x${have_git_version}" = "xyes"])
552
553 # For Python
554 # SWIG version needed or newer:
555 swig_version=2.0.0
556
557 AC_ARG_ENABLE([python-bindings],
558 [AC_HELP_STRING([--enable-python-bindings],
559 [compile Python bindings])],
560 [enable_python_binding=$enableval], [enable_python_binding=no])
561
562 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
563
564 if test "x$enable_python_binding" = xyes; then
565 AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
566 AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
567 AM_PATH_PYTHON([3.0])
568
569 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
570 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
571 AS_IF([test -z "$PYTHON_INCLUDE"], [
572 AS_IF([test -z "$PYTHON_CONFIG"], [
573 AC_PATH_PROGS([PYTHON_CONFIG],
574 [python$PYTHON_VERSION-config python-config],
575 [no],
576 [`dirname $PYTHON`])
577 AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
578 ])
579 AC_MSG_CHECKING([python include flags])
580 PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
581 AC_MSG_RESULT([$PYTHON_INCLUDE])
582 ])
583
584 else
585 AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
586 [if you want Python bindings.])
587
588 fi
589
590 # Epoll check. If not present, the build will fallback on poll() API
591 AX_HAVE_EPOLL(
592 [AX_CONFIG_FEATURE_ENABLE(epoll)],
593 [AX_CONFIG_FEATURE_DISABLE(epoll)]
594 )
595 AX_CONFIG_FEATURE(
596 [epoll], [This platform supports epoll(7)],
597 [HAVE_EPOLL], [This platform supports epoll(7).],
598 [enable_epoll="yes"], [enable_epoll="no"]
599 )
600 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
601
602 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
603 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
604
605 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
606 AX_JAVA_OPTIONS
607 AX_PROG_JAVAC
608 AX_PROG_JAVA
609 AX_PROG_JAR
610
611 AX_CHECK_CLASSPATH
612
613 # Check for Java UST agent common class first
614 AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
615 if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
616 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
617 fi
618
619 if test "x$test_java_agent_jul" = "xyes"; then
620 # Check for JUL agent class
621 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
622 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
623 AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
624 fi
625 fi
626
627 if test "x$test_java_agent_log4j" = "xyes"; then
628 # Check for Log4j agent class
629 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
630 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
631 AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
632 fi
633
634 # Check for Log4j class
635 AX_CHECK_CLASS(org.apache.log4j.Logger)
636 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
637 AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
638 fi
639 fi
640 fi
641
642 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
643 # is not distributed in tarballs
644 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
645 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
646
647 # enable building man pages (user's intention)
648 AC_ARG_ENABLE(
649 man-pages,
650 AS_HELP_STRING(
651 [--disable-man-pages],
652 [Do not build and install man pages (already built in a distributed tarball)]
653 ),
654 [man_pages_opt=$enableval],
655 [man_pages_opt=yes]
656 )
657
658 # check for asciidoc and xmlto if we enabled building the man pages
659 have_asciidoc_xmlto=no
660 warn_prebuilt_man_pages=no
661
662 AS_IF([test "x$man_pages_opt" = "xyes"], [
663 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
664 AC_PATH_PROG([XMLTO], [xmlto], [no])
665
666 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
667 AS_IF([test "x$in_git_repo" = "xyes"], [
668 # this is an error because we're in the Git repo, which
669 # means the man pages are not already generated for us,
670 # thus asciidoc/xmlto are required because we were asked
671 # to build the man pages
672 AC_MSG_ERROR([
673 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
674 --disable-man-pages to disable building the man pages, in which case
675 they will not be installed.
676 ])
677 ], [
678 # only warn here: since we're in the tarball, the man
679 # pages should already be generated at this point, thus
680 # asciidoc/xmlto are not strictly required
681 warn_prebuilt_man_pages=yes
682 ])
683 ], [
684 have_asciidoc_xmlto=yes
685 ])
686 ])
687
688 # export man page build condition: build the man pages if the user
689 # asked for it, and if the tools are available
690 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
691 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
692
693 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
694
695 # embedded --help message
696 AC_ARG_ENABLE(
697 [embedded-help],
698 AS_HELP_STRING(
699 [--enable-embedded-help],
700 [Embed the --help messages in the executable files]
701 ),
702 [embedded_help=$enableval],
703 [embedded_help=no]
704 )
705 AS_IF([test "x$embedded_help" = "xyes"], [
706 AS_IF([test "x$man_pages_opt" = "xno"], [
707 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
708 ])
709 AC_PATH_PROG([man_prog_path], [man], [no])
710 AS_IF([test "x$man_prog_path" = "xno"], [
711 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
712 ])
713 AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
714 AC_SUBST([MANPROG], [$man_prog_path])
715 ])
716 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
717
718 # Python agent test
719 UST_PYTHON_AGENT="lttngust"
720
721 AC_ARG_ENABLE(test-python2-agent,
722 AS_HELP_STRING([--enable-test-python2-agent],
723 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
724 ),[:],[test_python2_agent_autodetect=yes]
725 )
726
727 AC_ARG_ENABLE(test-python3-agent,
728 AS_HELP_STRING([--enable-test-python3-agent],
729 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
730 ),[:],[test_python3_agent_autodetect=yes]
731 )
732
733 AC_ARG_ENABLE(test-python-agent-all,
734 AS_HELP_STRING([--enable-test-python-agent-all],
735 [enable test for all python{2/3} agent.]
736 ),
737 )
738
739 AS_IF([test ! -z "$enable_test_python_agent_all"], [
740 unset test_python2_agent_autodetect
741 unset test_python3_agent_autodetect
742 ])
743
744 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
745 enable_test_python2_agent=yes
746 enable_test_python3_agent=yes
747 ])
748
749 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
750 enable_test_python2_agent=no
751 enable_test_python3_agent=no
752 ])
753
754
755 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
756 AS_IF([test -z "$PYTHON2"], [
757 PYTHON2=python2
758 ], [
759 AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
760 ])
761
762 AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
763 AS_IF([test -z "$PYTHON2_BIN"], [
764 AS_IF([test -z "$test_python2_agent_autodetect"],[
765 AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
766 ])
767 ], [
768 AC_MSG_CHECKING([for python2 lttng-ust agent])
769 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
770 PYTHON2_AGENT=$PYTHON2_BIN
771 AC_MSG_RESULT([yes])
772 RUN_PYTHON_AGENT_TEST=yes
773 ], [
774 AC_MSG_RESULT([no])
775 AS_IF([test -z "$test_python2_agent_autodetect"],[
776 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
777 ])
778 ])
779
780 ])
781
782 ])
783
784 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
785 AS_IF([test -z "$PYTHON3"], [
786 PYTHON3=python3
787 ], [
788 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
789 ])
790
791 AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
792 AS_IF([test -z "$PYTHON3_BIN"], [
793 AS_IF([test -z "$test_python3_agent_autodetect"],[
794 AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
795 ])
796 ], [
797 AC_MSG_CHECKING([for python3 lttng-ust agent])
798 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
799 PYTHON3_AGENT=$PYTHON3_BIN
800 AC_MSG_RESULT([yes])
801 RUN_PYTHON_AGENT_TEST=yes
802 ], [
803 AC_MSG_RESULT([no])
804 AS_IF([test -z "$test_python3_agent_autodetect"],[
805 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
806 ])
807 ])
808
809 ])
810 ])
811 AC_SUBST([RUN_PYTHON_AGENT_TEST])
812 AC_SUBST([PYTHON2_AGENT])
813 AC_SUBST([PYTHON3_AGENT])
814
815 # Arguments for binaries build exclusion
816 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
817 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
818 [Disable the build of lttng-consumerd binaries]))
819 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
820 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
821 [Disable the build of lttng-relayd binaries]))
822 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
823 [Disable the build of lttng-sessiond binaries]))
824 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
825 [Disable the build of the extra components]))
826
827
828 # Always build libconfig since it a dependency of libcommon
829 build_lib_config=yes
830
831 build_lib_compat=no
832 build_lib_consumer=no
833 build_lib_hashtable=no
834 build_lib_health=no
835 build_lib_index=no
836 build_lib_kernel_consumer=no
837 build_lib_kernel_ctl=no
838 build_lib_lttng_ctl=no
839 build_lib_relayd=no
840 build_lib_sessiond_comm=no
841 build_lib_testpoint=no
842 build_lib_ust_consumer=no
843
844 # There is an overlap for enabled dependencies, but this makes everything
845 # simpler. libcommon and libconfig are always compiled so they are not repeated
846 # here.
847
848 # Enable binary dependencies.
849 AS_IF([test x$enable_bin_lttng != xno],
850 [
851 build_lib_lttng_ctl=yes
852 ]
853 )
854
855 AS_IF([test x$enable_bin_lttng_consumerd != xno],
856 [
857 build_lib_consumer=yes
858 build_lib_sessiond_comm=yes
859 build_lib_index=yes
860 build_lib_health=yes
861 build_lib_testpoint=yes
862 ]
863 )
864
865 AS_IF([test x$enable_bin_lttng_crash != xno],
866 # Do nothing since libconfig and libcommon are built by default.
867 []
868 )
869
870 AS_IF([test x$enable_bin_lttng_relayd != xno],
871 [
872 build_lib_lttng_ctl=yes
873 build_lib_sessiond_comm=yes
874 build_lib_hashtable=yes
875 build_lib_compat=yes
876 build_lib_index=yes
877 build_lib_health=yes
878 build_lib_testpoint=yes
879 ]
880 )
881 AS_IF([test x$enable_bin_lttng_sessiond != xno],
882 [
883 build_lib_lttng_ctl=yes
884 build_lib_sessiond_comm=yes
885 build_lib_kernel_ctl=yes
886 build_lib_hashtable=yes
887 build_lib_compat=yes
888 build_lib_relayd=yes
889 build_lib_testpoint=yes
890 build_lib_health=yes
891 build_lib_health=yes
892 ]
893 )
894
895 # Libraries dependencies enabling
896 AS_IF([test x$build_lib_lttng_ctl = xyes],
897 [
898 build_lib_sessiond_comm=yes
899 build_lib_hashtable=yes
900 ]
901 )
902
903 AS_IF([test x$build_lib_consumer = xyes],
904 [
905 build_lib_sessiond_comm=yes
906 build_lib_kernel_consumer=yes
907 build_lib_hashtable=yes
908 build_lib_compat=yes
909 build_lib_relayd=yes
910 AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
911 ]
912 )
913
914 AS_IF([test x$build_lib_kernel_consumer = xyes],
915 [
916 build_lib_kernel_ctl=yes
917 build_lib_relayd=yes
918 ]
919 )
920
921 AS_IF([test x$build_lib_relayd = xyes],
922 [
923 build_lib_sessiond_comm=yes
924 ]
925 )
926
927
928 # Export binaries build conditions.
929 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
930 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
931 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
932 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
933 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
934
935 # Export the tests and extras build conditions.
936 AS_IF([\
937 test "x$enable_bin_lttng" != "xno" && \
938 test "x$enable_bin_lttng_consumerd" != "xno" && \
939 test "x$enable_bin_lttng_crash" != "xno" && \
940 test "x$enable_bin_lttng_relayd" != "xno" && \
941 test "x$enable_bin_lttng_sessiond" != "xno"],
942 [build_tests=yes],
943 [build_tests=no]
944 )
945
946 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
947 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
948
949 # Export libraries build conditions.
950 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
951 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
952 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
953 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
954 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
955 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
956 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
957 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
958 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
959 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
960 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
961 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
962 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
963
964 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
965 AC_SUBST(AM_CFLAGS)
966
967 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
968 AC_SUBST(AM_CPPFLAGS)
969
970 lttngincludedir="${includedir}/lttng"
971 AC_SUBST(lttngincludedir)
972
973 lttngactionincludedir="${includedir}/lttng/action"
974 AC_SUBST(lttngactionincludedir)
975
976 lttngconditionincludedir="${includedir}/lttng/condition"
977 AC_SUBST(lttngconditionincludedir)
978
979 lttngnotificationincludedir="${includedir}/lttng/notification"
980 AC_SUBST(lttngnotificationincludedir)
981
982 lttngtriggerincludedir="${includedir}/lttng/trigger"
983 AC_SUBST(lttngtriggerincludedir)
984
985 lttnglibexecdir="${libdir}/lttng/libexec"
986 AC_SUBST(lttnglibexecdir)
987
988 AC_CONFIG_FILES([
989 Makefile
990 doc/Makefile
991 doc/man/Makefile
992 doc/man/asciidoc-attrs.conf
993 include/Makefile
994 extras/Makefile
995 extras/bindings/Makefile
996 extras/bindings/swig/Makefile
997 extras/bindings/swig/python/Makefile
998 extras/core-handler/Makefile
999 src/Makefile
1000 src/common/Makefile
1001 src/common/kernel-ctl/Makefile
1002 src/common/kernel-consumer/Makefile
1003 src/common/consumer/Makefile
1004 src/common/ust-consumer/Makefile
1005 src/common/hashtable/Makefile
1006 src/common/sessiond-comm/Makefile
1007 src/common/compat/Makefile
1008 src/common/relayd/Makefile
1009 src/common/testpoint/Makefile
1010 src/common/index/Makefile
1011 src/common/health/Makefile
1012 src/common/config/Makefile
1013 src/common/string-utils/Makefile
1014 src/lib/Makefile
1015 src/lib/lttng-ctl/Makefile
1016 src/lib/lttng-ctl/filter/Makefile
1017 src/lib/lttng-ctl/lttng-ctl.pc
1018 src/bin/Makefile
1019 src/bin/lttng-consumerd/Makefile
1020 src/bin/lttng-sessiond/Makefile
1021 src/bin/lttng-relayd/Makefile
1022 src/bin/lttng/Makefile
1023 src/bin/lttng-crash/Makefile
1024 tests/Makefile
1025 tests/destructive/Makefile
1026 tests/regression/Makefile
1027 tests/regression/kernel/Makefile
1028 tests/regression/tools/Makefile
1029 tests/regression/tools/streaming/Makefile
1030 tests/regression/tools/filtering/Makefile
1031 tests/regression/tools/health/Makefile
1032 tests/regression/tools/tracefile-limits/Makefile
1033 tests/regression/tools/snapshots/Makefile
1034 tests/regression/tools/live/Makefile
1035 tests/regression/tools/exclusion/Makefile
1036 tests/regression/tools/save-load/Makefile
1037 tests/regression/tools/save-load/configuration/Makefile
1038 tests/regression/tools/mi/Makefile
1039 tests/regression/tools/wildcard/Makefile
1040 tests/regression/tools/crash/Makefile
1041 tests/regression/tools/regen-metadata/Makefile
1042 tests/regression/tools/regen-statedump/Makefile
1043 tests/regression/tools/notification/Makefile
1044 tests/regression/ust/Makefile
1045 tests/regression/ust/nprocesses/Makefile
1046 tests/regression/ust/high-throughput/Makefile
1047 tests/regression/ust/low-throughput/Makefile
1048 tests/regression/ust/before-after/Makefile
1049 tests/regression/ust/buffers-pid/Makefile
1050 tests/regression/ust/periodical-metadata-flush/Makefile
1051 tests/regression/ust/multi-session/Makefile
1052 tests/regression/ust/overlap/Makefile
1053 tests/regression/ust/overlap/demo/Makefile
1054 tests/regression/ust/linking/Makefile
1055 tests/regression/ust/daemon/Makefile
1056 tests/regression/ust/exit-fast/Makefile
1057 tests/regression/ust/fork/Makefile
1058 tests/regression/ust/libc-wrapper/Makefile
1059 tests/regression/ust/baddr-statedump/Makefile
1060 tests/regression/ust/ust-dl/Makefile
1061 tests/regression/ust/java-jul/Makefile
1062 tests/regression/ust/java-log4j/Makefile
1063 tests/regression/ust/python-logging/Makefile
1064 tests/regression/ust/getcpu-override/Makefile
1065 tests/regression/ust/clock-override/Makefile
1066 tests/regression/ust/type-declarations/Makefile
1067 tests/regression/ust/rotation-destroy-flush/Makefile
1068 tests/regression/ust/blocking/Makefile
1069 tests/stress/Makefile
1070 tests/unit/Makefile
1071 tests/unit/ini_config/Makefile
1072 tests/perf/Makefile
1073 tests/utils/Makefile
1074 tests/utils/tap/Makefile
1075 tests/utils/testapp/Makefile
1076 tests/utils/testapp/gen-ust-events/Makefile
1077 tests/utils/testapp/gen-ust-nevents/Makefile
1078 tests/utils/testapp/gen-ust-nevents-str/Makefile
1079 tests/utils/testapp/gen-ust-tracef/Makefile
1080 ])
1081
1082 # Inject variable into python test script.
1083 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1084 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1085 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1086
1087 AC_OUTPUT
1088
1089 #
1090 # Mini-report on what will be built.
1091 #
1092
1093 PPRINT_INIT
1094 PPRINT_SET_INDENT(1)
1095 PPRINT_SET_TS(38)
1096
1097 AS_ECHO
1098 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1099 AS_ECHO
1100
1101 AS_IF([test -n "$report_fold"], [
1102 AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1103 ], [
1104 AS_ECHO("$version_description")
1105 ])
1106
1107 AS_ECHO
1108 PPRINT_SUBTITLE([Features])
1109
1110 # Target architecture we're building for.
1111 target_arch=$host_cpu
1112 [
1113 for f in $CFLAGS; do
1114 if test $f = "-m32"; then
1115 target_arch="32-bit"
1116 elif test $f = "-m64"; then
1117 target_arch="64-bit"
1118 fi
1119 done
1120 ]
1121 PPRINT_PROP_STRING([Target architecture], $target_arch)
1122
1123 # kmod enabled/disabled
1124 test "x$with_kmod" != "xno" && value=1 || value=0
1125 PPRINT_PROP_BOOL([libkmod support], $value)
1126
1127 # LTTng-UST enabled/disabled
1128 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1129 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1130
1131 AS_ECHO
1132 PPRINT_SUBTITLE([Binaries])
1133
1134 # List binaries to be built
1135 test x$enable_bin_lttng != xno && value=1 || value=0
1136 PPRINT_PROP_BOOL([lttng], $value)
1137
1138 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1139 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1140
1141 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1142 PPRINT_PROP_BOOL([lttng-crash], $value)
1143
1144 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1145 PPRINT_PROP_BOOL([lttng-relayd], $value)
1146
1147 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1148 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1149
1150 # Extras
1151 test x$enable_extras != xno && value=1 || value=0
1152 AS_ECHO
1153 PPRINT_SET_INDENT(0)
1154 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1155 PPRINT_SET_INDENT(1)
1156
1157 AS_ECHO
1158 PPRINT_SUBTITLE([Tests])
1159
1160 # Print clear message that tests won't be built
1161 AS_IF([test "x$build_tests" = "xno"],[
1162 PPRINT_WARN([Tests won't be built since some binaries were disabled])
1163 ])
1164
1165 # LTTng UST Java agent JUL tests enabled/disabled
1166 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1167 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1168
1169 # LTTng UST Java agent Log4j tests enabled/disabled
1170 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1171 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1172
1173 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1174 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1175
1176 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1177 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1178
1179 #Python binding enabled/disabled
1180 test "x$enable_python_binding" = xyes && value=1 || value=0
1181 AS_ECHO
1182 PPRINT_SET_INDENT(0)
1183 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1184
1185 # man pages build enabled/disabled
1186 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1187
1188 AS_IF([test "x$man_pages_opt" != "xno"], [
1189 AS_IF([test "x$in_git_repo" = "xyes"], [
1190 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1191 ], [
1192 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1193 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1194 ], [
1195 PPRINT_PROP_STRING([build_man_pages_msg],
1196 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1197 $PPRINT_COLOR_SUBTITLE)
1198 ])
1199 ])
1200 ], [
1201 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1202 ])
1203
1204 m4_popdef([build_man_pages_msg])
1205
1206 test "x$embedded_help" = xyes && value=1 || value=0
1207 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1208
1209 PPRINT_SET_INDENT(1)
1210
1211 report_bindir="`eval eval echo $bindir`"
1212 report_libdir="`eval eval echo $libdir`"
1213
1214 # Print the bindir and libdir this `make install' will install into.
1215 AS_ECHO
1216 PPRINT_SUBTITLE([Install directories])
1217 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1218 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1219
1220 AS_ECHO
1221 PPRINT_SUBTITLE([Search directories])
1222
1223 # If we build the sessiond, print the paths it will use
1224 AS_IF([test "$SESSIOND_BIN" = ""],[
1225 path="$report_bindir/lttng-sessiond"
1226 ],[
1227 path="$SESSIOND_BIN"
1228 ])
1229 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1230
1231 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1232 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1233 ],[
1234 path="$CONSUMERD32_BIN"
1235 ])
1236 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1237
1238 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1239 path="`eval eval echo $libdir`"
1240 ],[
1241 path="$CONSUMERD32_LIBDIR"
1242 ])
1243 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1244
1245 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1246 path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1247 ],[
1248 path="$CONSUMERD64_BIN"
1249 ])
1250 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1251
1252 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1253 path="`eval eval echo $libdir`"
1254 ],[
1255 path="$CONSUMERD64_LIBDIR"
1256 ])
1257 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1258 PPRINT_SET_INDENT(0)
1259
1260 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1261 AS_ECHO
1262 PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1263
1264 Note that the man pages are already built in this distribution tarball,
1265 therefore asciidoc and xmlto are only needed if you intend to modify
1266 their sources.
1267
1268 Also note that the installed man pages will contain the project's
1269 default command-line option and environment variable values.
1270
1271 Use --disable-man-pages to completely disable building and installing
1272 the man pages.])
1273 ])
This page took 0.093033 seconds and 6 git commands to generate.