[deliverable/linux.git] / arch / arm / mm / proc-v6.S

/*
 *  linux/arch/arm/mm/proc-v6.S
 *
 *  Copyright (C) 2001 Deep Blue Solutions Ltd.
 *  Modified by Catalin Marinas for noMMU support
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 *
 *  This is the "shell" of the ARMv6 processor support.
 */
#include <linux/init.h>
#include <linux/linkage.h>
#include <asm/assembler.h>
#include <asm/asm-offsets.h>
#include <asm/hwcap.h>
#include <asm/pgtable-hwdef.h>
#include <asm/pgtable.h>

#include "proc-macros.S"

#define D_CACHE_LINE_SIZE	32

#define TTB_C		(1 << 0)
#define TTB_S		(1 << 1)
#define TTB_IMP		(1 << 2)
#define TTB_RGN_NC	(0 << 3)
#define TTB_RGN_WBWA	(1 << 3)
#define TTB_RGN_WT	(2 << 3)
#define TTB_RGN_WB	(3 << 3)

#define TTB_FLAGS_UP	TTB_RGN_WBWA
#define PMD_FLAGS_UP	PMD_SECT_WB
#define TTB_FLAGS_SMP	TTB_RGN_WBWA|TTB_S
#define PMD_FLAGS_SMP	PMD_SECT_WBWA|PMD_SECT_S

ENTRY(cpu_v6_proc_init)
	mov	pc, lr

ENTRY(cpu_v6_proc_fin)
	mrc	p15, 0, r0, c1, c0, 0		@ ctrl register
	bic	r0, r0, #0x1000			@ ...i............
	bic	r0, r0, #0x0006			@ .............ca.
	mcr	p15, 0, r0, c1, c0, 0		@ disable caches
	mov	pc, lr

/*
 *	cpu_v6_reset(loc)
 *
 *	Perform a soft reset of the system.  Put the CPU into the
 *	same state as it would be if it had been reset, and branch
 *	to what would be the reset vector.
 *
 *	- loc   - location to jump to for soft reset
 */
	.align	5
ENTRY(cpu_v6_reset)
	mrc	p15, 0, r1, c1, c0, 0		@ ctrl register
	bic	r1, r1, #0x1			@ ...............m
	mcr	p15, 0, r1, c1, c0, 0		@ disable MMU
	mov	r1, #0
	mcr	p15, 0, r1, c7, c5, 4		@ ISB
	mov	pc, r0

/*
 *	cpu_v6_do_idle()
 *
 *	Idle the processor (eg, wait for interrupt).
 *
 *	IRQs are already disabled.
 */
ENTRY(cpu_v6_do_idle)
	mov	r1, #0
	mcr	p15, 0, r1, c7, c10, 4		@ DWB - WFI may enter a low-power mode
	mcr	p15, 0, r1, c7, c0, 4		@ wait for interrupt
	mov	pc, lr

ENTRY(cpu_v6_dcache_clean_area)
#ifndef TLB_CAN_READ_FROM_L1_CACHE
1:	mcr	p15, 0, r0, c7, c10, 1		@ clean D entry
	add	r0, r0, #D_CACHE_LINE_SIZE
	subs	r1, r1, #D_CACHE_LINE_SIZE
	bhi	1b
#endif
	mov	pc, lr

/*
 *	cpu_arm926_switch_mm(pgd_phys, tsk)
 *
 *	Set the translation table base pointer to be pgd_phys
 *
 *	- pgd_phys - physical address of new TTB
 *
 *	It is assumed that:
 *	- we are not using split page tables
 */
