[deliverable/linux.git] / arch / sparc / kernel / syscalls.S

	/* SunOS's execv() call only specifies the argv argument, the
	 * environment settings are the same as the calling processes.
	 */
sys64_execve:
	set	sys_execve, %g1
	jmpl	%g1, %g0
	 flushw

sys64_execveat:
	set	sys_execveat, %g1
	jmpl	%g1, %g0
	 flushw

#ifdef CONFIG_COMPAT
sunos_execv:
	mov	%g0, %o2
sys32_execve:
	set	compat_sys_execve, %g1
	jmpl	%g1, %g0
	 flushw

sys32_execveat:
	set	compat_sys_execveat, %g1
	jmpl	%g1, %g0
	 flushw
#endif

	.align	32
sys_sparc_pipe:
	ba,pt	%xcc, sys_sparc_pipe_real
	 add	%sp, PTREGS_OFF, %o0
sys_nis_syscall:
	ba,pt	%xcc, c_sys_nis_syscall
	 add	%sp, PTREGS_OFF, %o0
sys_memory_ordering:
	ba,pt	%xcc, sparc_memory_ordering
	 add	%sp, PTREGS_OFF, %o1
#ifdef CONFIG_COMPAT
sys32_sigstack:
	ba,pt	%xcc, do_sys32_sigstack
	 mov	%i6, %o2
#endif
	.align	32
#ifdef CONFIG_COMPAT
sys32_sigreturn:
	add	%sp, PTREGS_OFF, %o0
	call	do_sigreturn32
	 add	%o7, 1f-.-4, %o7
	nop
#endif
sys_rt_sigreturn:
	add	%sp, PTREGS_OFF, %o0
	call	do_rt_sigreturn
	 add	%o7, 1f-.-4, %o7
	nop
#ifdef CONFIG_COMPAT
sys32_rt_sigreturn:
	add	%sp, PTREGS_OFF, %o0
	call	do_rt_sigreturn32
	 add	%o7, 1f-.-4, %o7
	nop
#endif
	.align	32
1:	ldx	[%g6 + TI_FLAGS], %l5
	andcc	%l5, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT|_TIF_NOHZ), %g0
	be,pt	%icc, rtrap
	 nop
	call	syscall_trace_leave
	 add	%sp, PTREGS_OFF, %o0
	ba,pt	%xcc, rtrap
	 nop

	/* This is how fork() was meant to be done, 8 instruction entry.
	 *
	 * I questioned the following code briefly, let me clear things
	 * up so you must not reason on it like I did.
	 *
	 * Know the fork_kpsr etc. we use in the sparc32 port?  We don't
	 * need it here because the only piece of window state we copy to
	 * the child is the CWP register.  Even if the parent sleeps,
	 * we are safe because we stuck it into pt_regs of the parent
	 * so it will not change.
	 *
	 * XXX This raises the question, whether we can do the same on
	 * XXX sparc32 to get rid of fork_kpsr _and_ fork_kwim.  The
	 * XXX answer is yes.  We stick fork_kpsr in UREG_G0 and
	 * XXX fork_kwim in UREG_G1 (global registers are considered
	 * XXX volatile across a system call in the sparc ABI I think
	 * XXX if it isn't we can use regs->y instead, anyone who depends
	 * XXX upon the Y register being preserved across a fork deserves
	 * XXX to lose).
	 *
	 * In fact we should take advantage of that fact for other things
	 * during system calls...
	 */
	.align	32
sys_vfork: /* Under Linux, vfork and fork are just special cases of clone. */
	sethi	%hi(0x4000 | 0x0100 | SIGCHLD), %o0
	or	%o0, %lo(0x4000 | 0x0100 | SIGCHLD), %o0
	ba,pt	%xcc, sys_clone
sys_fork:
	 clr	%o1
	mov	SIGCHLD, %o0
sys_clone:
	flushw
	movrz	%o1, %fp, %o1
	mov	0, %o3
	ba,pt	%xcc, sparc_do_fork
	 add	%sp, PTREGS_OFF, %o2

	.globl	ret_from_fork
