[deliverable/binutils-gdb.git] / gdb / gdbserver / configure.ac

dnl Autoconf configure script for GDB server.
dnl Copyright (C) 2000, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
dnl 2010, 2011 Free Software Foundation, Inc.
dnl
dnl This file is part of GDB.
dnl
dnl This program is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 3 of the License, or
dnl (at your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.

dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)dnl

AC_INIT(server.c)
AC_CONFIG_HEADER(config.h:config.in)
AC_CONFIG_LIBOBJ_DIR(../gnulib)

AC_PROG_CC
AC_GNU_SOURCE

AC_CANONICAL_SYSTEM

AC_PROG_INSTALL

AC_ARG_PROGRAM

AC_HEADER_STDC
AC_HEADER_DIRENT

AC_FUNC_ALLOCA
AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
		 proc_service.h sys/procfs.h thread_db.h linux/elf.h dnl
		 stdlib.h unistd.h dnl
		 errno.h fcntl.h signal.h sys/file.h malloc.h dnl
		 sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
		 netinet/tcp.h arpa/inet.h sys/wait.h)
AC_CHECK_FUNCS(pread pwrite pread64)
AC_REPLACE_FUNCS(memmem vasprintf vsnprintf)

# Check for UST
ustlibs=""
ustinc=""

AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
                          Equivalent to --with-ust-include=PATH/include
                          plus --with-ust-lib=PATH/lib])
AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])

case $with_ust in
  no)
    ustlibs=
    ustinc=
    ;;
  "" | yes)
    ustlibs=" -lust "
    ustinc=""
    ;;
  *)
    ustlibs="-L$with_ust/lib -lust"
    ustinc="-I$with_ust/include "
    ;;
esac
if test "x$with_ust_include" != x; then
  ustinc="-I$with_ust_include "
fi
if test "x$with_ust_lib" != x; then
  ustlibs="-L$with_ust_lib -lust"
fi

if test "x$with_ust" != "xno"; then
  saved_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS $ustinc"
  AC_MSG_CHECKING([for ust])
  AC_TRY_COMPILE([
#define CONFIG_UST_GDB_INTEGRATION
#include <ust/ust.h>
  ],[],
  [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
  [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
  CFLAGS="$saved_CFLAGS"
fi

# Flags needed for UST
AC_SUBST(ustlibs)
AC_SUBST(ustinc)

AC_ARG_ENABLE(werror,
  AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  [case "${enableval}" in
     yes | y) ERROR_ON_WARNING="yes" ;;
     no | n)  ERROR_ON_WARNING="no" ;;
     *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
   esac])

# Enable -Werror by default when using gcc
if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
    ERROR_ON_WARNING=yes
fi

WERROR_CFLAGS=""
if test "${ERROR_ON_WARNING}" = yes ; then
    WERROR_CFLAGS="-Werror"
fi

build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
-Wformat-nonliteral -Wno-char-subscripts"

WARN_CFLAGS=""
if test "x$GCC" = xyes
then
    AC_MSG_CHECKING(compiler warning flags)
    # Separate out the -Werror flag as some files just cannot be
    # compiled with it enabled.
    for w in ${build_warnings}; do
	case $w in
	-Werr*) WERROR_CFLAGS=-Werror ;;
	*) # Check that GCC accepts it
	    saved_CFLAGS="$CFLAGS"
	    CFLAGS="$CFLAGS $w"
	    AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
	    CFLAGS="$saved_CFLAGS"
	esac
    done
    AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
fi
AC_SUBST(WARN_CFLAGS)
AC_SUBST(WERROR_CFLAGS)

dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
dnl debugging messages.  It lives in -ldl which is handled below so we don't
dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
dnl augment LIBS.
old_LIBS="$LIBS"
LIBS="$LIBS -ldl"
AC_CHECK_FUNCS(dladdr)
LIBS="$old_LIBS"

have_errno=no
AC_MSG_CHECKING(for errno)
AC_TRY_LINK([
#if HAVE_ERRNO_H
#include <errno.h>
#endif], [static int x; x = errno;],
  [AC_MSG_RESULT(yes - in errno.h); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) have_errno=yes])
if test $have_errno = no; then
AC_TRY_LINK([
#if HAVE_ERRNO_H
#include <errno.h>
#endif], [extern int errno; static int x; x = errno;],
  [AC_MSG_RESULT(yes - must define); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) AC_DEFINE(MUST_DEFINE_ERRNO, 1, [Checking if errno must be defined])],
  [AC_MSG_RESULT(no)])
