configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.9.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Checks for C compiler
  18 AC_USE_SYSTEM_EXTENSIONS
  19 AC_SYS_LARGEFILE
  20 AC_PROG_CC
  21 AC_PROG_CC_STDC
  22
  23 # Checks for programs.
  24 AC_PROG_GREP
  25 AC_PROG_LEX
  26 AC_PROG_MAKE_SET
  27 AC_PROG_SED
  28 AC_PROG_YACC
  29 AC_PATH_PROG(report_fold, fold)
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  34 AS_IF([test "x$OBJCOPY" = xno],
  35         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # Checks for typedefs, structures, and compiler characteristics.
  40 AC_C_INLINE
  41 AC_TYPE_INT32_T
  42 AC_TYPE_INT64_T
  43 AC_TYPE_MODE_T
  44 AC_TYPE_OFF_T
  45 AC_TYPE_PID_T
  46 AC_TYPE_SIZE_T
  47 AC_TYPE_SSIZE_T
  48 AC_TYPE_UID_T
  49 AC_TYPE_UINT16_T
  50 AC_TYPE_UINT32_T
  51 AC_TYPE_UINT64_T
  52 AC_TYPE_UINT8_T
  53
  54 AX_C___ATTRIBUTE__
  55 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  56         [:],
  57         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  58
  59 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  60 LIBS="$PTHREAD_LIBS $LIBS"
  61 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  62 CC="$PTHREAD_CC"
  63
  64 AX_LIB_SOCKET_NSL
  65
  66 # Compute minor/major/patchlevel version numbers
  67 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  68 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  69 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  70
  71 AC_SUBST([MAJOR_VERSION], [$major_version])
  72 AC_SUBST([MINOR_VERSION], [$minor_version])
  73 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  74 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  75 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  76 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  77
  78 version_name="Codename TBD"
  79 version_description='Description TBD'
  80 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  81
  82 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  83 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  84
  85 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  86 AC_ARG_ENABLE(libtool-linkdep-fixup,
  87         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  88                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  89         libtool_fixup=$enableval,
  90         libtool_fixup=yes)
  91
  92 AS_IF([test "x$libtool_fixup" = "xyes"],
  93             [
  94             libtool_m4="$srcdir/m4/libtool.m4"
  95             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  96             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  97             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  98             AS_IF([test $libtool_flag_pattern_count -ne 0],
  99             [
 100                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 101                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 102                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 103                   ],
 104                   [
 105                   AC_MSG_RESULT([none])
 106                   ])
 107             ])
 108
 109 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 110
 111 AC_CHECK_HEADERS([ \
 112         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 113         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 114         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 115         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 116         sys/mount.h sys/param.h sys/time.h
 117 ])
 118
 119 # Basic functions check
 120 AC_CHECK_FUNCS([ \
 121         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 122         gethostbyname gethostname getpagesize localtime_r memchr memset \
 123         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 124         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 125         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 126 ])
 127
 128 # Babeltrace viewer check
 129 AC_ARG_WITH([babeltrace-bin],
 130         AS_HELP_STRING([--with-babeltrace-bin],
 131         [Location of the babeltrace viewer executable (including the filename)]),
 132         [BABELTRACE_BIN="$withval"],
 133         [BABELTRACE_BIN=''])
 134 AC_SUBST([BABELTRACE_BIN])
 135
 136 # lttv-gui
 137 AC_ARG_WITH([lttv-gui-bin],
 138         AS_HELP_STRING([--with-lttv-gui-bin],
 139    [Location of the lttv GUI viewer executable (including the filename)]),
 140    [LTTV_GUI_BIN="$withval"],
 141    [LTTV_GUI_BIN=''])
 142 AC_SUBST([LTTV_GUI_BIN])
 143
 144 AC_ARG_WITH([consumerd32-bin],
 145         AS_HELP_STRING([--with-consumerd32-bin],
 146         [Location of the 32-bit consumerd executable (including the filename)]),
 147         [CONSUMERD32_BIN="$withval"],
 148         [CONSUMERD32_BIN=''])
 149 AC_SUBST([CONSUMERD32_BIN])
 150
 151 AC_ARG_WITH([consumerd64-bin],
 152         AS_HELP_STRING([--with-consumerd64-bin],
 153         [Location of the 64-bit consumerd executable (including the filename)]),
 154         [CONSUMERD64_BIN="$withval"],
 155         [CONSUMERD64_BIN=''])
 156 AC_SUBST([CONSUMERD64_BIN])
 157
 158 AC_ARG_WITH([consumerd32-libdir],
 159         AS_HELP_STRING([--with-consumerd32-libdir],
 160         [Directory containing the 32-bit consumerd libraries]),
 161         [CONSUMERD32_LIBDIR="$withval"],
 162         [CONSUMERD32_LIBDIR=''])
 163 AC_SUBST([CONSUMERD32_LIBDIR])
 164
 165 AC_ARG_WITH([consumerd64-libdir],
 166         AS_HELP_STRING([--with-consumerd64-libdir],
 167         [Directory containing the 64-bit consumerd libraries]),
 168         [CONSUMERD64_LIBDIR="$withval"],
 169         [CONSUMERD64_LIBDIR=''])
 170 AC_SUBST([CONSUMERD64_LIBDIR])
 171
 172 AC_ARG_WITH([sessiond-bin],
 173         AS_HELP_STRING([--with-sessiond-bin],
 174         [Location of the sessiond executable (including the filename)]),
 175         [SESSIOND_BIN="$withval"],
 176         [SESSIOND_BIN=''])
 177 AC_SUBST([SESSIOND_BIN])
 178
 179 AC_ARG_WITH([lttng-system-rundir],
 180         AS_HELP_STRING([--with-lttng-system-rundir],
 181         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 182         [LTTNG_SYSTEM_RUNDIR="$withval"],
 183         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 184 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 185
 186 AC_ARG_ENABLE([test-java-agent-jul],
 187         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 188         [test_java_agent_jul=$enableval],
 189         [test_java_agent_jul=no]
 190 )
 191
 192 AC_ARG_ENABLE([test-java-agent-log4j],
 193         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 194         [test_java_agent_log4j=$enableval],
 195         [test_java_agent_log4j=no]
 196 )
 197
 198 AC_ARG_ENABLE([test-java-agent-all],
 199         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 200         [test_java_agent_jul=$enableval
 201          test_java_agent_log4j=$enableval],
 202         [:]
 203 )
 204
 205 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 206 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 209 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 210 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 211 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 212 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 213
 214 if test "x$prefix" = "xNONE"; then
 215         prefix=$ac_default_prefix
 216 fi
 217 CONFDIR=`eval echo $sysconfdir`
 218 AC_SUBST(CONFDIR)
 219 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 220
 221 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 222
 223 #
 224 # Check for pthread
 225 AC_CHECK_LIB([pthread], [pthread_create], [],
 226         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 227 )
 228
 229 # Check libpopt
 230 PKG_CHECK_MODULES([POPT], [popt],
 231         [LIBS="$LIBS $POPT_LIBS"],
 232         [
 233                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 234                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 235                 AC_CHECK_LIB([popt],
 236                         [poptGetContext],
 237                         [],
 238                         [
 239                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 240                         ]
 241                 )
 242         ]
 243 )
 244
 245 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 246
 247 # Check for libuuid
 248 PKG_CHECK_MODULES([UUID], [uuid],
 249 [
 250         LIBS="$LIBS $UUID_LIBS"
 251         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 252         have_libuuid=yes
 253 ],
 254 [
 255         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 256         AC_MSG_WARN([Finding libuuid without pkg-config.])
 257         AC_CHECK_LIB([uuid],
 258                 [uuid_generate],
 259                 [
 260                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 261                         have_libuuid=yes
 262                 ],
 263                 [
 264                         # libuuid not found, check for uuid_create in libc.
 265                         AC_CHECK_LIB([c],
 266                                 [uuid_create],
 267                                 [
 268                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 269                                         have_libc_uuid=yes
 270                                 ],
 271                                 [
 272                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 273                                 ]
 274                         )
 275                 ]
 276         )
 277 ])
 278 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 279 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 280
 281 # URCU library version needed or newer
 282 liburcu_version=">= 0.8.0"
 283
 284 # Check liburcu needed function calls
 285 AC_CHECK_DECL([cds_list_add], [],
 286         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 287 )
 288 AC_CHECK_DECL([cds_wfcq_init], [],
 289         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 290 )
 291 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 292     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 293 )
 294 AC_CHECK_DECL([futex_async], [],
 295         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 296 )
 297 AC_CHECK_DECL([rcu_thread_offline], [],
 298         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 299 )
 300 AC_CHECK_DECL([rcu_thread_online], [],
 301         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 302 )
 303 AC_CHECK_DECL([caa_likely], [],
 304         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 305 )
 306 #Function added in urcu 0.7.0
 307 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 308         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 309 )
 310
 311 # Check kmod library
 312 AC_ARG_WITH(kmod-prefix,
 313   AS_HELP_STRING([--with-kmod-prefix=PATH],
 314                 [Specify the installation prefix of the kmod library.
 315                 Headers must be in PATH/include; libraries in PATH/lib.]),
 316                 [
 317                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 318                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 319                 ])
 320
 321 AC_ARG_ENABLE(kmod,
 322         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 323         kmod_support=zz$enableval, kmod_support=yes)
 324
 325 AS_IF([test "x$kmod_support" = "xyes"], [
 326         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 327                 [
 328                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 329                         LIBS="$LIBS -lkmod"
 330                         kmod_found=yes
 331                 ],
 332                 kmod_found=no
 333         )
 334 ])
 335 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 336
 337 AC_ARG_WITH(lttng-ust-prefix,
 338   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 339                  [Specify the installation prefix of the lttng-ust library.
 340                   Headers must be in PATH/include; libraries in PATH/lib.]),
 341                   [
 342                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 343                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 344                   ])
 345
 346 # Check liblttng-ust-ctl library
 347 AC_ARG_WITH(lttng-ust,
 348         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 349         lttng_ust_support=$withval, lttng_ust_support=yes)
 350
 351 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 352         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 353                 [
 354                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 355                         lttng_ust_ctl_found=yes
 356                 ],
 357                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 358                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 359         )
 360 ])
 361 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 362 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 363
 364 # check for dlopen
 365 AC_CHECK_LIB([dl], [dlopen],
 366 [
 367         have_libdl=yes
 368 ],
 369 [
 370         #libdl not found, check for dlopen in libc.
 371         AC_CHECK_LIB([c], [dlopen],
 372         [
 373                 have_libc_dl=yes
 374         ],
 375         [
 376                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 377         ])
 378 ])
 379 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 380 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 381
 382 # Check for fmemopen
 383 AC_CHECK_LIB([c], [fmemopen],
 384 [
 385         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 386 ]
 387 )
 388
 389 # Check for open_memstream
 390 AC_CHECK_LIB([c], [open_memstream],
 391 [
 392         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 393 ]
 394 )
 395
 396 AC_ARG_ENABLE([git-version],
 397               [AC_HELP_STRING([--disable-git-version],
 398                               [Do not use the git version for the build])],
 399               [have_git_version=$enableval], [have_git_version=yes]
 400 )
 401
 402 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 403         [test "x${have_git_version}" = "xyes"])
 404
 405 # For Python
 406 # SWIG version needed or newer:
 407 swig_version=2.0.0
 408
 409 AC_ARG_ENABLE([python-bindings],
 410               [AC_HELP_STRING([--enable-python-bindings],
 411                               [compile Python bindings])],
 412               [enable_python_binding=yes], [enable_python_binding=no])
 413
 414 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 415
 416 if test "x${enable_python_binding:-yes}" = xyes; then
 417   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 418   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 419   AM_PATH_PYTHON([3.0])
 420
 421   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 422   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 423   AS_IF([test -z "$PYTHON_INCLUDE"], [
 424     AS_IF([test -z "$PYTHON_CONFIG"], [
 425       AC_PATH_PROGS([PYTHON_CONFIG],
 426                     [python$PYTHON_VERSION-config python-config],
 427                     [no],
 428                     [`dirname $PYTHON`])
 429       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 430     ])
 431     AC_MSG_CHECKING([python include flags])
 432     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 433     AC_MSG_RESULT([$PYTHON_INCLUDE])
 434   ])
 435
 436 else
 437     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 438 [if you want Python bindings.])
 439
 440 fi
 441
 442 # Epoll check. If not present, the build will fallback on poll() API
 443 AX_HAVE_EPOLL(
 444         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 445         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 446 )
 447 AX_CONFIG_FEATURE(
 448         [epoll], [This platform supports epoll(7)],
 449         [HAVE_EPOLL], [This platform supports epoll(7).],
 450         [enable_epoll="yes"], [enable_epoll="no"]
 451 )
 452 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 453
 454 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 455 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 456
 457 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 458         AX_JAVA_OPTIONS
 459         AX_PROG_JAVAC
 460         AX_PROG_JAVA
 461         AX_PROG_JAR
 462
 463         AX_CHECK_CLASSPATH
 464
 465         # Check for Java UST agent common class first
 466         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 467         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 468                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 469         fi
 470
 471         if test "x$test_java_agent_jul" = "xyes"; then
 472                 # Check for JUL agent class
 473                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 474                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 475                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 476                 fi
 477         fi
 478
 479         if test "x$test_java_agent_log4j" = "xyes"; then
 480                 # Check for Log4j agent class
 481                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 482                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 483                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 484                 fi
 485
 486                 # Check for Log4j class
 487                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 488                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 489                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 490                 fi
 491         fi
 492 fi
 493
 494 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 495 # is not distributed in tarballs
 496 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 497 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 498
 499 # enable building man pages
 500 AC_ARG_ENABLE(
 501         build-man-pages,
 502         AS_HELP_STRING(
 503                 [--disable-build-man-pages],
 504                 [Build man pages (already built in a distributed tarball)]
 505         ),
 506         [build_man_pages=$enableval],
 507         [build_man_pages=yes]
 508 )
 509
 510 # export man page build condition
 511 AM_CONDITIONAL([BUILD_MAN_PAGES], [test "x$build_man_pages" != "xno"])
 512
 513 # check for asciidoc and xmlto if we enabled building the man pages
 514 AS_IF([test "x$build_man_pages" = "xyes"], [
 515         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 516         AC_PATH_PROG([XMLTO], [xmlto], [no])
 517
 518         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 519                 AC_MSG_ERROR([Both asciidoc and xmlto are needed to build the LTTng man pages.])
 520         ])
 521 ])
 522
 523 # Python agent test
 524 UST_PYTHON_AGENT="lttngust"
 525
 526 AC_ARG_ENABLE(test-python2-agent,
 527         AS_HELP_STRING([--enable-test-python2-agent],
 528                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 529         ),[:],[test_python2_agent_autodetect=yes]
 530 )
 531
 532 AC_ARG_ENABLE(test-python3-agent,
 533         AS_HELP_STRING([--enable-test-python3-agent],
 534                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 535         ),[:],[test_python3_agent_autodetect=yes]
 536 )
 537
 538 AC_ARG_ENABLE(test-python-agent-all,
 539         AS_HELP_STRING([--enable-test-python-agent-all],
 540                 [enable test for all python{2/3} agent.]
 541         ),
 542 )
 543
 544 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 545        unset test_python2_agent_autodetect
 546        unset test_python3_agent_autodetect
 547 ])
 548
 549 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 550        enable_test_python2_agent=yes
 551        enable_test_python3_agent=yes
 552 ])
 553
 554 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 555        enable_test_python2_agent=no
 556        enable_test_python3_agent=no
 557 ])
 558
 559
 560 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 561         AS_IF([test -z "$PYTHON2"], [
 562                         PYTHON2=python2
 563                 ], [
 564                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 565         ])
 566
 567         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 568         AS_IF([test -z "$PYTHON2_BIN"], [
 569                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 570                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 571                 ])
 572         ], [
 573                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 574                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 575                         PYTHON2_AGENT=$PYTHON2_BIN
 576                         AC_MSG_RESULT([yes])
 577                         RUN_PYTHON_AGENT_TEST=yes
 578                 ], [
 579                         AC_MSG_RESULT([no])
 580                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 581                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 582                         ])
 583                 ])
 584
 585         ])
 586
 587 ])
 588
 589 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 590         AS_IF([test -z "$PYTHON3"], [
 591                 PYTHON3=python3
 592         ], [
 593                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 594         ])
 595
 596         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 597         AS_IF([test -z "$PYTHON3_BIN"], [
 598                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 599                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 600                 ])
 601         ], [
 602                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 603                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 604                         PYTHON3_AGENT=$PYTHON3_BIN
 605                         AC_MSG_RESULT([yes])
 606                         RUN_PYTHON_AGENT_TEST=yes
 607                 ], [
 608                         AC_MSG_RESULT([no])
 609                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 610                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 611                         ])
 612                 ])
 613
 614         ])
 615 ])
 616 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 617 AC_SUBST([PYTHON2_AGENT])
 618 AC_SUBST([PYTHON3_AGENT])
 619
 620 # Arguments for binaries build exclusion
 621 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 622 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 623               [Disable the build of lttng-consumerd binaries]))
 624 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 625 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 626               [Disable the build of lttng-relayd binaries]))
 627 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 628               [Disable the build of lttng-sessiond binaries]))
 629 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 630               [Disable the build of the extra components]))
 631
 632
 633 # Always build libconfig since it a dependency of libcommon
 634 build_lib_config=yes
 635
 636 build_lib_compat=no
 637 build_lib_consumer=no
 638 build_lib_hashtable=no
 639 build_lib_health=no
 640 build_lib_index=no
 641 build_lib_kernel_consumer=no
 642 build_lib_kernel_ctl=no
 643 build_lib_lttng_ctl=no
 644 build_lib_relayd=no
 645 build_lib_sessiond_comm=no
 646 build_lib_testpoint=no
 647 build_lib_ust_consumer=no
 648
 649 # There is an overlap for enabled dependencies, but this makes everything
 650 # simpler. libcommon and libconfig are always compiled so they are not repeated
 651 # here.
 652
 653 # Enable binary dependencies.
 654 AS_IF([test x$enable_bin_lttng != xno],
 655       [
 656        build_lib_lttng_ctl=yes
 657       ]
 658 )
 659
 660 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 661       [
 662        build_lib_consumer=yes
 663        build_lib_sessiond_comm=yes
 664        build_lib_index=yes
 665        build_lib_health=yes
 666        build_lib_testpoint=yes
 667       ]
 668 )
 669
 670 AS_IF([test x$enable_bin_lttng_crash != xno],
 671       # Do nothing since libconfig and libcommon are built by default.
 672       []
 673 )
 674
 675 AS_IF([test x$enable_bin_lttng_relayd != xno],
 676       [
 677        build_lib_lttng_ctl=yes
 678        build_lib_sessiond_comm=yes
 679        build_lib_hashtable=yes
 680        build_lib_compat=yes
 681        build_lib_index=yes
 682        build_lib_health=yes
 683        build_lib_testpoint=yes
 684       ]
 685 )
 686 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 687       [
 688        build_lib_lttng_ctl=yes
 689        build_lib_sessiond_comm=yes
 690        build_lib_kernel_ctl=yes
 691        build_lib_hashtable=yes
 692        build_lib_compat=yes
 693        build_lib_relayd=yes
 694        build_lib_testpoint=yes
 695        build_lib_health=yes
 696        build_lib_health=yes
 697       ]
 698 )
 699
 700 # Libraries dependencies enabling
 701 AS_IF([test x$build_lib_lttng_ctl = xyes],
 702       [
 703        build_lib_sessiond_comm=yes
 704        build_lib_hashtable=yes
 705       ]
 706 )
 707
 708 AS_IF([test x$build_lib_consumer = xyes],
 709       [
 710        build_lib_sessiond_comm=yes
 711        build_lib_kernel_consumer=yes
 712        build_lib_hashtable=yes
 713        build_lib_compat=yes
 714        build_lib_relayd=yes
 715        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 716       ]
 717 )
 718
 719 AS_IF([test x$build_lib_kernel_consumer = xyes],
 720       [
 721        build_lib_kernel_ctl=yes
 722        build_lib_relayd=yes
 723       ]
 724 )
 725
 726 AS_IF([test x$build_lib_relayd = xyes],
 727       [
 728        build_lib_sessiond_comm=yes
 729       ]
 730 )
 731
 732
 733 # Export binaries build conditions.
 734 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 735 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 736 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 737 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 738 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 739
 740 # Export the tests and extras build conditions.
 741 AS_IF([\
 742 test "x$enable_bin_lttng" != "xno" && \
 743 test "x$enable_bin_lttng_consumerd" != "xno" && \
 744 test "x$enable_bin_lttng_crash" != "xno" && \
 745 test "x$enable_bin_lttng_relayd" != "xno" && \
 746 test "x$enable_bin_lttng_sessiond" != "xno"],
 747 [build_tests=yes],
 748 [build_tests=no]
 749 )
 750
 751 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 752 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 753
 754 # Export libraries build conditions.
 755 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 756 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 757 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 758 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 759 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 760 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 761 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 762 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 763 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 764 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 765 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 766 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 767 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 768
 769 # check for pgrep
 770 AC_PATH_PROG([PGREP], [pgrep], [no])
 771 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 772
 773 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 774         if test x"$(basename "$YACC")" != "xbison -y"; then
 775                 AC_MSG_ERROR([[bison not found and is required when building from git.
 776                 Please install bison]])
 777         fi
 778         AC_PATH_PROG([BISON],[bison])
 779         AX_PROG_BISON_VERSION([2.4], [],[
 780                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 781         ])
 782 fi
 783
 784 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 785         if test x"$LEX" != "xflex"; then
 786                 AC_MSG_ERROR([[flex not found and is required when building from git.
 787                 Please install flex]])
 788         fi
 789         AC_PATH_PROG([FLEX],[flex])
 790         AX_PROG_FLEX_VERSION([2.5.35], [],[
 791                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 792         ])
 793 fi
 794
 795 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 796
 797 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 798
 799 lttngincludedir="${includedir}/lttng"
 800
 801 AC_SUBST(lttngincludedir)
 802 AC_SUBST(DEFAULT_INCLUDES)
 803
 804 lttnglibexecdir="${libdir}/lttng/libexec"
 805 AC_SUBST(lttnglibexecdir)
 806
 807 AC_CONFIG_FILES([
 808         Makefile
 809         doc/Makefile
 810         doc/man/Makefile
 811         include/Makefile
 812         extras/Makefile
 813         extras/bindings/Makefile
 814         extras/bindings/swig/Makefile
 815         extras/bindings/swig/python/Makefile
 816         extras/core-handler/Makefile
 817         src/Makefile
 818         src/common/Makefile
 819         src/common/kernel-ctl/Makefile
 820         src/common/kernel-consumer/Makefile
 821         src/common/consumer/Makefile
 822         src/common/ust-consumer/Makefile
 823         src/common/hashtable/Makefile
 824         src/common/sessiond-comm/Makefile
 825         src/common/compat/Makefile
 826         src/common/relayd/Makefile
 827         src/common/testpoint/Makefile
 828         src/common/index/Makefile
 829         src/common/health/Makefile
 830         src/common/config/Makefile
 831         src/lib/Makefile
 832         src/lib/lttng-ctl/Makefile
 833         src/lib/lttng-ctl/filter/Makefile
 834         src/lib/lttng-ctl/lttng-ctl.pc
 835         src/bin/Makefile
 836         src/bin/lttng-consumerd/Makefile
 837         src/bin/lttng-sessiond/Makefile
 838         src/bin/lttng-relayd/Makefile
 839         src/bin/lttng/Makefile
 840         src/bin/lttng-crash/Makefile
 841         tests/Makefile
 842         tests/destructive/Makefile
 843         tests/regression/Makefile
 844         tests/regression/kernel/Makefile
 845         tests/regression/tools/Makefile
 846         tests/regression/tools/streaming/Makefile
 847         tests/regression/tools/filtering/Makefile
 848         tests/regression/tools/health/Makefile
 849         tests/regression/tools/tracefile-limits/Makefile
 850         tests/regression/tools/snapshots/Makefile
 851         tests/regression/tools/live/Makefile
 852         tests/regression/tools/exclusion/Makefile
 853         tests/regression/tools/save-load/Makefile
 854         tests/regression/tools/mi/Makefile
 855         tests/regression/tools/wildcard/Makefile
 856         tests/regression/tools/crash/Makefile
 857         tests/regression/tools/metadata-regen/Makefile
 858         tests/regression/ust/Makefile
 859         tests/regression/ust/nprocesses/Makefile
 860         tests/regression/ust/high-throughput/Makefile
 861         tests/regression/ust/low-throughput/Makefile
 862         tests/regression/ust/before-after/Makefile
 863         tests/regression/ust/buffers-pid/Makefile
 864         tests/regression/ust/periodical-metadata-flush/Makefile
 865         tests/regression/ust/multi-session/Makefile
 866         tests/regression/ust/overlap/Makefile
 867         tests/regression/ust/overlap/demo/Makefile
 868         tests/regression/ust/linking/Makefile
 869         tests/regression/ust/daemon/Makefile
 870         tests/regression/ust/exit-fast/Makefile
 871         tests/regression/ust/fork/Makefile
 872         tests/regression/ust/libc-wrapper/Makefile
 873         tests/regression/ust/baddr-statedump/Makefile
 874         tests/regression/ust/ust-dl/Makefile
 875         tests/regression/ust/java-jul/Makefile
 876         tests/regression/ust/java-log4j/Makefile
 877         tests/regression/ust/python-logging/Makefile
 878         tests/regression/ust/getcpu-override/Makefile
 879         tests/regression/ust/clock-override/Makefile
 880         tests/regression/ust/type-declarations/Makefile
 881         tests/stress/Makefile
 882         tests/unit/Makefile
 883         tests/unit/ini_config/Makefile
 884         tests/utils/Makefile
 885         tests/utils/tap/Makefile
 886         tests/utils/testapp/Makefile
 887         tests/utils/testapp/gen-ust-events/Makefile
 888         tests/utils/testapp/gen-ust-nevents/Makefile
 889         tests/utils/testapp/gen-ust-tracef/Makefile
 890 ])
 891
 892 # Inject variable into python test script.
 893 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 894
 895 AC_OUTPUT
 896
 897 #
 898 # Mini-report on what will be built.
 899 #
 900
 901 PPRINT_INIT
 902 PPRINT_SET_INDENT(1)
 903 PPRINT_SET_TS(38)
 904
 905 AS_ECHO
 906 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
 907 AS_ECHO
 908
 909 AS_IF([test -n "$report_fold"], [
 910         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
 911 ], [
 912         AS_ECHO("$version_description")
 913 ])
 914
 915 AS_ECHO
 916 PPRINT_SUBTITLE([Features])
 917
 918 # Target architecture we're building for.
 919 target_arch=$host_cpu
 920 [
 921 for f in $CFLAGS; do
 922         if test $f = "-m32"; then
 923                         target_arch="32-bit"
 924         elif test $f = "-m64"; then
 925                         target_arch="64-bit"
 926         fi
 927 done
 928 ]
 929 PPRINT_PROP_STRING([Target architecture], $target_arch)
 930
 931 # kmod enabled/disabled
 932 test "x$kmod_found" = "xyes" && value=1 || value=0
 933 PPRINT_PROP_BOOL([libkmod support], $value)
 934
 935 # LTTng-UST enabled/disabled
 936 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
 937 PPRINT_PROP_BOOL([LTTng-UST support], $value)
 938
 939 AS_ECHO
 940 PPRINT_SUBTITLE([Binaries])
 941
 942 # List binaries to be built
 943 test x$enable_bin_lttng != xno && value=1 || value=0
 944 PPRINT_PROP_BOOL([lttng], $value)
 945
 946 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
 947 PPRINT_PROP_BOOL([lttng-consumerd], $value)
 948
 949 test x$enable_bin_lttng_crash != xno && value=1 || value=0
 950 PPRINT_PROP_BOOL([lttng-crash], $value)
 951
 952 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
 953 PPRINT_PROP_BOOL([lttng-relayd], $value)
 954
 955 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
 956 PPRINT_PROP_BOOL([lttng-sessiond], $value)
 957
 958 # Extras
 959 test x$enable_extras != xno && value=1 || value=0
 960 AS_ECHO
 961 PPRINT_SET_INDENT(0)
 962 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
 963 PPRINT_SET_INDENT(1)
 964
 965 AS_ECHO
 966 PPRINT_SUBTITLE([Tests])
 967
 968 # Print clear message that tests won't be built
 969 AS_IF([test "x$build_tests" = "xno"],[
 970         PPRINT_WARN([Tests won't be built since some binaries were disabled])
 971 ])
 972
 973 # LTTng UST Java agent JUL tests enabled/disabled
 974 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
 975 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
 976
 977 # LTTng UST Java agent Log4j tests enabled/disabled
 978 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
 979 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
 980
 981 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
 982 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
 983
 984 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
 985 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
 986
 987 #Python binding enabled/disabled
 988 test "x${enable_python_binding:-yes}" = xyes && value=1 || value=0
 989 AS_ECHO
 990 PPRINT_SET_INDENT(0)
 991 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
 992 PPRINT_SET_INDENT(1)
 993
 994 AS_ECHO
 995 PPRINT_SUBTITLE([Man pages])
 996
 997 # man pages build enabled/disabled
 998 AS_IF([test "x$build_man_pages" = "xyes"], [
 999         PPRINT_PROP_BOOL([Build man pages], 1)
1000 ], [
1001         AS_IF([test "x$in_git_repo" = "xyes"], [
1002                 PPRINT_PROP_BOOL([Build man pages], 0)
1003         ], [
1004                 PPRINT_PROP_STRING([Build man pages], [${PPRINT_COLOR_BLDGRN}Already built])
1005         ])
1006 ])
1007
1008 # man pages install enabled/disabled (always true in tarball)
1009 test "x$build_man_pages" != "xyes" && test "x$in_git_repo" = "xyes" && value=0 || value=1
1010 PPRINT_PROP_BOOL([Install man pages], $value)
1011
1012 report_bindir="`eval eval echo $bindir`"
1013 report_libdir="`eval eval echo $libdir`"
1014
1015 # Print the bindir and libdir this `make install' will install into.
1016 AS_ECHO
1017 PPRINT_SUBTITLE([Install directories])
1018 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1019 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1020
1021 AS_ECHO
1022 PPRINT_SUBTITLE([Search directories])
1023
1024 # If we build the sessiond, print the paths it will use
1025 AS_IF([test "$SESSIOND_BIN" = ""],[
1026         path="$report_bindir/lttng-sessiond"
1027 ],[
1028         path="$SESSIOND_BIN"
1029 ])
1030 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1031
1032 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1033         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1034 ],[
1035         path="$CONSUMERD32_BIN"
1036 ])
1037 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1038
1039 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1040         path="`eval eval echo $libdir`"
1041 ],[
1042         path="$CONSUMERD32_LIBDIR"
1043 ])
1044 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1045
1046 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1047         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1048 ],[
1049         path="$CONSUMERD64_BIN"
1050 ])
1051 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1052
1053 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1054         path="`eval eval echo $libdir`"
1055 ],[
1056         path="$CONSUMERD64_LIBDIR"
1057 ])
1058 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])