ret_from_fork:
	/* Clear current_thread_info()->new_child. */
	stb	%g0, [%g6 + TI_NEW_CHILD]
	call	schedule_tail
	 mov	%g7, %o0
	ldx	[%sp + PTREGS_OFF + PT_V9_I0], %o0
	brnz,pt	%o0, ret_sys_call
	 ldx	[%g6 + TI_FLAGS], %l0
	ldx	[%sp + PTREGS_OFF + PT_V9_G1], %l1
	call	%l1
	 ldx	[%sp + PTREGS_OFF + PT_V9_G2], %o0
	ba,pt	%xcc, ret_sys_call
	 mov	0, %o0

	.globl	sparc_exit_group
	.type	sparc_exit_group,#function
sparc_exit_group:
	sethi	%hi(sys_exit_group), %g7
	ba,pt	%xcc, 1f
	 or	%g7, %lo(sys_exit_group), %g7
	.size	sparc_exit_group,.-sparc_exit_group

	.globl	sparc_exit
	.type	sparc_exit,#function
sparc_exit:
	sethi	%hi(sys_exit), %g7
	or	%g7, %lo(sys_exit), %g7
1:	rdpr	%pstate, %g2
	wrpr	%g2, PSTATE_IE, %pstate
	rdpr	%otherwin, %g1
	rdpr	%cansave, %g3
	add	%g3, %g1, %g3
	wrpr	%g3, 0x0, %cansave
	wrpr	%g0, 0x0, %otherwin
	wrpr	%g2, 0x0, %pstate
	jmpl	%g7, %g0
	 stb	%g0, [%g6 + TI_WSAVED]
	.size	sparc_exit,.-sparc_exit

linux_sparc_ni_syscall:
	sethi	%hi(sys_ni_syscall), %l7
	ba,pt	%xcc, 4f
	 or	%l7, %lo(sys_ni_syscall), %l7

linux_syscall_trace32:
	call	syscall_trace_enter
	 add	%sp, PTREGS_OFF, %o0
	brnz,pn	%o0, 3f
	 mov	-ENOSYS, %o0

	/* Syscall tracing can modify the registers.  */
	ldx	[%sp + PTREGS_OFF + PT_V9_G1], %g1
	sethi	%hi(sys_call_table32), %l7
	ldx	[%sp + PTREGS_OFF + PT_V9_I0], %i0
	or	%l7, %lo(sys_call_table32), %l7
	ldx	[%sp + PTREGS_OFF + PT_V9_I1], %i1
	ldx	[%sp + PTREGS_OFF + PT_V9_I2], %i2
	ldx	[%sp + PTREGS_OFF + PT_V9_I3], %i3
	ldx	[%sp + PTREGS_OFF + PT_V9_I4], %i4
	ldx	[%sp + PTREGS_OFF + PT_V9_I5], %i5

	cmp	%g1, NR_syscalls
	bgeu,pn	%xcc, 3f
	 mov	-ENOSYS, %o0

	sll	%g1, 2, %l4
	srl	%i0, 0, %o0
	lduw	[%l7 + %l4], %l7
	srl	%i4, 0, %o4
	srl	%i1, 0, %o1
	srl	%i2, 0, %o2
	ba,pt	%xcc, 5f
	 srl	%i3, 0, %o3

linux_syscall_trace:
	call	syscall_trace_enter
	 add	%sp, PTREGS_OFF, %o0
	brnz,pn	%o0, 3f
	 mov	-ENOSYS, %o0

	/* Syscall tracing can modify the registers.  */
	ldx	[%sp + PTREGS_OFF + PT_V9_G1], %g1
	sethi	%hi(sys_call_table64), %l7
	ldx	[%sp + PTREGS_OFF + PT_V9_I0], %i0
	or	%l7, %lo(sys_call_table64), %l7
	ldx	[%sp + PTREGS_OFF + PT_V9_I1], %i1
	ldx	[%sp + PTREGS_OFF + PT_V9_I2], %i2
	ldx	[%sp + PTREGS_OFF + PT_V9_I3], %i3
	ldx	[%sp + PTREGS_OFF + PT_V9_I4], %i4
	ldx	[%sp + PTREGS_OFF + PT_V9_I5], %i5

	cmp	%g1, NR_syscalls
	bgeu,pn	%xcc, 3f
	 mov	-ENOSYS, %o0

	sll	%g1, 2, %l4
	mov	%i0, %o0
	lduw	[%l7 + %l4], %l7
	mov	%i1, %o1
	mov	%i2, %o2
	mov	%i3, %o3
	b,pt	%xcc, 2f
	 mov	%i4, %o4


	/* Linux 32-bit system calls enter here... */
	.align	32
	.globl	linux_sparc_syscall32