fi

AC_CHECK_DECLS([strerror, perror, memmem, vasprintf, vsnprintf])

AC_CHECK_TYPES(socklen_t, [], [],
[#include <sys/types.h>
#include <sys/socket.h>
])

ACX_PKGVERSION([GDB])
ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])

# Check for various supplementary target information (beyond the
# triplet) which might affect the choices in configure.srv.
case "${target}" in
changequote(,)dnl
  i[34567]86-*-linux*)
changequote([,])dnl
    AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
      	           [save_CPPFLAGS="$CPPFLAGS"
                    CPPFLAGS="$CPPFLAGS $CFLAGS"
                    AC_EGREP_CPP([got it], [
#if __x86_64__
got it
#endif
                 ], [gdb_cv_i386_is_x86_64=yes],
                    [gdb_cv_i386_is_x86_64=no])
                    CPPFLAGS="$save_CPPFLAGS"])
    ;;
  m68k-*-*)
    AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
      	           [save_CPPFLAGS="$CPPFLAGS"
                    CPPFLAGS="$CPPFLAGS $CFLAGS"
                    AC_EGREP_CPP([got it], [
#ifdef __mcoldfire__
got it
#endif
                 ], [gdb_cv_m68k_is_coldfire=yes],
                    [gdb_cv_m68k_is_coldfire=no])
                    CPPFLAGS="$save_CPPFLAGS"])
    ;;
esac

. ${srcdir}/configure.srv

if test "${srv_mingwce}" = "yes"; then
  LIBS="$LIBS -lws2"
elif test "${srv_mingw}" = "yes"; then
  LIBS="$LIBS -lws2_32"
elif test "${srv_qnx}" = "yes"; then
  LIBS="$LIBS -lsocket"
elif test "${srv_lynxos}" = "yes"; then
  LIBS="$LIBS -lnetinet"
fi

if test "${srv_mingw}" = "yes"; then
  AC_DEFINE(USE_WIN32API, 1,
	    [Define if we should use the Windows API, instead of the
	     POSIX API.  On Windows, we use the Windows API when
	     building for MinGW, but the POSIX API when building
	     for Cygwin.])
fi

if test "${srv_linux_usrregs}" = "yes"; then
  AC_DEFINE(HAVE_LINUX_USRREGS, 1,
	    [Define if the target supports PTRACE_PEEKUSR for register ]
	    [access.])
fi

if test "${srv_linux_regsets}" = "yes"; then
  AC_DEFINE(HAVE_LINUX_REGSETS, 1,
	    [Define if the target supports register sets.])

  AC_MSG_CHECKING(for PTRACE_GETREGS)
  AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
  [AC_TRY_COMPILE([#include <sys/ptrace.h>],
		  [PTRACE_GETREGS;],
		  [gdbsrv_cv_have_ptrace_getregs=yes],
		  [gdbsrv_cv_have_ptrace_getregs=no])])
  AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
  if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
    AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
	      [Define if the target supports PTRACE_GETREGS for register ]
	      [access.])
  fi

  AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
  AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
  [AC_TRY_COMPILE([#include <sys/ptrace.h>],
		  [PTRACE_GETFPXREGS;],
		  [gdbsrv_cv_have_ptrace_getfpxregs=yes],
		  [gdbsrv_cv_have_ptrace_getfpxregs=no])])
  AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
  if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
    AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
	      [Define if the target supports PTRACE_GETFPXREGS for extended ]
	      [register access.])
  fi
fi

if test "$ac_cv_header_sys_procfs_h" = yes; then
  BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
  BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
  BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
  BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
fi

