[deliverable/linux.git] / scripts / kconfig / zconf.l

%option nostdinit noyywrap never-interactive full ecs
%option 8bit nodefault perf-report perf-report
%option noinput
%x COMMAND HELP STRING PARAM
%{
/*
 * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
 * Released under the terms of the GNU GPL v2.0.
 */

#include <limits.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <unistd.h>

#include "lkc.h"

#define START_STRSIZE	16

static struct {
	struct file *file;
	int lineno;
} current_pos;

static char *text;
static int text_size, text_asize;

struct buffer {
	struct buffer *parent;
	YY_BUFFER_STATE state;
};

struct buffer *current_buf;

static int last_ts, first_ts;

static void zconf_endhelp(void);
static void zconf_endfile(void);

static void new_string(void)
{
	text = xmalloc(START_STRSIZE);
	text_asize = START_STRSIZE;
	text_size = 0;
	*text = 0;
}

static void append_string(const char *str, int size)
{
	int new_size = text_size + size + 1;
	if (new_size > text_asize) {
		new_size += START_STRSIZE - 1;
		new_size &= -START_STRSIZE;
		text = realloc(text, new_size);
		text_asize = new_size;
	}
	memcpy(text + text_size, str, size);
	text_size += size;
	text[text_size] = 0;
}

static void alloc_string(const char *str, int size)
{
	text = xmalloc(size + 1);
	memcpy(text, str, size);
	text[size] = 0;
}
%}

n	[A-Za-z0-9_]

%%
	int str = 0;
	int ts, i;

[ \t]*#.*\n	|
[ \t]*\n	{
	current_file->lineno++;
	return T_EOL;
}
[ \t]*#.*


[ \t]+	{
	BEGIN(COMMAND);
}

.	{
	unput(yytext[0]);
	BEGIN(COMMAND);
}


<COMMAND>{
	{n}+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		BEGIN(PARAM);
		current_pos.file = current_file;
		current_pos.lineno = current_file->lineno;
		if (id && id->flags & TF_COMMAND) {
			zconflval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		zconflval.string = text;
		return T_WORD;
	}
	.
	\n	{
		BEGIN(INITIAL);
		current_file->lineno++;
		return T_EOL;
	}
}

<PARAM>{
	"&&"	return T_AND;
	"||"	return T_OR;
	"("	return T_OPEN_PAREN;
	")"	return T_CLOSE_PAREN;
	"!"	return T_NOT;
	"="	return T_EQUAL;
	"!="	return T_UNEQUAL;
	"<="	return T_LESS_EQUAL;
	">="	return T_GREATER_EQUAL;
	"<"	return T_LESS;
	">"	return T_GREATER;
	\"|\'	{
		str = yytext[0];
		new_string();
		BEGIN(STRING);
	}
	\n	BEGIN(INITIAL); current_file->lineno++; return T_EOL;
	---	/* ignore */
	({n}|[-/.])+	{
		const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
		if (id && id->flags & TF_PARAM) {
			zconflval.id = id;
			return id->token;
		}
		alloc_string(yytext, yyleng);
		zconflval.string = text;
		return T_WORD;
	}
	#.*	/* comment */
	\\\n	current_file->lineno++;
	[[:blank:]]+
	.	{
		fprintf(stderr,
		        "%s:%d:warning: ignoring unsupported character '%c'\n",
		        zconf_curname(), zconf_lineno(), *yytext);
	}
	<<EOF>> {
		BEGIN(INITIAL);
	}
}

<STRING>{
	[^'"\\\n]+/\n	{
		append_string(yytext, yyleng);
		zconflval.string = text;
		return T_WORD_QUOTE;
	}
	[^'"\\\n]+	{
		append_string(yytext, yyleng);
	}
	\\.?/\n	{
		append_string(yytext + 1, yyleng - 1);
		zconflval.string = text;
		return T_WORD_QUOTE;
	}
	\\.?	{
		append_string(yytext + 1, yyleng - 1);
	}
	\'|\"	{
		if (str == yytext[0]) {
			BEGIN(PARAM);
			zconflval.string = text;
			return T_WORD_QUOTE;
		} else
			append_string(yytext, 1);
	}
	\n	{
		printf("%s:%d:warning: multi-line strings not supported\n", zconf_curname(), zconf_lineno());
		current_file->lineno++;
		BEGIN(INITIAL);
		return T_EOL;
	}
	<<EOF>>	{
		BEGIN(INITIAL);
	}
}