linux_sparc_syscall32:
	/* Direct access to user regs, much faster. */
	cmp	%g1, NR_syscalls			! IEU1	Group
	bgeu,pn	%xcc, linux_sparc_ni_syscall		! CTI
	 srl	%i0, 0, %o0				! IEU0
	sll	%g1, 2, %l4				! IEU0	Group
	srl	%i4, 0, %o4				! IEU1
	lduw	[%l7 + %l4], %l7			! Load
	srl	%i1, 0, %o1				! IEU0	Group
	ldx	[%g6 + TI_FLAGS], %l0		! Load

	srl	%i3, 0, %o3				! IEU0
	srl	%i2, 0, %o2				! IEU0	Group
	andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT|_TIF_NOHZ), %g0
	bne,pn	%icc, linux_syscall_trace32		! CTI
	 mov	%i0, %l5				! IEU1
5:	call	%l7					! CTI	Group brk forced
	 srl	%i5, 0, %o5				! IEU1
	ba,pt	%xcc, 3f
	 sra	%o0, 0, %o0

	/* Linux native system calls enter here... */
	.align	32
	.globl	linux_sparc_syscall
linux_sparc_syscall:
	/* Direct access to user regs, much faster. */
	cmp	%g1, NR_syscalls			! IEU1	Group
	bgeu,pn	%xcc, linux_sparc_ni_syscall		! CTI
	 mov	%i0, %o0				! IEU0
	sll	%g1, 2, %l4				! IEU0	Group
	mov	%i1, %o1				! IEU1
	lduw	[%l7 + %l4], %l7			! Load
4:	mov	%i2, %o2				! IEU0	Group
	ldx	[%g6 + TI_FLAGS], %l0		! Load

	mov	%i3, %o3				! IEU1
	mov	%i4, %o4				! IEU0	Group
	andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT|_TIF_NOHZ), %g0
	bne,pn	%icc, linux_syscall_trace		! CTI	Group
	 mov	%i0, %l5				! IEU0
2:	call	%l7					! CTI	Group brk forced
	 mov	%i5, %o5				! IEU0
	nop

3:	stx	%o0, [%sp + PTREGS_OFF + PT_V9_I0]
ret_sys_call:
	ldx	[%sp + PTREGS_OFF + PT_V9_TSTATE], %g3
	mov	%ulo(TSTATE_XCARRY | TSTATE_ICARRY), %g2
	sllx	%g2, 32, %g2

	cmp	%o0, -ERESTART_RESTARTBLOCK
	bgeu,pn	%xcc, 1f
	 andcc	%l0, (_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT|_TIF_SYSCALL_TRACEPOINT|_TIF_NOHZ), %g0
	ldx	[%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc

2:
	/* System call success, clear Carry condition code. */
	andn	%g3, %g2, %g3
3:
	stx	%g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]	
	bne,pn	%icc, linux_syscall_trace2
	 add	%l1, 0x4, %l2			! npc = npc+4
	stx	%l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	ba,pt	%xcc, rtrap
	 stx	%l2, [%sp + PTREGS_OFF + PT_V9_TNPC]

