[deliverable/linux.git] / arch / mips / kernel / mcount.S

/*
 * MIPS specific _mcount support
 *
 * This file is subject to the terms and conditions of the GNU General Public
 * License.  See the file "COPYING" in the main directory of this archive for
 * more details.
 *
 * Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
 * Copyright (C) 2010 DSLab, Lanzhou University, China
 * Author: Wu Zhangjin <wuzhangjin@gmail.com>
 */

#include <asm/regdef.h>
#include <asm/stackframe.h>
#include <asm/ftrace.h>

	.text
	.set noreorder
	.set noat

	.macro MCOUNT_SAVE_REGS
	PTR_SUBU	sp, PT_SIZE
	PTR_S	ra, PT_R31(sp)
	PTR_S	AT, PT_R1(sp)
	PTR_S	a0, PT_R4(sp)
	PTR_S	a1, PT_R5(sp)
	PTR_S	a2, PT_R6(sp)
	PTR_S	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_S	a4, PT_R8(sp)
	PTR_S	a5, PT_R9(sp)
	PTR_S	a6, PT_R10(sp)
	PTR_S	a7, PT_R11(sp)
#endif
	.endm

	.macro MCOUNT_RESTORE_REGS
	PTR_L	ra, PT_R31(sp)
	PTR_L	AT, PT_R1(sp)
	PTR_L	a0, PT_R4(sp)
	PTR_L	a1, PT_R5(sp)
	PTR_L	a2, PT_R6(sp)
	PTR_L	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_L	a4, PT_R8(sp)
	PTR_L	a5, PT_R9(sp)
	PTR_L	a6, PT_R10(sp)
	PTR_L	a7, PT_R11(sp)
#else
	PTR_ADDIU	sp, PT_SIZE
#endif
.endm

	.macro RETURN_BACK
	jr ra
	 move ra, AT
	.endm

/*
 * The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
 * the location of the parent's return address.
 */
#define MCOUNT_RA_ADDRESS_REG	$12

#ifdef CONFIG_DYNAMIC_FTRACE

NESTED(ftrace_caller, PT_SIZE, ra)
	.globl _mcount
_mcount:
	b	ftrace_stub
	addiu sp,sp,8

	/* When tracing is activated, it calls ftrace_caller+8 (aka here) */
	lw	t1, function_trace_stop
	bnez	t1, ftrace_stub
	 nop

	MCOUNT_SAVE_REGS
#ifdef KBUILD_MCOUNT_RA_ADDRESS
	PTR_S	MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
#endif

	move	a0, ra		/* arg1: self return address */
	.globl ftrace_call
ftrace_call:
	nop	/* a placeholder for the call to a real tracing function */
	 move	a1, AT		/* arg2: parent's return address */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	.globl ftrace_graph_call
ftrace_graph_call:
	nop
	 nop
#endif

	MCOUNT_RESTORE_REGS
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(ftrace_caller)

#else	/* ! CONFIG_DYNAMIC_FTRACE */

NESTED(_mcount, PT_SIZE, ra)
	lw	t1, function_trace_stop
	bnez	t1, ftrace_stub
	 nop
	PTR_LA	t1, ftrace_stub
	PTR_L	t2, ftrace_trace_function /* Prepare t2 for (1) */
	bne	t1, t2, static_trace
	 nop

#ifdef	CONFIG_FUNCTION_GRAPH_TRACER
	PTR_L	t3, ftrace_graph_return
	bne	t1, t3, ftrace_graph_caller
	 nop
	PTR_LA	t1, ftrace_graph_entry_stub
	PTR_L	t3, ftrace_graph_entry
	bne	t1, t3, ftrace_graph_caller
	 nop
#endif
	b	ftrace_stub
	 nop

static_trace:
	MCOUNT_SAVE_REGS

	move	a0, ra		/* arg1: self return address */
	jalr	t2		/* (1) call *ftrace_trace_function */
	 move	a1, AT		/* arg2: parent's return address */

	MCOUNT_RESTORE_REGS
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(_mcount)

#endif	/* ! CONFIG_DYNAMIC_FTRACE */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER

NESTED(ftrace_graph_caller, PT_SIZE, ra)
#ifndef CONFIG_DYNAMIC_FTRACE
	MCOUNT_SAVE_REGS
#endif

	/* arg1: Get the location of the parent's return address */
#ifdef KBUILD_MCOUNT_RA_ADDRESS
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a0, PT_R12(sp)
#else
	move	a0, MCOUNT_RA_ADDRESS_REG
#endif
	bnez	a0, 1f	/* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
	 nop
#endif
	PTR_LA	a0, PT_R1(sp)	/* leaf func: the location in current stack */
1:

	/* arg2: Get self return address */
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a1, PT_R31(sp)
#else
	move	a1, ra
#endif

	/* arg3: Get frame pointer of current stack */
