Commit | Line | Data |
---|---|---|
a4da2e3e DG |
1 | /* |
2 | * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation. 2005. | |
3 | * | |
4 | * | |
5 | * This program is free software; you can redistribute it and/or | |
6 | * modify it under the terms of the GNU General Public License as | |
7 | * published by the Free Software Foundation; either version 2 of the | |
8 | * License, or (at your option) any later version. | |
9 | * | |
10 | * This program is distributed in the hope that it will be useful, | |
11 | * but WITHOUT ANY WARRANTY; without even the implied warranty of | |
12 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU | |
13 | * General Public License for more details. | |
14 | * | |
15 | * You should have received a copy of the GNU General Public License | |
16 | * along with this program; if not, write to the Free Software | |
17 | * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 | |
18 | * USA | |
19 | */ | |
20 | ||
658f29a5 | 21 | %option noyywrap nounput noinput never-interactive |
a4da2e3e | 22 | |
a4da2e3e DG |
23 | %x BYTESTRING |
24 | %x PROPNODENAME | |
25 | %s V1 | |
26 | ||
27 | PROPNODECHAR [a-zA-Z0-9,._+*#?@-] | |
28 | PATHCHAR ({PROPNODECHAR}|[/]) | |
29 | LABEL [a-zA-Z_][a-zA-Z0-9_]* | |
ed95d745 | 30 | STRING \"([^\\"]|\\.)*\" |
cd296721 | 31 | CHAR_LITERAL '([^']|\\')*' |
ed95d745 DG |
32 | WS [[:space:]] |
33 | COMMENT "/*"([^*]|\*+[^*/])*\*+"/" | |
34 | LINECOMMENT "//".*\n | |
a4da2e3e DG |
35 | |
36 | %{ | |
37 | #include "dtc.h" | |
38 | #include "srcpos.h" | |
39 | #include "dtc-parser.tab.h" | |
40 | ||
658f29a5 | 41 | YYLTYPE yylloc; |
47605971 | 42 | extern bool treesource_error; |
658f29a5 JB |
43 | |
44 | /* CAUTION: this will stop working if we ever use yyless() or yyunput() */ | |
45 | #define YY_USER_ACTION \ | |
46 | { \ | |
47 | srcpos_update(&yylloc, yytext, yyleng); \ | |
48 | } | |
a4da2e3e DG |
49 | |
50 | /*#define LEXDEBUG 1*/ | |
51 | ||
52 | #ifdef LEXDEBUG | |
53 | #define DPRINT(fmt, ...) fprintf(stderr, fmt, ##__VA_ARGS__) | |
54 | #else | |
55 | #define DPRINT(fmt, ...) do { } while (0) | |
56 | #endif | |
57 | ||
658f29a5 | 58 | static int dts_version = 1; |
a4da2e3e | 59 | |
658f29a5 | 60 | #define BEGIN_DEFAULT() DPRINT("<V1>\n"); \ |
a4da2e3e | 61 | BEGIN(V1); \ |
ed95d745 DG |
62 | |
63 | static void push_input_file(const char *filename); | |
47605971 RH |
64 | static bool pop_input_file(void); |
65 | static void lexical_error(const char *fmt, ...); | |
a4da2e3e DG |
66 | %} |
67 | ||
68 | %% | |
ed95d745 DG |
69 | <*>"/include/"{WS}*{STRING} { |
70 | char *name = strchr(yytext, '\"') + 1; | |
71 | yytext[yyleng-1] = '\0'; | |
72 | push_input_file(name); | |
a4da2e3e DG |
73 | } |
74 | ||
706b78f3 | 75 | <*>^"#"(line)?[ \t]+[0-9]+[ \t]+{STRING}([ \t]+[0-9]+)? { |
91feabc2 RH |
76 | char *line, *fnstart, *fnend; |
77 | struct data fn; | |
cd296721 SW |
78 | /* skip text before line # */ |
79 | line = yytext; | |
47605971 | 80 | while (!isdigit((unsigned char)*line)) |
cd296721 | 81 | line++; |
91feabc2 RH |
82 | |
83 | /* regexp ensures that first and list " | |
84 | * in the whole yytext are those at | |
85 | * beginning and end of the filename string */ | |
86 | fnstart = memchr(yytext, '"', yyleng); | |
87 | for (fnend = yytext + yyleng - 1; | |
88 | *fnend != '"'; fnend--) | |
89 | ; | |
90 | assert(fnstart && fnend && (fnend > fnstart)); | |
91 | ||
92 | fn = data_copy_escape_string(fnstart + 1, | |
93 | fnend - fnstart - 1); | |
94 | ||
95 | /* Don't allow nuls in filenames */ | |
96 | if (memchr(fn.val, '\0', fn.len - 1)) | |
97 | lexical_error("nul in line number directive"); | |
98 | ||
cd296721 | 99 | /* -1 since #line is the number of the next line */ |
91feabc2 RH |
100 | srcpos_set_line(xstrdup(fn.val), atoi(line) - 1); |
101 | data_free(fn); | |
cd296721 SW |
102 | } |
103 | ||
a4da2e3e DG |
104 | <*><<EOF>> { |
105 | if (!pop_input_file()) { | |
106 | yyterminate(); | |
107 | } | |
108 | } | |
109 | ||
ed95d745 | 110 | <*>{STRING} { |
a4da2e3e DG |
111 | DPRINT("String: %s\n", yytext); |
112 | yylval.data = data_copy_escape_string(yytext+1, | |
113 | yyleng-2); | |
a4da2e3e DG |
114 | return DT_STRING; |
115 | } | |
116 | ||
117 | <*>"/dts-v1/" { | |
a4da2e3e DG |
118 | DPRINT("Keyword: /dts-v1/\n"); |
119 | dts_version = 1; | |
120 | BEGIN_DEFAULT(); | |
121 | return DT_V1; | |
122 | } | |
123 | ||
124 | <*>"/memreserve/" { | |
a4da2e3e DG |
125 | DPRINT("Keyword: /memreserve/\n"); |
126 | BEGIN_DEFAULT(); | |
127 | return DT_MEMRESERVE; | |
128 | } | |
129 | ||
cd296721 SW |
130 | <*>"/bits/" { |
131 | DPRINT("Keyword: /bits/\n"); | |
132 | BEGIN_DEFAULT(); | |
133 | return DT_BITS; | |
134 | } | |
135 | ||
136 | <*>"/delete-property/" { | |
137 | DPRINT("Keyword: /delete-property/\n"); | |
138 | DPRINT("<PROPNODENAME>\n"); | |
139 | BEGIN(PROPNODENAME); | |
140 | return DT_DEL_PROP; | |
141 | } | |
142 | ||
143 | <*>"/delete-node/" { | |
144 | DPRINT("Keyword: /delete-node/\n"); | |
145 | DPRINT("<PROPNODENAME>\n"); | |
146 | BEGIN(PROPNODENAME); | |
147 | return DT_DEL_NODE; | |
148 | } | |
149 | ||
a4da2e3e | 150 | <*>{LABEL}: { |
a4da2e3e | 151 | DPRINT("Label: %s\n", yytext); |
658f29a5 | 152 | yylval.labelref = xstrdup(yytext); |
a4da2e3e DG |
153 | yylval.labelref[yyleng-1] = '\0'; |
154 | return DT_LABEL; | |
155 | } | |
156 | ||
cd296721 | 157 | <V1>([0-9]+|0[xX][0-9a-fA-F]+)(U|L|UL|LL|ULL)? { |
47605971 RH |
158 | char *e; |
159 | DPRINT("Integer Literal: '%s'\n", yytext); | |
160 | ||
161 | errno = 0; | |
162 | yylval.integer = strtoull(yytext, &e, 0); | |
163 | ||
91feabc2 RH |
164 | if (*e && e[strspn(e, "UL")]) { |
165 | lexical_error("Bad integer literal '%s'", | |
166 | yytext); | |
167 | } | |
47605971 RH |
168 | |
169 | if (errno == ERANGE) | |
170 | lexical_error("Integer literal '%s' out of range", | |
171 | yytext); | |
172 | else | |
173 | /* ERANGE is the only strtoull error triggerable | |
174 | * by strings matching the pattern */ | |
175 | assert(errno == 0); | |
a4da2e3e DG |
176 | return DT_LITERAL; |
177 | } | |
178 | ||
cd296721 | 179 | <*>{CHAR_LITERAL} { |
47605971 RH |
180 | struct data d; |
181 | DPRINT("Character literal: %s\n", yytext); | |
182 | ||
183 | d = data_copy_escape_string(yytext+1, yyleng-2); | |
184 | if (d.len == 1) { | |
185 | lexical_error("Empty character literal"); | |
186 | yylval.integer = 0; | |
187 | return DT_CHAR_LITERAL; | |
188 | } | |
189 | ||
190 | yylval.integer = (unsigned char)d.val[0]; | |
191 | ||
192 | if (d.len > 2) | |
193 | lexical_error("Character literal has %d" | |
194 | " characters instead of 1", | |
195 | d.len - 1); | |
196 | ||
cd296721 SW |
197 | return DT_CHAR_LITERAL; |
198 | } | |
199 | ||
658f29a5 | 200 | <*>\&{LABEL} { /* label reference */ |
a4da2e3e | 201 | DPRINT("Ref: %s\n", yytext+1); |
658f29a5 | 202 | yylval.labelref = xstrdup(yytext+1); |
a4da2e3e DG |
203 | return DT_REF; |
204 | } | |
205 | ||
47605971 | 206 | <*>"&{/"{PATHCHAR}*\} { /* new-style path reference */ |
a4da2e3e DG |
207 | yytext[yyleng-1] = '\0'; |
208 | DPRINT("Ref: %s\n", yytext+2); | |
658f29a5 | 209 | yylval.labelref = xstrdup(yytext+2); |
a4da2e3e DG |
210 | return DT_REF; |
211 | } | |
212 | ||
213 | <BYTESTRING>[0-9a-fA-F]{2} { | |
a4da2e3e DG |
214 | yylval.byte = strtol(yytext, NULL, 16); |
215 | DPRINT("Byte: %02x\n", (int)yylval.byte); | |
216 | return DT_BYTE; | |
217 | } | |
218 | ||
219 | <BYTESTRING>"]" { | |
a4da2e3e DG |
220 | DPRINT("/BYTESTRING\n"); |
221 | BEGIN_DEFAULT(); | |
222 | return ']'; | |
223 | } | |
224 | ||
cd296721 | 225 | <PROPNODENAME>\\?{PROPNODECHAR}+ { |
a4da2e3e | 226 | DPRINT("PropNodeName: %s\n", yytext); |
cd296721 SW |
227 | yylval.propnodename = xstrdup((yytext[0] == '\\') ? |
228 | yytext + 1 : yytext); | |
a4da2e3e DG |
229 | BEGIN_DEFAULT(); |
230 | return DT_PROPNODENAME; | |
231 | } | |
232 | ||
ed95d745 | 233 | "/incbin/" { |
ed95d745 DG |
234 | DPRINT("Binary Include\n"); |
235 | return DT_INCBIN; | |
a4da2e3e DG |
236 | } |
237 | ||
ed95d745 DG |
238 | <*>{WS}+ /* eat whitespace */ |
239 | <*>{COMMENT}+ /* eat C-style comments */ | |
240 | <*>{LINECOMMENT}+ /* eat C++-style comments */ | |
a4da2e3e | 241 | |
cd296721 SW |
242 | <*>"<<" { return DT_LSHIFT; }; |
243 | <*>">>" { return DT_RSHIFT; }; | |
244 | <*>"<=" { return DT_LE; }; | |
245 | <*>">=" { return DT_GE; }; | |
246 | <*>"==" { return DT_EQ; }; | |
247 | <*>"!=" { return DT_NE; }; | |
248 | <*>"&&" { return DT_AND; }; | |
249 | <*>"||" { return DT_OR; }; | |
250 | ||
a4da2e3e | 251 | <*>. { |
a4da2e3e DG |
252 | DPRINT("Char: %c (\\x%02x)\n", yytext[0], |
253 | (unsigned)yytext[0]); | |
254 | if (yytext[0] == '[') { | |
255 | DPRINT("<BYTESTRING>\n"); | |
256 | BEGIN(BYTESTRING); | |
257 | } | |
258 | if ((yytext[0] == '{') | |
259 | || (yytext[0] == ';')) { | |
260 | DPRINT("<PROPNODENAME>\n"); | |
261 | BEGIN(PROPNODENAME); | |
262 | } | |
263 | return yytext[0]; | |
264 | } | |
265 | ||
266 | %% | |
267 | ||
ed95d745 | 268 | static void push_input_file(const char *filename) |
a4da2e3e | 269 | { |
ed95d745 | 270 | assert(filename); |
a4da2e3e | 271 | |
658f29a5 | 272 | srcfile_push(filename); |
a4da2e3e | 273 | |
658f29a5 | 274 | yyin = current_srcfile->f; |
a4da2e3e | 275 | |
658f29a5 | 276 | yypush_buffer_state(yy_create_buffer(yyin, YY_BUF_SIZE)); |
a4da2e3e DG |
277 | } |
278 | ||
279 | ||
47605971 | 280 | static bool pop_input_file(void) |
a4da2e3e | 281 | { |
658f29a5 | 282 | if (srcfile_pop() == 0) |
47605971 | 283 | return false; |
a4da2e3e | 284 | |
658f29a5 JB |
285 | yypop_buffer_state(); |
286 | yyin = current_srcfile->f; | |
a4da2e3e | 287 | |
47605971 RH |
288 | return true; |
289 | } | |
290 | ||
291 | static void lexical_error(const char *fmt, ...) | |
292 | { | |
293 | va_list ap; | |
294 | ||
295 | va_start(ap, fmt); | |
296 | srcpos_verror(&yylloc, "Lexical error", fmt, ap); | |
297 | va_end(ap); | |
298 | ||
299 | treesource_error = true; | |
a4da2e3e | 300 | } |