Commit | Line | Data |
---|---|---|
13a9cd42 TG |
1 | /* ld script to make x86-64 Linux kernel |
2 | * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>; | |
3 | */ | |
4 | ||
5 | #define LOAD_OFFSET __START_KERNEL_map | |
6 | ||
7 | #include <asm-generic/vmlinux.lds.h> | |
8 | #include <asm/page.h> | |
9 | ||
10 | #undef i386 /* in case the preprocessor is a 32bit one */ | |
11 | ||
12 | OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64") | |
13 | OUTPUT_ARCH(i386:x86-64) | |
14 | ENTRY(phys_startup_64) | |
15 | jiffies_64 = jiffies; | |
16 | _proxy_pda = 1; | |
17 | PHDRS { | |
18 | text PT_LOAD FLAGS(5); /* R_E */ | |
19 | data PT_LOAD FLAGS(7); /* RWE */ | |
20 | user PT_LOAD FLAGS(7); /* RWE */ | |
21 | data.init PT_LOAD FLAGS(7); /* RWE */ | |
3e5d8f97 TH |
22 | #ifdef CONFIG_SMP |
23 | percpu PT_LOAD FLAGS(7); /* RWE */ | |
24 | #endif | |
6360b1fb | 25 | note PT_NOTE FLAGS(0); /* ___ */ |
13a9cd42 TG |
26 | } |
27 | SECTIONS | |
28 | { | |
29 | . = __START_KERNEL; | |
30 | phys_startup_64 = startup_64 - LOAD_OFFSET; | |
31 | _text = .; /* Text and read-only data */ | |
32 | .text : AT(ADDR(.text) - LOAD_OFFSET) { | |
33 | /* First the code that has to be first for bootstrapping */ | |
34 | *(.text.head) | |
35 | _stext = .; | |
36 | /* Then the rest */ | |
37 | TEXT_TEXT | |
38 | SCHED_TEXT | |
39 | LOCK_TEXT | |
40 | KPROBES_TEXT | |
a0343e82 | 41 | IRQENTRY_TEXT |
13a9cd42 TG |
42 | *(.fixup) |
43 | *(.gnu.warning) | |
3cdac41f | 44 | _etext = .; /* End of text section */ |
c0400030 | 45 | } :text = 0x9090 |
13a9cd42 | 46 | |
6360b1fb JB |
47 | NOTES :text :note |
48 | ||
13a9cd42 | 49 | . = ALIGN(16); /* Exception table */ |
c0400030 JB |
50 | __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { |
51 | __start___ex_table = .; | |
52 | *(__ex_table) | |
53 | __stop___ex_table = .; | |
6360b1fb | 54 | } :text = 0x9090 |
13a9cd42 TG |
55 | |
56 | RODATA | |
57 | ||
3cdac41f | 58 | . = ALIGN(PAGE_SIZE); /* Align data segment to page size boundary */ |
13a9cd42 TG |
59 | /* Data */ |
60 | .data : AT(ADDR(.data) - LOAD_OFFSET) { | |
61 | DATA_DATA | |
62 | CONSTRUCTORS | |
63 | } :data | |
64 | ||
65 | _edata = .; /* End of data section */ | |
66 | ||
67 | . = ALIGN(PAGE_SIZE); | |
68 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); | |
69 | .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) { | |
70 | *(.data.cacheline_aligned) | |
71 | } | |
72 | . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES); | |
73 | .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { | |
74 | *(.data.read_mostly) | |
75 | } | |
76 | ||
77 | #define VSYSCALL_ADDR (-10*1024*1024) | |
78 | #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095)) | |
79 | #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095)) | |
80 | ||
81 | #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR) | |
82 | #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET) | |
83 | ||
84 | #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR) | |
85 | #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET) | |
86 | ||
87 | . = VSYSCALL_ADDR; | |
88 | .vsyscall_0 : AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user | |
89 | __vsyscall_0 = VSYSCALL_VIRT_ADDR; | |
90 | ||
91 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); | |
92 | .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) } | |
93 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); | |
94 | .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data)) | |
95 | { *(.vsyscall_gtod_data) } | |
96 | vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data); | |
97 | .vsyscall_clock : AT(VLOAD(.vsyscall_clock)) | |
98 | { *(.vsyscall_clock) } | |
99 | vsyscall_clock = VVIRT(.vsyscall_clock); | |
100 | ||
101 | ||
102 | .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) | |
103 | { *(.vsyscall_1) } | |
104 | .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) | |
105 | { *(.vsyscall_2) } | |
106 | ||
107 | .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) } | |
108 | vgetcpu_mode = VVIRT(.vgetcpu_mode); | |
109 | ||
110 | . = ALIGN(CONFIG_X86_L1_CACHE_BYTES); | |
111 | .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) } | |
112 | jiffies = VVIRT(.jiffies); | |
113 | ||
114 | .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) | |
115 | { *(.vsyscall_3) } | |
116 | ||
3cdac41f | 117 | . = VSYSCALL_VIRT_ADDR + PAGE_SIZE; |
13a9cd42 TG |
118 | |
119 | #undef VSYSCALL_ADDR | |
120 | #undef VSYSCALL_PHYS_ADDR | |
121 | #undef VSYSCALL_VIRT_ADDR | |
122 | #undef VLOAD_OFFSET | |
123 | #undef VLOAD | |
124 | #undef VVIRT_OFFSET | |
125 | #undef VVIRT | |
126 | ||
85c42d0d | 127 | . = ALIGN(THREAD_SIZE); /* init_task */ |
13a9cd42 TG |
128 | .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) { |
129 | *(.data.init_task) | |
130 | }:data.init | |
131 | ||
3cdac41f | 132 | . = ALIGN(PAGE_SIZE); |
13a9cd42 TG |
133 | .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) { |
134 | *(.data.page_aligned) | |
135 | } | |
136 | ||
137 | /* might get freed after init */ | |
3cdac41f | 138 | . = ALIGN(PAGE_SIZE); |
13a9cd42 TG |
139 | __smp_alt_begin = .; |
140 | __smp_locks = .; | |
141 | .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) { | |
142 | *(.smp_locks) | |
143 | } | |
144 | __smp_locks_end = .; | |
3cdac41f | 145 | . = ALIGN(PAGE_SIZE); |
13a9cd42 TG |
146 | __smp_alt_end = .; |
147 | ||
3cdac41f | 148 | . = ALIGN(PAGE_SIZE); /* Init code and data */ |
13a9cd42 TG |
149 | __init_begin = .; |
150 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { | |
151 | _sinittext = .; | |
01ba2bdc | 152 | INIT_TEXT |
13a9cd42 TG |
153 | _einittext = .; |
154 | } | |
01ba2bdc SR |
155 | .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { |
156 | __initdata_begin = .; | |
157 | INIT_DATA | |
158 | __initdata_end = .; | |
159 | } | |
160 | ||
13a9cd42 TG |
161 | . = ALIGN(16); |
162 | __setup_start = .; | |
163 | .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) } | |
164 | __setup_end = .; | |
165 | __initcall_start = .; | |
166 | .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) { | |
167 | INITCALLS | |
168 | } | |
169 | __initcall_end = .; | |
170 | __con_initcall_start = .; | |
171 | .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) { | |
172 | *(.con_initcall.init) | |
173 | } | |
174 | __con_initcall_end = .; | |
10a434fc YL |
175 | __x86_cpu_dev_start = .; |
176 | .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) { | |
177 | *(.x86_cpu_dev.init) | |
03ae5768 | 178 | } |
10a434fc | 179 | __x86_cpu_dev_end = .; |
cb58ffc3 | 180 | SECURITY_INIT |
fbf51924 GOC |
181 | |
182 | . = ALIGN(8); | |
183 | .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) { | |
184 | __parainstructions = .; | |
185 | *(.parainstructions) | |
186 | __parainstructions_end = .; | |
187 | } | |
188 | ||
13a9cd42 TG |
189 | . = ALIGN(8); |
190 | __alt_instructions = .; | |
191 | .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) { | |
192 | *(.altinstructions) | |
193 | } | |
3cdac41f | 194 | __alt_instructions_end = .; |
13a9cd42 TG |
195 | .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) { |
196 | *(.altinstr_replacement) | |
197 | } | |
198 | /* .exit.text is discard at runtime, not link time, to deal with references | |
199 | from .altinstructions and .eh_frame */ | |
01ba2bdc SR |
200 | .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { |
201 | EXIT_TEXT | |
202 | } | |
203 | .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { | |
204 | EXIT_DATA | |
205 | } | |
13a9cd42 | 206 | |
13a9cd42 | 207 | #ifdef CONFIG_BLK_DEV_INITRD |
3cdac41f | 208 | . = ALIGN(PAGE_SIZE); |
13a9cd42 TG |
209 | __initramfs_start = .; |
210 | .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) } | |
211 | __initramfs_end = .; | |
212 | #endif | |
213 | ||
3e5d8f97 TH |
214 | #ifdef CONFIG_SMP |
215 | /* | |
216 | * percpu offsets are zero-based on SMP. PERCPU_VADDR() changes the | |
217 | * output PHDR, so the next output section - __data_nosave - should | |
218 | * switch it back to data.init. | |
219 | */ | |
220 | . = ALIGN(PAGE_SIZE); | |
221 | PERCPU_VADDR(0, :percpu) | |
222 | #else | |
3cdac41f | 223 | PERCPU(PAGE_SIZE) |
3e5d8f97 | 224 | #endif |
13a9cd42 | 225 | |
3cdac41f | 226 | . = ALIGN(PAGE_SIZE); |
13a9cd42 TG |
227 | __init_end = .; |
228 | ||
3cdac41f | 229 | . = ALIGN(PAGE_SIZE); |
13a9cd42 | 230 | __nosave_begin = .; |
3e5d8f97 TH |
231 | .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { |
232 | *(.data.nosave) | |
233 | } :data.init /* switch back to data.init, see PERCPU_VADDR() above */ | |
3cdac41f | 234 | . = ALIGN(PAGE_SIZE); |
13a9cd42 TG |
235 | __nosave_end = .; |
236 | ||
237 | __bss_start = .; /* BSS */ | |
238 | .bss : AT(ADDR(.bss) - LOAD_OFFSET) { | |
239 | *(.bss.page_aligned) | |
240 | *(.bss) | |
241 | } | |
242 | __bss_stop = .; | |
243 | ||
244 | _end = . ; | |
245 | ||
246 | /* Sections to be discarded */ | |
247 | /DISCARD/ : { | |
248 | *(.exitcall.exit) | |
249 | *(.eh_frame) | |
250 | } | |
251 | ||
252 | STABS_DEBUG | |
253 | ||
254 | DWARF_DEBUG | |
255 | } | |
b4e0409a IM |
256 | |
257 | /* | |
258 | * Build-time check on the image size: | |
259 | */ | |
260 | ASSERT((_end - _text <= KERNEL_IMAGE_SIZE), | |
261 | "kernel image bigger than KERNEL_IMAGE_SIZE") |