dnl Check for libdl, but do not add it to LIBS as only gdbserver
dnl needs it (and gdbreplay doesn't).
old_LIBS="$LIBS"
AC_CHECK_LIB(dl, dlopen)
LIBS="$old_LIBS"

srv_thread_depfiles=
srv_libs=
USE_THREAD_DB=

if test "$srv_linux_thread_db" = "yes"; then
  if test "$ac_cv_lib_dl_dlopen" = "yes"; then
    srv_libs="-ldl"
    AC_MSG_CHECKING(for the dynamic export flag)
    old_LDFLAGS="$LDFLAGS"
    # Older GNU ld supports --export-dynamic but --dynamic-list may not be
    # supported there.
    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
    LDFLAGS="$LDFLAGS $RDYNAMIC"
    AC_TRY_LINK([], [],
		[found="-Wl,--dynamic-list"
		 RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
		[RDYNAMIC="-rdynamic"
		 LDFLAGS="$old_LDFLAGS $RDYNAMIC"
		 AC_TRY_LINK([], [],
			     [found="-rdynamic"],
			     [found="no"
			      RDYNAMIC=""])])
    AC_SUBST(RDYNAMIC)
    LDFLAGS="$old_LDFLAGS"
    AC_MSG_RESULT($found)
  else
    srv_libs="-lthread_db"
  fi

  srv_thread_depfiles="thread-db.o proc-service.o"
  USE_THREAD_DB="-DUSE_THREAD_DB"
  AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
  [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
		  [gdbsrv_cv_have_td_version=yes],
		  [gdbsrv_cv_have_td_version=no])])
  if test $gdbsrv_cv_have_td_version = yes; then
    AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
  fi
fi

AC_ARG_WITH(libthread-db,
AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
[srv_libthread_db_path="${withval}"
  srv_libs="$srv_libthread_db_path"
])

if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
  AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
fi

if test "$srv_xmlfiles" != ""; then
  srv_xmlbuiltin="xml-builtin.o"
  AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])

  tmp_xmlfiles=$srv_xmlfiles
  srv_xmlfiles=""
  for f in $tmp_xmlfiles; do
    srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
  done
fi

GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
GDBSERVER_LIBS="$srv_libs"

dnl Check whether the target supports __sync_*_compare_and_swap.
AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
		gdbsrv_cv_have_sync_builtins, [
AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
		gdbsrv_cv_have_sync_builtins=yes,
		gdbsrv_cv_have_sync_builtins=no)])
if test $gdbsrv_cv_have_sync_builtins = yes; then
  AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
    [Define to 1 if the target supports __sync_*_compare_and_swap])
fi

dnl Check for -fvisibility=hidden support in the compiler.
saved_cflags="$CFLAGS"
CFLAGS="$CFLAGS -fvisibility=hidden"
AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
		        [gdbsrv_cv_have_visibility_hidden=yes],
	        	[gdbsrv_cv_have_visibility_hidden=no])
CFLAGS="$saved_cflags"


IPA_DEPFILES=""
extra_libraries=""

# check whether to enable the inprocess agent
if test "$ipa_obj" != "" \
   -a "$gdbsrv_cv_have_sync_builtins" = yes \
   -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
   have_ipa=true
else
   have_ipa=false
fi

AC_ARG_ENABLE(inprocess-agent,
AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
[case "$enableval" in
  yes) want_ipa=true ;;
  no) want_ipa=false ;;
  *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
esac],
[want_ipa=$have_ipa])

if $want_ipa ; then
   if $have_ipa ; then
     IPA_DEPFILES="$ipa_obj"
     extra_libraries="$extra_libraries libinproctrace.so"
   else
     AC_MSG_ERROR([inprocess agent not supported for this target])
   fi
fi

AC_SUBST(GDBSERVER_DEPFILES)
AC_SUBST(GDBSERVER_LIBS)
AC_SUBST(USE_THREAD_DB)
AC_SUBST(srv_xmlbuiltin)
AC_SUBST(srv_xmlfiles)
AC_SUBST(IPA_DEPFILES)
AC_SUBST(extra_libraries)

AC_OUTPUT(Makefile,
[case x$CONFIG_HEADERS in
xconfig.h:config.in)
echo > stamp-h ;;
esac
])
Commit	Line	Data
d6e9fb05	1	dnl Autoconf configure script for GDB server.
abd775ce	2	dnl Copyright (C) 2000, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
44944448	3	dnl 2010, 2011 Free Software Foundation, Inc.
d6e9fb05 JK	4	dnl
	5	dnl This file is part of GDB.
	6	dnl
	7	dnl This program is free software; you can redistribute it and/or modify
	8	dnl it under the terms of the GNU General Public License as published by
5a0e3bd0	9	dnl the Free Software Foundation; either version 3 of the License, or
d6e9fb05 JK	10	dnl (at your option) any later version.
	11	dnl
	12	dnl This program is distributed in the hope that it will be useful,
	13	dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	dnl GNU General Public License for more details.
	16	dnl
	17	dnl You should have received a copy of the GNU General Public License
