| 1 | dnl Autoconf configure script for GDB, the GNU debugger. |
| 2 | dnl Copyright (C) 1995-2020 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | m4_include(../config/debuginfod.m4) |
| 22 | |
| 23 | AC_INIT(main.c) |
| 24 | AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h]) |
| 25 | AM_MAINTAINER_MODE |
| 26 | |
| 27 | AC_PROG_CC |
| 28 | AC_PROG_CXX |
| 29 | |
| 30 | AC_USE_SYSTEM_EXTENSIONS |
| 31 | ACX_LARGEFILE |
| 32 | AM_PROG_CC_STDC |
| 33 | AM_PROG_INSTALL_STRIP |
| 34 | |
| 35 | AC_CONFIG_AUX_DIR(..) |
| 36 | AC_CANONICAL_SYSTEM |
| 37 | AC_ARG_PROGRAM |
| 38 | |
| 39 | # We require a C++11 compiler. Check if one is available, and if |
| 40 | # necessary, set CXX_DIALECT to some -std=xxx switch. |
| 41 | AX_CXX_COMPILE_STDCXX(11, , mandatory) |
| 42 | |
| 43 | # Dependency checking. |
| 44 | ZW_CREATE_DEPDIR |
| 45 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 46 | |
| 47 | dnl List of object files and targets accumulated by configure. |
| 48 | |
| 49 | CONFIG_OBS= |
| 50 | CONFIG_DEPS= |
| 51 | CONFIG_SRCS= |
| 52 | ENABLE_CFLAGS= |
| 53 | |
| 54 | CONFIG_ALL= |
| 55 | CONFIG_CLEAN= |
| 56 | CONFIG_INSTALL= |
| 57 | CONFIG_UNINSTALL= |
| 58 | |
| 59 | dnl Set up for gettext. |
| 60 | ZW_GNU_GETTEXT_SISTER_DIR |
| 61 | |
| 62 | localedir='${datadir}/locale' |
| 63 | AC_SUBST(localedir) |
| 64 | |
| 65 | if test x"$USE_NLS" = xyes; then |
| 66 | CONFIG_ALL="$CONFIG_ALL all-po" |
| 67 | CONFIG_CLEAN="$CONFIG_CLEAN clean-po" |
| 68 | CONFIG_INSTALL="$CONFIG_INSTALL install-po" |
| 69 | CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po" |
| 70 | fi |
| 71 | |
| 72 | PACKAGE=gdb |
| 73 | AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ]) |
| 74 | AC_SUBST(PACKAGE) |
| 75 | |
| 76 | # We never need to detect it in this sub-configure. |
| 77 | # But preserve it for config.status --recheck. |
| 78 | AC_ARG_VAR(MAKEINFO, |
| 79 | [Parent configure detects if it is of sufficient version.]) |
| 80 | AC_ARG_VAR(MAKEINFOFLAGS, |
| 81 | [Parameters for MAKEINFO.]) |
| 82 | |
| 83 | MAKEINFO_EXTRA_FLAGS="" |
| 84 | AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click, |
| 85 | [echo '@clicksequence{a @click{} b}' >conftest.texinfo |
| 86 | if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then |
| 87 | gdb_cv_have_makeinfo_click=yes |
| 88 | else |
| 89 | gdb_cv_have_makeinfo_click=no |
| 90 | fi]) |
| 91 | if test x"$gdb_cv_have_makeinfo_click" = xyes; then |
| 92 | MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK" |
| 93 | fi |
| 94 | AC_SUBST(MAKEINFO_EXTRA_FLAGS) |
| 95 | |
| 96 | GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir, |
| 97 | [look for global separate debug info in this path @<:@LIBDIR/debug@:>@], |
| 98 | [${libdir}/debug]) |
| 99 | |
| 100 | # We can't pass paths as command line arguments. |
| 101 | # Mingw32 tries to be clever and will convert the paths for us. |
| 102 | # For example -DBINDIR="/usr/local/bin" passed on the command line may get |
| 103 | # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin". |
| 104 | # This breaks GDB's relocatable path conversions since paths passed in |
| 105 | # config.h would not get so translated, the path prefixes no longer match. |
| 106 | AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.]) |
| 107 | |
| 108 | # GDB's datadir relocation |
| 109 | |
| 110 | GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir, |
| 111 | [look for global separate data files in this path @<:@DATADIR/gdb@:>@], |
| 112 | [${datadir}/gdb]) |
| 113 | |
| 114 | AC_ARG_WITH(relocated-sources, |
| 115 | AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]), |
| 116 | [reloc_srcdir="${withval}" |
| 117 | AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir, |
| 118 | [Relocated directory for source files. ]) |
| 119 | ]) |
| 120 | |
| 121 | AC_MSG_CHECKING([for default auto-load directory]) |
| 122 | AC_ARG_WITH(auto-load-dir, |
| 123 | AS_HELP_STRING([--with-auto-load-dir=PATH], |
| 124 | [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),, |
| 125 | [with_auto_load_dir='$debugdir:$datadir/auto-load']) |
| 126 | escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'` |
| 127 | AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir, |
| 128 | [Directories from which to load auto-loaded scripts.]) |
| 129 | AC_MSG_RESULT([$with_auto_load_dir]) |
| 130 | |
| 131 | AC_MSG_CHECKING([for default auto-load safe-path]) |
| 132 | AC_ARG_WITH(auto-load-safe-path, |
| 133 | AS_HELP_STRING([--with-auto-load-safe-path=PATH], |
| 134 | [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@]) |
| 135 | AS_HELP_STRING([--without-auto-load-safe-path], |
| 136 | [do not restrict auto-loaded files locations]), |
| 137 | [if test "$with_auto_load_safe_path" = "no"; then |
| 138 | with_auto_load_safe_path="/" |
| 139 | fi], |
| 140 | [with_auto_load_safe_path="$with_auto_load_dir"]) |
| 141 | escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'` |
| 142 | AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir, |
| 143 | [Directories safe to hold auto-loaded files.]) |
| 144 | AC_MSG_RESULT([$with_auto_load_safe_path]) |
| 145 | |
| 146 | AC_CONFIG_SUBDIRS(testsuite) |
| 147 | |
| 148 | # Check whether to support alternative target configurations |
| 149 | AC_ARG_ENABLE(targets, |
| 150 | AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]), |
| 151 | [case "${enableval}" in |
| 152 | yes | "") AC_ERROR(enable-targets option must specify target names or 'all') |
| 153 | ;; |
| 154 | no) enable_targets= ;; |
| 155 | *) enable_targets=$enableval ;; |
| 156 | esac]) |
| 157 | |
| 158 | # Check whether to enable 64-bit support on 32-bit hosts |
| 159 | AC_ARG_ENABLE(64-bit-bfd, |
| 160 | AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]), |
| 161 | [case "${enableval}" in |
| 162 | yes) want64=true ;; |
| 163 | no) want64=false ;; |
| 164 | *) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;; |
| 165 | esac],[want64=false])dnl |
| 166 | |
| 167 | # Provide defaults for some variables set by the per-host and per-target |
| 168 | # configuration. |
| 169 | gdb_host_obs=posix-hdep.o |
| 170 | |
| 171 | if test "${target}" = "${host}"; then |
| 172 | gdb_native=yes |
| 173 | else |
| 174 | gdb_native=no |
| 175 | fi |
| 176 | |
| 177 | . $srcdir/configure.host |
| 178 | |
| 179 | # Accumulate some settings from configure.tgt over all enabled targets |
| 180 | |
| 181 | TARGET_OBS= |
| 182 | all_targets= |
| 183 | HAVE_NATIVE_GCORE_TARGET= |
| 184 | |
| 185 | for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'` |
| 186 | do |
| 187 | if test "$targ_alias" = "all"; then |
| 188 | all_targets=true |
| 189 | else |
| 190 | # Canonicalize the secondary target names. |
| 191 | result=`$ac_config_sub $targ_alias 2>/dev/null` |
| 192 | if test -n "$result"; then |
| 193 | targ=$result |
| 194 | else |
| 195 | targ=$targ_alias |
| 196 | fi |
| 197 | |
| 198 | . ${srcdir}/configure.tgt |
| 199 | |
| 200 | AS_IF([test -z "${gdb_target_obs}"], |
| 201 | [AC_MSG_ERROR([configuration ${targ} is unsupported.])]) |
| 202 | |
| 203 | # Target-specific object files |
| 204 | for i in ${gdb_target_obs}; do |
| 205 | case " $TARGET_OBS " in |
| 206 | *" ${i} "*) ;; |
| 207 | *) |
| 208 | TARGET_OBS="$TARGET_OBS ${i}" |
| 209 | ;; |
| 210 | esac |
| 211 | done |
| 212 | |
| 213 | # Check whether this target needs 64-bit CORE_ADDR |
| 214 | if test x${want64} = xfalse; then |
| 215 | . ${srcdir}/../bfd/config.bfd |
| 216 | fi |
| 217 | |
| 218 | # Check whether this target is native and supports gcore. |
| 219 | if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \ |
| 220 | && $gdb_have_gcore; then |
| 221 | HAVE_NATIVE_GCORE_TARGET=1 |
| 222 | fi |
| 223 | fi |
| 224 | done |
| 225 | |
| 226 | if test x${all_targets} = xtrue; then |
| 227 | |
| 228 | # We want all 64-bit targets if we either: |
| 229 | # - run on a 64-bit host or |
| 230 | # - already require 64-bit support for some other target or |
| 231 | # - the --enable-64-bit-bfd option was supplied |
| 232 | # Otherwise we only support all 32-bit targets. |
| 233 | # |
| 234 | # NOTE: This test must be in sync with the corresponding |
| 235 | # tests in BFD! |
| 236 | |
| 237 | if test x${want64} = xfalse; then |
| 238 | AC_CHECK_SIZEOF(long) |
| 239 | if test "x${ac_cv_sizeof_long}" = "x8"; then |
| 240 | want64=true |
| 241 | fi |
| 242 | fi |
| 243 | if test x${want64} = xtrue; then |
| 244 | TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)' |
| 245 | else |
| 246 | TARGET_OBS='$(ALL_TARGET_OBS)' |
| 247 | fi |
| 248 | fi |
| 249 | |
| 250 | AC_SUBST(TARGET_OBS) |
| 251 | AC_SUBST(HAVE_NATIVE_GCORE_TARGET) |
| 252 | |
| 253 | # For other settings, only the main target counts. |
| 254 | gdb_sim= |
| 255 | gdb_osabi= |
| 256 | targ=$target; . ${srcdir}/configure.tgt |
| 257 | |
| 258 | # Fetch the default architecture and default target vector from BFD. |
| 259 | targ=$target; . $srcdir/../bfd/config.bfd |
| 260 | |
| 261 | # We only want the first architecture, so strip off the others if |
| 262 | # there is more than one. |
| 263 | targ_archs=`echo $targ_archs | sed 's/ .*//'` |
| 264 | |
| 265 | if test "x$targ_archs" != x; then |
| 266 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs, |
| 267 | [Define to BFD's default architecture. ]) |
| 268 | fi |
| 269 | if test "x$targ_defvec" != x; then |
| 270 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec, |
| 271 | [Define to BFD's default target vector. ]) |
| 272 | fi |
| 273 | |
| 274 | # Enable MI. |
| 275 | AC_ARG_ENABLE(gdbmi, |
| 276 | AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]), |
| 277 | [case $enableval in |
| 278 | yes | no) |
| 279 | ;; |
| 280 | *) |
| 281 | AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;; |
| 282 | esac], |
| 283 | [enable_gdbmi=yes]) |
| 284 | if test x"$enable_gdbmi" = xyes; then |
| 285 | if test -d "$srcdir/mi"; then |
| 286 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)" |
| 287 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)" |
| 288 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)" |
| 289 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)" |
| 290 | fi |
| 291 | fi |
| 292 | |
| 293 | # Enable TUI. |
| 294 | AC_ARG_ENABLE(tui, |
| 295 | AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]), |
| 296 | [case $enableval in |
| 297 | yes | no | auto) |
| 298 | ;; |
| 299 | *) |
| 300 | AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;; |
| 301 | esac],enable_tui=auto) |
| 302 | |
| 303 | # Enable gdbtk. |
| 304 | AC_ARG_ENABLE(gdbtk, |
| 305 | AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]), |
| 306 | [case $enableval in |
| 307 | yes | no) |
| 308 | ;; |
| 309 | *) |
| 310 | AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;; |
| 311 | esac], |
| 312 | [if test -d "$srcdir/gdbtk"; then |
| 313 | enable_gdbtk=yes |
| 314 | else |
| 315 | enable_gdbtk=no |
| 316 | fi]) |
| 317 | # We unconditionally disable gdbtk tests on selected platforms. |
| 318 | case $host_os in |
| 319 | go32* | windows*) |
| 320 | AC_MSG_WARN([gdbtk isn't supported on $host; disabling]) |
| 321 | enable_gdbtk=no ;; |
| 322 | esac |
| 323 | |
| 324 | # Handle optional debuginfod support |
| 325 | AC_DEBUGINFOD |
| 326 | |
| 327 | # Libunwind support for ia64. |
| 328 | AC_ARG_WITH(libunwind-ia64, |
| 329 | AS_HELP_STRING([--with-libunwind-ia64], |
| 330 | [use libunwind frame unwinding for ia64 targets]),, |
| 331 | [with_libunwind_ia64=auto]) |
| 332 | |
| 333 | # Backward compatibility option. |
| 334 | if test "${with_libunwind+set}" = set; then |
| 335 | if test x"$with_libunwind_ia64" != xauto; then |
| 336 | AC_MSG_ERROR( |
| 337 | [option --with-libunwind is deprecated, use --with-libunwind-ia64]) |
| 338 | fi |
| 339 | AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64]) |
| 340 | with_libunwind_ia64="$with_libunwind" |
| 341 | fi |
| 342 | |
| 343 | case "$with_libunwind_ia64" in |
| 344 | yes | no) |
| 345 | ;; |
| 346 | auto) |
| 347 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 348 | with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h |
| 349 | ;; |
| 350 | *) |
| 351 | AC_MSG_ERROR( |
| 352 | [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option]) |
| 353 | ;; |
| 354 | esac |
| 355 | |
| 356 | if test x"$with_libunwind_ia64" = xyes; then |
| 357 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 358 | if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then |
| 359 | AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h]) |
| 360 | fi |
| 361 | CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o" |
| 362 | CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o" |
| 363 | CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c" |
| 364 | fi |
| 365 | |
| 366 | opt_curses=no |
| 367 | AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval) |
| 368 | |
| 369 | prefer_curses=no |
| 370 | if test "$opt_curses" = "yes"; then |
| 371 | prefer_curses=yes |
| 372 | fi |
| 373 | |
| 374 | # Profiling support. |
| 375 | AC_ARG_ENABLE(profiling, |
| 376 | AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]), |
| 377 | [case $enableval in |
| 378 | yes | no) |
| 379 | ;; |
| 380 | *) |
| 381 | AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;; |
| 382 | esac], |
| 383 | [enable_profiling=no]) |
| 384 | |
| 385 | AC_CHECK_FUNCS(monstartup _mcleanup) |
| 386 | AC_CACHE_CHECK([for _etext], ac_cv_var__etext, |
| 387 | [AC_TRY_LINK( |
| 388 | [#include <stdlib.h> |
| 389 | extern char _etext; |
| 390 | ], |
| 391 | [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)]) |
| 392 | if test "$ac_cv_var__etext" = yes; then |
| 393 | AC_DEFINE(HAVE__ETEXT, 1, |
| 394 | [Define to 1 if your system has the _etext variable. ]) |
| 395 | fi |
| 396 | AC_CACHE_CHECK([for etext], ac_cv_var_etext, |
| 397 | [AC_TRY_LINK( |
| 398 | [#include <stdlib.h> |
| 399 | extern char etext; |
| 400 | ], |
| 401 | [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)]) |
| 402 | if test "$ac_cv_var_etext" = yes; then |
| 403 | AC_DEFINE(HAVE_ETEXT, 1, |
| 404 | [Define to 1 if your system has the etext variable. ]) |
| 405 | fi |
| 406 | if test "$enable_profiling" = yes ; then |
| 407 | if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then |
| 408 | AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup) |
| 409 | fi |
| 410 | PROFILE_CFLAGS=-pg |
| 411 | OLD_CFLAGS="$CFLAGS" |
| 412 | CFLAGS="$CFLAGS $PROFILE_CFLAGS" |
| 413 | |
| 414 | AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg, |
| 415 | [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes, |
| 416 | ac_cv_cc_supports_pg=no)]) |
| 417 | |
| 418 | if test "$ac_cv_cc_supports_pg" = no; then |
| 419 | AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg) |
| 420 | fi |
| 421 | |
| 422 | CFLAGS="$OLD_CFLAGS" |
| 423 | fi |
| 424 | |
| 425 | CODESIGN_CERT= |
| 426 | AC_ARG_ENABLE([codesign], |
| 427 | AS_HELP_STRING([--enable-codesign=CERT], |
| 428 | [sign gdb with 'codesign -s CERT']), |
| 429 | [CODESIGN_CERT=$enableval]) |
| 430 | AC_SUBST([CODESIGN_CERT]) |
| 431 | |
| 432 | ACX_PKGVERSION([GDB]) |
| 433 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 434 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 435 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 436 | |
| 437 | # --------------------- # |
| 438 | # Checks for programs. # |
| 439 | # --------------------- # |
| 440 | |
| 441 | AC_PROG_AWK |
| 442 | AC_PROG_INSTALL |
| 443 | AC_PROG_LN_S |
| 444 | AC_PROG_RANLIB |
| 445 | AC_PROG_YACC |
| 446 | |
| 447 | AC_CHECK_TOOL(AR, ar) |
| 448 | AC_CHECK_TOOL(DLLTOOL, dlltool) |
| 449 | AC_CHECK_TOOL(WINDRES, windres) |
| 450 | |
| 451 | case $host_os in |
| 452 | gnu*) |
| 453 | # Needed for GNU Hurd hosts. |
| 454 | AC_CHECK_TOOL(MIG, mig) |
| 455 | if test x"$MIG" = x; then |
| 456 | AC_MSG_ERROR([MIG not found but required for $host hosts]) |
| 457 | fi |
| 458 | ;; |
| 459 | esac |
| 460 | |
| 461 | # ---------------------- # |
| 462 | # Checks for libraries. # |
| 463 | # ---------------------- # |
| 464 | |
| 465 | # We might need to link with -lm; most simulators need it. |
| 466 | AC_CHECK_LIB(m, main) |
| 467 | |
| 468 | # Some systems (e.g. Solaris) have `gethostbyname' in libnsl. |
| 469 | AC_SEARCH_LIBS(gethostbyname, nsl) |
| 470 | |
| 471 | # Some systems (e.g. Solaris) have `socketpair' in libsocket. |
| 472 | AC_SEARCH_LIBS(socketpair, socket) |
| 473 | |
| 474 | # Link in zlib if we can. This allows us to read compressed debug sections. |
| 475 | AM_ZLIB |
| 476 | |
| 477 | # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c). |
| 478 | # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd. |
| 479 | AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd, |
| 480 | [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1, |
| 481 | [Define to 1 if your system has the kinfo_getvmmap function. ])]) |
| 482 | |
| 483 | AM_ICONV |
| 484 | |
| 485 | # GDB may fork/exec the iconv program to get the list of supported character |
| 486 | # sets. Allow the user to specify where to find it. |
| 487 | # There are several factors affecting the choice of option name: |
| 488 | # - There is already --with-libiconv-prefix but we can't use it, it specifies |
| 489 | # the build-time location of libiconv files. |
| 490 | # - The program we need to find is iconv, which comes with glibc. The user |
| 491 | # doesn't necessarily have libiconv installed. Therefore naming this |
| 492 | # --with-libiconv-foo feels wrong. |
| 493 | # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is |
| 494 | # defined to work on directories not files (though it really doesn't know |
| 495 | # the difference). |
| 496 | # - Calling this --with-iconv-prefix is perceived to cause too much confusion |
| 497 | # with --with-libiconv-prefix. |
| 498 | # Putting these together is why the option name is --with-iconv-bin. |
| 499 | |
| 500 | AC_ARG_WITH(iconv-bin, |
| 501 | AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]), |
| 502 | [iconv_bin="${withval}" |
| 503 | AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"], |
| 504 | [Path of directory of iconv program.]) |
| 505 | GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin}) |
| 506 | ]) |
| 507 | |
| 508 | # For the TUI, we need enhanced curses functionality. |
| 509 | if test x"$enable_tui" != xno; then |
| 510 | prefer_curses=yes |
| 511 | fi |
| 512 | |
| 513 | curses_found=no |
| 514 | if test x"$prefer_curses" = xyes; then |
| 515 | # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied |
| 516 | # curses library because the latter might not provide all the |
| 517 | # functionality we need. However, this leads to problems on systems |
| 518 | # where the linker searches /usr/local/lib, but the compiler doesn't |
| 519 | # search /usr/local/include, if ncurses is installed in /usr/local. A |
| 520 | # default installation of ncurses on alpha*-dec-osf* will lead to such |
| 521 | # a situation. |
| 522 | AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses]) |
| 523 | |
| 524 | if test "$ac_cv_search_waddstr" != no; then |
| 525 | curses_found=yes |
| 526 | fi |
| 527 | fi |
| 528 | |
| 529 | # Check whether we should enable the TUI, but only do so if we really |
| 530 | # can. |
| 531 | if test x"$enable_tui" != xno; then |
| 532 | if test -d "$srcdir/tui"; then |
| 533 | if test "$curses_found" != no; then |
| 534 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)" |
| 535 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)" |
| 536 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)" |
| 537 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)" |
| 538 | else |
| 539 | if test x"$enable_tui" = xyes; then |
| 540 | AC_MSG_ERROR([no enhanced curses library found; disable TUI]) |
| 541 | else |
| 542 | AC_MSG_WARN([no enhanced curses library found; disabling TUI]) |
| 543 | fi |
| 544 | fi |
| 545 | fi |
| 546 | fi |
| 547 | |
| 548 | # Since GDB uses Readline, we need termcap functionality. In many |
| 549 | # cases this will be provided by the curses library, but some systems |
| 550 | # have a separate termcap library, or no curses library at all. |
| 551 | |
| 552 | case $host_os in |
| 553 | cygwin*) |
| 554 | if test -d "$srcdir/libtermcap"; then |
| 555 | LIBS="../libtermcap/libtermcap.a $LIBS" |
| 556 | ac_cv_search_tgetent="../libtermcap/libtermcap.a" |
| 557 | fi ;; |
| 558 | go32* | *djgpp*) |
| 559 | ac_cv_search_tgetent="none required" |
| 560 | ;; |
| 561 | esac |
| 562 | |
| 563 | # These are the libraries checked by Readline. |
| 564 | AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses]) |
| 565 | |
| 566 | if test "$ac_cv_search_tgetent" = no; then |
| 567 | CONFIG_OBS="$CONFIG_OBS stub-termcap.o" |
| 568 | fi |
| 569 | |
| 570 | AC_ARG_WITH([system-readline], |
| 571 | [AS_HELP_STRING([--with-system-readline], |
| 572 | [use installed readline library])]) |
| 573 | |
| 574 | if test "$with_system_readline" = yes; then |
| 575 | AC_CACHE_CHECK([whether system readline is new enough], |
| 576 | [gdb_cv_readline_ok], |
| 577 | [AC_TRY_COMPILE( |
| 578 | [#include <stdio.h> |
| 579 | #include <readline/readline.h>], |
| 580 | [#if RL_VERSION_MAJOR < 7 |
| 581 | # error "readline version 7 required" |
| 582 | #endif], |
| 583 | gdb_cv_readline_ok=yes, |
| 584 | gdb_cv_readline_ok=no)]) |
| 585 | if test "$gdb_cv_readline_ok" != yes; then |
| 586 | AC_MSG_ERROR([system readline is not new enough]) |
| 587 | fi |
| 588 | |
| 589 | READLINE=-lreadline |
| 590 | READLINE_DEPS= |
| 591 | READLINE_CFLAGS= |
| 592 | READLINE_TEXI_INCFLAG= |
| 593 | else |
| 594 | READLINE='$(READLINE_DIR)/libreadline.a' |
| 595 | READLINE_DEPS='$(READLINE)' |
| 596 | READLINE_CFLAGS='-I$(READLINE_SRC)/..' |
| 597 | READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)' |
| 598 | fi |
| 599 | AC_SUBST(READLINE) |
| 600 | AC_SUBST(READLINE_DEPS) |
| 601 | AC_SUBST(READLINE_CFLAGS) |
| 602 | AC_SUBST(READLINE_TEXI_INCFLAG) |
| 603 | |
| 604 | # Generate jit-reader.h |
| 605 | |
| 606 | # This is typedeffed to GDB_CORE_ADDR in jit-reader.h |
| 607 | TARGET_PTR= |
| 608 | |
| 609 | AC_CHECK_SIZEOF(unsigned long long) |
| 610 | AC_CHECK_SIZEOF(unsigned long) |
| 611 | AC_CHECK_SIZEOF(unsigned __int128) |
| 612 | |
| 613 | if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then |
| 614 | TARGET_PTR="unsigned long" |
| 615 | elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then |
| 616 | TARGET_PTR="unsigned long long" |
| 617 | elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then |
| 618 | TARGET_PTR="unsigned __int128" |
| 619 | else |
| 620 | TARGET_PTR="unsigned long" |
| 621 | fi |
| 622 | |
| 623 | AC_SUBST(TARGET_PTR) |
| 624 | AC_CONFIG_FILES([jit-reader.h:jit-reader.in]) |
| 625 | |
| 626 | AC_SEARCH_LIBS(dlopen, dl) |
| 627 | |
| 628 | GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir], |
| 629 | [directory to load the JIT readers from], |
| 630 | [${libdir}/gdb]) |
| 631 | |
| 632 | AC_ARG_WITH(expat, |
| 633 | AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]), |
| 634 | [], [with_expat=auto]) |
| 635 | AC_MSG_CHECKING([whether to use expat]) |
| 636 | AC_MSG_RESULT([$with_expat]) |
| 637 | |
| 638 | if test "${with_expat}" = no; then |
| 639 | AC_MSG_WARN([expat support disabled; some features may be unavailable.]) |
| 640 | HAVE_LIBEXPAT=no |
| 641 | else |
| 642 | AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"], |
| 643 | [XML_Parser p = XML_ParserCreate (0);]) |
| 644 | if test "$HAVE_LIBEXPAT" != yes; then |
| 645 | if test "$with_expat" = yes; then |
| 646 | AC_MSG_ERROR([expat is missing or unusable]) |
| 647 | else |
| 648 | AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.]) |
| 649 | fi |
| 650 | else |
| 651 | save_LIBS=$LIBS |
| 652 | LIBS="$LIBS $LIBEXPAT" |
| 653 | AC_CHECK_FUNCS(XML_StopParser) |
| 654 | LIBS=$save_LIBS |
| 655 | fi |
| 656 | fi |
| 657 | |
| 658 | AC_ARG_WITH(mpfr, |
| 659 | AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]), |
| 660 | [], [with_mpfr=auto]) |
| 661 | AC_MSG_CHECKING([whether to use MPFR]) |
| 662 | AC_MSG_RESULT([$with_mpfr]) |
| 663 | |
| 664 | if test "${with_mpfr}" = no; then |
| 665 | AC_MSG_WARN([MPFR support disabled; some features may be unavailable.]) |
| 666 | HAVE_LIBMPFR=no |
| 667 | else |
| 668 | AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>], |
| 669 | [mpfr_exp_t exp; mpfr_t x; |
| 670 | mpfr_frexp (&exp, x, x, MPFR_RNDN);]) |
| 671 | if test "$HAVE_LIBMPFR" != yes; then |
| 672 | if test "$with_mpfr" = yes; then |
| 673 | AC_MSG_ERROR([MPFR is missing or unusable]) |
| 674 | else |
| 675 | AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.]) |
| 676 | fi |
| 677 | fi |
| 678 | fi |
| 679 | |
| 680 | # --------------------- # |
| 681 | # Check for libpython. # |
| 682 | # --------------------- # |
| 683 | |
| 684 | dnl Utility to simplify finding libpython. |
| 685 | dnl $1 = the shell variable to assign the result to |
| 686 | dnl If libpython is found we store $version here. |
| 687 | dnl $2 = additional flags to add to CPPFLAGS |
| 688 | dnl $3 = additional flags to add to LIBS |
| 689 | |
| 690 | AC_DEFUN([AC_TRY_LIBPYTHON], |
| 691 | [ |
| 692 | define([have_libpython_var],$1) |
| 693 | new_CPPFLAGS=$2 |
| 694 | new_LIBS=$3 |
| 695 | AC_MSG_CHECKING([for python]) |
| 696 | save_CPPFLAGS=$CPPFLAGS |
| 697 | save_LIBS=$LIBS |
| 698 | CPPFLAGS="$CPPFLAGS $new_CPPFLAGS" |
| 699 | LIBS="$new_LIBS $LIBS" |
| 700 | found_usable_python=no |
| 701 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]], |
| 702 | [[Py_Initialize ();]])], |
| 703 | [have_libpython_var=yes |
| 704 | found_usable_python=yes |
| 705 | PYTHON_CPPFLAGS=$new_CPPFLAGS |
| 706 | PYTHON_LIBS=$new_LIBS]) |
| 707 | CPPFLAGS=$save_CPPFLAGS |
| 708 | LIBS=$save_LIBS |
| 709 | AC_MSG_RESULT([${found_usable_python}]) |
| 710 | ]) |
| 711 | |
| 712 | dnl There are several different values for --with-python: |
| 713 | dnl |
| 714 | dnl no - Don't include python support. |
| 715 | dnl yes - Include python support, error if it's missing. |
| 716 | dnl If we find python in $PATH, use it to fetch configure options, |
| 717 | dnl otherwise assume the compiler can find it with no help from us. |
| 718 | dnl Python 2.7 and 2.6 are tried in turn. |
| 719 | dnl auto - Same as "yes", but if python is missing from the system, |
| 720 | dnl fall back to "no". |
| 721 | dnl /path/to/python/exec-prefix - |
| 722 | dnl Use the python located in this directory. |
| 723 | dnl If /path/to/python/exec-prefix/bin/python exists, use it to find |
| 724 | dnl the compilation parameters. Otherwise use |
| 725 | dnl -I/path/to/python/exec-prefix/include, |
| 726 | dnl -L/path/to/python/exec-prefix/lib. |
| 727 | dnl Python 2.7 and 2.6 are tried in turn. |
| 728 | dnl NOTE: This case is historical. It is what was done for 7.0/7.1 |
| 729 | dnl but is deprecated. |
| 730 | dnl /path/to/python/executable - |
| 731 | dnl Run python-config.py with this version of python to fetch the |
| 732 | dnl compilation parameters. |
| 733 | dnl NOTE: This needn't be the real python executable. |
| 734 | dnl In a cross-compilation scenario (build != host), this could be |
| 735 | dnl a shell script that provides what python-config.py provides for |
| 736 | dnl --ldflags, --includes, --exec-prefix. |
| 737 | dnl python-executable - |
| 738 | dnl Find python-executable in $PATH, and then handle the same as |
| 739 | dnl /path/to/python/executable. |
| 740 | dnl |
| 741 | dnl If a python program is specified, it is used to run python-config.py and |
| 742 | dnl is passed --ldflags, --includes, --exec-prefix. |
| 743 | |
| 744 | AC_ARG_WITH(python, |
| 745 | AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]), |
| 746 | [], [with_python=auto]) |
| 747 | AC_MSG_CHECKING([whether to use python]) |
| 748 | AC_MSG_RESULT([$with_python]) |
| 749 | |
| 750 | if test "${with_python}" = no; then |
| 751 | AC_MSG_WARN([python support disabled; some features may be unavailable.]) |
| 752 | have_libpython=no |
| 753 | else |
| 754 | case "${with_python}" in |
| 755 | [[\\/]]* | ?:[[\\/]]*) |
| 756 | if test -d "${with_python}"; then |
| 757 | # Assume the python binary is ${with_python}/bin/python. |
| 758 | python_prog="${with_python}/bin/python" |
| 759 | python_prefix= |
| 760 | # If python does not exit ${with_python}/bin, then try in |
| 761 | # ${with_python}. On Windows/MinGW, this is where the Python |
| 762 | # executable is. |
| 763 | if test ! -x "${python_prog}"; then |
| 764 | python_prog="${with_python}/python" |
| 765 | python_prefix= |
| 766 | fi |
| 767 | if test ! -x "${python_prog}"; then |
| 768 | # Fall back to gdb 7.0/7.1 behaviour. |
| 769 | python_prog=missing |
| 770 | python_prefix=${with_python} |
| 771 | fi |
| 772 | elif test -x "${with_python}"; then |
| 773 | # While we can't run python compiled for $host (unless host == build), |
| 774 | # the user could write a script that provides the needed information, |
| 775 | # so we support that. |
| 776 | python_prog=${with_python} |
| 777 | python_prefix= |
| 778 | else |
| 779 | AC_ERROR(invalid value for --with-python) |
| 780 | fi |
| 781 | ;; |
| 782 | */*) |
| 783 | # Disallow --with-python=foo/bar. |
| 784 | AC_ERROR(invalid value for --with-python) |
| 785 | ;; |
| 786 | *) |
| 787 | # The user has either specified auto, yes, or the name of the python |
| 788 | # program assumed to be in $PATH. |
| 789 | python_prefix= |
| 790 | case "${with_python}" in |
| 791 | yes | auto) |
| 792 | if test "${build}" = "${host}"; then |
| 793 | AC_PATH_PROG(python_prog_path, python, missing) |
| 794 | if test "${python_prog_path}" = missing; then |
| 795 | python_prog=missing |
| 796 | else |
| 797 | python_prog=${python_prog_path} |
| 798 | fi |
| 799 | else |
| 800 | # Not much we can do except assume the cross-compiler will find the |
| 801 | # right files. |
| 802 | python_prog=missing |
| 803 | fi |
| 804 | ;; |
| 805 | *) |
| 806 | # While we can't run python compiled for $host (unless host == build), |
| 807 | # the user could write a script that provides the needed information, |
| 808 | # so we support that. |
| 809 | python_prog="${with_python}" |
| 810 | AC_PATH_PROG(python_prog_path, ${python_prog}, missing) |
| 811 | if test "${python_prog_path}" = missing; then |
| 812 | AC_ERROR(unable to find python program ${python_prog}) |
| 813 | fi |
| 814 | ;; |
| 815 | esac |
| 816 | esac |
| 817 | |
| 818 | if test "${python_prog}" != missing; then |
| 819 | # We have a python program to use, but it may be too old. |
| 820 | # Don't flag an error for --with-python=auto (the default). |
| 821 | have_python_config=yes |
| 822 | python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes` |
| 823 | if test $? != 0; then |
| 824 | have_python_config=failed |
| 825 | if test "${with_python}" != auto; then |
| 826 | AC_ERROR(failure running python-config --includes) |
| 827 | fi |
| 828 | fi |
| 829 | python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags` |
| 830 | if test $? != 0; then |
| 831 | have_python_config=failed |
| 832 | if test "${with_python}" != auto; then |
| 833 | AC_ERROR(failure running python-config --ldflags) |
| 834 | fi |
| 835 | fi |
| 836 | python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix` |
| 837 | if test $? != 0; then |
| 838 | have_python_config=failed |
| 839 | if test "${with_python}" != auto; then |
| 840 | AC_ERROR(failure running python-config --exec-prefix) |
| 841 | fi |
| 842 | fi |
| 843 | else |
| 844 | # We do not have a python executable we can use to determine where |
| 845 | # to find the Python headers and libs. We cannot guess the include |
| 846 | # path from the python_prefix either, because that include path |
| 847 | # depends on the Python version. So, there is nothing much we can |
| 848 | # do except assume that the compiler will be able to find those files. |
| 849 | python_includes= |
| 850 | python_libs= |
| 851 | have_python_config=no |
| 852 | fi |
| 853 | |
| 854 | # If we have python-config, only try the configuration it provides. |
| 855 | # Otherwise fallback on the old way of trying different versions of |
| 856 | # python in turn. |
| 857 | |
| 858 | have_libpython=no |
| 859 | if test "${have_python_config}" = yes; then |
| 860 | AC_TRY_LIBPYTHON(have_libpython, |
| 861 | ${python_includes}, ${python_libs}) |
| 862 | elif test "${have_python_config}" != failed; then |
| 863 | if test "${have_libpython}" = no; then |
| 864 | AC_TRY_LIBPYTHON(have_libpython, |
| 865 | ${python_includes}, "-lpython2.7 ${python_libs}") |
| 866 | fi |
| 867 | if test "${have_libpython}" = no; then |
| 868 | AC_TRY_LIBPYTHON(have_libpython, |
| 869 | ${python_includes}, "-lpython2.6 ${python_libs}") |
| 870 | fi |
| 871 | fi |
| 872 | |
| 873 | if test "${have_libpython}" = no; then |
| 874 | case "${with_python}" in |
| 875 | yes) |
| 876 | AC_MSG_ERROR([python is missing or unusable]) |
| 877 | ;; |
| 878 | auto) |
| 879 | AC_MSG_WARN([python is missing or unusable; some features may be unavailable.]) |
| 880 | ;; |
| 881 | *) |
| 882 | AC_MSG_ERROR([no usable python found at ${with_python}]) |
| 883 | ;; |
| 884 | esac |
| 885 | else |
| 886 | if test -n "${python_prefix}"; then |
| 887 | AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}", |
| 888 | [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.]) |
| 889 | GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix}) |
| 890 | fi |
| 891 | fi |
| 892 | fi |
| 893 | |
| 894 | dnl Use --with-python-libdir to control where GDB looks for the Python |
| 895 | dnl libraries. |
| 896 | dnl |
| 897 | dnl If this is not given then the default will be based on the value |
| 898 | dnl passed to --with-python, which is in the python_prefix variable. |
| 899 | dnl If the --with-python option wasn't given then the default value in |
| 900 | dnl python_prefix is based on running the 'gdb/python/python-config |
| 901 | dnl --exec-prefix' script. |
| 902 | AC_ARG_WITH(python-libdir, |
| 903 | AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]), |
| 904 | [],[ |
| 905 | # If no python libdir is specified then select one based on |
| 906 | # python's prefix path. |
| 907 | if test -n "${python_prefix}"; then |
| 908 | with_python_libdir=${python_prefix}/lib |
| 909 | fi |
| 910 | ]) |
| 911 | |
| 912 | if test "${have_libpython}" != no; then |
| 913 | AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.]) |
| 914 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)" |
| 915 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)" |
| 916 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)" |
| 917 | CONFIG_INSTALL="$CONFIG_INSTALL install-python" |
| 918 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)" |
| 919 | |
| 920 | if test -n "${with_python_libdir}"; then |
| 921 | AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}", |
| 922 | [Directory containing Python's standard libraries from --with-python-libdir.]) |
| 923 | GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir}) |
| 924 | fi |
| 925 | |
| 926 | # Flags needed to compile Python code (taken from python-config --cflags). |
| 927 | # We cannot call python-config directly because it will output whatever was |
| 928 | # used when compiling the Python interpreter itself, including flags which |
| 929 | # would make the python-related objects be compiled differently from the |
| 930 | # rest of GDB (e.g., -O2 and -fPIC). |
| 931 | if test "${GCC}" = yes; then |
| 932 | tentative_python_cflags="-fno-strict-aliasing -fwrapv" |
| 933 | # Python headers recommend -DNDEBUG, but it's unclear if that just |
| 934 | # refers to building Python itself. In release mode, though, it |
| 935 | # doesn't hurt for the Python code in gdb to follow. |
| 936 | $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG" |
| 937 | fi |
| 938 | |
| 939 | if test "x${tentative_python_cflags}" != x; then |
| 940 | AC_MSG_CHECKING(compiler flags for python code) |
| 941 | for flag in ${tentative_python_cflags}; do |
| 942 | # Check that the compiler accepts it |
| 943 | saved_CFLAGS="$CFLAGS" |
| 944 | CFLAGS="$CFLAGS $flag" |
| 945 | AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",) |
| 946 | CFLAGS="$saved_CFLAGS" |
| 947 | done |
| 948 | AC_MSG_RESULT(${PYTHON_CFLAGS}) |
| 949 | fi |
| 950 | |
| 951 | # On x64 Windows, Python's include headers, and pyconfig.h in |
| 952 | # particular, rely on MS_WIN64 macro to detect that it's a 64bit |
| 953 | # version of Windows. Unfortunately, MS_WIN64 is only defined if |
| 954 | # _MSC_VER, a Microsoft-specific macro, is defined. So, when |
| 955 | # building on x64 Windows with GCC, we define MS_WIN64 ourselves. |
| 956 | # The issue was reported to the Python community, but still isn't |
| 957 | # solved as of 2012-10-02 (http://bugs.python.org/issue4709). |
| 958 | |
| 959 | case "$gdb_host" in |
| 960 | mingw64) |
| 961 | if test "${GCC}" = yes; then |
| 962 | CPPFLAGS="$CPPFLAGS -DMS_WIN64" |
| 963 | fi |
| 964 | ;; |
| 965 | esac |
| 966 | else |
| 967 | # Even if Python support is not compiled in, we need to have this file |
| 968 | # included so that the "python" command, et.al., still exists. |
| 969 | CONFIG_OBS="$CONFIG_OBS python/python.o" |
| 970 | CONFIG_SRCS="$CONFIG_SRCS python/python.c" |
| 971 | fi |
| 972 | |
| 973 | # Work around Python http://bugs.python.org/issue10112. See also |
| 974 | # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has |
| 975 | # no effect. Note that the only test after this that uses Python is |
| 976 | # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be |
| 977 | # run without -export-dynamic too. |
| 978 | PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'` |
| 979 | |
| 980 | AC_SUBST(PYTHON_CFLAGS) |
| 981 | AC_SUBST(PYTHON_CPPFLAGS) |
| 982 | AC_SUBST(PYTHON_LIBS) |
| 983 | AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no) |
| 984 | |
| 985 | # -------------------- # |
| 986 | # Check for libguile. # |
| 987 | # -------------------- # |
| 988 | |
| 989 | dnl Utility to simplify finding libguile. |
| 990 | dnl $1 = pkg-config-program |
| 991 | dnl $2 = space-separate list of guile versions to try |
| 992 | dnl $3 = yes|no, indicating whether to flag errors or ignore them |
| 993 | dnl $4 = the shell variable to assign the result to |
| 994 | dnl If libguile is found we store "yes" here. |
| 995 | |
| 996 | AC_DEFUN([AC_TRY_LIBGUILE], |
| 997 | [ |
| 998 | pkg_config=$1 |
| 999 | guile_version_list=$2 |
| 1000 | flag_errors=$3 |
| 1001 | define([have_libguile_var],$4) |
| 1002 | found_usable_guile=checking |
| 1003 | AC_MSG_CHECKING([for usable guile from ${pkg_config}]) |
| 1004 | for guile_version in ${guile_version_list}; do |
| 1005 | ${pkg_config} --exists ${guile_version} 2>/dev/null |
| 1006 | if test $? != 0; then |
| 1007 | continue |
| 1008 | fi |
| 1009 | dnl pkg-config says the package exists, so if we get an error now, |
| 1010 | dnl that's bad. |
| 1011 | new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}` |
| 1012 | if test $? != 0; then |
| 1013 | AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}]) |
| 1014 | fi |
| 1015 | new_LIBS=`${pkg_config} --libs ${guile_version}` |
| 1016 | if test $? != 0; then |
| 1017 | AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}]) |
| 1018 | fi |
| 1019 | dnl If we get this far, great. |
| 1020 | found_usable_guile=${guile_version} |
| 1021 | break |
| 1022 | done |
| 1023 | if test "${found_usable_guile}" = "checking"; then |
| 1024 | if test "${flag_errors}" = "yes"; then |
| 1025 | AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"]) |
| 1026 | else |
| 1027 | found_usable_guile=no |
| 1028 | fi |
| 1029 | fi |
| 1030 | dnl One final sanity check. |
| 1031 | dnl The user could have said --with-guile=python-2.7. |
| 1032 | if test "${found_usable_guile}" != no; then |
| 1033 | save_CPPFLAGS=$CPPFLAGS |
| 1034 | save_LIBS=$LIBS |
| 1035 | CPPFLAGS="$CPPFLAGS $new_CPPFLAGS" |
| 1036 | LIBS="$LIBS $new_LIBS" |
| 1037 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]], |
| 1038 | [[scm_init_guile ();]])], |
| 1039 | [have_libguile_var=yes |
| 1040 | GUILE_CPPFLAGS=$new_CPPFLAGS |
| 1041 | GUILE_LIBS=$new_LIBS], |
| 1042 | [found_usable_guile=no]) |
| 1043 | dnl scm_set_automatic_finalization_enabled added in Guile 2.2. |
| 1044 | AC_CHECK_FUNC(scm_set_automatic_finalization_enabled, |
| 1045 | AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1, |
| 1046 | [Define if Guile supports manual finalization.]) |
| 1047 | ) |
| 1048 | CPPFLAGS=$save_CPPFLAGS |
| 1049 | LIBS=$save_LIBS |
| 1050 | if test "${found_usable_guile}" = no; then |
| 1051 | if test "${flag_errors}" = yes; then |
| 1052 | AC_MSG_FAILURE([linking guile version ${guile_version} test program failed]) |
| 1053 | fi |
| 1054 | fi |
| 1055 | fi |
| 1056 | AC_MSG_RESULT([${found_usable_guile}]) |
| 1057 | ]) |
| 1058 | |
| 1059 | dnl There are several different values for --with-guile: |
| 1060 | dnl |
| 1061 | dnl no - Don't include guile support. |
| 1062 | dnl yes - Include guile support, error if it's missing. |
| 1063 | dnl The pkg-config program must be in $PATH. |
| 1064 | dnl auto - Same as "yes", but if guile is missing from the system, |
| 1065 | dnl fall back to "no". |
| 1066 | dnl guile-version [guile-version-choice-2 ...] - |
| 1067 | dnl A space-separated list of guile package versions to try. |
| 1068 | dnl These are passed to pkg-config as-is. |
| 1069 | dnl E.g., guile-2.0 or guile-2.2-uninstalled |
| 1070 | dnl This requires making sure PKG_CONFIG_PATH is set appropriately. |
| 1071 | dnl /path/to/pkg-config - |
| 1072 | dnl Use this pkg-config program. |
| 1073 | dnl NOTE: This needn't be the "real" pkg-config program. |
| 1074 | dnl It could be a shell script. It is invoked as: |
| 1075 | dnl pkg-config --exists $version |
| 1076 | dnl pkg-config --cflags $version |
| 1077 | dnl pkg-config --libs $version |
| 1078 | dnl pkg-config --variable guild $version |
| 1079 | dnl The script will be called with $version having each value in |
| 1080 | dnl $try_guile_versions until --exists indicates success. |
| 1081 | |
| 1082 | AC_ARG_WITH(guile, |
| 1083 | AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]), |
| 1084 | [], [with_guile=auto]) |
| 1085 | AC_MSG_CHECKING([whether to use guile]) |
| 1086 | AC_MSG_RESULT([$with_guile]) |
| 1087 | |
| 1088 | dnl We check guile with pkg-config. |
| 1089 | AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing) |
| 1090 | |
| 1091 | try_guile_versions="guile-2.0" |
| 1092 | have_libguile=no |
| 1093 | case "${with_guile}" in |
| 1094 | no) |
| 1095 | AC_MSG_WARN([guile support disabled; some features will be unavailable.]) |
| 1096 | ;; |
| 1097 | auto) |
| 1098 | if test "${pkg_config_prog_path}" = "missing"; then |
| 1099 | AC_MSG_WARN([pkg-config not found, guile support disabled]) |
| 1100 | else |
| 1101 | AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile) |
| 1102 | fi |
| 1103 | ;; |
| 1104 | yes) |
| 1105 | if test "${pkg_config_prog_path}" = "missing"; then |
| 1106 | AC_MSG_ERROR([pkg-config not found]) |
| 1107 | fi |
| 1108 | AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile) |
| 1109 | ;; |
| 1110 | [[\\/]]* | ?:[[\\/]]*) |
| 1111 | if test -x "${with_guile}"; then |
| 1112 | AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile) |
| 1113 | else |
| 1114 | AC_MSG_ERROR([Guile config program not executable: ${with_guile}]) |
| 1115 | fi |
| 1116 | ;; |
| 1117 | "" | */*) |
| 1118 | # Disallow --with=guile="" and --with-guile=foo/bar. |
| 1119 | AC_MSG_ERROR([invalid value for --with-guile]) |
| 1120 | ;; |
| 1121 | *) |
| 1122 | # A space separate list of guile versions to try, in order. |
| 1123 | if test "${pkg_config_prog_path}" = "missing"; then |
| 1124 | AC_MSG_ERROR([pkg-config not found]) |
| 1125 | fi |
| 1126 | AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile) |
| 1127 | ;; |
| 1128 | esac |
| 1129 | |
| 1130 | if test "${have_libguile}" != no; then |
| 1131 | dnl Get the name of the 'guild' program. |
| 1132 | case "${with_guile}" in |
| 1133 | [[\\/]]* | ?:[[\\/]]*) |
| 1134 | GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"]) |
| 1135 | ;; |
| 1136 | *) |
| 1137 | GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"]) |
| 1138 | ;; |
| 1139 | esac |
| 1140 | |
| 1141 | dnl Make sure guild can handle this host. |
| 1142 | GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm]) |
| 1143 | dnl If not, disable guile support. |
| 1144 | if test "$ac_cv_guild_ok" = no; then |
| 1145 | have_libguile=no |
| 1146 | AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host) |
| 1147 | fi |
| 1148 | fi |
| 1149 | |
| 1150 | if test "${have_libguile}" != no; then |
| 1151 | AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.]) |
| 1152 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)" |
| 1153 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)" |
| 1154 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)" |
| 1155 | CONFIG_INSTALL="$CONFIG_INSTALL install-guile" |
| 1156 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)" |
| 1157 | |
| 1158 | dnl The 'scm_new_smob' function appeared in Guile 2.0.6. |
| 1159 | save_LIBS="$LIBS" |
| 1160 | save_CPPFLAGS="$CPPFLAGS" |
| 1161 | LIBS="$GUILE_LIBS" |
| 1162 | CPPFLAGS="$GUILE_CPPFLAGS" |
| 1163 | AC_CHECK_FUNCS([scm_new_smob]) |
| 1164 | LIBS="$save_LIBS" |
| 1165 | CPPFLAGS="$save_CPPFLAGS" |
| 1166 | else |
| 1167 | # Even if Guile support is not compiled in, we need to have these files |
| 1168 | # included. |
| 1169 | CONFIG_OBS="$CONFIG_OBS guile/guile.o" |
| 1170 | CONFIG_SRCS="$CONFIG_SRCS guile/guile.c" |
| 1171 | fi |
| 1172 | AC_SUBST(GUILE_CPPFLAGS) |
| 1173 | AC_SUBST(GUILE_LIBS) |
| 1174 | AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no) |
| 1175 | |
| 1176 | # ---------------------------- # |
| 1177 | # Check for source highlight. # |
| 1178 | # ---------------------------- # |
| 1179 | |
| 1180 | SRCHIGH_LIBS= |
| 1181 | SRCHIGH_CFLAGS= |
| 1182 | |
| 1183 | AC_ARG_ENABLE(source-highlight, |
| 1184 | AS_HELP_STRING([--enable-source-highlight], |
| 1185 | [enable source-highlight for source listings]), |
| 1186 | [case "${enableval}" in |
| 1187 | yes) enable_source_highlight=yes ;; |
| 1188 | no) enable_source_highlight=no ;; |
| 1189 | *) AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;; |
| 1190 | esac], |
| 1191 | [enable_source_highlight=auto]) |
| 1192 | |
| 1193 | if test "${enable_source_highlight}" != "no"; then |
| 1194 | AC_MSG_CHECKING([for the source-highlight library]) |
| 1195 | if test "${pkg_config_prog_path}" = "missing"; then |
| 1196 | AC_MSG_RESULT([no - pkg-config not found]) |
| 1197 | if test "${enable_source_highlight}" = "yes"; then |
| 1198 | AC_MSG_ERROR([pkg-config was not found in your system]) |
| 1199 | fi |
| 1200 | else |
| 1201 | case "$LDFLAGS" in |
| 1202 | *static-libstdc*) |
| 1203 | AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl |
| 1204 | either use --disable-source-highlight or dnl |
| 1205 | --without-static-standard-libraries]) |
| 1206 | ;; |
| 1207 | esac |
| 1208 | |
| 1209 | if ${pkg_config_prog_path} --exists source-highlight; then |
| 1210 | SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight` |
| 1211 | SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight` |
| 1212 | AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1, |
| 1213 | [Define to 1 if the source-highlight library is available]) |
| 1214 | AC_MSG_RESULT([yes]) |
| 1215 | else |
| 1216 | AC_MSG_RESULT([no]) |
| 1217 | if test "${enable_source_highlight}" = "yes"; then |
| 1218 | AC_MSG_ERROR([source-highlight was not found in your system]) |
| 1219 | fi |
| 1220 | fi |
| 1221 | fi |
| 1222 | fi |
| 1223 | AC_SUBST(SRCHIGH_LIBS) |
| 1224 | AC_SUBST(SRCHIGH_CFLAGS) |
| 1225 | |
| 1226 | # ------------------------- # |
| 1227 | # Checks for header files. # |
| 1228 | # ------------------------- # |
| 1229 | |
| 1230 | AC_HEADER_STDC |
| 1231 | # elf_hp.h is for HP/UX 64-bit shared library support. |
| 1232 | AC_CHECK_HEADERS([nlist.h machine/reg.h \ |
| 1233 | thread_db.h \ |
| 1234 | sys/file.h sys/filio.h sys/ioctl.h sys/param.h \ |
| 1235 | sys/resource.h sys/ptrace.h ptrace.h \ |
| 1236 | sys/reg.h sys/debugreg.h \ |
| 1237 | termios.h elf_hp.h]) |
| 1238 | AC_CHECK_HEADERS(sys/user.h, [], [], |
| 1239 | [#if HAVE_SYS_PARAM_H |
| 1240 | # include <sys/param.h> |
| 1241 | #endif |
| 1242 | ]) |
| 1243 | |
| 1244 | AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h) |
| 1245 | AC_CHECK_HEADERS(term.h, [], [], |
| 1246 | [#if HAVE_CURSES_H |
| 1247 | # include <curses.h> |
| 1248 | #endif |
| 1249 | ]) |
| 1250 | |
| 1251 | # ------------------------- # |
| 1252 | # Checks for declarations. # |
| 1253 | # ------------------------- # |
| 1254 | |
| 1255 | libiberty_INIT |
| 1256 | |
| 1257 | AC_CHECK_DECLS([snprintf]) |
| 1258 | AM_LC_MESSAGES |
| 1259 | |
| 1260 | # ------------------ # |
| 1261 | # Checks for types. # |
| 1262 | # ------------------ # |
| 1263 | |
| 1264 | AC_CHECK_TYPES(socklen_t, [], [], |
| 1265 | [#include <sys/types.h> |
| 1266 | #include <sys/socket.h> |
| 1267 | ]) |
| 1268 | |
| 1269 | # ------------------------------------- # |
| 1270 | # Checks for compiler characteristics. # |
| 1271 | # ------------------------------------- # |
| 1272 | |
| 1273 | AC_C_CONST |
| 1274 | AC_C_INLINE |
| 1275 | AC_C_BIGENDIAN |
| 1276 | |
| 1277 | # ------------------------------ # |
| 1278 | # Checks for library functions. # |
| 1279 | # ------------------------------ # |
| 1280 | |
| 1281 | AC_CHECK_FUNCS([getuid getgid \ |
| 1282 | pipe pread pread64 pwrite resize_term \ |
| 1283 | getpgid setsid \ |
| 1284 | sigaction sigsetmask socketpair \ |
| 1285 | ttrace wborder wresize setlocale iconvlist libiconvlist btowc \ |
| 1286 | setrlimit getrlimit posix_madvise waitpid \ |
| 1287 | use_default_colors]) |
| 1288 | AM_LANGINFO_CODESET |
| 1289 | GDB_AC_COMMON |
| 1290 | |
| 1291 | # Check the return and argument types of ptrace. |
| 1292 | GDB_AC_PTRACE |
| 1293 | |
| 1294 | dnl AC_FUNC_SETPGRP does not work when cross compiling |
| 1295 | dnl Instead, assume we will have a prototype for setpgrp if cross compiling. |
| 1296 | if test "$cross_compiling" = no; then |
| 1297 | AC_FUNC_SETPGRP |
| 1298 | else |
| 1299 | AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void, |
| 1300 | [AC_TRY_COMPILE([ |
| 1301 | #include <unistd.h> |
| 1302 | ], [ |
| 1303 | if (setpgrp(1,1) == -1) |
| 1304 | exit (0); |
| 1305 | else |
| 1306 | exit (1); |
| 1307 | ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)]) |
| 1308 | if test "$ac_cv_func_setpgrp_void" = yes; then |
| 1309 | AC_DEFINE(SETPGRP_VOID, 1) |
| 1310 | fi |
| 1311 | fi |
| 1312 | |
| 1313 | # Assume we'll default to using the included libiberty regex. |
| 1314 | gdb_use_included_regex=yes |
| 1315 | |
| 1316 | # However, if the system regex is GNU regex, then default to *not* |
| 1317 | # using the included regex. |
| 1318 | AC_CACHE_CHECK( |
| 1319 | [for GNU regex], |
| 1320 | [gdb_cv_have_gnu_regex], |
| 1321 | [AC_TRY_COMPILE( |
| 1322 | [#include <gnu-versions.h>], |
| 1323 | [#define REGEX_INTERFACE_VERSION 1 |
| 1324 | #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION |
| 1325 | # error "Version mismatch" |
| 1326 | #endif], |
| 1327 | gdb_cv_have_gnu_regex=yes, |
| 1328 | gdb_cv_have_gnu_regex=no)]) |
| 1329 | if test "$gdb_cv_have_gnu_regex" = yes; then |
| 1330 | gdb_use_included_regex=no |
| 1331 | fi |
| 1332 | |
| 1333 | AC_ARG_WITH(included-regex, |
| 1334 | AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]), |
| 1335 | gdb_with_regex=$withval, |
| 1336 | gdb_with_regex=$gdb_use_included_regex) |
| 1337 | if test "$gdb_with_regex" = yes; then |
| 1338 | AC_DEFINE(USE_INCLUDED_REGEX, 1, |
| 1339 | [Define to 1 if the regex included in libiberty should be used.]) |
| 1340 | fi |
| 1341 | |
| 1342 | # Check if <sys/proc.h> defines `struct thread' with a td_pcb member. |
| 1343 | AC_CHECK_MEMBERS([struct thread.td_pcb], [], [], |
| 1344 | [#include <sys/param.h> |
| 1345 | #include <sys/proc.h> |
| 1346 | ]) |
| 1347 | |
| 1348 | # See if <sys/lwp.h> defines `struct lwp`. |
| 1349 | AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp, |
| 1350 | [AC_TRY_COMPILE([#include <sys/param.h> |
| 1351 | #define _KMEMUSER |
| 1352 | #include <sys/lwp.h>], [struct lwp l;], |
| 1353 | gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)]) |
| 1354 | if test "$gdb_cv_struct_lwp" = yes; then |
| 1355 | AC_DEFINE(HAVE_STRUCT_LWP, 1, |
| 1356 | [Define to 1 if your system has struct lwp.]) |
| 1357 | fi |
| 1358 | |
| 1359 | # See if <machine/reg.h> degines `struct reg'. |
| 1360 | AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg, |
| 1361 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 1362 | #include <machine/reg.h>], [struct reg r;], |
| 1363 | gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)]) |
| 1364 | if test "$gdb_cv_struct_reg" = yes; then |
| 1365 | AC_DEFINE(HAVE_STRUCT_REG, 1, |
| 1366 | [Define to 1 if your system has struct reg in <machine/reg.h>.]) |
| 1367 | fi |
| 1368 | |
| 1369 | # See if <machine/reg.h> supports the %fs and %gs i386 segment registers. |
| 1370 | # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'. |
| 1371 | AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [], |
| 1372 | [#include <sys/types.h> |
| 1373 | #include <machine/reg.h>]) |
| 1374 | |
| 1375 | # See if <sys/ptrace.h> provides the PTRACE_GETREGS request. |
| 1376 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 1377 | AC_CACHE_VAL(gdb_cv_have_ptrace_getregs, |
| 1378 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 1379 | [PTRACE_GETREGS;], |
| 1380 | [gdb_cv_have_ptrace_getregs=yes], |
| 1381 | [gdb_cv_have_ptrace_getregs=no])]) |
| 1382 | AC_MSG_RESULT($gdb_cv_have_ptrace_getregs) |
| 1383 | if test "$gdb_cv_have_ptrace_getregs" = yes; then |
| 1384 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 1385 | [Define if sys/ptrace.h defines the PTRACE_GETREGS request.]) |
| 1386 | fi |
| 1387 | |
| 1388 | # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request. |
| 1389 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 1390 | AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs, |
| 1391 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 1392 | [PTRACE_GETFPXREGS;], |
| 1393 | [gdb_cv_have_ptrace_getfpxregs=yes], |
| 1394 | [gdb_cv_have_ptrace_getfpxregs=no])]) |
| 1395 | AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs) |
| 1396 | if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then |
| 1397 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 1398 | [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.]) |
| 1399 | fi |
| 1400 | |
| 1401 | # See if <sys/ptrace.h> provides the PT_GETDBREGS request. |
| 1402 | AC_MSG_CHECKING(for PT_GETDBREGS) |
| 1403 | AC_CACHE_VAL(gdb_cv_have_pt_getdbregs, |
| 1404 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 1405 | #include <sys/ptrace.h>], |
| 1406 | [PT_GETDBREGS;], |
| 1407 | [gdb_cv_have_pt_getdbregs=yes], |
| 1408 | [gdb_cv_have_pt_getdbregs=no])]) |
| 1409 | AC_MSG_RESULT($gdb_cv_have_pt_getdbregs) |
| 1410 | if test "$gdb_cv_have_pt_getdbregs" = yes; then |
| 1411 | AC_DEFINE(HAVE_PT_GETDBREGS, 1, |
| 1412 | [Define if sys/ptrace.h defines the PT_GETDBREGS request.]) |
| 1413 | fi |
| 1414 | |
| 1415 | # See if <sys/ptrace.h> provides the PT_GETXMMREGS request. |
| 1416 | AC_MSG_CHECKING(for PT_GETXMMREGS) |
| 1417 | AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs, |
| 1418 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 1419 | #include <sys/ptrace.h>], |
| 1420 | [PT_GETXMMREGS;], |
| 1421 | [gdb_cv_have_pt_getxmmregs=yes], |
| 1422 | [gdb_cv_have_pt_getxmmregs=no])]) |
| 1423 | AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs) |
| 1424 | if test "$gdb_cv_have_pt_getxmmregs" = yes; then |
| 1425 | AC_DEFINE(HAVE_PT_GETXMMREGS, 1, |
| 1426 | [Define if sys/ptrace.h defines the PT_GETXMMREGS request.]) |
| 1427 | fi |
| 1428 | |
| 1429 | # See if <sys/ptrace.h> supports LWP names on FreeBSD |
| 1430 | # Older FreeBSD versions don't have the pl_tdname member of |
| 1431 | # `struct ptrace_lwpinfo'. |
| 1432 | AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [], |
| 1433 | [#include <sys/ptrace.h>]) |
| 1434 | |
| 1435 | # See if <sys/ptrace.h> supports syscall fields on FreeBSD. The |
| 1436 | # pl_syscall_code member of `struct ptrace_lwpinfo' was added in |
| 1437 | # FreeBSD 10.3. |
| 1438 | AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [], |
| 1439 | [#include <sys/ptrace.h>]) |
| 1440 | |
| 1441 | # Check if the compiler supports the `long long' type. |
| 1442 | |
| 1443 | AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long, |
| 1444 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM( |
| 1445 | [[extern long long foo;]], |
| 1446 | [[switch (foo & 2) { case 0: return 1; }]])], |
| 1447 | gdb_cv_c_long_long=yes, |
| 1448 | gdb_cv_c_long_long=no)]) |
| 1449 | if test "$gdb_cv_c_long_long" != yes; then |
| 1450 | # libdecnumber requires long long. |
| 1451 | AC_MSG_ERROR([Compiler must support long long for GDB.]) |
| 1452 | fi |
| 1453 | |
| 1454 | # Check if the compiler and runtime support printing long longs. |
| 1455 | |
| 1456 | AC_CACHE_CHECK([for long long support in printf], |
| 1457 | gdb_cv_printf_has_long_long, |
| 1458 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1459 | [[char buf[32]; |
| 1460 | long long l = 0; |
| 1461 | l = (l << 16) + 0x0123; |
| 1462 | l = (l << 16) + 0x4567; |
| 1463 | l = (l << 16) + 0x89ab; |
| 1464 | l = (l << 16) + 0xcdef; |
| 1465 | sprintf (buf, "0x%016llx", l); |
| 1466 | return (strcmp ("0x0123456789abcdef", buf));]])], |
| 1467 | gdb_cv_printf_has_long_long=yes, |
| 1468 | gdb_cv_printf_has_long_long=no, |
| 1469 | gdb_cv_printf_has_long_long=no)]) |
| 1470 | if test "$gdb_cv_printf_has_long_long" = yes; then |
| 1471 | AC_DEFINE(PRINTF_HAS_LONG_LONG, 1, |
| 1472 | [Define to 1 if the "%ll" format works to print long longs.]) |
| 1473 | fi |
| 1474 | |
| 1475 | # Check if the compiler and runtime support printing decfloats. |
| 1476 | |
| 1477 | AC_CACHE_CHECK([for decfloat support in printf], |
| 1478 | gdb_cv_printf_has_decfloat, |
| 1479 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1480 | [[char buf[64]; |
| 1481 | _Decimal32 d32 = 1.2345df; |
| 1482 | _Decimal64 d64 = 1.2345dd; |
| 1483 | _Decimal128 d128 = 1.2345dl; |
| 1484 | sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128); |
| 1485 | return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])], |
| 1486 | gdb_cv_printf_has_decfloat=yes, |
| 1487 | gdb_cv_printf_has_decfloat=no, |
| 1488 | gdb_cv_printf_has_decfloat=no)]) |
| 1489 | if test "$gdb_cv_printf_has_decfloat" = yes; then |
| 1490 | AC_DEFINE(PRINTF_HAS_DECFLOAT, 1, |
| 1491 | [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.]) |
| 1492 | fi |
| 1493 | |
| 1494 | # Check if the compiler supports the `long double' type. We can't use |
| 1495 | # AC_C_LONG_DOUBLE because that one does additional checks on the |
| 1496 | # constants defined in <float.h> that fail on some systems, |
| 1497 | # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6. |
| 1498 | |
| 1499 | AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double, |
| 1500 | [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])], |
| 1501 | gdb_cv_c_long_double=yes, |
| 1502 | gdb_cv_c_long_double=no)]) |
| 1503 | if test "$gdb_cv_c_long_double" = yes; then |
| 1504 | AC_DEFINE(HAVE_LONG_DOUBLE, 1, |
| 1505 | [Define to 1 if the compiler supports long double.]) |
| 1506 | fi |
| 1507 | |
| 1508 | # Check if the compiler and runtime support printing long doubles. |
| 1509 | |
| 1510 | AC_CACHE_CHECK([for long double support in printf], |
| 1511 | gdb_cv_printf_has_long_double, |
| 1512 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1513 | [[char buf[16]; |
| 1514 | long double f = 3.141592653; |
| 1515 | sprintf (buf, "%Lg", f); |
| 1516 | return (strncmp ("3.14159", buf, 7));]])], |
| 1517 | gdb_cv_printf_has_long_double=yes, |
| 1518 | gdb_cv_printf_has_long_double=no, |
| 1519 | gdb_cv_printf_has_long_double=no)]) |
| 1520 | if test "$gdb_cv_printf_has_long_double" = yes; then |
| 1521 | AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1, |
| 1522 | [Define to 1 if the "%Lg" format works to print long doubles.]) |
| 1523 | fi |
| 1524 | |
| 1525 | # Check if the compiler and runtime support scanning long doubles. |
| 1526 | |
| 1527 | AC_CACHE_CHECK([for long double support in scanf], |
| 1528 | gdb_cv_scanf_has_long_double, |
| 1529 | [AC_RUN_IFELSE([AC_LANG_PROGRAM( |
| 1530 | [[#include <stdio.h>]], |
| 1531 | [[char *buf = "3.141592653"; |
| 1532 | long double f = 0; |
| 1533 | sscanf (buf, "%Lg", &f); |
| 1534 | return !(f > 3.14159 && f < 3.14160);]])], |
| 1535 | gdb_cv_scanf_has_long_double=yes, |
| 1536 | gdb_cv_scanf_has_long_double=no, |
| 1537 | gdb_cv_scanf_has_long_double=no)]) |
| 1538 | if test "$gdb_cv_scanf_has_long_double" = yes; then |
| 1539 | AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1, |
| 1540 | [Define to 1 if the "%Lg" format works to scan long doubles.]) |
| 1541 | fi |
| 1542 | |
| 1543 | case ${host_os} in |
| 1544 | aix*) |
| 1545 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| 1546 | SAVE_LDFLAGS=$LDFLAGS |
| 1547 | |
| 1548 | case $GCC in |
| 1549 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| 1550 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| 1551 | esac |
| 1552 | |
| 1553 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| 1554 | AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=]) |
| 1555 | LDFLAGS="${SAVE_LDFLAGS}" |
| 1556 | ]) |
| 1557 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}" |
| 1558 | ;; |
| 1559 | esac |
| 1560 | |
| 1561 | AC_MSG_CHECKING(for the dynamic export flag) |
| 1562 | dynamic_list=false |
| 1563 | if test "${gdb_native}" = yes; then |
| 1564 | # The dynamically loaded libthread_db needs access to symbols in the gdb |
| 1565 | # executable. Older GNU ld supports --export-dynamic but --dynamic-list |
| 1566 | # may not be supported there. |
| 1567 | old_LDFLAGS="$LDFLAGS" |
| 1568 | # Older GNU ld supports --export-dynamic but --dynamic-list it does not. |
| 1569 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 1570 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 1571 | if test "${have_libpython}" = no; then |
| 1572 | AC_TRY_LINK([], [], [dynamic_list=true]) |
| 1573 | else |
| 1574 | # Workaround http://bugs.python.org/issue4434 where static |
| 1575 | # libpythonX.Y.a would get its symbols required for |
| 1576 | # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list. |
| 1577 | # Problem does not happen for the recommended libpythonX.Y.so linkage. |
| 1578 | |
| 1579 | # Note the workaround for Python |
| 1580 | # http://bugs.python.org/issue10112 earlier has removed |
| 1581 | # -export-dynamic from PYTHON_LIBS. That's exactly what we want |
| 1582 | # here too, as otherwise it'd make this -Wl,--dynamic-list test |
| 1583 | # always pass. |
| 1584 | old_CFLAGS="$CFLAGS" |
| 1585 | CFLAGS="$CFLAGS $PYTHON_CFLAGS" |
| 1586 | old_LIBS="$LIBS" |
| 1587 | LIBS="$LIBS $PYTHON_LIBS" |
| 1588 | old_CPPFLAGS="$CPPFLAGS" |
| 1589 | CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS" |
| 1590 | AC_RUN_IFELSE( |
| 1591 | [AC_LANG_PROGRAM( |
| 1592 | [#include "Python.h"], |
| 1593 | [int err; |
| 1594 | Py_Initialize (); |
| 1595 | err = PyRun_SimpleString ("import itertools\n"); |
| 1596 | Py_Finalize (); |
| 1597 | return err == 0 ? 0 : 1;])], |
| 1598 | [dynamic_list=true], [], [true]) |
| 1599 | LIBS="$old_LIBS" |
| 1600 | CFLAGS="$old_CFLAGS" |
| 1601 | CPPFLAGS="$old_CPPFLAGS" |
| 1602 | fi |
| 1603 | LDFLAGS="$old_LDFLAGS" |
| 1604 | fi |
| 1605 | if $dynamic_list; then |
| 1606 | found="-Wl,--dynamic-list" |
| 1607 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list' |
| 1608 | else |
| 1609 | found="-rdynamic" |
| 1610 | RDYNAMIC="-rdynamic" |
| 1611 | fi |
| 1612 | AC_SUBST(RDYNAMIC) |
| 1613 | AC_MSG_RESULT($found) |
| 1614 | |
| 1615 | dnl For certain native configurations, we need to check whether thread |
| 1616 | dnl support can be built in or not. |
| 1617 | dnl |
| 1618 | dnl Note that we only want this if we are both native (host == target), |
| 1619 | dnl and not doing a canadian cross build (build == host). |
| 1620 | |
| 1621 | if test "${build}" = "${host}" -a "${host}" = "${target}" ; then |
| 1622 | case ${host_os} in |
| 1623 | aix*) |
| 1624 | AC_MSG_CHECKING(for AiX thread debugging library) |
| 1625 | AC_CACHE_VAL(gdb_cv_have_aix_thread_debug, |
| 1626 | [AC_TRY_COMPILE([#include <sys/pthdebug.h>], |
| 1627 | [#ifndef PTHDB_VERSION_3 |
| 1628 | #error |
| 1629 | #endif], |
| 1630 | gdb_cv_have_aix_thread_debug=yes, |
| 1631 | gdb_cv_have_aix_thread_debug=no)]) |
| 1632 | AC_MSG_RESULT($gdb_cv_have_aix_thread_debug) |
| 1633 | if test "$gdb_cv_have_aix_thread_debug" = yes; then |
| 1634 | CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c" |
| 1635 | CONFIG_OBS="${CONFIG_OBS} aix-thread.o" |
| 1636 | LIBS="$LIBS -lpthdebug" |
| 1637 | |
| 1638 | # Older versions of AIX do not provide the declaration for |
| 1639 | # the getthrds function (it appears that it was introduced |
| 1640 | # with AIX 6.x). |
| 1641 | AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]]) |
| 1642 | fi |
| 1643 | ;; |
| 1644 | esac |
| 1645 | AC_SUBST(CONFIG_LDFLAGS) |
| 1646 | fi |
| 1647 | |
| 1648 | dnl See if we have a thread_db header file that has TD_NOTALLOC and |
| 1649 | dnl other error codes. |
| 1650 | if test "x$ac_cv_header_thread_db_h" = "xyes"; then |
| 1651 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC], |
| 1652 | gdb_cv_thread_db_h_has_td_notalloc, |
| 1653 | AC_TRY_COMPILE( |
| 1654 | [#include <thread_db.h>], |
| 1655 | [int i = TD_NOTALLOC;], |
| 1656 | gdb_cv_thread_db_h_has_td_notalloc=yes, |
| 1657 | gdb_cv_thread_db_h_has_td_notalloc=no |
| 1658 | ) |
| 1659 | ) |
| 1660 | AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION], |
| 1661 | gdb_cv_thread_db_h_has_td_version, |
| 1662 | AC_TRY_COMPILE( |
| 1663 | [#include <thread_db.h>], |
| 1664 | [int i = TD_VERSION;], |
| 1665 | gdb_cv_thread_db_h_has_td_version=yes, |
| 1666 | gdb_cv_thread_db_h_has_td_version=no |
| 1667 | ) |
| 1668 | ) |
| 1669 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS], |
| 1670 | gdb_cv_thread_db_h_has_td_notls, |
| 1671 | AC_TRY_COMPILE( |
| 1672 | [#include <thread_db.h>], |
| 1673 | [int i = TD_NOTLS;], |
| 1674 | gdb_cv_thread_db_h_has_td_notls=yes, |
| 1675 | gdb_cv_thread_db_h_has_td_notls=no |
| 1676 | ) |
| 1677 | ) |
| 1678 | fi |
| 1679 | if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then |
| 1680 | AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1, |
| 1681 | [Define if <thread_db.h> has the TD_NOTALLOC error code.]) |
| 1682 | fi |
| 1683 | if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then |
| 1684 | AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1, |
| 1685 | [Define if <thread_db.h> has the TD_VERSION error code.]) |
| 1686 | fi |
| 1687 | if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then |
| 1688 | AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1, |
| 1689 | [Define if <thread_db.h> has the TD_NOTLS error code.]) |
| 1690 | fi |
| 1691 | |
| 1692 | dnl Set the host's .gdbinit filename. |
| 1693 | case $host_os in |
| 1694 | go32* | *djgpp*) |
| 1695 | gdbinit=gdb.ini |
| 1696 | ;; |
| 1697 | *) |
| 1698 | gdbinit=.gdbinit |
| 1699 | ;; |
| 1700 | esac |
| 1701 | AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.]) |
| 1702 | |
| 1703 | dnl Handle optional features that can be enabled. |
| 1704 | |
| 1705 | # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR, |
| 1706 | # except that the argument to --with-sysroot is optional. |
| 1707 | # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path. |
| 1708 | if test "x$with_sysroot" = xyes; then |
| 1709 | with_sysroot="${exec_prefix}/${target_alias}/sys-root" |
| 1710 | fi |
| 1711 | AC_ARG_WITH(sysroot, |
| 1712 | AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], |
| 1713 | [search for usr/lib et al within DIR]), |
| 1714 | [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=]) |
| 1715 | AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT, |
| 1716 | [search for usr/lib et al within DIR]) |
| 1717 | AC_SUBST(TARGET_SYSTEM_ROOT) |
| 1718 | GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir}) |
| 1719 | |
| 1720 | GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit, |
| 1721 | [automatically load a system-wide gdbinit file], |
| 1722 | []) |
| 1723 | GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir, |
| 1724 | [automatically load system-wide gdbinit files from this directory], |
| 1725 | []) |
| 1726 | |
| 1727 | AM_GDB_WARNINGS |
| 1728 | AM_GDB_UBSAN |
| 1729 | |
| 1730 | # In the Cygwin environment, we need some additional flags. |
| 1731 | AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin, |
| 1732 | [AC_EGREP_CPP(^lose$, [ |
| 1733 | #if defined (__CYGWIN__) || defined (__CYGWIN32__) |
| 1734 | lose |
| 1735 | #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])]) |
| 1736 | |
| 1737 | |
| 1738 | dnl Figure out which of the many generic ser-*.c files the _host_ supports. |
| 1739 | SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o" |
| 1740 | case ${host} in |
| 1741 | *go32* ) SER_HARDWIRE=ser-go32.o ;; |
| 1742 | *djgpp* ) SER_HARDWIRE=ser-go32.o ;; |
| 1743 | *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;; |
| 1744 | *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;; |
| 1745 | esac |
| 1746 | AC_SUBST(SER_HARDWIRE) |
| 1747 | |
| 1748 | # libreadline needs libuser32.a in a cygwin environment |
| 1749 | WIN32LIBS= |
| 1750 | if test x"$gdb_cv_os_cygwin" = xyes; then |
| 1751 | WIN32LIBS="-luser32" |
| 1752 | case "${target}" in |
| 1753 | *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp" |
| 1754 | ;; |
| 1755 | esac |
| 1756 | fi |
| 1757 | |
| 1758 | # The ser-tcp.c module requires sockets. |
| 1759 | # Note that WIN32APILIBS is set by GDB_AC_COMMON. |
| 1760 | WIN32LIBS="$WIN32LIBS $WIN32APILIBS" |
| 1761 | |
| 1762 | # Add ELF support to GDB, but only if BFD includes ELF support. |
| 1763 | GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf, |
| 1764 | [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h) |
| 1765 | if test "$gdb_cv_var_elf" = yes; then |
| 1766 | CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o" |
| 1767 | AC_DEFINE(HAVE_ELF, 1, |
| 1768 | [Define if ELF support should be included.]) |
| 1769 | # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>. |
| 1770 | if test "$plugins" = "yes"; then |
| 1771 | AC_SEARCH_LIBS(dlopen, dl) |
| 1772 | fi |
| 1773 | fi |
| 1774 | |
| 1775 | # Add macho support to GDB, but only if BFD includes it. |
| 1776 | GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho, |
| 1777 | [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h) |
| 1778 | if test "$gdb_cv_var_macho" = yes; then |
| 1779 | CONFIG_OBS="$CONFIG_OBS machoread.o" |
| 1780 | fi |
| 1781 | |
| 1782 | # Add any host-specific objects to GDB. |
| 1783 | CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}" |
| 1784 | |
| 1785 | # If building on ELF, look for lzma support for embedded compressed debug info. |
| 1786 | if test "$gdb_cv_var_elf" = yes; then |
| 1787 | AC_ARG_WITH(lzma, |
| 1788 | AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]), |
| 1789 | [], [with_lzma=auto]) |
| 1790 | AC_MSG_CHECKING([whether to use lzma]) |
| 1791 | AC_MSG_RESULT([$with_lzma]) |
| 1792 | |
| 1793 | if test "${with_lzma}" != no; then |
| 1794 | AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"], |
| 1795 | [lzma_index_iter iter; |
| 1796 | lzma_index_iter_init (&iter, 0); |
| 1797 | lzma_mf_is_supported (LZMA_MF_HC3);]) |
| 1798 | if test "$HAVE_LIBLZMA" != yes; then |
| 1799 | if test "$with_lzma" = yes; then |
| 1800 | AC_MSG_ERROR([missing liblzma for --with-lzma]) |
| 1801 | fi |
| 1802 | fi |
| 1803 | fi |
| 1804 | fi |
| 1805 | |
| 1806 | LIBGUI="../libgui/src/libgui.a" |
| 1807 | GUI_CFLAGS_X="-I${srcdir}/../libgui/src" |
| 1808 | AC_SUBST(LIBGUI) |
| 1809 | AC_SUBST(GUI_CFLAGS_X) |
| 1810 | |
| 1811 | WIN32LDAPP= |
| 1812 | AC_SUBST(WIN32LIBS) |
| 1813 | AC_SUBST(WIN32LDAPP) |
| 1814 | |
| 1815 | case "${host}" in |
| 1816 | *-*-cygwin* | *-*-mingw* ) |
| 1817 | configdir="win" |
| 1818 | ;; |
| 1819 | *) |
| 1820 | configdir="unix" |
| 1821 | ;; |
| 1822 | esac |
| 1823 | |
| 1824 | GDBTKLIBS= |
| 1825 | if test "${enable_gdbtk}" = "yes"; then |
| 1826 | |
| 1827 | # Gdbtk must have an absolute path to srcdir in order to run |
| 1828 | # properly when not installed. |
| 1829 | here=`pwd` |
| 1830 | cd ${srcdir} |
| 1831 | GDBTK_SRC_DIR=`pwd` |
| 1832 | cd $here |
| 1833 | |
| 1834 | SC_PATH_TCLCONFIG |
| 1835 | |
| 1836 | # If $no_tk is nonempty, then we can't do Tk, and there is no |
| 1837 | # point to doing Tcl. |
| 1838 | SC_PATH_TKCONFIG |
| 1839 | |
| 1840 | if test -z "${no_tcl}" -a -z "${no_tk}"; then |
| 1841 | SC_LOAD_TCLCONFIG |
| 1842 | |
| 1843 | # Check for in-tree tcl |
| 1844 | here=`pwd` |
| 1845 | cd ${srcdir}/.. |
| 1846 | topdir=`pwd` |
| 1847 | cd ${here} |
| 1848 | |
| 1849 | intree="no" |
| 1850 | if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then |
| 1851 | intree="yes" |
| 1852 | fi |
| 1853 | |
| 1854 | # Find Tcl private headers |
| 1855 | if test x"${intree}" = xno; then |
| 1856 | CY_AC_TCL_PRIVATE_HEADERS |
| 1857 | TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}" |
| 1858 | TCL_LIBRARY="${TCL_LIB_SPEC}" |
| 1859 | TCL_DEPS="" |
| 1860 | else |
| 1861 | # If building tcl in the same src tree, private headers |
| 1862 | # are not needed, but we need to be sure to use the right |
| 1863 | # headers library |
| 1864 | TCL_INCLUDE="-I${TCL_SRC_DIR}/generic" |
| 1865 | TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}" |
| 1866 | TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}" |
| 1867 | fi |
| 1868 | AC_SUBST(TCL_INCLUDE) |
| 1869 | AC_SUBST(TCL_LIBRARY) |
| 1870 | AC_SUBST(TCL_DEPS) |
| 1871 | |
| 1872 | SC_LOAD_TKCONFIG |
| 1873 | |
| 1874 | # Check for in-tree Tk |
| 1875 | intree="no" |
| 1876 | if test "${TK_SRC_DIR}" = "${topdir}/tk"; then |
| 1877 | intree="yes" |
| 1878 | fi |
| 1879 | |
| 1880 | # Find Tk private headers |
| 1881 | if test x"${intree}" = xno; then |
| 1882 | CY_AC_TK_PRIVATE_HEADERS |
| 1883 | TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}" |
| 1884 | TK_LIBRARY=${TK_LIB_SPEC} |
| 1885 | TK_DEPS="" |
| 1886 | else |
| 1887 | TK_INCLUDE="-I${TK_SRC_DIR}/generic" |
| 1888 | TK_LIBRARY="${TK_BUILD_LIB_SPEC}" |
| 1889 | TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}" |
| 1890 | fi |
| 1891 | AC_SUBST(TK_INCLUDE) |
| 1892 | AC_SUBST(TK_LIBRARY) |
| 1893 | AC_SUBST(TK_DEPS) |
| 1894 | AC_SUBST(TK_XINCLUDES) |
| 1895 | |
| 1896 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)" |
| 1897 | |
| 1898 | # Include some libraries that Tcl and Tk want. |
| 1899 | TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)' |
| 1900 | # Yes, the ordering seems wrong here. But it isn't. |
| 1901 | # TK_LIBS is the list of libraries that need to be linked |
| 1902 | # after Tcl/Tk. Note that this isn't put into LIBS. If it |
| 1903 | # were in LIBS then any link tests after this point would |
| 1904 | # try to include things like `$(LIBGUI)', which wouldn't work. |
| 1905 | GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}" |
| 1906 | |
| 1907 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)" |
| 1908 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)" |
| 1909 | CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)" |
| 1910 | CONFIG_ALL="${CONFIG_ALL} all-gdbtk" |
| 1911 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk" |
| 1912 | CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk" |
| 1913 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk" |
| 1914 | |
| 1915 | if test x"$gdb_cv_os_cygwin" = xyes; then |
| 1916 | WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32" |
| 1917 | WIN32LDAPP="-Wl,--subsystem,console" |
| 1918 | CONFIG_OBS="${CONFIG_OBS} gdbres.o" |
| 1919 | fi |
| 1920 | |
| 1921 | AC_CONFIG_SUBDIRS(gdbtk) |
| 1922 | fi |
| 1923 | fi |
| 1924 | |
| 1925 | AC_SUBST(X_CFLAGS) |
| 1926 | AC_SUBST(X_LDFLAGS) |
| 1927 | AC_SUBST(X_LIBS) |
| 1928 | AC_SUBST(GDBTKLIBS) |
| 1929 | AC_SUBST(GDBTK_CFLAGS) |
| 1930 | AC_SUBST(GDBTK_SRC_DIR) |
| 1931 | |
| 1932 | AC_PATH_X |
| 1933 | |
| 1934 | # Unlike the sim directory, whether a simulator is linked is controlled by |
| 1935 | # presence of a gdb_sim definition in the target configure.tgt entry. |
| 1936 | # This code just checks for a few cases where we'd like to ignore those |
| 1937 | # definitions, even when they're present in the '.mt' file. These cases |
| 1938 | # are when --disable-sim is specified, or if the simulator directory is |
| 1939 | # not part of the source tree. |
| 1940 | # |
| 1941 | AC_ARG_ENABLE(sim, |
| 1942 | AS_HELP_STRING([--enable-sim], [link gdb with simulator]), |
| 1943 | [echo "enable_sim = $enable_sim"; |
| 1944 | echo "enableval = ${enableval}"; |
| 1945 | case "${enableval}" in |
| 1946 | yes) ignore_sim=false ;; |
| 1947 | no) ignore_sim=true ;; |
| 1948 | *) ignore_sim=false ;; |
| 1949 | esac], |
| 1950 | [ignore_sim=false]) |
| 1951 | |
| 1952 | if test ! -d "${srcdir}/../sim"; then |
| 1953 | ignore_sim=true |
| 1954 | fi |
| 1955 | |
| 1956 | SIM= |
| 1957 | SIM_OBS= |
| 1958 | if test "${ignore_sim}" = "false"; then |
| 1959 | if test x"${gdb_sim}" != x ; then |
| 1960 | SIM="${gdb_sim}" |
| 1961 | SIM_OBS="remote-sim.o" |
| 1962 | AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.]) |
| 1963 | |
| 1964 | # Some tdep code should only be compiled in when the ppc sim is |
| 1965 | # built. PR sim/13418. |
| 1966 | case $target in |
| 1967 | powerpc*-*-*) |
| 1968 | AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.]) |
| 1969 | ;; |
| 1970 | esac |
| 1971 | fi |
| 1972 | fi |
| 1973 | AC_SUBST(SIM) |
| 1974 | AC_SUBST(SIM_OBS) |
| 1975 | |
| 1976 | AC_SUBST(ENABLE_CFLAGS) |
| 1977 | AC_SUBST(PROFILE_CFLAGS) |
| 1978 | |
| 1979 | AC_SUBST(CONFIG_OBS) |
| 1980 | AC_SUBST(CONFIG_DEPS) |
| 1981 | AC_SUBST(CONFIG_SRCS) |
| 1982 | AC_SUBST(CONFIG_ALL) |
| 1983 | AC_SUBST(CONFIG_CLEAN) |
| 1984 | AC_SUBST(CONFIG_INSTALL) |
| 1985 | AC_SUBST(CONFIG_UNINSTALL) |
| 1986 | |
| 1987 | # List of host floatformats. |
| 1988 | AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat]) |
| 1989 | AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat]) |
| 1990 | AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat]) |
| 1991 | |
| 1992 | # target_subdir is used by the testsuite to find the target libraries. |
| 1993 | target_subdir= |
| 1994 | if test "${host}" != "${target}"; then |
| 1995 | target_subdir="${target_alias}/" |
| 1996 | fi |
| 1997 | AC_SUBST(target_subdir) |
| 1998 | |
| 1999 | # Import nat definitions. |
| 2000 | nat_makefile_frag=/dev/null |
| 2001 | if test "${gdb_native}" = "yes"; then |
| 2002 | . ${srcdir}/configure.nat |
| 2003 | nativefile=$NAT_FILE |
| 2004 | fi |
| 2005 | |
| 2006 | AC_SUBST(NAT_FILE) |
| 2007 | AC_SUBST(NATDEPFILES) |
| 2008 | AC_SUBST(NAT_CDEPS) |
| 2009 | AC_SUBST(LOADLIBES) |
| 2010 | AC_SUBST(MH_CFLAGS) |
| 2011 | AC_SUBST(XM_CLIBS) |
| 2012 | AC_SUBST(NAT_GENERATED_FILES) |
| 2013 | AC_SUBST(HAVE_NATIVE_GCORE_HOST) |
| 2014 | AC_SUBST_FILE(nat_makefile_frag) |
| 2015 | |
| 2016 | if test x"${gdb_osabi}" != x ; then |
| 2017 | AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi, |
| 2018 | [Define to the default OS ABI for this configuration.]) |
| 2019 | fi |
| 2020 | |
| 2021 | # Check for babeltrace and babeltrace-ctf |
| 2022 | AC_ARG_WITH(babeltrace, |
| 2023 | AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]), |
| 2024 | [], [with_babeltrace=auto]) |
| 2025 | AC_MSG_CHECKING([whether to use babeltrace]) |
| 2026 | AC_MSG_RESULT([$with_babeltrace]) |
| 2027 | |
| 2028 | if test "x$with_babeltrace" = "xno"; then |
| 2029 | AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.]) |
| 2030 | else |
| 2031 | # Append -Werror to CFLAGS so that configure can catch the warning |
| 2032 | # "assignment from incompatible pointer type", which is related to |
| 2033 | # the babeltrace change from 1.0.3 to 1.1.0. Babeltrace 1.1.0 works |
| 2034 | # in GDB, while babeltrace 1.0.3 is broken. |
| 2035 | # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be |
| 2036 | # safe to save and restore CFLAGS here. |
| 2037 | saved_CFLAGS=$CFLAGS |
| 2038 | CFLAGS="$CFLAGS -Werror" |
| 2039 | AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf], |
| 2040 | [#include <babeltrace/babeltrace.h> |
| 2041 | #include <babeltrace/ctf/events.h> |
| 2042 | #include <babeltrace/ctf/iterator.h>], |
| 2043 | [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL)); |
| 2044 | struct bt_ctf_event *event = NULL; |
| 2045 | const struct bt_definition *scope; |
| 2046 | |
| 2047 | pos->type = BT_SEEK_BEGIN; |
| 2048 | bt_iter_set_pos (bt_ctf_get_iter (NULL), pos); |
| 2049 | scope = bt_ctf_get_top_level_scope (event, |
| 2050 | BT_STREAM_EVENT_HEADER); |
| 2051 | bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id")); |
| 2052 | ]) |
| 2053 | CFLAGS=$saved_CFLAGS |
| 2054 | |
| 2055 | if test "$HAVE_LIBBABELTRACE" != yes; then |
| 2056 | if test "$with_babeltrace" = yes; then |
| 2057 | AC_MSG_ERROR([babeltrace is missing or unusable]) |
| 2058 | else |
| 2059 | AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.]) |
| 2060 | fi |
| 2061 | fi |
| 2062 | fi |
| 2063 | |
| 2064 | # Check for xxhash |
| 2065 | AC_ARG_WITH(xxhash, |
| 2066 | AC_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]), |
| 2067 | [], [with_xxhash=auto]) |
| 2068 | |
| 2069 | if test "x$with_xxhash" != "xno"; then |
| 2070 | AC_LIB_HAVE_LINKFLAGS([xxhash], [], |
| 2071 | [#include <xxhash.h>], |
| 2072 | [XXH32("foo", 3, 0); |
| 2073 | ]) |
| 2074 | if test "$HAVE_LIBXXHASH" != yes; then |
| 2075 | if test "$with_xxhash" = yes; then |
| 2076 | AC_MSG_ERROR([xxhash is missing or unusable]) |
| 2077 | fi |
| 2078 | fi |
| 2079 | if test "x$with_xxhash" = "xauto"; then |
| 2080 | with_xxhash="$HAVE_LIBXXHASH" |
| 2081 | fi |
| 2082 | fi |
| 2083 | |
| 2084 | AC_MSG_CHECKING([whether to use xxhash]) |
| 2085 | AC_MSG_RESULT([$with_xxhash]) |
| 2086 | |
| 2087 | NM_H= |
| 2088 | rm -f nm.h |
| 2089 | if test "${nativefile}" != ""; then |
| 2090 | case "${nativefile}" in |
| 2091 | nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;; |
| 2092 | * ) GDB_NM_FILE="${nativefile}" |
| 2093 | esac |
| 2094 | AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh], |
| 2095 | [GDB_NM_FILE=$GDB_NM_FILE]) |
| 2096 | AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile]) |
| 2097 | NM_H=nm.h |
| 2098 | fi |
| 2099 | AC_SUBST(GDB_NM_FILE) |
| 2100 | AC_SUBST(NM_H) |
| 2101 | |
| 2102 | dnl Add dependency for xsltproc if building with maintainer-mode enabled. |
| 2103 | AC_PATH_PROGS(XSLTPROC, xsltproc, missing) |
| 2104 | if test "x$USE_MAINTAINER_MODE" = xyes; then |
| 2105 | if test "${XSLTPROC}" = missing; then |
| 2106 | AC_ERROR(unable to find xsltproc. maintainer-mode requires xsltproc.) |
| 2107 | fi |
| 2108 | fi |
| 2109 | AC_SUBST(XSLTPROC) |
| 2110 | |
| 2111 | dnl Check for exe extension set on certain hosts (e.g. Win32) |
| 2112 | AC_EXEEXT |
| 2113 | |
| 2114 | dnl Detect the character set used by this host. |
| 2115 | dnl At the moment, we just assume it's UTF-8. |
| 2116 | AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8", |
| 2117 | [Define to be a string naming the default host character set.]) |
| 2118 | |
| 2119 | GDB_AC_SELFTEST([ |
| 2120 | CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)" |
| 2121 | CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)" |
| 2122 | ]) |
| 2123 | |
| 2124 | GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME]) |
| 2125 | GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME]) |
| 2126 | AC_CONFIG_FILES([gcore], [chmod +x gcore]) |
| 2127 | AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile]) |
| 2128 | |
| 2129 | AC_OUTPUT |