| 1 | %{ |
| 2 | #include <stdio.h> |
| 3 | #include "ctf-scanner.h" |
| 4 | #include "ctf-parser.h" |
| 5 | #include "ctf-ast.h" |
| 6 | |
| 7 | extern void setstring(struct ctf_scanner *scanner, YYSTYPE *lvalp, const char *src); |
| 8 | |
| 9 | #define printf_dbg(fmt, args...) fprintf(stderr, "%s: " fmt, __func__, args) |
| 10 | #define printf_dbg_noarg(fmt) fprintf(stderr, "%s: " fmt, __func__) |
| 11 | |
| 12 | %} |
| 13 | |
| 14 | %x comment_ml comment_sl string_lit char_const |
| 15 | %option reentrant yylineno noyywrap bison-bridge |
| 16 | %option extra-type="struct ctf_scanner *" |
| 17 | /* bison-locations */ |
| 18 | INTEGER_SUFFIX [ \n\t]*(U|UL|ULL|LU|LLU|Ul|Ull|lU|llU|u|uL|uLL|Lu|LLu|ul|ull|lu|llu) |
| 19 | DIGIT [0-9] |
| 20 | NONDIGIT [a-zA-Z_] |
| 21 | HEXDIGIT [0-9A-Fa-f] |
| 22 | OCTALDIGIT [0-7] |
| 23 | UCHARLOWERCASE \\u{HEXDIGIT}{4} |
| 24 | UCHARUPPERCASE \\U{HEXDIGIT}{8} |
| 25 | ID_NONDIGIT {NONDIGIT}|{UCHARLOWERCASE}|{UCHARUPPERCASE} |
| 26 | IDENTIFIER {ID_NONDIGIT}({ID_NONDIGIT}|{DIGIT})* |
| 27 | ESCSEQ \\(\'|\"|\?|\\|a|b|f|n|r|t|v|{OCTALDIGIT}{1,3}|u{HEXDIGIT}{4}|U{HEXDIGIT}{8}|x{HEXDIGIT}+) |
| 28 | %% |
| 29 | |
| 30 | /* |
| 31 | * Using start conditions to deal with comments |
| 32 | * and strings. |
| 33 | */ |
| 34 | |
| 35 | "/*" BEGIN(comment_ml); |
| 36 | <comment_ml>[^*\n]* /* eat anything that's not a '*' */ |
| 37 | <comment_ml>"*"+[^*/\n]* /* eat up '*'s not followed by '/'s */ |
| 38 | <comment_ml>\n ++yylineno; |
| 39 | <comment_ml>"*"+"/" BEGIN(INITIAL); |
| 40 | |
| 41 | "//" BEGIN(comment_sl); |
| 42 | <comment_sl>[^\n]*\n ++yylineno; BEGIN(INITIAL); |
| 43 | |
| 44 | L\' BEGIN(char_const); return CHARACTER_CONSTANT_START; |
| 45 | \' BEGIN(char_const); return CHARACTER_CONSTANT_START; |
| 46 | <char_const>\' BEGIN(INITIAL); return SQUOTE; |
| 47 | |
| 48 | L\" BEGIN(string_lit); return STRING_LITERAL_START; |
| 49 | \" BEGIN(string_lit); return STRING_LITERAL_START; |
| 50 | <string_lit>\" BEGIN(INITIAL); return DQUOTE; |
| 51 | |
| 52 | <char_const,string_lit>ESCSEQ return ESCSEQ; |
| 53 | <char_const,string_lit>\n ; /* ignore */ |
| 54 | <char_const,string_lit>. return CHAR_STRING_TOKEN; |
| 55 | |
| 56 | "[" return LSBRAC; |
| 57 | "]" return RSBRAC; |
| 58 | "(" return LPAREN; |
| 59 | ")" return RPAREN; |
| 60 | "{" return LBRAC; |
| 61 | "}" return RBRAC; |
| 62 | "->" return RARROW; |
| 63 | "*" return STAR; |
| 64 | "+" return PLUS; |
| 65 | "-" return MINUS; |
| 66 | "<" return LT; |
| 67 | ">" return GT; |
| 68 | := return TYPEASSIGN; |
| 69 | : return COLON; |
| 70 | ; return SEMICOLON; |
| 71 | "..." return DOTDOTDOT; |
| 72 | "." return DOT; |
| 73 | = return EQUAL; |
| 74 | "," return COMMA; |
| 75 | const return CONST; |
| 76 | char return CHAR; |
| 77 | double return DOUBLE; |
| 78 | enum return ENUM; |
| 79 | event return EVENT; |
| 80 | floating_point return FLOATING_POINT; |
| 81 | float return FLOAT; |
| 82 | integer return INTEGER; |
| 83 | int return INT; |
| 84 | long return LONG; |
| 85 | short return SHORT; |
| 86 | signed return SIGNED; |
| 87 | stream return STREAM; |
| 88 | string return STRING; |
| 89 | struct return STRUCT; |
| 90 | trace return TRACE; |
| 91 | typealias return TYPEALIAS; |
| 92 | typedef return TYPEDEF; |
| 93 | unsigned return UNSIGNED; |
| 94 | variant return VARIANT; |
| 95 | void return VOID; |
| 96 | _Bool return _BOOL; |
| 97 | _Complex return _COMPLEX; |
| 98 | _Imaginary return _IMAGINARY; |
| 99 | [1-9]{DIGIT}*{INTEGER_SUFFIX}? return DECIMAL_CONSTANT; |
| 100 | 0{OCTALDIGIT}*{INTEGER_SUFFIX}? return OCTAL_CONSTANT; |
| 101 | 0[xX]{HEXDIGIT}+{INTEGER_SUFFIX}? return HEXADECIMAL_CONSTANT; |
| 102 | {IDENTIFIER} printf_dbg("<IDENTIFIER %s>\n", yytext); setstring(yyextra, yylval, yytext); if (is_type(yyextra, yytext)) return ID_TYPE; else return IDENTIFIER; |
| 103 | [ \t\n]+ ; /* ignore */ |
| 104 | . return ERROR; |
| 105 | %% |