5a0e3bd0	18	dnl along with this program. If not, see <http://www.gnu.org/licenses/>.
d6e9fb05 JK	19
	20	dnl Process this file with autoconf to produce a configure script.
	21
bec39cab AC	22	AC_PREREQ(2.59)dnl
bec39cab AC	23
d6e9fb05	24	AC_INIT(server.c)
84563040	25	AC_CONFIG_HEADER(config.h:config.in)
e28b3332	26	AC_CONFIG_LIBOBJ_DIR(../gnulib)
84563040 DJ	27
84563040 DJ	28	AC_PROG_CC
fd462a61	29	AC_GNU_SOURCE
d6e9fb05 JK	30
d6e9fb05 JK	31	AC_CANONICAL_SYSTEM
84563040	32
d6e9fb05	33	AC_PROG_INSTALL
c906108c	34
dcdb98d2 DJ	35	AC_ARG_PROGRAM
dcdb98d2 DJ	36
ee6e2b82	37	AC_HEADER_STDC
d26e3629	38	AC_HEADER_DIRENT
84563040	39
a1723c35	40	AC_FUNC_ALLOCA
0d62e5e8	41	AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
94e10508	42	proc_service.h sys/procfs.h thread_db.h linux/elf.h dnl
b80864fb	43	stdlib.h unistd.h dnl
1b3f6016	44	errno.h fcntl.h signal.h sys/file.h malloc.h dnl
61ff6e04	45	sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
b80864fb	46	netinet/tcp.h arpa/inet.h sys/wait.h)
4e799345	47	AC_CHECK_FUNCS(pread pwrite pread64)
bb0116a4	48	AC_REPLACE_FUNCS(memmem vasprintf vsnprintf)
84563040	49
0fb4aa4b PA	50	# Check for UST
	51	ustlibs=""
	52	ustinc=""
	53
	54	AC_ARG_WITH(ust, [ --with-ust=PATH Specify prefix directory for the installed UST package
	55	Equivalent to --with-ust-include=PATH/include
	56	plus --with-ust-lib=PATH/lib])
	57	AC_ARG_WITH(ust_include, [ --with-ust-include=PATH Specify directory for installed UST include files])
	58	AC_ARG_WITH(ust_lib, [ --with-ust-lib=PATH Specify the directory for the installed UST library])
	59
	60	case $with_ust in
	61	no)
	62	ustlibs=
	63	ustinc=
	64	;;
	65	"" \| yes)
	66	ustlibs=" -lust "
	67	ustinc=""
	68	;;
	69	*)
	70	ustlibs="-L$with_ust/lib -lust"
	71	ustinc="-I$with_ust/include "
	72	;;
	73	esac
	74	if test "x$with_ust_include" != x; then
	75	ustinc="-I$with_ust_include "
	76	fi
	77	if test "x$with_ust_lib" != x; then
	78	ustlibs="-L$with_ust_lib -lust"
	79	fi
	80
	81	if test "x$with_ust" != "xno"; then
	82	saved_CFLAGS="$CFLAGS"
	83	CFLAGS="$CFLAGS $ustinc"
	84	AC_MSG_CHECKING([for ust])
	85	AC_TRY_COMPILE([
	86	#define CONFIG_UST_GDB_INTEGRATION
	87	#include <ust/ust.h>
	88	],[],
	89	[AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
	90	[AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
	91	CFLAGS="$saved_CFLAGS"
	92	fi
	93
	94	# Flags needed for UST
	95	AC_SUBST(ustlibs)
	96	AC_SUBST(ustinc)
	97
d4596a3d PA	98	AC_ARG_ENABLE(werror,
	99	AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
	100	[case "${enableval}" in
	101	yes \| y) ERROR_ON_WARNING="yes" ;;
	102	no \| n) ERROR_ON_WARNING="no" ;;
	103	*) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
	104	esac])
	105
	106	# Enable -Werror by default when using gcc
	107	if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
	108	ERROR_ON_WARNING=yes
	109	fi
	110
	111	WERROR_CFLAGS=""
	112	if test "${ERROR_ON_WARNING}" = yes ; then
	113	WERROR_CFLAGS="-Werror"
	114	fi
	115
	116	build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