#ifdef CONFIG_FRAME_POINTER
	move	a2, fp
#else /* ! CONFIG_FRAME_POINTER */
#ifdef CONFIG_64BIT
	PTR_LA	a2, PT_SIZE(sp)
#else
	PTR_LA	a2, (PT_SIZE+8)(sp)
#endif
#endif

	jal	prepare_ftrace_return
	 nop
	MCOUNT_RESTORE_REGS
	RETURN_BACK
	END(ftrace_graph_caller)

	.align	2
	.globl	return_to_handler
return_to_handler:
	PTR_SUBU	sp, PT_SIZE
	PTR_S	v0, PT_R2(sp)

	jal	ftrace_return_to_handler
	 PTR_S	v1, PT_R3(sp)

	/* restore the real parent address: v0 -> ra */
	move	ra, v0

	PTR_L	v0, PT_R2(sp)
	PTR_L	v1, PT_R3(sp)
	jr	ra
	 PTR_ADDIU	sp, PT_SIZE
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */

	.set at
	.set reorder
Commit	Line	Data
d2bb0762 WZ	1	/*
	2	* MIPS specific _mcount support
	3	*
	4	* This file is subject to the terms and conditions of the GNU General Public
	5	* License. See the file "COPYING" in the main directory of this archive for
	6	* more details.
	7	*
	8	* Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
042e571d	9	* Copyright (C) 2010 DSLab, Lanzhou University, China
f7a904df	10	* Author: Wu Zhangjin <wuzhangjin@gmail.com>
d2bb0762 WZ	11	*/
	12
	13	#include <asm/regdef.h>
	14	#include <asm/stackframe.h>
	15	#include <asm/ftrace.h>
	16
	17	.text
	18	.set noreorder
	19	.set noat
	20
	21	.macro MCOUNT_SAVE_REGS
	22	PTR_SUBU sp, PT_SIZE
	23	PTR_S ra, PT_R31(sp)
	24	PTR_S AT, PT_R1(sp)
	25	PTR_S a0, PT_R4(sp)
	26	PTR_S a1, PT_R5(sp)
	27	PTR_S a2, PT_R6(sp)
	28	PTR_S a3, PT_R7(sp)
	29	#ifdef CONFIG_64BIT
	30	PTR_S a4, PT_R8(sp)
	31	PTR_S a5, PT_R9(sp)
	32	PTR_S a6, PT_R10(sp)
	33	PTR_S a7, PT_R11(sp)
	34	#endif
	35	.endm
	36
	37	.macro MCOUNT_RESTORE_REGS
	38	PTR_L ra, PT_R31(sp)
	39	PTR_L AT, PT_R1(sp)
	40	PTR_L a0, PT_R4(sp)
	41	PTR_L a1, PT_R5(sp)
	42	PTR_L a2, PT_R6(sp)
	43	PTR_L a3, PT_R7(sp)
	44	#ifdef CONFIG_64BIT
	45	PTR_L a4, PT_R8(sp)
	46	PTR_L a5, PT_R9(sp)
	47	PTR_L a6, PT_R10(sp)
	48	PTR_L a7, PT_R11(sp)
d2bb0762	49	#else
58b69401	50	PTR_ADDIU sp, PT_SIZE
d2bb0762 WZ	51	#endif
	52	.endm
	53
	54	.macro RETURN_BACK
	55	jr ra
	56	move ra, AT
	57	.endm
	58
56b49cd3 WZ	59	/*
	60	* The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
	61	* the location of the parent's return address.
	62	*/
	63	#define MCOUNT_RA_ADDRESS_REG $12
	64
538f1952 WZ	65	#ifdef CONFIG_DYNAMIC_FTRACE
	66
	67	NESTED(ftrace_caller, PT_SIZE, ra)
	68	.globl _mcount
	69	_mcount:
	70	b ftrace_stub
58b69401 AC	71	addiu sp,sp,8
	72
	73	/* When tracing is activated, it calls ftrace_caller+8 (aka here) */
fc49a3be WZ	74	lw t1, function_trace_stop
fc49a3be WZ	75	bnez t1, ftrace_stub
538f1952 WZ	76	nop
	77
	78	MCOUNT_SAVE_REGS
7326c4e5	79	#ifdef KBUILD_MCOUNT_RA_ADDRESS
56b49cd3	80	PTR_S MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
7326c4e5	81	#endif
538f1952	82
042e571d	83	move a0, ra /* arg1: self return address */
538f1952 WZ	84	.globl ftrace_call
	85	ftrace_call:
	86	nop /* a placeholder for the call to a real tracing function */
042e571d	87	move a1, AT /* arg2: parent's return address */
538f1952	88
e17ff5fe WZ	89	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	90	.globl ftrace_graph_call
	91	ftrace_graph_call:
	92	nop
	93	nop
	94	#endif
	95