<HELP>{
	[ \t]+	{
		ts = 0;
		for (i = 0; i < yyleng; i++) {
			if (yytext[i] == '\t')
				ts = (ts & ~7) + 8;
			else
				ts++;
		}
		last_ts = ts;
		if (first_ts) {
			if (ts < first_ts) {
				zconf_endhelp();
				return T_HELPTEXT;
			}
			ts -= first_ts;
			while (ts > 8) {
				append_string("        ", 8);
				ts -= 8;
			}
			append_string("        ", ts);
		}
	}
	[ \t]*\n/[^ \t\n] {
		current_file->lineno++;
		zconf_endhelp();
		return T_HELPTEXT;
	}
	[ \t]*\n	{
		current_file->lineno++;
		append_string("\n", 1);
	}
	[^ \t\n].* {
		while (yyleng) {
			if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
				break;
			yyleng--;
		}
		append_string(yytext, yyleng);
		if (!first_ts)
			first_ts = last_ts;
	}
	<<EOF>>	{
		zconf_endhelp();
		return T_HELPTEXT;
	}
}

<<EOF>>	{
	if (current_file) {
		zconf_endfile();
		return T_EOL;
	}
	fclose(yyin);
	yyterminate();
}

%%
void zconf_starthelp(void)
{
	new_string();
	last_ts = first_ts = 0;
	BEGIN(HELP);
}

static void zconf_endhelp(void)
{
	zconflval.string = text;
	BEGIN(INITIAL);
}


/*
 * Try to open specified file with following names:
 * ./name
 * $(srctree)/name
 * The latter is used when srctree is separate from objtree
 * when compiling the kernel.
 * Return NULL if file is not found.
 */
FILE *zconf_fopen(const char *name)
{
	char *env, fullname[PATH_MAX+1];
	FILE *f;

	f = fopen(name, "r");
	if (!f && name != NULL && name[0] != '/') {
		env = getenv(SRCTREE);
		if (env) {
			sprintf(fullname, "%s/%s", env, name);
			f = fopen(fullname, "r");
		}
	}
	return f;
}

void zconf_initscan(const char *name)
{
	yyin = zconf_fopen(name);
	if (!yyin) {
		printf("can't find file %s\n", name);
		exit(1);
	}

	current_buf = xmalloc(sizeof(*current_buf));
	memset(current_buf, 0, sizeof(*current_buf));

	current_file = file_lookup(name);
	current_file->lineno = 1;
}

void zconf_nextfile(const char *name)
{
	struct file *iter;
	struct file *file = file_lookup(name);
	struct buffer *buf = xmalloc(sizeof(*buf));
	memset(buf, 0, sizeof(*buf));

	current_buf->state = YY_CURRENT_BUFFER;
	yyin = zconf_fopen(file->name);
	if (!yyin) {
		printf("%s:%d: can't open file \"%s\"\n",
		    zconf_curname(), zconf_lineno(), file->name);
		exit(1);
	}
	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	buf->parent = current_buf;
	current_buf = buf;

	for (iter = current_file->parent; iter; iter = iter->parent ) {
		if (!strcmp(current_file->name,iter->name) ) {
			printf("%s:%d: recursive inclusion detected. "
			       "Inclusion path:\n  current file : '%s'\n",
			       zconf_curname(), zconf_lineno(),
			       zconf_curname());
			iter = current_file->parent;
			while (iter && \
			       strcmp(iter->name,current_file->name)) {
				printf("  included from: '%s:%d'\n",
				       iter->name, iter->lineno-1);
				iter = iter->parent;
			}
			if (iter)
				printf("  included from: '%s:%d'\n",
				       iter->name, iter->lineno+1);
			exit(1);
		}
	}
	file->lineno = 1;
	file->parent = current_file;
	current_file = file;
}

static void zconf_endfile(void)
{
	struct buffer *parent;

	current_file = current_file->parent;

	parent = current_buf->parent;
	if (parent) {
		fclose(yyin);
		yy_delete_buffer(YY_CURRENT_BUFFER);
		yy_switch_to_buffer(parent->state);
	}
	free(current_buf);
	current_buf = parent;
}