854d88f0	117	-Wformat-nonliteral -Wno-char-subscripts"
d4596a3d PA	118
	119	WARN_CFLAGS=""
	120	if test "x$GCC" = xyes
	121	then
	122	AC_MSG_CHECKING(compiler warning flags)
	123	# Separate out the -Werror flag as some files just cannot be
	124	# compiled with it enabled.
	125	for w in ${build_warnings}; do
	126	case $w in
	127	-Werr*) WERROR_CFLAGS=-Werror ;;
	128	*) # Check that GCC accepts it
	129	saved_CFLAGS="$CFLAGS"
	130	CFLAGS="$CFLAGS $w"
	131	AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
	132	CFLAGS="$saved_CFLAGS"
	133	esac
	134	done
	135	AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
	136	fi
	137	AC_SUBST(WARN_CFLAGS)
	138	AC_SUBST(WERROR_CFLAGS)
	139
10e86dd7 DE	140	dnl dladdr is glibc-specific. It is used by thread-db.c but only for
	141	dnl debugging messages. It lives in -ldl which is handled below so we don't
	142	dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here. Instead we just temporarily
	143	dnl augment LIBS.
	144	old_LIBS="$LIBS"
	145	LIBS="$LIBS -ldl"
	146	AC_CHECK_FUNCS(dladdr)
	147	LIBS="$old_LIBS"
	148
68070c10 PA	149	have_errno=no
	150	AC_MSG_CHECKING(for errno)
	151	AC_TRY_LINK([
	152	#if HAVE_ERRNO_H
	153	#include <errno.h>
	154	#endif], [static int x; x = errno;],
	155	[AC_MSG_RESULT(yes - in errno.h); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) have_errno=yes])
	156	if test $have_errno = no; then
	157	AC_TRY_LINK([
	158	#if HAVE_ERRNO_H
	159	#include <errno.h>
	160	#endif], [extern int errno; static int x; x = errno;],
	161	[AC_MSG_RESULT(yes - must define); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) AC_DEFINE(MUST_DEFINE_ERRNO, 1, [Checking if errno must be defined])],
	162	[AC_MSG_RESULT(no)])
	163	fi
	164
bb0116a4	165	AC_CHECK_DECLS([strerror, perror, memmem, vasprintf, vsnprintf])
43d5792c	166
ccbd4912 MK	167	AC_CHECK_TYPES(socklen_t, [], [],
	168	[#include <sys/types.h>
	169	#include <sys/socket.h>
	170	])
fb1e4ffc	171
c16158bc JM	172	ACX_PKGVERSION([GDB])
	173	ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
	174	AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
	175	AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
	176
8838b45e NS	177	# Check for various supplementary target information (beyond the
	178	# triplet) which might affect the choices in configure.srv.
	179	case "${target}" in
	180	changequote(,)dnl
	181	i[34567]86--linux)
	182	changequote([,])dnl
	183	AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
	184	[save_CPPFLAGS="$CPPFLAGS"
	185	CPPFLAGS="$CPPFLAGS $CFLAGS"
	186	AC_EGREP_CPP([got it], [
	187	#if __x86_64__
	188	got it
	189	#endif
	190	], [gdb_cv_i386_is_x86_64=yes],
	191	[gdb_cv_i386_is_x86_64=no])
	192	CPPFLAGS="$save_CPPFLAGS"])
	193	;;
9ac544ce MK	194	m68k--)
	195	AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
	196	[save_CPPFLAGS="$CPPFLAGS"
	197	CPPFLAGS="$CPPFLAGS $CFLAGS"
	198	AC_EGREP_CPP([got it], [
	199	#ifdef __mcoldfire__
	200	got it
	201	#endif
	202	], [gdb_cv_m68k_is_coldfire=yes],
	203	[gdb_cv_m68k_is_coldfire=no])
	204	CPPFLAGS="$save_CPPFLAGS"])
	205	;;
8838b45e NS	206	esac
8838b45e NS	207
7ea81414	208	. ${srcdir}/configure.srv
c906108c	209
68070c10 PA	210	if test "${srv_mingwce}" = "yes"; then
	211	LIBS="$LIBS -lws2"
	212	elif test "${srv_mingw}" = "yes"; then
