Commit | Line | Data |
---|---|---|
07ad157f RR |
1 | #include <linux/linkage.h> |
2 | #include <linux/lguest.h> | |
47436aa4 | 3 | #include <asm/lguest_hcall.h> |
07ad157f RR |
4 | #include <asm/asm-offsets.h> |
5 | #include <asm/thread_info.h> | |
876be9d8 | 6 | #include <asm/processor-flags.h> |
07ad157f | 7 | |
a6bd8e13 RR |
8 | /*G:020 Our story starts with the kernel booting into startup_32 in |
9 | * arch/x86/kernel/head_32.S. It expects a boot header, which is created by | |
10 | * the bootloader (the Launcher in our case). | |
11 | * | |
12 | * The startup_32 function does very little: it clears the uninitialized global | |
13 | * C variables which we expect to be zero (ie. BSS) and then copies the boot | |
14 | * header and kernel command line somewhere safe. Finally it checks the | |
15 | * 'hardware_subarch' field. This was introduced in 2.6.24 for lguest and Xen: | |
16 | * if it's set to '1' (lguest's assigned number), then it calls us here. | |
47436aa4 RR |
17 | * |
18 | * WARNING: be very careful here! We're running at addresses equal to physical | |
19 | * addesses (around 0), not above PAGE_OFFSET as most code expectes | |
20 | * (eg. 0xC0000000). Jumps are relative, so they're OK, but we can't touch any | |
a6bd8e13 | 21 | * data without remembering to subtract __PAGE_OFFSET! |
07ad157f | 22 | * |
b2b47c21 RR |
23 | * The .section line puts this code in .init.text so it will be discarded after |
24 | * boot. */ | |
07ad157f | 25 | .section .init.text, "ax", @progbits |
814a0e5c | 26 | ENTRY(lguest_entry) |
e1e72965 RR |
27 | /* We make the "initialization" hypercall now to tell the Host about |
28 | * us, and also find out where it put our page tables. */ | |
47436aa4 RR |
29 | movl $LHCALL_LGUEST_INIT, %eax |
30 | movl $lguest_data - __PAGE_OFFSET, %edx | |
31 | int $LGUEST_TRAP_ENTRY | |
32 | ||
47436aa4 RR |
33 | /* Set up the initial stack so we can run C code. */ |
34 | movl $(init_thread_union+THREAD_SIZE),%esp | |
35 | ||
47436aa4 RR |
36 | /* Jumps are relative, and we're running __PAGE_OFFSET too low at the |
37 | * moment. */ | |
38 | jmp lguest_init+__PAGE_OFFSET | |
07ad157f | 39 | |
b2b47c21 | 40 | /*G:055 We create a macro which puts the assembler code between lgstart_ and |
bbbd2bf0 RR |
41 | * lgend_ markers. These templates are put in the .text section: they can't be |
42 | * discarded after boot as we may need to patch modules, too. */ | |
43 | .text | |
07ad157f RR |
44 | #define LGUEST_PATCH(name, insns...) \ |
45 | lgstart_##name: insns; lgend_##name:; \ | |
46 | .globl lgstart_##name; .globl lgend_##name | |
47 | ||
48 | LGUEST_PATCH(cli, movl $0, lguest_data+LGUEST_DATA_irq_enabled) | |
49 | LGUEST_PATCH(sti, movl $X86_EFLAGS_IF, lguest_data+LGUEST_DATA_irq_enabled) | |
50 | LGUEST_PATCH(popf, movl %eax, lguest_data+LGUEST_DATA_irq_enabled) | |
51 | LGUEST_PATCH(pushf, movl lguest_data+LGUEST_DATA_irq_enabled, %eax) | |
b2b47c21 | 52 | /*:*/ |
07ad157f | 53 | |
07ad157f RR |
54 | /* These demark the EIP range where host should never deliver interrupts. */ |
55 | .global lguest_noirq_start | |
56 | .global lguest_noirq_end | |
57 | ||
f56a384e RR |
58 | /*M:004 When the Host reflects a trap or injects an interrupt into the Guest, |
59 | * it sets the eflags interrupt bit on the stack based on | |
60 | * lguest_data.irq_enabled, so the Guest iret logic does the right thing when | |
61 | * restoring it. However, when the Host sets the Guest up for direct traps, | |
62 | * such as system calls, the processor is the one to push eflags onto the | |
63 | * stack, and the interrupt bit will be 1 (in reality, interrupts are always | |
64 | * enabled in the Guest). | |
65 | * | |
66 | * This turns out to be harmless: the only trap which should happen under Linux | |
67 | * with interrupts disabled is Page Fault (due to our lazy mapping of vmalloc | |
68 | * regions), which has to be reflected through the Host anyway. If another | |
69 | * trap *does* go off when interrupts are disabled, the Guest will panic, and | |
70 | * we'll never get to this iret! :*/ | |
71 | ||
b2b47c21 RR |
72 | /*G:045 There is one final paravirt_op that the Guest implements, and glancing |
73 | * at it you can see why I left it to last. It's *cool*! It's in *assembler*! | |
74 | * | |
75 | * The "iret" instruction is used to return from an interrupt or trap. The | |
76 | * stack looks like this: | |
77 | * old address | |
78 | * old code segment & privilege level | |
79 | * old processor flags ("eflags") | |
80 | * | |
81 | * The "iret" instruction pops those values off the stack and restores them all | |
82 | * at once. The only problem is that eflags includes the Interrupt Flag which | |
83 | * the Guest can't change: the CPU will simply ignore it when we do an "iret". | |
84 | * So we have to copy eflags from the stack to lguest_data.irq_enabled before | |
85 | * we do the "iret". | |
86 | * | |
87 | * There are two problems with this: firstly, we need to use a register to do | |
88 | * the copy and secondly, the whole thing needs to be atomic. The first | |
89 | * problem is easy to solve: push %eax on the stack so we can use it, and then | |
90 | * restore it at the end just before the real "iret". | |
91 | * | |
92 | * The second is harder: copying eflags to lguest_data.irq_enabled will turn | |
93 | * interrupts on before we're finished, so we could be interrupted before we | |
94 | * return to userspace or wherever. Our solution to this is to surround the | |
95 | * code with lguest_noirq_start: and lguest_noirq_end: labels. We tell the | |
96 | * Host that it is *never* to interrupt us there, even if interrupts seem to be | |
97 | * enabled. */ | |
07ad157f RR |
98 | ENTRY(lguest_iret) |
99 | pushl %eax | |
100 | movl 12(%esp), %eax | |
101 | lguest_noirq_start: | |
b2b47c21 RR |
102 | /* Note the %ss: segment prefix here. Normal data accesses use the |
103 | * "ds" segment, but that will have already been restored for whatever | |
104 | * we're returning to (such as userspace): we can't trust it. The %ss: | |
105 | * prefix makes sure we use the stack segment, which is still valid. */ | |
07ad157f RR |
106 | movl %eax,%ss:lguest_data+LGUEST_DATA_irq_enabled |
107 | popl %eax | |
108 | iret | |
109 | lguest_noirq_end: |