| | 1 | AC_PREREQ([2.64]) |
| | 2 | AC_INIT([lttng-tools],[2.11.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 3 | |
| | 4 | AC_CONFIG_HEADERS([include/config.h]) |
| | 5 | AC_CONFIG_AUX_DIR([config]) |
| | 6 | AC_CONFIG_MACRO_DIR([m4]) |
| | 7 | |
| | 8 | AC_CANONICAL_TARGET |
| | 9 | AC_CANONICAL_HOST |
| | 10 | |
| | 11 | AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 12 | AM_MAINTAINER_MODE([enable]) |
| | 13 | |
| | 14 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 15 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 16 | |
| | 17 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| | 18 | |
| | 19 | # Checks for C compiler |
| | 20 | AC_USE_SYSTEM_EXTENSIONS |
| | 21 | AC_SYS_LARGEFILE |
| | 22 | AC_PROG_CC |
| | 23 | AC_PROG_CC_STDC |
| | 24 | |
| | 25 | # Checks for programs. |
| | 26 | AC_PROG_GREP |
| | 27 | AC_PROG_MAKE_SET |
| | 28 | AC_PROG_SED |
| | 29 | AC_PATH_PROG([report_fold], [fold]) |
| | 30 | LT_INIT |
| | 31 | |
| | 32 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 33 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 34 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 35 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 36 | ) |
| | 37 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 38 | |
| | 39 | # check for pgrep |
| | 40 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 41 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 42 | |
| | 43 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 44 | # is not distributed in tarballs |
| | 45 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 46 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 47 | |
| | 48 | # check for bison |
| | 49 | AC_PROG_YACC |
| | 50 | BISON=$YACC |
| | 51 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 52 | |
| | 53 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 54 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 55 | AC_MSG_FAILURE([ |
| | 56 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 57 | set the YACC variable to override automatic detection. |
| | 58 | ]) |
| | 59 | ], [ |
| | 60 | AC_MSG_WARN([ |
| | 61 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 62 | this distribution tarball, so Bison is only needed if you intend to |
| | 63 | modify their sources. You can set the YACC variable to override automatic |
| | 64 | detection. |
| | 65 | ]) |
| | 66 | ]) |
| | 67 | ]) |
| | 68 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 69 | |
| | 70 | # check for flex |
| | 71 | AC_PROG_LEX |
| | 72 | FLEX=$LEX |
| | 73 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 74 | |
| | 75 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 76 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 77 | AC_MSG_FAILURE([ |
| | 78 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 79 | set the LEX variable to override automatic detection. |
| | 80 | ]) |
| | 81 | ], [ |
| | 82 | AC_MSG_WARN([ |
| | 83 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 84 | this distribution tarball, so Flex is only needed if you intend to |
| | 85 | modify their sources. You can set the LEX variable to override automatic |
| | 86 | detection. |
| | 87 | ]) |
| | 88 | ]) |
| | 89 | ]) |
| | 90 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 91 | |
| | 92 | |
| | 93 | # Checks for typedefs, structures, and compiler characteristics. |
| | 94 | AC_C_INLINE |
| | 95 | AC_TYPE_INT32_T |
| | 96 | AC_TYPE_INT64_T |
| | 97 | AC_TYPE_MODE_T |
| | 98 | AC_TYPE_OFF_T |
| | 99 | AC_TYPE_PID_T |
| | 100 | AC_TYPE_SIZE_T |
| | 101 | AC_TYPE_SSIZE_T |
| | 102 | AC_TYPE_UID_T |
| | 103 | AC_TYPE_UINT16_T |
| | 104 | AC_TYPE_UINT32_T |
| | 105 | AC_TYPE_UINT64_T |
| | 106 | AC_TYPE_UINT8_T |
| | 107 | |
| | 108 | AX_C___ATTRIBUTE__ |
| | 109 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| | 110 | [:], |
| | 111 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 112 | |
| | 113 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| | 114 | |
| | 115 | AX_LIB_SOCKET_NSL |
| | 116 | |
| | 117 | LT_NO_UNDEFINED="" |
| | 118 | AS_CASE([$host_os], |
| | 119 | [cygwin*], |
| | 120 | [ |
| | 121 | LT_NO_UNDEFINED="-no-undefined" |
| | 122 | ], |
| | 123 | [cygwin*|darwin*|mingw*|solaris*], |
| | 124 | [ |
| | 125 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 126 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 127 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 128 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 129 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 130 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 131 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 132 | ] |
| | 133 | ) |
| | 134 | |
| | 135 | AC_SUBST(LT_NO_UNDEFINED) |
| | 136 | |
| | 137 | # Compute minor/major/patchlevel version numbers |
| | 138 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 139 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 140 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 141 | |
| | 142 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 143 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 144 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 145 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 146 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 147 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 148 | |
| | 149 | version_name="Codename TBD" |
| | 150 | version_description='Description TBD' |
| | 151 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 152 | |
| | 153 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 154 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 155 | |
| | 156 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 157 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 158 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 159 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 160 | libtool_fixup=$enableval, |
| | 161 | libtool_fixup=yes) |
| | 162 | |
| | 163 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 164 | [ |
| | 165 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 166 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 167 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 168 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 169 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 170 | [ |
| | 171 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 172 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 173 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 174 | ], |
| | 175 | [ |
| | 176 | AC_MSG_RESULT([none]) |
| | 177 | ]) |
| | 178 | ]) |
| | 179 | |
| | 180 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 181 | |
| | 182 | AC_CHECK_HEADERS([ \ |
| | 183 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 184 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 185 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 186 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 187 | sys/mount.h sys/param.h sys/time.h |
| | 188 | ]) |
| | 189 | |
| | 190 | # Basic functions check |
| | 191 | AC_CHECK_FUNCS([ \ |
| | 192 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 193 | gethostbyname gethostname getpagesize localtime_r memchr memset \ |
| | 194 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 195 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 196 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 197 | sched_getcpu sysconf sync_file_range |
| | 198 | ]) |
| | 199 | |
| | 200 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 201 | # add -lrt to LIBS |
| | 202 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 203 | |
| | 204 | # Checks for dl. |
| | 205 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 206 | have_libdl=yes |
| | 207 | libdl_name=dl |
| | 208 | ], [ |
| | 209 | # libdl not found, check for dlopen in libc. |
| | 210 | AC_CHECK_LIB([c], [dlopen], [ |
| | 211 | have_libc_dl=yes |
| | 212 | libdl_name=c |
| | 213 | ], [ |
| | 214 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 215 | ]) |
| | 216 | ]) |
| | 217 | |
| | 218 | # Check if libdl has dlmopen support. |
| | 219 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 220 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 221 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 222 | HAVE_DLMOPEN=1 |
| | 223 | ], [ |
| | 224 | HAVE_DLMOPEN=0 |
| | 225 | ]) |
| | 226 | AC_SUBST(HAVE_DLMOPEN) |
| | 227 | |
| | 228 | # Babeltrace viewer check |
| | 229 | AC_ARG_WITH([babeltrace-bin], |
| | 230 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 231 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 232 | [BABELTRACE_BIN="$withval"], |
| | 233 | [BABELTRACE_BIN='']) |
| | 234 | AC_SUBST([BABELTRACE_BIN]) |
| | 235 | |
| | 236 | # lttv-gui |
| | 237 | AC_ARG_WITH([lttv-gui-bin], |
| | 238 | AS_HELP_STRING([--with-lttv-gui-bin], |
| | 239 | [Location of the lttv GUI viewer executable (including the filename)]), |
| | 240 | [LTTV_GUI_BIN="$withval"], |
| | 241 | [LTTV_GUI_BIN='']) |
| | 242 | AC_SUBST([LTTV_GUI_BIN]) |
| | 243 | |
| | 244 | AC_ARG_WITH([consumerd32-bin], |
| | 245 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 246 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 247 | [CONSUMERD32_BIN="$withval"], |
| | 248 | [CONSUMERD32_BIN='']) |
| | 249 | AC_SUBST([CONSUMERD32_BIN]) |
| | 250 | |
| | 251 | AC_ARG_WITH([consumerd64-bin], |
| | 252 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 253 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 254 | [CONSUMERD64_BIN="$withval"], |
| | 255 | [CONSUMERD64_BIN='']) |
| | 256 | AC_SUBST([CONSUMERD64_BIN]) |
| | 257 | |
| | 258 | AC_ARG_WITH([consumerd32-libdir], |
| | 259 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 260 | [Directory containing the 32-bit consumerd libraries]), |
| | 261 | [CONSUMERD32_LIBDIR="$withval"], |
| | 262 | [CONSUMERD32_LIBDIR='']) |
| | 263 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 264 | |
| | 265 | AC_ARG_WITH([consumerd64-libdir], |
| | 266 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 267 | [Directory containing the 64-bit consumerd libraries]), |
| | 268 | [CONSUMERD64_LIBDIR="$withval"], |
| | 269 | [CONSUMERD64_LIBDIR='']) |
| | 270 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 271 | |
| | 272 | AC_ARG_WITH([sessiond-bin], |
| | 273 | AS_HELP_STRING([--with-sessiond-bin], |
| | 274 | [Location of the sessiond executable (including the filename)]), |
| | 275 | [SESSIOND_BIN="$withval"], |
| | 276 | [SESSIOND_BIN='']) |
| | 277 | AC_SUBST([SESSIOND_BIN]) |
| | 278 | |
| | 279 | AC_ARG_WITH([lttng-system-rundir], |
| | 280 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 281 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 282 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 283 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 284 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 285 | |
| | 286 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 287 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 288 | [test_java_agent_jul=$enableval], |
| | 289 | [test_java_agent_jul=no] |
| | 290 | ) |
| | 291 | |
| | 292 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 293 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| | 294 | [test_java_agent_log4j=$enableval], |
| | 295 | [test_java_agent_log4j=no] |
| | 296 | ) |
| | 297 | |
| | 298 | AC_ARG_ENABLE([test-java-agent-all], |
| | 299 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 300 | [test_java_agent_jul=$enableval |
| | 301 | test_java_agent_log4j=$enableval], |
| | 302 | [:] |
| | 303 | ) |
| | 304 | |
| | 305 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 306 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 307 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 308 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 309 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 310 | AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.]) |
| | 311 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 312 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 313 | |
| | 314 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 315 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 316 | $1="$2" |
| | 317 | AC_SUBST([$1]) |
| | 318 | ]) |
| | 319 | |
| | 320 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 321 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 322 | $1="$2" |
| | 323 | AC_SUBST([$1]) |
| | 324 | ]) |
| | 325 | |
| | 326 | # Default values |
| | 327 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 328 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 329 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 330 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 331 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 332 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 333 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 334 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 335 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 336 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 337 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 338 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 339 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 340 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 341 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 342 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 343 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 344 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 345 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 346 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 347 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 348 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 349 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 350 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 351 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 352 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 353 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 354 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 355 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 356 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 357 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 358 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 359 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 360 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 361 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 362 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 363 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 364 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 365 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 366 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 367 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 368 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 369 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 370 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 371 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 372 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 373 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 374 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 375 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_RELAY_TIMER], [200000]) |
| | 376 | |
| | 377 | # Command short descriptions |
| | 378 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel]) |
| | 379 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session]) |
| | 380 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions]) |
| | 381 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels]) |
| | 382 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules]) |
| | 383 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 384 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels]) |
| | 385 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules]) |
| | 386 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 387 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command]) |
| | 388 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events]) |
| | 389 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations]) |
| | 390 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration]) |
| | 391 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk]) |
| | 392 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations]) |
| | 393 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session]) |
| | 394 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session]) |
| | 395 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing]) |
| | 396 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session]) |
| | 397 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing]) |
| | 398 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources]) |
| | 399 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources]) |
| | 400 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information]) |
| | 401 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer]) |
| | 402 | |
| | 403 | if test "x$prefix" = "xNONE"; then |
| | 404 | prefix=$ac_default_prefix |
| | 405 | fi |
| | 406 | CONFDIR=`eval echo $sysconfdir` |
| | 407 | AC_SUBST(CONFDIR) |
| | 408 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 409 | |
| | 410 | AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.]) |
| | 411 | |
| | 412 | # Check libpopt |
| | 413 | PKG_CHECK_MODULES([POPT], [popt], |
| | 414 | [ |
| | 415 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 416 | ], |
| | 417 | [ |
| | 418 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 419 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 420 | AC_CHECK_LIB([popt], |
| | 421 | [poptGetContext], |
| | 422 | [POPT_LIBS="-lpopt"], |
| | 423 | [ |
| | 424 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 425 | ] |
| | 426 | ) |
| | 427 | ] |
| | 428 | ) |
| | 429 | AC_SUBST(POPT_LIBS) |
| | 430 | |
| | 431 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 432 | |
| | 433 | # First, check for uuid in system libs |
| | 434 | AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support]) |
| | 435 | AC_CHECK_FUNCS([uuid_generate], |
| | 436 | [ |
| | 437 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 438 | UUID_LIBS="" |
| | 439 | ], |
| | 440 | [ |
| | 441 | # Then, check if the pkg-config module is available, otherwise explicitly check |
| | 442 | # for libuuid, or uuid support in the C-library. |
| | 443 | PKG_CHECK_MODULES([UUID], [uuid], |
| | 444 | [ |
| | 445 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 446 | dnl PKG_CHECK_MODULES defines UUID_LIBS |
| | 447 | ], |
| | 448 | [ |
| | 449 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 450 | AC_MSG_WARN([Finding libuuid without pkg-config.]) |
| | 451 | AC_CHECK_LIB([uuid], [uuid_generate], |
| | 452 | [ |
| | 453 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 454 | UUID_LIBS="-luuid" |
| | 455 | ], |
| | 456 | [ |
| | 457 | # libuuid not found, check for uuid_create in libc. |
| | 458 | AC_CHECK_LIB([c], [uuid_create], |
| | 459 | [ |
| | 460 | AC_DEFINE([LTTNG_HAVE_LIBUUID], [1]) |
| | 461 | UUID_LIBS="-lc" |
| | 462 | ], |
| | 463 | [ |
| | 464 | AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 465 | ] |
| | 466 | ) |
| | 467 | ] |
| | 468 | ) |
| | 469 | ] |
| | 470 | ) |
| | 471 | ] |
| | 472 | ) |
| | 473 | AC_SUBST(UUID_LIBS) |
| | 474 | |
| | 475 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 476 | |
| | 477 | # URCU library version needed or newer |
| | 478 | m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed]) |
| | 479 | |
| | 480 | # Check liburcu needed function calls |
| | 481 | AC_CHECK_DECL([cds_list_add], [], |
| | 482 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]]) |
| | 483 | AC_CHECK_DECL([cds_wfcq_init], [], |
| | 484 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 485 | AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [], |
| | 486 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| | 487 | AC_CHECK_DECL([futex_async], [], |
| | 488 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]]) |
| | 489 | AC_CHECK_DECL([rcu_thread_offline], [], |
| | 490 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 491 | AC_CHECK_DECL([rcu_thread_online], [], |
| | 492 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 493 | AC_CHECK_DECL([caa_likely], [], |
| | 494 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| | 495 | AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], |
| | 496 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])]) |
| | 497 | |
| | 498 | #Function added in urcu 0.7.0 |
| | 499 | AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [], |
| | 500 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]] |
| | 501 | ) |
| | 502 | |
| | 503 | #Function added in urcu 0.9.0 |
| | 504 | AC_CHECK_DECL([urcu_ref_get_unless_zero], [], |
| | 505 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]] |
| | 506 | ) |
| | 507 | |
| | 508 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 509 | # it can be explicitly disabled with --without-kmod |
| | 510 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 511 | AC_ARG_WITH([kmod], |
| | 512 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 513 | [], |
| | 514 | [with_kmod=check] |
| | 515 | ) |
| | 516 | |
| | 517 | AS_IF([test "x$with_kmod" != "xno"], |
| | 518 | [ |
| | 519 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 520 | [ |
| | 521 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 522 | KMOD_LIBS="-lkmod" |
| | 523 | ], |
| | 524 | [ |
| | 525 | if test "x$with_kmod" != xcheck; then |
| | 526 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 527 | else |
| | 528 | with_kmod=no |
| | 529 | fi |
| | 530 | ] |
| | 531 | ) |
| | 532 | ] |
| | 533 | ) |
| | 534 | AC_SUBST(KMOD_LIBS) |
| | 535 | |
| | 536 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 537 | # it can be explicitly disabled with --without-lttng-ust |
| | 538 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 539 | AC_ARG_WITH([lttng-ust], |
| | 540 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 541 | [], |
| | 542 | [with_lttng_ust=yes] |
| | 543 | ) |
| | 544 | |
| | 545 | AS_IF([test "x$with_lttng_ust" = "xyes"], |
| | 546 | [ |
| | 547 | AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer], |
| | 548 | [ |
| | 549 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 550 | ], |
| | 551 | [ |
| | 552 | AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.]) |
| | 553 | ], |
| | 554 | [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl] |
| | 555 | ) |
| | 556 | ] |
| | 557 | ) |
| | 558 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 559 | |
| | 560 | |
| | 561 | |
| | 562 | # check for dlopen |
| | 563 | AC_CHECK_LIB([dl], [dlopen], |
| | 564 | [DL_LIBS="-ldl"], |
| | 565 | [ |
| | 566 | #libdl not found, check for dlopen in libc. |
| | 567 | AC_CHECK_LIB([c], [dlopen], |
| | 568 | [DL_LIBS="-lc"], |
| | 569 | [AC_MSG_FAILURE([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])] |
| | 570 | ) |
| | 571 | ] |
| | 572 | ) |
| | 573 | AC_SUBST(DL_LIBS) |
| | 574 | |
| | 575 | # Check for fmemopen |
| | 576 | AC_CHECK_LIB([c], [fmemopen], |
| | 577 | [ |
| | 578 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 579 | ] |
| | 580 | ) |
| | 581 | |
| | 582 | # check for libpfm |
| | 583 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 584 | [ |
| | 585 | have_libpfm=yes |
| | 586 | ]) |
| | 587 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 588 | |
| | 589 | # For Python |
| | 590 | # SWIG version needed or newer: |
| | 591 | swig_version=2.0.0 |
| | 592 | |
| | 593 | AC_ARG_ENABLE([python-bindings], |
| | 594 | [AC_HELP_STRING([--enable-python-bindings], |
| | 595 | [compile Python bindings])], |
| | 596 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 597 | |
| | 598 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 599 | |
| | 600 | if test "x$enable_python_binding" = xyes; then |
| | 601 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 602 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 603 | AM_PATH_PYTHON([3.0]) |
| | 604 | |
| | 605 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 606 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 607 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 608 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 609 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 610 | [python$PYTHON_VERSION-config python-config], |
| | 611 | [no], |
| | 612 | [`dirname $PYTHON`]) |
| | 613 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 614 | ]) |
| | 615 | AC_MSG_CHECKING([python include flags]) |
| | 616 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 617 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 618 | ]) |
| | 619 | |
| | 620 | else |
| | 621 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 622 | [if you want Python bindings.]) |
| | 623 | |
| | 624 | fi |
| | 625 | |
| | 626 | # Epoll check. If not present, the build will fallback on poll() API |
| | 627 | AX_HAVE_EPOLL( |
| | 628 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 629 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 630 | ) |
| | 631 | AX_CONFIG_FEATURE( |
| | 632 | [epoll], [This platform supports epoll(7)], |
| | 633 | [HAVE_EPOLL], [This platform supports epoll(7).], |
| | 634 | [enable_epoll="yes"], [enable_epoll="no"] |
| | 635 | ) |
| | 636 | AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ]) |
| | 637 | |
| | 638 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 639 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 640 | |
| | 641 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| | 642 | AX_JAVA_OPTIONS |
| | 643 | AX_PROG_JAVAC |
| | 644 | AX_PROG_JAVA |
| | 645 | AX_PROG_JAR |
| | 646 | |
| | 647 | AX_CHECK_CLASSPATH |
| | 648 | |
| | 649 | # Check for Java UST agent common class first |
| | 650 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 651 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 652 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 653 | fi |
| | 654 | |
| | 655 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 656 | # Check for JUL agent class |
| | 657 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 658 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 659 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 660 | fi |
| | 661 | fi |
| | 662 | |
| | 663 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 664 | # Check for Log4j agent class |
| | 665 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 666 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 667 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 668 | fi |
| | 669 | |
| | 670 | # Check for Log4j class |
| | 671 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 672 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 673 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 674 | fi |
| | 675 | fi |
| | 676 | fi |
| | 677 | |
| | 678 | # enable building man pages (user's intention) |
| | 679 | AC_ARG_ENABLE( |
| | 680 | man-pages, |
| | 681 | AS_HELP_STRING( |
| | 682 | [--disable-man-pages], |
| | 683 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 684 | ), |
| | 685 | [man_pages_opt=$enableval], |
| | 686 | [man_pages_opt=yes] |
| | 687 | ) |
| | 688 | |
| | 689 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 690 | have_asciidoc_xmlto=no |
| | 691 | warn_prebuilt_man_pages=no |
| | 692 | |
| | 693 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 694 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 695 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 696 | |
| | 697 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 698 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 699 | # this is an error because we're in the Git repo, which |
| | 700 | # means the man pages are not already generated for us, |
| | 701 | # thus asciidoc/xmlto are required because we were asked |
| | 702 | # to build the man pages |
| | 703 | AC_MSG_ERROR([ |
| | 704 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 705 | --disable-man-pages to disable building the man pages, in which case |
| | 706 | they will not be installed. |
| | 707 | ]) |
| | 708 | ], [ |
| | 709 | # only warn here: since we're in the tarball, the man |
| | 710 | # pages should already be generated at this point, thus |
| | 711 | # asciidoc/xmlto are not strictly required |
| | 712 | warn_prebuilt_man_pages=yes |
| | 713 | ]) |
| | 714 | ], [ |
| | 715 | have_asciidoc_xmlto=yes |
| | 716 | ]) |
| | 717 | ]) |
| | 718 | |
| | 719 | # export man page build condition: build the man pages if the user |
| | 720 | # asked for it, and if the tools are available |
| | 721 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 722 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 723 | |
| | 724 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 725 | |
| | 726 | # embedded --help message |
| | 727 | AC_ARG_ENABLE( |
| | 728 | [embedded-help], |
| | 729 | AS_HELP_STRING( |
| | 730 | [--enable-embedded-help], |
| | 731 | [Embed the --help messages in the executable files] |
| | 732 | ), |
| | 733 | [embedded_help=$enableval], |
| | 734 | [embedded_help=no] |
| | 735 | ) |
| | 736 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 737 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 738 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 739 | ]) |
| | 740 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 741 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 742 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 743 | ]) |
| | 744 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 745 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 746 | ]) |
| | 747 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 748 | |
| | 749 | # Python agent test |
| | 750 | UST_PYTHON_AGENT="lttngust" |
| | 751 | |
| | 752 | AC_ARG_ENABLE(test-python2-agent, |
| | 753 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 754 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 755 | ),[:],[test_python2_agent_autodetect=yes] |
| | 756 | ) |
| | 757 | |
| | 758 | AC_ARG_ENABLE(test-python3-agent, |
| | 759 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 760 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 761 | ),[:],[test_python3_agent_autodetect=yes] |
| | 762 | ) |
| | 763 | |
| | 764 | AC_ARG_ENABLE(test-python-agent-all, |
| | 765 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 766 | [enable test for all python{2/3} agent.] |
| | 767 | ), |
| | 768 | ) |
| | 769 | |
| | 770 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 771 | unset test_python2_agent_autodetect |
| | 772 | unset test_python3_agent_autodetect |
| | 773 | ]) |
| | 774 | |
| | 775 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 776 | enable_test_python2_agent=yes |
| | 777 | enable_test_python3_agent=yes |
| | 778 | ]) |
| | 779 | |
| | 780 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 781 | enable_test_python2_agent=no |
| | 782 | enable_test_python3_agent=no |
| | 783 | ]) |
| | 784 | |
| | 785 | |
| | 786 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 787 | AS_IF([test -z "$PYTHON2"], [ |
| | 788 | PYTHON2=python2 |
| | 789 | ], [ |
| | 790 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 791 | ]) |
| | 792 | |
| | 793 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 794 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 795 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 796 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 797 | ]) |
| | 798 | ], [ |
| | 799 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 800 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 801 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 802 | AC_MSG_RESULT([yes]) |
| | 803 | RUN_PYTHON_AGENT_TEST=yes |
| | 804 | ], [ |
| | 805 | AC_MSG_RESULT([no]) |
| | 806 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 807 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 808 | ]) |
| | 809 | ]) |
| | 810 | |
| | 811 | ]) |
| | 812 | |
| | 813 | ]) |
| | 814 | |
| | 815 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 816 | AS_IF([test -z "$PYTHON3"], [ |
| | 817 | PYTHON3=python3 |
| | 818 | ], [ |
| | 819 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 820 | ]) |
| | 821 | |
| | 822 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 823 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 824 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 825 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 826 | ]) |
| | 827 | ], [ |
| | 828 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 829 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 830 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 831 | AC_MSG_RESULT([yes]) |
| | 832 | RUN_PYTHON_AGENT_TEST=yes |
| | 833 | ], [ |
| | 834 | AC_MSG_RESULT([no]) |
| | 835 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 836 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 837 | ]) |
| | 838 | ]) |
| | 839 | |
| | 840 | ]) |
| | 841 | ]) |
| | 842 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 843 | AC_SUBST([PYTHON2_AGENT]) |
| | 844 | AC_SUBST([PYTHON3_AGENT]) |
| | 845 | |
| | 846 | # Arguments for binaries build exclusion |
| | 847 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 848 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 849 | [Disable the build of lttng-consumerd binaries])) |
| | 850 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 851 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 852 | [Disable the build of lttng-relayd binaries])) |
| | 853 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 854 | [Disable the build of lttng-sessiond binaries])) |
| | 855 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 856 | [Disable the build of the extra components])) |
| | 857 | |
| | 858 | |
| | 859 | # Always build libconfig since it a dependency of libcommon |
| | 860 | build_lib_config=yes |
| | 861 | |
| | 862 | build_lib_compat=no |
| | 863 | build_lib_consumer=no |
| | 864 | build_lib_hashtable=no |
| | 865 | build_lib_health=no |
| | 866 | build_lib_index=no |
| | 867 | build_lib_kernel_consumer=no |
| | 868 | build_lib_kernel_ctl=no |
| | 869 | build_lib_lttng_ctl=no |
| | 870 | build_lib_relayd=no |
| | 871 | build_lib_sessiond_comm=no |
| | 872 | build_lib_testpoint=no |
| | 873 | build_lib_ust_consumer=no |
| | 874 | |
| | 875 | # There is an overlap for enabled dependencies, but this makes everything |
| | 876 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 877 | # here. |
| | 878 | |
| | 879 | # Enable binary dependencies. |
| | 880 | AS_IF([test x$enable_bin_lttng != xno], |
| | 881 | [ |
| | 882 | build_lib_lttng_ctl=yes |
| | 883 | ] |
| | 884 | ) |
| | 885 | |
| | 886 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 887 | [ |
| | 888 | build_lib_consumer=yes |
| | 889 | build_lib_sessiond_comm=yes |
| | 890 | build_lib_index=yes |
| | 891 | build_lib_health=yes |
| | 892 | build_lib_testpoint=yes |
| | 893 | ] |
| | 894 | ) |
| | 895 | |
| | 896 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 897 | # Do nothing since libconfig and libcommon are built by default. |
| | 898 | [] |
| | 899 | ) |
| | 900 | |
| | 901 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 902 | [ |
| | 903 | build_lib_lttng_ctl=yes |
| | 904 | build_lib_sessiond_comm=yes |
| | 905 | build_lib_hashtable=yes |
| | 906 | build_lib_compat=yes |
| | 907 | build_lib_index=yes |
| | 908 | build_lib_health=yes |
| | 909 | build_lib_testpoint=yes |
| | 910 | ] |
| | 911 | ) |
| | 912 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 913 | [ |
| | 914 | build_lib_lttng_ctl=yes |
| | 915 | build_lib_sessiond_comm=yes |
| | 916 | build_lib_kernel_ctl=yes |
| | 917 | build_lib_hashtable=yes |
| | 918 | build_lib_compat=yes |
| | 919 | build_lib_relayd=yes |
| | 920 | build_lib_testpoint=yes |
| | 921 | build_lib_health=yes |
| | 922 | build_lib_health=yes |
| | 923 | ] |
| | 924 | ) |
| | 925 | |
| | 926 | # Libraries dependencies enabling |
| | 927 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 928 | [ |
| | 929 | build_lib_sessiond_comm=yes |
| | 930 | build_lib_hashtable=yes |
| | 931 | ] |
| | 932 | ) |
| | 933 | |
| | 934 | AS_IF([test x$build_lib_consumer = xyes], |
| | 935 | [ |
| | 936 | build_lib_sessiond_comm=yes |
| | 937 | build_lib_kernel_consumer=yes |
| | 938 | build_lib_hashtable=yes |
| | 939 | build_lib_compat=yes |
| | 940 | build_lib_relayd=yes |
| | 941 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 942 | ] |
| | 943 | ) |
| | 944 | |
| | 945 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 946 | [ |
| | 947 | build_lib_kernel_ctl=yes |
| | 948 | build_lib_relayd=yes |
| | 949 | ] |
| | 950 | ) |
| | 951 | |
| | 952 | AS_IF([test x$build_lib_relayd = xyes], |
| | 953 | [ |
| | 954 | build_lib_sessiond_comm=yes |
| | 955 | ] |
| | 956 | ) |
| | 957 | |
| | 958 | # Find arch type |
| | 959 | AS_CASE([$host_cpu], |
| | 960 | [k1om], [ARCHTYPE="x86"], |
| | 961 | [i386], [ARCHTYPE="x86"], |
| | 962 | [i486], [ARCHTYPE="x86"], |
| | 963 | [i586], [ARCHTYPE="x86"], |
| | 964 | [i686], [ARCHTYPE="x86"], |
| | 965 | [amd64], [ARCHTYPE="x86"], |
| | 966 | [x86_64], [ARCHTYPE="x86"], |
| | 967 | [powerpc], [ARCHTYPE="ppc"], |
| | 968 | [ppc64], [ARCHTYPE="ppc"], |
| | 969 | [powerpc64], [ARCHTYPE="ppc"], |
| | 970 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 971 | [ppc], [ARCHTYPE="ppc"], |
| | 972 | [s390], [ARCHTYPE="s390"], |
| | 973 | [s390x], [ARCHTYPE="s390"], |
| | 974 | [sparc], [ARCHTYPE="sparc64"], |
| | 975 | [sparc64], [ARCHTYPE="sparc64"], |
| | 976 | [alpha*], [ARCHTYPE="alpha"], |
| | 977 | [ia64], [ARCHTYPE="ia64"], |
| | 978 | [arm*], [ARCHTYPE="arm"], |
| | 979 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 980 | [mips*], [ARCHTYPE="mips"], |
| | 981 | [nios2*], [ARCHTYPE="nios2"], |
| | 982 | [tile*], [ARCHTYPE="tile"], |
| | 983 | [hppa*], [ARCHTYPE="hppa"], |
| | 984 | [m68k], [ARCHTYPE="m68k"], |
| | 985 | [riscv*], [ARCHTYPE="riscv"], |
| | 986 | [ARCHTYPE="unknown"] |
| | 987 | ) |
| | 988 | |
| | 989 | AC_SUBST(ARCHTYPE) |
| | 990 | |
| | 991 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 992 | AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel]) |
| | 993 | AS_IF([test "x$ARCHTYPE" = "xx86"],[ |
| | 994 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 995 | AC_MSG_RESULT([yes]) |
| | 996 | have_modules_userspace_callstack_context=yes |
| | 997 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 998 | ], [ |
| | 999 | AC_MSG_RESULT([no]) |
| | 1000 | have_modules_userspace_callstack_context=no |
| | 1001 | ]) |
| | 1002 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno]) |
| | 1003 | |
| | 1004 | # Export binaries build conditions. |
| | 1005 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1006 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1007 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1008 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1009 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1010 | |
| | 1011 | # Export the tests and extras build conditions. |
| | 1012 | AS_IF([\ |
| | 1013 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1014 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1015 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1016 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1017 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1018 | [build_tests=yes], |
| | 1019 | [build_tests=no] |
| | 1020 | ) |
| | 1021 | |
| | 1022 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1023 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1024 | |
| | 1025 | # Export libraries build conditions. |
| | 1026 | AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes]) |
| | 1027 | AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes]) |
| | 1028 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1029 | AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes]) |
| | 1030 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1031 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1032 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1033 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1034 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1035 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1036 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1037 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1038 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1039 | |
| | 1040 | AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS" |
| | 1041 | AC_SUBST(AM_CFLAGS) |
| | 1042 | |
| | 1043 | AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1044 | AC_SUBST(AM_CPPFLAGS) |
| | 1045 | |
| | 1046 | lttngincludedir="${includedir}/lttng" |
| | 1047 | AC_SUBST(lttngincludedir) |
| | 1048 | |
| | 1049 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1050 | AC_SUBST(lttngactionincludedir) |
| | 1051 | |
| | 1052 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1053 | AC_SUBST(lttngconditionincludedir) |
| | 1054 | |
| | 1055 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1056 | AC_SUBST(lttngnotificationincludedir) |
| | 1057 | |
| | 1058 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1059 | AC_SUBST(lttngtriggerincludedir) |
| | 1060 | |
| | 1061 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1062 | AC_SUBST(lttnglibexecdir) |
| | 1063 | |
| | 1064 | AC_CONFIG_FILES([ |
| | 1065 | Makefile |
| | 1066 | doc/Makefile |
| | 1067 | doc/man/Makefile |
| | 1068 | doc/man/asciidoc-attrs.conf |
| | 1069 | include/Makefile |
| | 1070 | extras/Makefile |
| | 1071 | extras/bindings/Makefile |
| | 1072 | extras/bindings/swig/Makefile |
| | 1073 | extras/bindings/swig/python/Makefile |
| | 1074 | extras/core-handler/Makefile |
| | 1075 | src/Makefile |
| | 1076 | src/common/Makefile |
| | 1077 | src/common/kernel-ctl/Makefile |
| | 1078 | src/common/kernel-consumer/Makefile |
| | 1079 | src/common/consumer/Makefile |
| | 1080 | src/common/ust-consumer/Makefile |
| | 1081 | src/common/hashtable/Makefile |
| | 1082 | src/common/sessiond-comm/Makefile |
| | 1083 | src/common/compat/Makefile |
| | 1084 | src/common/relayd/Makefile |
| | 1085 | src/common/testpoint/Makefile |
| | 1086 | src/common/index/Makefile |
| | 1087 | src/common/health/Makefile |
| | 1088 | src/common/config/Makefile |
| | 1089 | src/common/string-utils/Makefile |
| | 1090 | src/lib/Makefile |
| | 1091 | src/lib/lttng-ctl/Makefile |
| | 1092 | src/lib/lttng-ctl/filter/Makefile |
| | 1093 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1094 | src/bin/Makefile |
| | 1095 | src/bin/lttng-consumerd/Makefile |
| | 1096 | src/bin/lttng-sessiond/Makefile |
| | 1097 | src/bin/lttng-relayd/Makefile |
| | 1098 | src/bin/lttng/Makefile |
| | 1099 | src/bin/lttng-crash/Makefile |
| | 1100 | tests/Makefile |
| | 1101 | tests/destructive/Makefile |
| | 1102 | tests/regression/Makefile |
| | 1103 | tests/regression/kernel/Makefile |
| | 1104 | tests/regression/tools/Makefile |
| | 1105 | tests/regression/tools/streaming/Makefile |
| | 1106 | tests/regression/tools/filtering/Makefile |
| | 1107 | tests/regression/tools/health/Makefile |
| | 1108 | tests/regression/tools/tracefile-limits/Makefile |
| | 1109 | tests/regression/tools/snapshots/Makefile |
| | 1110 | tests/regression/tools/live/Makefile |
| | 1111 | tests/regression/tools/exclusion/Makefile |
| | 1112 | tests/regression/tools/save-load/Makefile |
| | 1113 | tests/regression/tools/save-load/configuration/Makefile |
| | 1114 | tests/regression/tools/mi/Makefile |
| | 1115 | tests/regression/tools/wildcard/Makefile |
| | 1116 | tests/regression/tools/crash/Makefile |
| | 1117 | tests/regression/tools/regen-metadata/Makefile |
| | 1118 | tests/regression/tools/regen-statedump/Makefile |
| | 1119 | tests/regression/tools/notification/Makefile |
| | 1120 | tests/regression/tools/rotation/Makefile |
| | 1121 | tests/regression/ust/Makefile |
| | 1122 | tests/regression/ust/nprocesses/Makefile |
| | 1123 | tests/regression/ust/high-throughput/Makefile |
| | 1124 | tests/regression/ust/low-throughput/Makefile |
| | 1125 | tests/regression/ust/before-after/Makefile |
| | 1126 | tests/regression/ust/buffers-pid/Makefile |
| | 1127 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1128 | tests/regression/ust/multi-session/Makefile |
| | 1129 | tests/regression/ust/multi-lib/Makefile |
| | 1130 | tests/regression/ust/overlap/Makefile |
| | 1131 | tests/regression/ust/overlap/demo/Makefile |
| | 1132 | tests/regression/ust/linking/Makefile |
| | 1133 | tests/regression/ust/daemon/Makefile |
| | 1134 | tests/regression/ust/exit-fast/Makefile |
| | 1135 | tests/regression/ust/fork/Makefile |
| | 1136 | tests/regression/ust/libc-wrapper/Makefile |
| | 1137 | tests/regression/ust/baddr-statedump/Makefile |
| | 1138 | tests/regression/ust/ust-dl/Makefile |
| | 1139 | tests/regression/ust/java-jul/Makefile |
| | 1140 | tests/regression/ust/java-log4j/Makefile |
| | 1141 | tests/regression/ust/python-logging/Makefile |
| | 1142 | tests/regression/ust/getcpu-override/Makefile |
| | 1143 | tests/regression/ust/clock-override/Makefile |
| | 1144 | tests/regression/ust/type-declarations/Makefile |
| | 1145 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1146 | tests/regression/ust/blocking/Makefile |
| | 1147 | tests/stress/Makefile |
| | 1148 | tests/unit/Makefile |
| | 1149 | tests/unit/ini_config/Makefile |
| | 1150 | tests/perf/Makefile |
| | 1151 | tests/utils/Makefile |
| | 1152 | tests/utils/tap/Makefile |
| | 1153 | tests/utils/testapp/Makefile |
| | 1154 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1155 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1156 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1157 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1158 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1159 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1160 | ]) |
| | 1161 | |
| | 1162 | # Inject variable into python test script. |
| | 1163 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1164 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1165 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1166 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1167 | |
| | 1168 | AC_OUTPUT |
| | 1169 | |
| | 1170 | # |
| | 1171 | # Mini-report on what will be built. |
| | 1172 | # |
| | 1173 | |
| | 1174 | PPRINT_INIT |
| | 1175 | PPRINT_SET_INDENT(1) |
| | 1176 | PPRINT_SET_TS(38) |
| | 1177 | |
| | 1178 | AS_ECHO |
| | 1179 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1180 | AS_ECHO |
| | 1181 | |
| | 1182 | AS_IF([test -n "$report_fold"], [ |
| | 1183 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1184 | ], [ |
| | 1185 | AS_ECHO("$version_description") |
| | 1186 | ]) |
| | 1187 | |
| | 1188 | AS_ECHO |
| | 1189 | PPRINT_SUBTITLE([Features]) |
| | 1190 | |
| | 1191 | # Target architecture we're building for. |
| | 1192 | target_arch=$host_cpu |
| | 1193 | [ |
| | 1194 | for f in $CFLAGS; do |
| | 1195 | if test $f = "-m32"; then |
| | 1196 | target_arch="32-bit" |
| | 1197 | elif test $f = "-m64"; then |
| | 1198 | target_arch="64-bit" |
| | 1199 | fi |
| | 1200 | done |
| | 1201 | ] |
| | 1202 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1203 | |
| | 1204 | # kmod enabled/disabled |
| | 1205 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1206 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1207 | |
| | 1208 | # LTTng-UST enabled/disabled |
| | 1209 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1210 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1211 | |
| | 1212 | AS_ECHO |
| | 1213 | PPRINT_SUBTITLE([Binaries]) |
| | 1214 | |
| | 1215 | # List binaries to be built |
| | 1216 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1217 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1218 | |
| | 1219 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1220 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1221 | |
| | 1222 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1223 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1224 | |
| | 1225 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1226 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1227 | |
| | 1228 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1229 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1230 | |
| | 1231 | # Extras |
| | 1232 | test x$enable_extras != xno && value=1 || value=0 |
| | 1233 | AS_ECHO |
| | 1234 | PPRINT_SET_INDENT(0) |
| | 1235 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1236 | PPRINT_SET_INDENT(1) |
| | 1237 | |
| | 1238 | AS_ECHO |
| | 1239 | PPRINT_SUBTITLE([Tests]) |
| | 1240 | |
| | 1241 | # Print clear message that tests won't be built |
| | 1242 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1243 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1244 | ]) |
| | 1245 | |
| | 1246 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1247 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1248 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1249 | |
| | 1250 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1251 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1252 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| | 1253 | |
| | 1254 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1255 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1256 | |
| | 1257 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1258 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1259 | |
| | 1260 | #Python binding enabled/disabled |
| | 1261 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1262 | AS_ECHO |
| | 1263 | PPRINT_SET_INDENT(0) |
| | 1264 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1265 | |
| | 1266 | # man pages build enabled/disabled |
| | 1267 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1268 | |
| | 1269 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1270 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1271 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1272 | ], [ |
| | 1273 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1274 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1275 | ], [ |
| | 1276 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1277 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1278 | $PPRINT_COLOR_SUBTITLE) |
| | 1279 | ]) |
| | 1280 | ]) |
| | 1281 | ], [ |
| | 1282 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1283 | ]) |
| | 1284 | |
| | 1285 | m4_popdef([build_man_pages_msg]) |
| | 1286 | |
| | 1287 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1288 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1289 | |
| | 1290 | PPRINT_SET_INDENT(1) |
| | 1291 | |
| | 1292 | report_bindir="`eval eval echo $bindir`" |
| | 1293 | report_libdir="`eval eval echo $libdir`" |
| | 1294 | |
| | 1295 | # Print the bindir and libdir this `make install' will install into. |
| | 1296 | AS_ECHO |
| | 1297 | PPRINT_SUBTITLE([Install directories]) |
| | 1298 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1299 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1300 | |
| | 1301 | AS_ECHO |
| | 1302 | PPRINT_SUBTITLE([Search directories]) |
| | 1303 | |
| | 1304 | # If we build the sessiond, print the paths it will use |
| | 1305 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1306 | path="$report_bindir/lttng-sessiond" |
| | 1307 | ],[ |
| | 1308 | path="$SESSIOND_BIN" |
| | 1309 | ]) |
| | 1310 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1311 | |
| | 1312 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1313 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1314 | ],[ |
| | 1315 | path="$CONSUMERD32_BIN" |
| | 1316 | ]) |
| | 1317 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1318 | |
| | 1319 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1320 | path="`eval eval echo $libdir`" |
| | 1321 | ],[ |
| | 1322 | path="$CONSUMERD32_LIBDIR" |
| | 1323 | ]) |
| | 1324 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1325 | |
| | 1326 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1327 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1328 | ],[ |
| | 1329 | path="$CONSUMERD64_BIN" |
| | 1330 | ]) |
| | 1331 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1332 | |
| | 1333 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1334 | path="`eval eval echo $libdir`" |
| | 1335 | ],[ |
| | 1336 | path="$CONSUMERD64_LIBDIR" |
| | 1337 | ]) |
| | 1338 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1339 | PPRINT_SET_INDENT(0) |
| | 1340 | |
| | 1341 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1342 | AS_ECHO |
| | 1343 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1344 | |
| | 1345 | Note that the man pages are already built in this distribution tarball, |
| | 1346 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1347 | their sources. |
| | 1348 | |
| | 1349 | Also note that the installed man pages will contain the project's |
| | 1350 | default command-line option and environment variable values. |
| | 1351 | |
| | 1352 | Use --disable-man-pages to completely disable building and installing |
| | 1353 | the man pages.]) |
| | 1354 | ]) |
projects / lttng-tools.git / blame_incremental