12ea4b69	213	LIBS="$LIBS -lws2_32"
ac8c974e AR	214	elif test "${srv_qnx}" = "yes"; then
ac8c974e AR	215	LIBS="$LIBS -lsocket"
8ed54b31 JB	216	elif test "${srv_lynxos}" = "yes"; then
8ed54b31 JB	217	LIBS="$LIBS -lnetinet"
68070c10 PA	218	fi
	219
	220	if test "${srv_mingw}" = "yes"; then
b80864fb DJ	221	AC_DEFINE(USE_WIN32API, 1,
	222	[Define if we should use the Windows API, instead of the
	223	POSIX API. On Windows, we use the Windows API when
	224	building for MinGW, but the POSIX API when building
	225	for Cygwin.])
	226	fi
	227
58caa3dc	228	if test "${srv_linux_usrregs}" = "yes"; then
f450004a DJ	229	AC_DEFINE(HAVE_LINUX_USRREGS, 1,
	230	[Define if the target supports PTRACE_PEEKUSR for register ]
	231	[access.])
58caa3dc DJ	232	fi
	233
	234	if test "${srv_linux_regsets}" = "yes"; then
e9d25b98 DJ	235	AC_DEFINE(HAVE_LINUX_REGSETS, 1,
	236	[Define if the target supports register sets.])
	237
58caa3dc DJ	238	AC_MSG_CHECKING(for PTRACE_GETREGS)
	239	AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
	240	[AC_TRY_COMPILE([#include <sys/ptrace.h>],
	241	[PTRACE_GETREGS;],
	242	[gdbsrv_cv_have_ptrace_getregs=yes],
	243	[gdbsrv_cv_have_ptrace_getregs=no])])
	244	AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
	245	if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
e9d25b98	246	AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
f450004a DJ	247	[Define if the target supports PTRACE_GETREGS for register ]
f450004a DJ	248	[access.])
58caa3dc DJ	249	fi
	250
	251	AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
	252	AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
	253	[AC_TRY_COMPILE([#include <sys/ptrace.h>],
	254	[PTRACE_GETFPXREGS;],
	255	[gdbsrv_cv_have_ptrace_getfpxregs=yes],
	256	[gdbsrv_cv_have_ptrace_getfpxregs=no])])
	257	AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
	258	if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
f450004a DJ	259	AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
	260	[Define if the target supports PTRACE_GETFPXREGS for extended ]
	261	[register access.])
58caa3dc DJ	262	fi
	263	fi
	264
0d62e5e8 DJ	265	if test "$ac_cv_header_sys_procfs_h" = yes; then
	266	BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
	267	BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
	268	BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
0d62e5e8 DJ	269	BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
	270	fi
	271
193f13e6 MK	272	dnl Check for libdl, but do not add it to LIBS as only gdbserver
	273	dnl needs it (and gdbreplay doesn't).
	274	old_LIBS="$LIBS"
	275	AC_CHECK_LIB(dl, dlopen)
	276	LIBS="$old_LIBS"
	277
0d62e5e8 DJ	278	srv_thread_depfiles=
	279	srv_libs=
	280	USE_THREAD_DB=
	281
	282	if test "$srv_linux_thread_db" = "yes"; then
193f13e6 MK	283	if test "$ac_cv_lib_dl_dlopen" = "yes"; then
193f13e6 MK	284	srv_libs="-ldl"
f6528abd	285	AC_MSG_CHECKING(for the dynamic export flag)
193f13e6	286	old_LDFLAGS="$LDFLAGS"
f6528abd JK	287	# Older GNU ld supports --export-dynamic but --dynamic-list may not be
	288	# supported there.
	289	RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
	290	LDFLAGS="$LDFLAGS $RDYNAMIC"
	291	AC_TRY_LINK([], [],
	292	[found="-Wl,--dynamic-list"
	293	RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
	294	[RDYNAMIC="-rdynamic"
	295	LDFLAGS="$old_LDFLAGS $RDYNAMIC"
	296	AC_TRY_LINK([], [],
	297	[found="-rdynamic"],
	298	[found="no"
	299	RDYNAMIC=""])])
193f13e6 MK	300	AC_SUBST(RDYNAMIC)
193f13e6 MK	301	LDFLAGS="$old_LDFLAGS"
f6528abd	302	AC_MSG_RESULT($found)
193f13e6 MK	303	else
	304	srv_libs="-lthread_db"
	305	fi
0d62e5e8	306
0d62e5e8 DJ	307	srv_thread_depfiles="thread-db.o proc-service.o"
0d62e5e8 DJ	308	USE_THREAD_DB="-DUSE_THREAD_DB"
3db0444b DJ	309	AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
3db0444b DJ	310	[AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
1b3f6016 PA	311	[gdbsrv_cv_have_td_version=yes],
1b3f6016 PA	312	[gdbsrv_cv_have_td_version=no])])
3db0444b DJ	313	if test $gdbsrv_cv_have_td_version = yes; then
	314	AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
	315	fi