1:
	/* Check if force_successful_syscall_return()
	 * was invoked.
	 */
	ldub	[%g6 + TI_SYS_NOERROR], %l2
	brnz,pn %l2, 2b
	 ldx	[%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc
	/* System call failure, set Carry condition code.
	 * Also, get abs(errno) to return to the process.
	 */
	sub	%g0, %o0, %o0
	stx	%o0, [%sp + PTREGS_OFF + PT_V9_I0]
	ba,pt	%xcc, 3b
	 or	%g3, %g2, %g3

linux_syscall_trace2:
	call	syscall_trace_leave
	 add	%sp, PTREGS_OFF, %o0
	stx	%l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	ba,pt	%xcc, rtrap
	 stx	%l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
Commit	Line	Data
6eda3a75 DM	1	/* SunOS's execv() call only specifies the argv argument, the
	2	* environment settings are the same as the calling processes.
	3	*/
eb48ffcf AV	4	sys64_execve:
	5	set sys_execve, %g1
	6	jmpl %g1, %g0
	7	flushw
6eda3a75	8
38351a32 DD	9	sys64_execveat:
	10	set sys_execveat, %g1
	11	jmpl %g1, %g0
	12	flushw
	13
6eda3a75 DM	14	#ifdef CONFIG_COMPAT
6eda3a75 DM	15	sunos_execv:
eb48ffcf	16	mov %g0, %o2
6eda3a75	17	sys32_execve:
eb48ffcf	18	set compat_sys_execve, %g1
6eda3a75	19	jmpl %g1, %g0
eb48ffcf	20	flushw
38351a32 DD	21
	22	sys32_execveat:
	23	set compat_sys_execveat, %g1
	24	jmpl %g1, %g0
	25	flushw
eb48ffcf	26	#endif
6eda3a75 DM	27
6eda3a75 DM	28	.align 32
1134723e	29	sys_sparc_pipe:
e4265019	30	ba,pt %xcc, sys_sparc_pipe_real
6eda3a75 DM	31	add %sp, PTREGS_OFF, %o0
	32	sys_nis_syscall:
	33	ba,pt %xcc, c_sys_nis_syscall
	34	add %sp, PTREGS_OFF, %o0
	35	sys_memory_ordering:
	36	ba,pt %xcc, sparc_memory_ordering
	37	add %sp, PTREGS_OFF, %o1
6eda3a75 DM	38	#ifdef CONFIG_COMPAT
	39	sys32_sigstack:
	40	ba,pt %xcc, do_sys32_sigstack
	41	mov %i6, %o2
6eda3a75 DM	42	#endif
	43	.align 32
	44	#ifdef CONFIG_COMPAT
	45	sys32_sigreturn:
	46	add %sp, PTREGS_OFF, %o0
	47	call do_sigreturn32
	48	add %o7, 1f-.-4, %o7
	49	nop
	50	#endif
	51	sys_rt_sigreturn:
	52	add %sp, PTREGS_OFF, %o0
	53	call do_rt_sigreturn
	54	add %o7, 1f-.-4, %o7
	55	nop
	56	#ifdef CONFIG_COMPAT
	57	sys32_rt_sigreturn:
	58	add %sp, PTREGS_OFF, %o0
	59	call do_rt_sigreturn32
	60	add %o7, 1f-.-4, %o7
	61	nop
	62	#endif
	63	.align 32
	64	1: ldx [%g6 + TI_FLAGS], %l5
812cb83a	65	andcc %l5, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT\|_TIF_NOHZ), %g0
6eda3a75 DM	66	be,pt %icc, rtrap
6eda3a75 DM	67	nop
fe06ccaa DM	68	call syscall_trace_leave
fe06ccaa DM	69	add %sp, PTREGS_OFF, %o0
6eda3a75 DM	70	ba,pt %xcc, rtrap
	71	nop
	72
	73	/* This is how fork() was meant to be done, 8 instruction entry.
	74	*
	75	* I questioned the following code briefly, let me clear things
	76	* up so you must not reason on it like I did.
	77	*
	78	* Know the fork_kpsr etc. we use in the sparc32 port? We don't
	79	* need it here because the only piece of window state we copy to
	80	* the child is the CWP register. Even if the parent sleeps,
	81	* we are safe because we stuck it into pt_regs of the parent
	82	* so it will not change.
	83	*
	84	* XXX This raises the question, whether we can do the same on
	85	* XXX sparc32 to get rid of fork_kpsr _and_ fork_kwim. The
	86	* XXX answer is yes. We stick fork_kpsr in UREG_G0 and
	87	* XXX fork_kwim in UREG_G1 (global registers are considered
	88	* XXX volatile across a system call in the sparc ABI I think
	89	* XXX if it isn't we can use regs->y instead, anyone who depends
	90	* XXX upon the Y register being preserved across a fork deserves
	91	* XXX to lose).
	92	*
	93	* In fact we should take advantage of that fact for other things
	94	* during system calls...
	95	*/
	96	.align 32
	97	sys_vfork: /* Under Linux, vfork and fork are just special cases of clone. */
	98	sethi %hi(0x4000 \| 0x0100 \| SIGCHLD), %o0
	99	or %o0, %lo(0x4000 \| 0x0100 \| SIGCHLD), %o0
	100	ba,pt %xcc, sys_clone
	101	sys_fork:
	102	clr %o1
	103	mov SIGCHLD, %o0
	104	sys_clone:
	105	flushw
	106	movrz %o1, %fp, %o1
	107	mov 0, %o3
	108	ba,pt %xcc, sparc_do_fork
	109	add %sp, PTREGS_OFF, %o2
	110