538f1952 WZ	96	MCOUNT_RESTORE_REGS
	97	.globl ftrace_stub
	98	ftrace_stub:
	99	RETURN_BACK
	100	END(ftrace_caller)
	101
	102	#else /* ! CONFIG_DYNAMIC_FTRACE */
	103
d2bb0762	104	NESTED(_mcount, PT_SIZE, ra)
fc49a3be WZ	105	lw t1, function_trace_stop
fc49a3be WZ	106	bnez t1, ftrace_stub
69a7d1b3	107	nop
fc49a3be WZ	108	PTR_LA t1, ftrace_stub
	109	PTR_L t2, ftrace_trace_function /* Prepare t2 for (1) */
	110	bne t1, t2, static_trace
d2bb0762	111	nop
29c5d346 WZ	112
29c5d346 WZ	113	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
fc49a3be WZ	114	PTR_L t3, ftrace_graph_return
fc49a3be WZ	115	bne t1, t3, ftrace_graph_caller
29c5d346	116	nop
fc49a3be WZ	117	PTR_LA t1, ftrace_graph_entry_stub
	118	PTR_L t3, ftrace_graph_entry
	119	bne t1, t3, ftrace_graph_caller
29c5d346 WZ	120	nop
29c5d346 WZ	121	#endif
d2bb0762 WZ	122	b ftrace_stub
	123	nop
	124
	125	static_trace:
	126	MCOUNT_SAVE_REGS
	127
042e571d	128	move a0, ra /* arg1: self return address */
fc49a3be	129	jalr t2 /* (1) call ftrace_trace_function /
042e571d	130	move a1, AT /* arg2: parent's return address */
d2bb0762 WZ	131
	132	MCOUNT_RESTORE_REGS
	133	.globl ftrace_stub
	134	ftrace_stub:
	135	RETURN_BACK
	136	END(_mcount)
	137
538f1952 WZ	138	#endif /* ! CONFIG_DYNAMIC_FTRACE */
538f1952 WZ	139
29c5d346 WZ	140	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	141
	142	NESTED(ftrace_graph_caller, PT_SIZE, ra)
cbe555b0	143	#ifndef CONFIG_DYNAMIC_FTRACE
29c5d346	144	MCOUNT_SAVE_REGS
e17ff5fe	145	#endif
7326c4e5	146
cbe555b0	147	/* arg1: Get the location of the parent's return address */
7326c4e5	148	#ifdef KBUILD_MCOUNT_RA_ADDRESS
cbe555b0 WZ	149	#ifdef CONFIG_DYNAMIC_FTRACE
	150	PTR_L a0, PT_R12(sp)
	151	#else
56b49cd3	152	move a0, MCOUNT_RA_ADDRESS_REG
cbe555b0	153	#endif
56b49cd3	154	bnez a0, 1f /* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
7326c4e5	155	nop
cbe555b0 WZ	156	#endif
	157	PTR_LA a0, PT_R1(sp) /* leaf func: the location in current stack */
	158	1:
	159
	160	/* arg2: Get self return address */
	161	#ifdef CONFIG_DYNAMIC_FTRACE
	162	PTR_L a1, PT_R31(sp)
7326c4e5	163	#else
cbe555b0	164	move a1, ra
7326c4e5	165	#endif
cbe555b0 WZ	166
cbe555b0 WZ	167	/* arg3: Get frame pointer of current stack */
046199ca	168	#ifdef CONFIG_FRAME_POINTER
65ab2826	169	move a2, fp
cbe555b0	170	#else /* ! CONFIG_FRAME_POINTER */
046199ca	171	#ifdef CONFIG_64BIT
65ab2826	172	PTR_LA a2, PT_SIZE(sp)
046199ca	173	#else
65ab2826	174	PTR_LA a2, (PT_SIZE+8)(sp)
046199ca WZ	175	#endif
046199ca WZ	176	#endif
29c5d346	177
cbe555b0 WZ	178	jal prepare_ftrace_return
cbe555b0 WZ	179	nop
29c5d346 WZ	180	MCOUNT_RESTORE_REGS
	181	RETURN_BACK
	182	END(ftrace_graph_caller)
	183
	184	.align 2
	185	.globl return_to_handler
	186	return_to_handler:
	187	PTR_SUBU sp, PT_SIZE
	188	PTR_S v0, PT_R2(sp)
	189
	190	jal ftrace_return_to_handler
	191	PTR_S v1, PT_R3(sp)
	192
	193	/* restore the real parent address: v0 -> ra */
	194	move ra, v0
	195
	196	PTR_L v0, PT_R2(sp)
	197	PTR_L v1, PT_R3(sp)
	198	jr ra
	199	PTR_ADDIU sp, PT_SIZE
	200	#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
	201
d2bb0762 WZ	202	.set at
d2bb0762 WZ	203	.set reorder