0d62e5e8 DJ	316	fi
0d62e5e8 DJ	317
96f15937 PP	318	AC_ARG_WITH(libthread-db,
	319	AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
	320	[srv_libthread_db_path="${withval}"
96f15937 PP	321	srv_libs="$srv_libthread_db_path"
	322	])
	323
193f13e6 MK	324	if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
	325	AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
	326	fi
	327
9b4b61c8	328	if test "$srv_xmlfiles" != ""; then
fb1e4ffc DJ	329	srv_xmlbuiltin="xml-builtin.o"
	330	AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
	331
	332	tmp_xmlfiles=$srv_xmlfiles
9b4b61c8	333	srv_xmlfiles=""
fb1e4ffc DJ	334	for f in $tmp_xmlfiles; do
	335	srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
	336	done
	337	fi
	338
59a016f0	339	GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
0d62e5e8	340	GDBSERVER_LIBS="$srv_libs"
c906108c	341
fa593d66 PA	342	dnl Check whether the target supports __sync_*_compare_and_swap.
	343	AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
	344	gdbsrv_cv_have_sync_builtins, [
	345	AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
	346	gdbsrv_cv_have_sync_builtins=yes,
	347	gdbsrv_cv_have_sync_builtins=no)])
	348	if test $gdbsrv_cv_have_sync_builtins = yes; then
	349	AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
	350	[Define to 1 if the target supports __sync_*_compare_and_swap])
	351	fi
	352
	353	dnl Check for -fvisibility=hidden support in the compiler.
	354	saved_cflags="$CFLAGS"
	355	CFLAGS="$CFLAGS -fvisibility=hidden"
	356	AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
	357	[gdbsrv_cv_have_visibility_hidden=yes],
	358	[gdbsrv_cv_have_visibility_hidden=no])
	359	CFLAGS="$saved_cflags"
	360
c2a66c29	361
fa593d66	362	IPA_DEPFILES=""
c2a66c29	363	extra_libraries=""
fa593d66	364
c2a66c29	365	# check whether to enable the inprocess agent
fa593d66 PA	366	if test "$ipa_obj" != "" \
	367	-a "$gdbsrv_cv_have_sync_builtins" = yes \
	368	-a "$gdbsrv_cv_have_visibility_hidden" = yes; then
c2a66c29 NS	369	have_ipa=true
	370	else
	371	have_ipa=false
	372	fi
	373
	374	AC_ARG_ENABLE(inprocess-agent,
	375	AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
	376	[case "$enableval" in
	377	yes) want_ipa=true ;;
	378	no) want_ipa=false ;;
	379	*) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
	380	esac],
	381	[want_ipa=$have_ipa])
	382
	383	if $want_ipa ; then
	384	if $have_ipa ; then
	385	IPA_DEPFILES="$ipa_obj"
	386	extra_libraries="$extra_libraries libinproctrace.so"
	387	else
	388	AC_MSG_ERROR([inprocess agent not supported for this target])
	389	fi
fa593d66 PA	390	fi
fa593d66 PA	391
7ea81414	392	AC_SUBST(GDBSERVER_DEPFILES)
0d62e5e8 DJ	393	AC_SUBST(GDBSERVER_LIBS)
0d62e5e8 DJ	394	AC_SUBST(USE_THREAD_DB)
fb1e4ffc DJ	395	AC_SUBST(srv_xmlbuiltin)
fb1e4ffc DJ	396	AC_SUBST(srv_xmlfiles)
fa593d66 PA	397	AC_SUBST(IPA_DEPFILES)
fa593d66 PA	398	AC_SUBST(extra_libraries)
c906108c	399
c3a3ccc7 DJ	400	AC_OUTPUT(Makefile,
	401	[case x$CONFIG_HEADERS in
	402	xconfig.h:config.in)
	403	echo > stamp-h ;;
	404	esac
	405	])