ENTRY(cpu_v6_switch_mm)
#ifdef CONFIG_MMU
	mov	r2, #0
	ldr	r1, [r1, #MM_CONTEXT_ID]	@ get mm->context.id
	ALT_SMP(orr	r0, r0, #TTB_FLAGS_SMP)
	ALT_UP(orr	r0, r0, #TTB_FLAGS_UP)
	mcr	p15, 0, r2, c7, c5, 6		@ flush BTAC/BTB
	mcr	p15, 0, r2, c7, c10, 4		@ drain write buffer
	mcr	p15, 0, r0, c2, c0, 0		@ set TTB 0
	mcr	p15, 0, r1, c13, c0, 1		@ set context ID
#endif
	mov	pc, lr

/*
 *	cpu_v6_set_pte_ext(ptep, pte, ext)
 *
 *	Set a level 2 translation table entry.
 *
 *	- ptep  - pointer to level 2 translation table entry
 *		  (hardware version is stored at -1024 bytes)
 *	- pte   - PTE value to store
 *	- ext	- value for extended PTE bits
 */
	armv6_mt_table cpu_v6

ENTRY(cpu_v6_set_pte_ext)
#ifdef CONFIG_MMU
	armv6_set_pte_ext cpu_v6
#endif
	mov	pc, lr

/* Suspend/resume support: taken from arch/arm/mach-s3c64xx/sleep.S */
.globl	cpu_v6_suspend_size
.equ	cpu_v6_suspend_size, 4 * 7
#ifdef CONFIG_PM_SLEEP
ENTRY(cpu_v6_do_suspend)
	stmfd	sp!, {r4 - r10, lr}
	mrc	p15, 0, r4, c13, c0, 0	@ FCSE/PID
	mrc	p15, 0, r5, c13, c0, 1	@ Context ID
	mrc	p15, 0, r6, c3, c0, 0	@ Domain ID
	mrc	p15, 0, r7, c2, c0, 1	@ Translation table base 1
	mrc	p15, 0, r8, c1, c0, 1	@ auxiliary control register
	mrc	p15, 0, r9, c1, c0, 2	@ co-processor access control
	mrc	p15, 0, r10, c1, c0, 0	@ control register
	stmia	r0, {r4 - r10}
	ldmfd	sp!, {r4- r10, pc}
ENDPROC(cpu_v6_do_suspend)

ENTRY(cpu_v6_do_resume)
	mov	ip, #0
	mcr	p15, 0, ip, c7, c14, 0	@ clean+invalidate D cache
	mcr	p15, 0, ip, c7, c5, 0	@ invalidate I cache
	mcr	p15, 0, ip, c7, c15, 0	@ clean+invalidate cache
	mcr	p15, 0, ip, c7, c10, 4	@ drain write buffer
	ldmia	r0, {r4 - r10}
	mcr	p15, 0, r4, c13, c0, 0	@ FCSE/PID
	mcr	p15, 0, r5, c13, c0, 1	@ Context ID
	mcr	p15, 0, r6, c3, c0, 0	@ Domain ID
	ALT_SMP(orr	r1, r1, #TTB_FLAGS_SMP)
	ALT_UP(orr	r1, r1, #TTB_FLAGS_UP)
	mcr	p15, 0, r1, c2, c0, 0	@ Translation table base 0
	mcr	p15, 0, r7, c2, c0, 1	@ Translation table base 1
	mcr	p15, 0, r8, c1, c0, 1	@ auxiliary control register
	mcr	p15, 0, r9, c1, c0, 2	@ co-processor access control
	mcr	p15, 0, ip, c2, c0, 2	@ TTB control register
	mcr	p15, 0, ip, c7, c5, 4	@ ISB
	mov	r0, r10			@ control register
	b	cpu_resume_mmu
ENDPROC(cpu_v6_do_resume)
#endif

	string	cpu_v6_name, "ARMv6-compatible processor"

	.align

	__CPUINIT

/*
 *	__v6_setup
 *
 *	Initialise TLB, Caches, and MMU state ready to switch the MMU
 *	on.  Return in r0 the new CP15 C1 control register setting.
 *
 *	We automatically detect if we have a Harvard cache, and use the
 *	Harvard cache control instructions insead of the unified cache
 *	control instructions.
 *
 *	This should be able to cover all ARMv6 cores.
 *
 *	It is assumed that:
 *	- cache type register is implemented
 */
__v6_setup:
#ifdef CONFIG_SMP
	ALT_SMP(mrc	p15, 0, r0, c1, c0, 1)	@ Enable SMP/nAMP mode
	ALT_UP(nop)
	orr	r0, r0, #0x20
	ALT_SMP(mcr	p15, 0, r0, c1, c0, 1)
	ALT_UP(nop)
#endif

	mov	r0, #0
	mcr	p15, 0, r0, c7, c14, 0		@ clean+invalidate D cache
	mcr	p15, 0, r0, c7, c5, 0		@ invalidate I cache
	mcr	p15, 0, r0, c7, c15, 0		@ clean+invalidate cache
	mcr	p15, 0, r0, c7, c10, 4		@ drain write buffer
#ifdef CONFIG_MMU
	mcr	p15, 0, r0, c8, c7, 0		@ invalidate I + D TLBs
	mcr	p15, 0, r0, c2, c0, 2		@ TTB control register
	ALT_SMP(orr	r4, r4, #TTB_FLAGS_SMP)
	ALT_UP(orr	r4, r4, #TTB_FLAGS_UP)
	ALT_SMP(orr	r8, r8, #TTB_FLAGS_SMP)
	ALT_UP(orr	r8, r8, #TTB_FLAGS_UP)
	mcr	p15, 0, r8, c2, c0, 1		@ load TTB1
#endif /* CONFIG_MMU */
	adr	r5, v6_crval
	ldmia	r5, {r5, r6}
#ifdef CONFIG_CPU_ENDIAN_BE8
	orr	r6, r6, #1 << 25		@ big-endian page tables
#endif
	mrc	p15, 0, r0, c1, c0, 0		@ read control register
	bic	r0, r0, r5			@ clear bits them
	orr	r0, r0, r6			@ set them
#ifdef CONFIG_ARM_ERRATA_364296
	/*
	 * Workaround for the 364296 ARM1136 r0p2 erratum (possible cache data
	 * corruption with hit-under-miss enabled). The conditional code below
	 * (setting the undocumented bit 31 in the auxiliary control register
	 * and the FI bit in the control register) disables hit-under-miss
	 * without putting the processor into full low interrupt latency mode.
	 */
	ldr	r6, =0x4107b362			@ id for ARM1136 r0p2
	mrc	p15, 0, r5, c0, c0, 0		@ get processor id
	teq	r5, r6				@ check for the faulty core
	mrceq	p15, 0, r5, c1, c0, 1		@ load aux control reg
	orreq	r5, r5, #(1 << 31)		@ set the undocumented bit 31
	mcreq	p15, 0, r5, c1, c0, 1		@ write aux control reg
	orreq	r0, r0, #(1 << 21)		@ low interrupt latency configuration
#endif
	mov	pc, lr				@ return to head.S:__ret

	/*
	 *         V X F   I D LR
	 * .... ...E PUI. .T.T 4RVI ZFRS BLDP WCAM
	 * rrrr rrrx xxx0 0101 xxxx xxxx x111 xxxx < forced
	 *         0 110       0011 1.00 .111 1101 < we want
	 */
	.type	v6_crval, #object
v6_crval:
	crval	clear=0x01e0fb7f, mmuset=0x00c0387d, ucset=0x00c0187c

	__INITDATA

	@ define struct processor (see <asm/proc-fns.h> and proc-macros.S)
	define_processor_functions v6, dabort=v6_early_abort, pabort=v6_pabort, suspend=1

	.section ".rodata"

	string	cpu_arch_name, "armv6"
	string	cpu_elf_name, "v6"
	.align

	.section ".proc.info.init", #alloc, #execinstr

	/*
	 * Match any ARMv6 processor core.
	 */
	.type	__v6_proc_info, #object
__v6_proc_info:
	.long	0x0007b000
	.long	0x0007f000
	ALT_SMP(.long \
		PMD_TYPE_SECT | \
		PMD_SECT_AP_WRITE | \
		PMD_SECT_AP_READ | \
		PMD_FLAGS_SMP)
	ALT_UP(.long \
		PMD_TYPE_SECT | \
		PMD_SECT_AP_WRITE | \
		PMD_SECT_AP_READ | \
		PMD_FLAGS_UP)
	.long   PMD_TYPE_SECT | \
		PMD_SECT_XN | \
		PMD_SECT_AP_WRITE | \
		PMD_SECT_AP_READ
	b	__v6_setup
	.long	cpu_arch_name
	.long	cpu_elf_name
	/* See also feat_v6_fixup() for HWCAP_TLS */
	.long	HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_EDSP|HWCAP_JAVA|HWCAP_TLS
	.long	cpu_v6_name
	.long	v6_processor_functions
	.long	v6wbi_tlb_fns
	.long	v6_user_fns
	.long	v6_cache_fns
	.size	__v6_proc_info, . - __v6_proc_info
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/mm/proc-v6.S
	3	*
	4	* Copyright (C) 2001 Deep Blue Solutions Ltd.
d090ddda	5	* Modified by Catalin Marinas for noMMU support
1da177e4 LT	6	*
	7	* This program is free software; you can redistribute it and/or modify
	8	* it under the terms of the GNU General Public License version 2 as
	9	* published by the Free Software Foundation.
	10	*
	11	* This is the "shell" of the ARMv6 processor support.
	12	*/
991da17e	13	#include <linux/init.h>
1da177e4 LT	14	#include <linux/linkage.h>
1da177e4 LT	15	#include <asm/assembler.h>
e6ae744d	16	#include <asm/asm-offsets.h>
5ec9407d	17	#include <asm/hwcap.h>
74945c86	18	#include <asm/pgtable-hwdef.h>
1da177e4 LT	19	#include <asm/pgtable.h>
	20
	21	#include "proc-macros.S"
	22
	23	#define D_CACHE_LINE_SIZE 32
	24
3747b36e RK	25	#define TTB_C (1 << 0)
	26	#define TTB_S (1 << 1)
	27	#define TTB_IMP (1 << 2)
	28	#define TTB_RGN_NC (0 << 3)
	29	#define TTB_RGN_WBWA (1 << 3)
	30	#define TTB_RGN_WT (2 << 3)
	31	#define TTB_RGN_WB (3 << 3)
	32
f00ec48f RK	33	#define TTB_FLAGS_UP TTB_RGN_WBWA
	34	#define PMD_FLAGS_UP PMD_SECT_WB
	35	#define TTB_FLAGS_SMP TTB_RGN_WBWA\|TTB_S
	36	#define PMD_FLAGS_SMP PMD_SECT_WBWA\|PMD_SECT_S
f2131d34	37
1da177e4 LT	38	ENTRY(cpu_v6_proc_init)
	39	mov pc, lr
	40
	41	ENTRY(cpu_v6_proc_fin)
67c5587a TL	42	mrc p15, 0, r0, c1, c0, 0 @ ctrl register
	43	bic r0, r0, #0x1000 @ ...i............
	44	bic r0, r0, #0x0006 @ .............ca.
	45	mcr p15, 0, r0, c1, c0, 0 @ disable caches
9ca03a21	46	mov pc, lr
1da177e4 LT	47
	48	/*
	49	* cpu_v6_reset(loc)
	50	*
	51	* Perform a soft reset of the system. Put the CPU into the
	52	* same state as it would be if it had been reset, and branch
	53	* to what would be the reset vector.
	54	*
	55	* - loc - location to jump to for soft reset
1da177e4 LT	56	*/
	57	.align 5
	58	ENTRY(cpu_v6_reset)
f4daf06f WD	59	mrc p15, 0, r1, c1, c0, 0 @ ctrl register
	60	bic r1, r1, #0x1 @ ...............m
	61	mcr p15, 0, r1, c1, c0, 0 @ disable MMU
	62	mov r1, #0
	63	mcr p15, 0, r1, c7, c5, 4 @ ISB
1da177e4 LT	64	mov pc, r0
	65
	66	/*
	67	* cpu_v6_do_idle()
	68	*
	69	* Idle the processor (eg, wait for interrupt).
	70	*
	71	* IRQs are already disabled.
	72	*/
	73	ENTRY(cpu_v6_do_idle)
8553cb67 CM	74	mov r1, #0
8553cb67 CM	75	mcr p15, 0, r1, c7, c10, 4 @ DWB - WFI may enter a low-power mode
1da177e4 LT	76	mcr p15, 0, r1, c7, c0, 4 @ wait for interrupt
	77	mov pc, lr
	78
	79	ENTRY(cpu_v6_dcache_clean_area)
	80	#ifndef TLB_CAN_READ_FROM_L1_CACHE
	81	1: mcr p15, 0, r0, c7, c10, 1 @ clean D entry
	82	add r0, r0, #D_CACHE_LINE_SIZE
	83	subs r1, r1, #D_CACHE_LINE_SIZE
	84	bhi 1b
	85	#endif
	86	mov pc, lr
	87
	88	/*
	89	* cpu_arm926_switch_mm(pgd_phys, tsk)
	90	*
	91	* Set the translation table base pointer to be pgd_phys
	92	*
	93	* - pgd_phys - physical address of new TTB
	94	*
	95	* It is assumed that:
	96	* - we are not using split page tables
	97	*/
	98	ENTRY(cpu_v6_switch_mm)
d090ddda	99	#ifdef CONFIG_MMU
1da177e4 LT	100	mov r2, #0
1da177e4 LT	101	ldr r1, [r1, #MM_CONTEXT_ID] @ get mm->context.id
f00ec48f RK	102	ALT_SMP(orr r0, r0, #TTB_FLAGS_SMP)
f00ec48f RK	103	ALT_UP(orr r0, r0, #TTB_FLAGS_UP)
d93742f5	104	mcr p15, 0, r2, c7, c5, 6 @ flush BTAC/BTB
1da177e4 LT	105	mcr p15, 0, r2, c7, c10, 4 @ drain write buffer
	106	mcr p15, 0, r0, c2, c0, 0 @ set TTB 0
	107	mcr p15, 0, r1, c13, c0, 1 @ set context ID
d090ddda	108	#endif
1da177e4 LT	109	mov pc, lr
1da177e4 LT	110
1da177e4	111	/*
ad1ae2fe	112	* cpu_v6_set_pte_ext(ptep, pte, ext)
1da177e4 LT	113	*
	114	* Set a level 2 translation table entry.
	115	*
	116	* - ptep - pointer to level 2 translation table entry
	117	* (hardware version is stored at -1024 bytes)
	118	* - pte - PTE value to store
ad1ae2fe	119	* - ext - value for extended PTE bits
1da177e4	120	*/
639b0ae7 RK	121	armv6_mt_table cpu_v6
639b0ae7 RK	122
ad1ae2fe	123	ENTRY(cpu_v6_set_pte_ext)
d090ddda	124	#ifdef CONFIG_MMU
639b0ae7	125	armv6_set_pte_ext cpu_v6
d090ddda	126	#endif
1da177e4 LT	127	mov pc, lr
1da177e4 LT	128
f6b0fa02 RK	129	/* Suspend/resume support: taken from arch/arm/mach-s3c64xx/sleep.S */
f6b0fa02 RK	130	.globl cpu_v6_suspend_size
de8e71ca	131	.equ cpu_v6_suspend_size, 4 * 7
29ea23ff	132	#ifdef CONFIG_PM_SLEEP
f6b0fa02	133	ENTRY(cpu_v6_do_suspend)
de8e71ca	134	stmfd sp!, {r4 - r10, lr}
f6b0fa02 RK	135	mrc p15, 0, r4, c13, c0, 0 @ FCSE/PID
	136	mrc p15, 0, r5, c13, c0, 1 @ Context ID
	137	mrc p15, 0, r6, c3, c0, 0 @ Domain ID
de8e71ca RK	138	mrc p15, 0, r7, c2, c0, 1 @ Translation table base 1
	139	mrc p15, 0, r8, c1, c0, 1 @ auxiliary control register
	140	mrc p15, 0, r9, c1, c0, 2 @ co-processor access control
	141	mrc p15, 0, r10, c1, c0, 0 @ control register
	142	stmia r0, {r4 - r10}
	143	ldmfd sp!, {r4- r10, pc}
f6b0fa02 RK	144	ENDPROC(cpu_v6_do_suspend)
	145
	146	ENTRY(cpu_v6_do_resume)
	147	mov ip, #0
	148	mcr p15, 0, ip, c7, c14, 0 @ clean+invalidate D cache
	149	mcr p15, 0, ip, c7, c5, 0 @ invalidate I cache
	150	mcr p15, 0, ip, c7, c15, 0 @ clean+invalidate cache
	151	mcr p15, 0, ip, c7, c10, 4 @ drain write buffer
de8e71ca	152	ldmia r0, {r4 - r10}
f6b0fa02 RK	153	mcr p15, 0, r4, c13, c0, 0 @ FCSE/PID
	154	mcr p15, 0, r5, c13, c0, 1 @ Context ID
	155	mcr p15, 0, r6, c3, c0, 0 @ Domain ID
de8e71ca RK	156	ALT_SMP(orr r1, r1, #TTB_FLAGS_SMP)
	157	ALT_UP(orr r1, r1, #TTB_FLAGS_UP)
	158	mcr p15, 0, r1, c2, c0, 0 @ Translation table base 0
	159	mcr p15, 0, r7, c2, c0, 1 @ Translation table base 1
	160	mcr p15, 0, r8, c1, c0, 1 @ auxiliary control register
	161	mcr p15, 0, r9, c1, c0, 2 @ co-processor access control
f6b0fa02 RK	162	mcr p15, 0, ip, c2, c0, 2 @ TTB control register
f6b0fa02 RK	163	mcr p15, 0, ip, c7, c5, 4 @ ISB
de8e71ca	164	mov r0, r10 @ control register
f6b0fa02 RK	165	b cpu_resume_mmu
f6b0fa02 RK	166	ENDPROC(cpu_v6_do_resume)
f6b0fa02	167	#endif
1da177e4	168
7b7dc6e8	169	string cpu_v6_name, "ARMv6-compatible processor"
edabd38e	170
1da177e4 LT	171	.align
1da177e4 LT	172
5085f3ff	173	__CPUINIT
1da177e4 LT	174
	175	/*
	176	* __v6_setup
	177	*
	178	* Initialise TLB, Caches, and MMU state ready to switch the MMU
	179	* on. Return in r0 the new CP15 C1 control register setting.
	180	*
	181	* We automatically detect if we have a Harvard cache, and use the
	182	* Harvard cache control instructions insead of the unified cache
	183	* control instructions.
	184	*
	185	* This should be able to cover all ARMv6 cores.
	186	*
	187	* It is assumed that:
	188	* - cache type register is implemented
	189	*/
	190	__v6_setup:
862184fe	191	#ifdef CONFIG_SMP
f00ec48f RK	192	ALT_SMP(mrc p15, 0, r0, c1, c0, 1) @ Enable SMP/nAMP mode
f00ec48f RK	193	ALT_UP(nop)
862184fe	194	orr r0, r0, #0x20
f00ec48f RK	195	ALT_SMP(mcr p15, 0, r0, c1, c0, 1)
f00ec48f RK	196	ALT_UP(nop)
862184fe RK	197	#endif
862184fe RK	198
1da177e4 LT	199	mov r0, #0
	200	mcr p15, 0, r0, c7, c14, 0 @ clean+invalidate D cache
	201	mcr p15, 0, r0, c7, c5, 0 @ invalidate I cache
	202	mcr p15, 0, r0, c7, c15, 0 @ clean+invalidate cache
	203	mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
d090ddda	204	#ifdef CONFIG_MMU
1da177e4 LT	205	mcr p15, 0, r0, c8, c7, 0 @ invalidate I + D TLBs
1da177e4 LT	206	mcr p15, 0, r0, c2, c0, 2 @ TTB control register
f00ec48f RK	207	ALT_SMP(orr r4, r4, #TTB_FLAGS_SMP)
f00ec48f RK	208	ALT_UP(orr r4, r4, #TTB_FLAGS_UP)
d427958a CM	209	ALT_SMP(orr r8, r8, #TTB_FLAGS_SMP)
	210	ALT_UP(orr r8, r8, #TTB_FLAGS_UP)
	211	mcr p15, 0, r8, c2, c0, 1 @ load TTB1
d090ddda	212	#endif /* CONFIG_MMU */
22b19086 RK	213	adr r5, v6_crval
22b19086 RK	214	ldmia r5, {r5, r6}
26584853 CM	215	#ifdef CONFIG_CPU_ENDIAN_BE8
	216	orr r6, r6, #1 << 25 @ big-endian page tables
	217	#endif
1da177e4	218	mrc p15, 0, r0, c1, c0, 0 @ read control register
1da177e4	219	bic r0, r0, r5 @ clear bits them
22b19086	220	orr r0, r0, r6 @ set them
145e10e1 CM	221	#ifdef CONFIG_ARM_ERRATA_364296
	222	/*
	223	* Workaround for the 364296 ARM1136 r0p2 erratum (possible cache data
	224	* corruption with hit-under-miss enabled). The conditional code below
	225	* (setting the undocumented bit 31 in the auxiliary control register
	226	* and the FI bit in the control register) disables hit-under-miss
	227	* without putting the processor into full low interrupt latency mode.
	228	*/
	229	ldr r6, =0x4107b362 @ id for ARM1136 r0p2
	230	mrc p15, 0, r5, c0, c0, 0 @ get processor id
	231	teq r5, r6 @ check for the faulty core
	232	mrceq p15, 0, r5, c1, c0, 1 @ load aux control reg
	233	orreq r5, r5, #(1 << 31) @ set the undocumented bit 31
	234	mcreq p15, 0, r5, c1, c0, 1 @ write aux control reg
	235	orreq r0, r0, #(1 << 21) @ low interrupt latency configuration
	236	#endif
1da177e4 LT	237	mov pc, lr @ return to head.S:__ret
	238
	239	/*
	240	* V X F I D LR
	241	* .... ...E PUI. .T.T 4RVI ZFRS BLDP WCAM
	242	* rrrr rrrx xxx0 0101 xxxx xxxx x111 xxxx < forced
	243	* 0 110 0011 1.00 .111 1101 < we want
	244	*/
22b19086 RK	245	.type v6_crval, #object
	246	v6_crval:
	247	crval clear=0x01e0fb7f, mmuset=0x00c0387d, ucset=0x00c0187c
1da177e4	248
5085f3ff RK	249	__INITDATA
5085f3ff RK	250
7b7dc6e8 DM	251	@ define struct processor (see <asm/proc-fns.h> and proc-macros.S)
7b7dc6e8 DM	252	define_processor_functions v6, dabort=v6_early_abort, pabort=v6_pabort, suspend=1
1da177e4	253
5085f3ff RK	254	.section ".rodata"
5085f3ff RK	255
7b7dc6e8 DM	256	string cpu_arch_name, "armv6"
7b7dc6e8 DM	257	string cpu_elf_name, "v6"
1da177e4 LT	258	.align
1da177e4 LT	259
02b7dd12	260	.section ".proc.info.init", #alloc, #execinstr
1da177e4 LT	261
	262	/*
	263	* Match any ARMv6 processor core.
	264	*/
	265	.type __v6_proc_info, #object
	266	__v6_proc_info:
	267	.long 0x0007b000
	268	.long 0x0007f000
f00ec48f RK	269	ALT_SMP(.long \
	270	PMD_TYPE_SECT \| \
	271	PMD_SECT_AP_WRITE \| \
	272	PMD_SECT_AP_READ \| \
	273	PMD_FLAGS_SMP)
	274	ALT_UP(.long \
	275	PMD_TYPE_SECT \| \
1da177e4	276	PMD_SECT_AP_WRITE \| \
4b46d641	277	PMD_SECT_AP_READ \| \
f00ec48f	278	PMD_FLAGS_UP)
8799ee9f RK	279	.long PMD_TYPE_SECT \| \
	280	PMD_SECT_XN \| \
	281	PMD_SECT_AP_WRITE \| \
	282	PMD_SECT_AP_READ
1da177e4 LT	283	b __v6_setup
	284	.long cpu_arch_name
	285	.long cpu_elf_name
f159f4ed TL	286	/* See also feat_v6_fixup() for HWCAP_TLS */
f159f4ed TL	287	.long HWCAP_SWP\|HWCAP_HALF\|HWCAP_THUMB\|HWCAP_FAST_MULT\|HWCAP_EDSP\|HWCAP_JAVA\|HWCAP_TLS
1da177e4 LT	288	.long cpu_v6_name
	289	.long v6_processor_functions
	290	.long v6wbi_tlb_fns
	291	.long v6_user_fns
	292	.long v6_cache_fns
	293	.size __v6_proc_info, . - __v6_proc_info