| 1 | dnl This file was derived from acinclude.m4. |
| 2 | |
| 3 | |
| 4 | dnl Check for existence of a type $1 in sys/procfs.h |
| 5 | |
| 6 | AC_DEFUN([BFD_HAVE_SYS_PROCFS_TYPE], |
| 7 | [AC_MSG_CHECKING([for $1 in sys/procfs.h]) |
| 8 | AC_CACHE_VAL(bfd_cv_have_sys_procfs_type_$1, |
| 9 | [AC_TRY_COMPILE([ |
| 10 | #define _SYSCALL32 |
| 11 | #include <sys/procfs.h>], |
| 12 | [$1 avar], |
| 13 | bfd_cv_have_sys_procfs_type_$1=yes, |
| 14 | bfd_cv_have_sys_procfs_type_$1=no |
| 15 | )]) |
| 16 | if test $bfd_cv_have_sys_procfs_type_$1 = yes; then |
| 17 | AC_DEFINE([HAVE_]translit($1, [a-z], [A-Z]), 1, |
| 18 | [Define if <sys/procfs.h> has $1.]) |
| 19 | fi |
| 20 | AC_MSG_RESULT($bfd_cv_have_sys_procfs_type_$1) |
| 21 | ]) |
| 22 | |
| 23 | |
| 24 | dnl Check for existence of member $2 in type $1 in sys/procfs.h |
| 25 | |
| 26 | AC_DEFUN([BFD_HAVE_SYS_PROCFS_TYPE_MEMBER], |
| 27 | [AC_MSG_CHECKING([for $1.$2 in sys/procfs.h]) |
| 28 | AC_CACHE_VAL(bfd_cv_have_sys_procfs_type_member_$1_$2, |
| 29 | [AC_TRY_COMPILE([ |
| 30 | #define _SYSCALL32 |
| 31 | #include <sys/procfs.h>], |
| 32 | [$1 avar; void* aref = (void*) &avar.$2], |
| 33 | bfd_cv_have_sys_procfs_type_member_$1_$2=yes, |
| 34 | bfd_cv_have_sys_procfs_type_member_$1_$2=no |
| 35 | )]) |
| 36 | if test $bfd_cv_have_sys_procfs_type_member_$1_$2 = yes; then |
| 37 | AC_DEFINE([HAVE_]translit($1, [a-z], [A-Z])[_]translit($2, [a-z], [A-Z]), 1, |
| 38 | [Define if <sys/procfs.h> has $1.$2.]) |
| 39 | fi |
| 40 | AC_MSG_RESULT($bfd_cv_have_sys_procfs_type_member_$1_$2) |
| 41 | ]) |
| 42 | |