int zconf_lineno(void)
{
	return current_pos.lineno;
}

const char *zconf_curname(void)
{
	return current_pos.file ? current_pos.file->name : "<none>";
}
Commit	Line	Data
674eed8a AL	1	%option nostdinit noyywrap never-interactive full ecs
674eed8a AL	2	%option 8bit nodefault perf-report perf-report
be2be1d5	3	%option noinput
1da177e4 LT	4	%x COMMAND HELP STRING PARAM
	5	%{
	6	/*
	7	* Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
	8	* Released under the terms of the GNU GPL v2.0.
	9	*/
	10
	11	#include <limits.h>
	12	#include <stdio.h>
	13	#include <stdlib.h>
	14	#include <string.h>
	15	#include <unistd.h>
	16
1da177e4 LT	17	#include "lkc.h"
	18
	19	#define START_STRSIZE 16
	20
a02f0570 RZ	21	static struct {
	22	struct file *file;
	23	int lineno;
	24	} current_pos;
	25
7a88488b	26	static char *text;
1da177e4 LT	27	static int text_size, text_asize;
	28
	29	struct buffer {
bb66fc67 MY	30	struct buffer *parent;
bb66fc67 MY	31	YY_BUFFER_STATE state;
1da177e4 LT	32	};
	33
	34	struct buffer *current_buf;
	35
	36	static int last_ts, first_ts;
	37
	38	static void zconf_endhelp(void);
a02f0570	39	static void zconf_endfile(void);
1da177e4	40
65166571	41	static void new_string(void)
1da177e4	42	{
177acf78	43	text = xmalloc(START_STRSIZE);
1da177e4	44	text_asize = START_STRSIZE;
1da177e4	45	text_size = 0;
7a88488b	46	*text = 0;
1da177e4 LT	47	}
1da177e4 LT	48
65166571	49	static void append_string(const char *str, int size)
1da177e4 LT	50	{
	51	int new_size = text_size + size + 1;
	52	if (new_size > text_asize) {
7a88488b RZ	53	new_size += START_STRSIZE - 1;
7a88488b RZ	54	new_size &= -START_STRSIZE;
1da177e4 LT	55	text = realloc(text, new_size);
1da177e4 LT	56	text_asize = new_size;
1da177e4	57	}
7a88488b	58	memcpy(text + text_size, str, size);
1da177e4	59	text_size += size;
7a88488b	60	text[text_size] = 0;
1da177e4 LT	61	}
1da177e4 LT	62
65166571	63	static void alloc_string(const char *str, int size)
1da177e4	64	{
177acf78	65	text = xmalloc(size + 1);
1da177e4 LT	66	memcpy(text, str, size);
	67	text[size] = 0;
	68	}
	69	%}
	70
1da177e4 LT	71	n [A-Za-z0-9_]
	72
	73	%%
	74	int str = 0;
	75	int ts, i;
	76
a02f0570 RZ	77	[ \t]#.\n \|
	78	[ \t]*\n {
	79	current_file->lineno++;
	80	return T_EOL;
	81	}
1da177e4 LT	82	[ \t]#.
1da177e4 LT	83
1da177e4 LT	84
	85	[ \t]+ {
	86	BEGIN(COMMAND);
	87	}
	88
	89	. {
	90	unput(yytext[0]);
	91	BEGIN(COMMAND);
	92	}
	93
	94
	95	<COMMAND>{
1da177e4	96	{n}+ {
61f956f5	97	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
a02f0570 RZ	98	BEGIN(PARAM);
	99	current_pos.file = current_file;
	100	current_pos.lineno = current_file->lineno;
7a88488b	101	if (id && id->flags & TF_COMMAND) {
3370f9f0	102	zconflval.id = id;
7a88488b RZ	103	return id->token;
7a88488b RZ	104	}
1da177e4 LT	105	alloc_string(yytext, yyleng);
	106	zconflval.string = text;
	107	return T_WORD;
	108	}
	109	.
a02f0570 RZ	110	\n {
	111	BEGIN(INITIAL);
	112	current_file->lineno++;
	113	return T_EOL;
	114	}
1da177e4 LT	115	}
	116
	117	<PARAM>{
	118	"&&" return T_AND;
	119	"\|\|" return T_OR;
	120	"(" return T_OPEN_PAREN;
	121	")" return T_CLOSE_PAREN;
	122	"!" return T_NOT;
	123	"=" return T_EQUAL;
	124	"!=" return T_UNEQUAL;
31847b67 JB	125	"<=" return T_LESS_EQUAL;
	126	">=" return T_GREATER_EQUAL;
	127	"<" return T_LESS;
	128	">" return T_GREATER;
1da177e4 LT	129	\"\|\' {
	130	str = yytext[0];
	131	new_string();
	132	BEGIN(STRING);
	133	}
	134	\n BEGIN(INITIAL); current_file->lineno++; return T_EOL;
	135	--- /* ignore */
	136	({n}\|[-/.])+ {
61f956f5	137	const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
3370f9f0 RZ	138	if (id && id->flags & TF_PARAM) {
3370f9f0 RZ	139	zconflval.id = id;
7a88488b	140	return id->token;
3370f9f0	141	}
1da177e4 LT	142	alloc_string(yytext, yyleng);
	143	zconflval.string = text;
	144	return T_WORD;
	145	}
	146	#.* /* comment */
	147	\\\n current_file->lineno++;