37d6fa34 KT	111	.globl ret_from_fork
37d6fa34 KT	112	ret_from_fork:
c7d5a005	113	/* Clear current_thread_info()->new_child. */
6eda3a75	114	stb %g0, [%g6 + TI_NEW_CHILD]
6eda3a75 DM	115	call schedule_tail
6eda3a75 DM	116	mov %g7, %o0
1918c7f5	117	ldx [%sp + PTREGS_OFF + PT_V9_I0], %o0
2f12af35	118	brnz,pt %o0, ret_sys_call
1918c7f5	119	ldx [%g6 + TI_FLAGS], %l0
2f12af35 AV	120	ldx [%sp + PTREGS_OFF + PT_V9_G1], %l1
2f12af35 AV	121	call %l1
1918c7f5	122	ldx [%sp + PTREGS_OFF + PT_V9_G2], %o0
c7d5a005	123	ba,pt %xcc, ret_sys_call
2f12af35	124	mov 0, %o0
6eda3a75	125
de7531e8 DM	126	.globl sparc_exit_group
	127	.type sparc_exit_group,#function
	128	sparc_exit_group:
	129	sethi %hi(sys_exit_group), %g7
	130	ba,pt %xcc, 1f
	131	or %g7, %lo(sys_exit_group), %g7
	132	.size sparc_exit_group,.-sparc_exit_group
	133
6eda3a75 DM	134	.globl sparc_exit
	135	.type sparc_exit,#function
	136	sparc_exit:
de7531e8 DM	137	sethi %hi(sys_exit), %g7
	138	or %g7, %lo(sys_exit), %g7
	139	1: rdpr %pstate, %g2
6eda3a75 DM	140	wrpr %g2, PSTATE_IE, %pstate
	141	rdpr %otherwin, %g1
	142	rdpr %cansave, %g3
	143	add %g3, %g1, %g3
	144	wrpr %g3, 0x0, %cansave
	145	wrpr %g0, 0x0, %otherwin
	146	wrpr %g2, 0x0, %pstate
de7531e8	147	jmpl %g7, %g0
6eda3a75 DM	148	stb %g0, [%g6 + TI_WSAVED]
	149	.size sparc_exit,.-sparc_exit
	150
	151	linux_sparc_ni_syscall:
	152	sethi %hi(sys_ni_syscall), %l7
	153	ba,pt %xcc, 4f
	154	or %l7, %lo(sys_ni_syscall), %l7
	155
	156	linux_syscall_trace32:
