[deliverable/linux.git] / arch / x86 / power / hibernate_asm_32.S

/*
 * This may not use any stack, nor any variable that is not "NoSave":
 *
 * Its rewriting one kernel image with another. What is stack in "old"
 * image could very well be data page in "new" image, and overwriting
 * your own stack under you is bad idea.
 */

#include <linux/linkage.h>
#include <asm/segment.h>
#include <asm/page_types.h>
#include <asm/asm-offsets.h>
#include <asm/processor-flags.h>

.text

ENTRY(swsusp_arch_suspend)
	movl %esp, saved_context_esp
	movl %ebx, saved_context_ebx
	movl %ebp, saved_context_ebp
	movl %esi, saved_context_esi
	movl %edi, saved_context_edi
	pushfl
	popl saved_context_eflags

	call swsusp_save
	ret

ENTRY(restore_image)
	movl	resume_pg_dir, %eax
	subl	$__PAGE_OFFSET, %eax
	movl	%eax, %cr3

	movl	restore_pblist, %edx
	.p2align 4,,7

copy_loop:
	testl	%edx, %edx
	jz	done

	movl	pbe_address(%edx), %esi
	movl	pbe_orig_address(%edx), %edi

	movl	$1024, %ecx
	rep
	movsl

	movl	pbe_next(%edx), %edx
	jmp	copy_loop
	.p2align 4,,7

done:
	/* go back to the original page tables */
	movl	$swapper_pg_dir, %eax
	subl	$__PAGE_OFFSET, %eax
	movl	%eax, %cr3
	/* Flush TLB, including "global" things (vmalloc) */
	movl	mmu_cr4_features, %ecx
	jecxz	1f	# cr4 Pentium and higher, skip if zero
	movl	%ecx, %edx
	andl	$~(X86_CR4_PGE), %edx
	movl	%edx, %cr4;  # turn off PGE
1:
	movl	%cr3, %eax;  # flush TLB
	movl	%eax, %cr3
	jecxz	1f	# cr4 Pentium and higher, skip if zero
	movl	%ecx, %cr4;  # turn PGE back on
1:

	movl saved_context_esp, %esp
	movl saved_context_ebp, %ebp
	movl saved_context_ebx, %ebx
	movl saved_context_esi, %esi
	movl saved_context_edi, %edi

	pushl saved_context_eflags
	popfl

	xorl	%eax, %eax

	ret
Commit	Line	Data
c5759124	1	/*
1da177e4 LT	2	* This may not use any stack, nor any variable that is not "NoSave":
	3	*
	4	* Its rewriting one kernel image with another. What is stack in "old"
	5	* image could very well be data page in "new" image, and overwriting
	6	* your own stack under you is bad idea.
	7	*/
	8
	9	#include <linux/linkage.h>
	10	#include <asm/segment.h>
0341c14d	11	#include <asm/page_types.h>
86feeaa8	12	#include <asm/asm-offsets.h>
c171f465	13	#include <asm/processor-flags.h>
1da177e4	14
c171f465	15	.text
1da177e4 LT	16
1da177e4 LT	17	ENTRY(swsusp_arch_suspend)
1da177e4 LT	18	movl %esp, saved_context_esp
	19	movl %ebx, saved_context_ebx
	20	movl %ebp, saved_context_ebp
	21	movl %esi, saved_context_esi
	22	movl %edi, saved_context_edi
c171f465 UB	23	pushfl
c171f465 UB	24	popl saved_context_eflags
1da177e4 LT	25
	26	call swsusp_save
	27	ret
	28
2d4a34c9	29	ENTRY(restore_image)
e532c06f DF	30	movl resume_pg_dir, %eax
	31	subl $__PAGE_OFFSET, %eax
	32	movl %eax, %cr3
1da177e4	33
75534b50	34	movl restore_pblist, %edx
1da177e4 LT	35	.p2align 4,,7
	36
	37	copy_loop:
	38	testl %edx, %edx
	39	jz done
	40
	41	movl pbe_address(%edx), %esi
	42	movl pbe_orig_address(%edx), %edi
	43
	44	movl $1024, %ecx
	45	rep
	46	movsl
	47
	48	movl pbe_next(%edx), %edx
	49	jmp copy_loop
	50	.p2align 4,,7
	51
	52	done:
2d4a34c9	53	/* go back to the original page tables */
e532c06f DF	54	movl $swapper_pg_dir, %eax
	55	subl $__PAGE_OFFSET, %eax
	56	movl %eax, %cr3
1da177e4	57	/* Flush TLB, including "global" things (vmalloc) */
e532c06f DF	58	movl mmu_cr4_features, %ecx
	59	jecxz 1f # cr4 Pentium and higher, skip if zero
	60	movl %ecx, %edx
c171f465	61	andl $~(X86_CR4_PGE), %edx
1da177e4	62	movl %edx, %cr4; # turn off PGE
e532c06f DF	63	1:
	64	movl %cr3, %eax; # flush TLB
	65	movl %eax, %cr3
	66	jecxz 1f # cr4 Pentium and higher, skip if zero
	67	movl %ecx, %cr4; # turn PGE back on
	68	1:
1da177e4 LT	69
	70	movl saved_context_esp, %esp
	71	movl saved_context_ebp, %ebp
	72	movl saved_context_ebx, %ebx
	73	movl saved_context_esi, %esi
	74	movl saved_context_edi, %edi
	75
c171f465 UB	76	pushl saved_context_eflags
c171f465 UB	77	popfl
1da177e4 LT	78
	79	xorl %eax, %eax
	80
	81	ret