2e0d737f JB	148	[[:blank:]]+
	149	. {
	150	fprintf(stderr,
	151	"%s:%d:warning: ignoring unsupported character '%c'\n",
	152	zconf_curname(), zconf_lineno(), *yytext);
	153	}
1da177e4 LT	154	<<EOF>> {
	155	BEGIN(INITIAL);
	156	}
	157	}
	158
	159	<STRING>{
	160	[^'"\\\n]+/\n {
	161	append_string(yytext, yyleng);
	162	zconflval.string = text;
	163	return T_WORD_QUOTE;
	164	}
	165	[^'"\\\n]+ {
	166	append_string(yytext, yyleng);
	167	}
	168	\\.?/\n {
	169	append_string(yytext + 1, yyleng - 1);
	170	zconflval.string = text;
	171	return T_WORD_QUOTE;
	172	}
	173	\\.? {
	174	append_string(yytext + 1, yyleng - 1);
	175	}
	176	\'\|\" {
	177	if (str == yytext[0]) {
	178	BEGIN(PARAM);
	179	zconflval.string = text;
	180	return T_WORD_QUOTE;
	181	} else
	182	append_string(yytext, 1);
	183	}
	184	\n {
	185	printf("%s:%d:warning: multi-line strings not supported\n", zconf_curname(), zconf_lineno());
	186	current_file->lineno++;
	187	BEGIN(INITIAL);
	188	return T_EOL;
	189	}
	190	<<EOF>> {
	191	BEGIN(INITIAL);
	192	}
	193	}
	194
	195	<HELP>{
	196	[ \t]+ {
	197	ts = 0;
	198	for (i = 0; i < yyleng; i++) {
	199	if (yytext[i] == '\t')
	200	ts = (ts & ~7) + 8;
	201	else
	202	ts++;
	203	}
	204	last_ts = ts;
	205	if (first_ts) {
	206	if (ts < first_ts) {
	207	zconf_endhelp();
	208	return T_HELPTEXT;
	209	}
	210	ts -= first_ts;
	211	while (ts > 8) {
	212	append_string(" ", 8);
	213	ts -= 8;
	214	}
	215	append_string(" ", ts);
	216	}
	217	}
218	[ \t]*\n/[^ \t\n] {
219	current_file->lineno++;
220	zconf_endhelp();
221	return T_HELPTEXT;
222	}
223	[ \t]*\n {
224	current_file->lineno++;
225	append_string("\n", 1);
226	}
227	[^ \t\n].* {
f7a4b4cd EG	228	while (yyleng) {
	229	if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
	230	break;
	231	yyleng--;
	232	}
1da177e4 LT	233	append_string(yytext, yyleng);
	234	if (!first_ts)
	235	first_ts = last_ts;
	236	}
	237	<<EOF>> {
	238	zconf_endhelp();
	239	return T_HELPTEXT;
	240	}
	241	}
	242
	243	<<EOF>> {
a02f0570	244	if (current_file) {
1da177e4	245	zconf_endfile();
a02f0570	246	return T_EOL;
1da177e4 LT	247	}
	248	fclose(yyin);
	249	yyterminate();
	250	}
	251
	252	%%
	253	void zconf_starthelp(void)
	254	{
	255	new_string();
	256	last_ts = first_ts = 0;
	257	BEGIN(HELP);
	258	}
	259
	260	static void zconf_endhelp(void)
	261	{
	262	zconflval.string = text;
	263	BEGIN(INITIAL);
	264	}
	265
	266
	267	/*
	268	* Try to open specified file with following names:
	269	* ./name
	270	* $(srctree)/name
	271	* The latter is used when srctree is separate from objtree
	272	* when compiling the kernel.
	273	* Return NULL if file is not found.
	274	*/
	275	FILE zconf_fopen(const char name)
	276	{
	277	char *env, fullname[PATH_MAX+1];
	278	FILE *f;
	279
	280	f = fopen(name, "r");
11de39e2	281	if (!f && name != NULL && name[0] != '/') {
1da177e4 LT	282	env = getenv(SRCTREE);
	283	if (env) {
	284	sprintf(fullname, "%s/%s", env, name);
	285	f = fopen(fullname, "r");
	286	}
	287	}
	288	return f;
	289	}
	290
	291	void zconf_initscan(const char *name)
	292	{
	293	yyin = zconf_fopen(name);
	294	if (!yyin) {
	295	printf("can't find file %s\n", name);
	296	exit(1);
	297	}
	298
177acf78	299	current_buf = xmalloc(sizeof(*current_buf));
1da177e4 LT	300	memset(current_buf, 0, sizeof(*current_buf));
	301
	302	current_file = file_lookup(name);
	303	current_file->lineno = 1;
1da177e4 LT	304	}
	305
	306	void zconf_nextfile(const char *name)
	307	{
f094f8a1	308	struct file *iter;
1da177e4	309	struct file *file = file_lookup(name);
177acf78	310	struct buffer buf = xmalloc(sizeof(buf));
1da177e4 LT	311	memset(buf, 0, sizeof(*buf));
	312
	313	current_buf->state = YY_CURRENT_BUFFER;
e82dae90	314	yyin = zconf_fopen(file->name);
1da177e4	315	if (!yyin) {
e82dae90 AL	316	printf("%s:%d: can't open file \"%s\"\n",
e82dae90 AL	317	zconf_curname(), zconf_lineno(), file->name);
1da177e4 LT	318	exit(1);
	319	}
	320	yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
	321	buf->parent = current_buf;
	322	current_buf = buf;
	323
f094f8a1 YM	324	for (iter = current_file->parent; iter; iter = iter->parent ) {
	325	if (!strcmp(current_file->name,iter->name) ) {
	326	printf("%s:%d: recursive inclusion detected. "
	327	"Inclusion path:\n current file : '%s'\n",
	328	zconf_curname(), zconf_lineno(),
	329	zconf_curname());
	330	iter = current_file->parent;
	331	while (iter && \
	332	strcmp(iter->name,current_file->name)) {
	333	printf(" included from: '%s:%d'\n",
	334	iter->name, iter->lineno-1);
	335	iter = iter->parent;
	336	}
	337	if (iter)
	338	printf(" included from: '%s:%d'\n",
	339	iter->name, iter->lineno+1);
	340	exit(1);
	341	}
1da177e4	342	}
1da177e4 LT	343	file->lineno = 1;
	344	file->parent = current_file;
	345	current_file = file;
	346	}
	347
a02f0570	348	static void zconf_endfile(void)
1da177e4 LT	349	{
	350	struct buffer *parent;
	351
1da177e4 LT	352	current_file = current_file->parent;
	353
	354	parent = current_buf->parent;
	355	if (parent) {
	356	fclose(yyin);
	357	yy_delete_buffer(YY_CURRENT_BUFFER);
	358	yy_switch_to_buffer(parent->state);
	359	}
	360	free(current_buf);
	361	current_buf = parent;
1da177e4 LT	362	}
	363
	364	int zconf_lineno(void)
	365	{
a02f0570	366	return current_pos.lineno;
1da177e4 LT	367	}
1da177e4 LT	368
2e7a0918	369	const char *zconf_curname(void)
1da177e4	370	{
a02f0570	371	return current_pos.file ? current_pos.file->name : "<none>";
1da177e4	372	}