fe06ccaa DM	157	call syscall_trace_enter
fe06ccaa DM	158	add %sp, PTREGS_OFF, %o0
73ccefab RM	159	brnz,pn %o0, 3f
73ccefab RM	160	mov -ENOSYS, %o0
1a40b953 MF	161
	162	/* Syscall tracing can modify the registers. */
	163	ldx [%sp + PTREGS_OFF + PT_V9_G1], %g1
	164	sethi %hi(sys_call_table32), %l7
	165	ldx [%sp + PTREGS_OFF + PT_V9_I0], %i0
	166	or %l7, %lo(sys_call_table32), %l7
	167	ldx [%sp + PTREGS_OFF + PT_V9_I1], %i1
	168	ldx [%sp + PTREGS_OFF + PT_V9_I2], %i2
	169	ldx [%sp + PTREGS_OFF + PT_V9_I3], %i3
	170	ldx [%sp + PTREGS_OFF + PT_V9_I4], %i4
	171	ldx [%sp + PTREGS_OFF + PT_V9_I5], %i5
	172
	173	cmp %g1, NR_syscalls
	174	bgeu,pn %xcc, 3f
	175	mov -ENOSYS, %o0
	176
	177	sll %g1, 2, %l4
6eda3a75	178	srl %i0, 0, %o0
1a40b953	179	lduw [%l7 + %l4], %l7
6eda3a75 DM	180	srl %i4, 0, %o4
	181	srl %i1, 0, %o1
	182	srl %i2, 0, %o2
ab2abda6	183	ba,pt %xcc, 5f
6eda3a75 DM	184	srl %i3, 0, %o3
	185
	186	linux_syscall_trace:
fe06ccaa DM	187	call syscall_trace_enter
fe06ccaa DM	188	add %sp, PTREGS_OFF, %o0
73ccefab RM	189	brnz,pn %o0, 3f
73ccefab RM	190	mov -ENOSYS, %o0
1a40b953 MF	191
	192	/* Syscall tracing can modify the registers. */
	193	ldx [%sp + PTREGS_OFF + PT_V9_G1], %g1
	194	sethi %hi(sys_call_table64), %l7
	195	ldx [%sp + PTREGS_OFF + PT_V9_I0], %i0
	196	or %l7, %lo(sys_call_table64), %l7
	197	ldx [%sp + PTREGS_OFF + PT_V9_I1], %i1
	198	ldx [%sp + PTREGS_OFF + PT_V9_I2], %i2
	199	ldx [%sp + PTREGS_OFF + PT_V9_I3], %i3
	200	ldx [%sp + PTREGS_OFF + PT_V9_I4], %i4
	201	ldx [%sp + PTREGS_OFF + PT_V9_I5], %i5
	202
	203	cmp %g1, NR_syscalls
	204	bgeu,pn %xcc, 3f
	205	mov -ENOSYS, %o0
	206
	207	sll %g1, 2, %l4
6eda3a75	208	mov %i0, %o0
1a40b953	209	lduw [%l7 + %l4], %l7
6eda3a75 DM	210	mov %i1, %o1
	211	mov %i2, %o2
	212	mov %i3, %o3
	213	b,pt %xcc, 2f
	214	mov %i4, %o4
	215
	216
	217	/* Linux 32-bit system calls enter here... */
	218	.align 32
	219	.globl linux_sparc_syscall32
	220	linux_sparc_syscall32:
	221	/* Direct access to user regs, much faster. */
c658ad1b	222	cmp %g1, NR_syscalls ! IEU1 Group
6eda3a75 DM	223	bgeu,pn %xcc, linux_sparc_ni_syscall ! CTI
	224	srl %i0, 0, %o0 ! IEU0
	225	sll %g1, 2, %l4 ! IEU0 Group
	226	srl %i4, 0, %o4 ! IEU1
	227	lduw [%l7 + %l4], %l7 ! Load
	228	srl %i1, 0, %o1 ! IEU0 Group
	229	ldx [%g6 + TI_FLAGS], %l0 ! Load
	230
