New win32 topics: 'symbol aliasing' and 'export dll symbols'.

[deliverable/binutils-gdb.git] / djunpack.bat

@echo off\r
Rem\r
Rem WARNING WARNING WARNING: This file needs to have DOS CRLF end-of-line\r
Rem format, or else stock DOS/Windows shells will refuse to run it.\r
Rem\r
Rem This batch file unpacks the GDB distribution while simultaneously\r
Rem renaming some of the files whose names are invalid on DOS or conflict\r
Rem with other file names after truncation to DOS 8+3 namespace.\r
Rem\r
Rem Invoke like this:\r
Rem\r
Rem     djunpack gdb-XYZ.tar\r
Rem\r
Rem where XYZ is the version number.  If the argument includes leading\r
Rem directories, it MUST use backslashes, not forward slashes.\r
Rem\r
Rem The following 2 lines need to be changed with each new GDB release, to\r
Rem be identical to the name of the top-level directory where the GDB\r
Rem distribution unpacks itself.\r
set GDBVER=gdb-5.0\r
if "%GDBVER%"=="gdb-5.0" GoTo EnvOk\r
Rem If their environment space is too small, re-exec with a larger one\r
command.com /e:4096 /c %0 %1\r
GoTo End\r
:EnvOk\r
if not exist %1 GoTo NoArchive\r
djtar -x -p -o %GDBVER%/gdb/config/djgpp/fnchange.lst %1 > fnchange.tmp\r
Rem The following uses a feature of COPY whereby it does not copy\r
Rem empty files.  We need that because the previous line will create\r
Rem an empty fnchange.tmp even if the command failed for some reason.\r
copy fnchange.tmp junk.tmp > nul\r
if not exist junk.tmp GoTo NoDjTar\r
del junk.tmp\r
sed -e 's,@V@,%GDBVER%,g' < fnchange.tmp > fnchange.lst\r
Rem See the comment above about the reason for using COPY.\r
copy fnchange.lst junk.tmp > nul\r
if not exist junk.tmp GoTo NoSed\r
del junk.tmp\r
djtar -x -n fnchange.lst %1\r
GoTo End\r
:NoSed\r
echo FAIL: Sed is not available.\r
GoTo End\r
:NoDjTar\r
echo FAIL: DJTAR is not available or no fnchange.lst file in %1.\r
GoTo End\r
:NoArchive\r
echo FAIL: the file %1 does not seem to exist.\r
echo Remember that %1 cannot use forward slashes, only backslashes.\r
GoTo End\r
:End\r
set GDBVER=\r