ab2abda6	231	srl %i3, 0, %o3 ! IEU0
6eda3a75	232	srl %i2, 0, %o2 ! IEU0 Group
812cb83a	233	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT\|_TIF_NOHZ), %g0
6eda3a75 DM	234	bne,pn %icc, linux_syscall_trace32 ! CTI
6eda3a75 DM	235	mov %i0, %l5 ! IEU1
ab2abda6 KT	236	5: call %l7 ! CTI Group brk forced
ab2abda6 KT	237	srl %i5, 0, %o5 ! IEU1
1535bd8a DK	238	ba,pt %xcc, 3f
1535bd8a DK	239	sra %o0, 0, %o0
6eda3a75 DM	240
	241	/* Linux native system calls enter here... */
	242	.align 32
	243	.globl linux_sparc_syscall
	244	linux_sparc_syscall:
	245	/* Direct access to user regs, much faster. */
c658ad1b	246	cmp %g1, NR_syscalls ! IEU1 Group
6eda3a75 DM	247	bgeu,pn %xcc, linux_sparc_ni_syscall ! CTI
	248	mov %i0, %o0 ! IEU0
	249	sll %g1, 2, %l4 ! IEU0 Group
	250	mov %i1, %o1 ! IEU1
	251	lduw [%l7 + %l4], %l7 ! Load
	252	4: mov %i2, %o2 ! IEU0 Group
	253	ldx [%g6 + TI_FLAGS], %l0 ! Load
	254
	255	mov %i3, %o3 ! IEU1
	256	mov %i4, %o4 ! IEU0 Group
812cb83a	257	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT\|_TIF_NOHZ), %g0
6eda3a75 DM	258	bne,pn %icc, linux_syscall_trace ! CTI Group
	259	mov %i0, %l5 ! IEU0
	260	2: call %l7 ! CTI Group brk forced
	261	mov %i5, %o5 ! IEU0
	262	nop
	263
	264	3: stx %o0, [%sp + PTREGS_OFF + PT_V9_I0]
	265	ret_sys_call:
	266	ldx [%sp + PTREGS_OFF + PT_V9_TSTATE], %g3
6eda3a75 DM	267	mov %ulo(TSTATE_XCARRY \| TSTATE_ICARRY), %g2
	268	sllx %g2, 32, %g2
	269
6eda3a75 DM	270	cmp %o0, -ERESTART_RESTARTBLOCK
6eda3a75 DM	271	bgeu,pn %xcc, 1f
812cb83a	272	andcc %l0, (_TIF_SYSCALL_TRACE\|_TIF_SECCOMP\|_TIF_SYSCALL_AUDIT\|_TIF_SYSCALL_TRACEPOINT\|_TIF_NOHZ), %g0
55c2770e AV	273	ldx [%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc
	274
	275	2:
6eda3a75 DM	276	/* System call success, clear Carry condition code. */
6eda3a75 DM	277	andn %g3, %g2, %g3
55c2770e	278	3:
6eda3a75 DM	279	stx %g3, [%sp + PTREGS_OFF + PT_V9_TSTATE]
	280	bne,pn %icc, linux_syscall_trace2
	281	add %l1, 0x4, %l2 ! npc = npc+4
	282	stx %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	283	ba,pt %xcc, rtrap
	284	stx %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]
	285
	286	1:
55c2770e AV	287	/* Check if force_successful_syscall_return()
	288	* was invoked.
	289	*/
	290	ldub [%g6 + TI_SYS_NOERROR], %l2
	291	brnz,pn %l2, 2b
	292	ldx [%sp + PTREGS_OFF + PT_V9_TNPC], %l1 ! pc = npc
6eda3a75 DM	293	/* System call failure, set Carry condition code.
	294	* Also, get abs(errno) to return to the process.
	295	*/
6eda3a75	296	sub %g0, %o0, %o0
6eda3a75	297	stx %o0, [%sp + PTREGS_OFF + PT_V9_I0]
55c2770e AV	298	ba,pt %xcc, 3b
55c2770e AV	299	or %g3, %g2, %g3
6eda3a75	300
6eda3a75	301	linux_syscall_trace2:
fe06ccaa DM	302	call syscall_trace_leave
fe06ccaa DM	303	add %sp, PTREGS_OFF, %o0
6eda3a75 DM	304	stx %l1, [%sp + PTREGS_OFF + PT_V9_TPC]
	305	ba,pt %xcc, rtrap
	306	stx %l2, [%sp + PTREGS_OFF + PT_V9_TNPC]