| 1 | dnl Autoconf configure script for GDB, the GNU debugger. |
| 2 | dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, |
| 3 | dnl 2005, 2006, 2007, 2008 |
| 4 | dnl Free Software Foundation, Inc. |
| 5 | dnl |
| 6 | dnl This file is part of GDB. |
| 7 | dnl |
| 8 | dnl This program is free software; you can redistribute it and/or modify |
| 9 | dnl it under the terms of the GNU General Public License as published by |
| 10 | dnl the Free Software Foundation; either version 3 of the License, or |
| 11 | dnl (at your option) any later version. |
| 12 | dnl |
| 13 | dnl This program is distributed in the hope that it will be useful, |
| 14 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 15 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 16 | dnl GNU General Public License for more details. |
| 17 | dnl |
| 18 | dnl You should have received a copy of the GNU General Public License |
| 19 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 20 | |
| 21 | dnl Process this file with autoconf to produce a configure script. |
| 22 | |
| 23 | AC_PREREQ(2.59)dnl |
| 24 | AC_INIT(main.c) |
| 25 | AC_CONFIG_HEADER(config.h:config.in) |
| 26 | AM_MAINTAINER_MODE |
| 27 | |
| 28 | AC_PROG_CC |
| 29 | AC_GNU_SOURCE |
| 30 | AC_AIX |
| 31 | AC_ISC_POSIX |
| 32 | gl_EARLY |
| 33 | AM_PROG_CC_STDC |
| 34 | |
| 35 | AC_CONFIG_AUX_DIR(..) |
| 36 | AC_CANONICAL_SYSTEM |
| 37 | |
| 38 | dnl List of object files and targets accumulated by configure. |
| 39 | |
| 40 | CONFIG_OBS= |
| 41 | CONFIG_DEPS= |
| 42 | CONFIG_SRCS= |
| 43 | ENABLE_CFLAGS= |
| 44 | |
| 45 | CONFIG_ALL= |
| 46 | CONFIG_CLEAN= |
| 47 | CONFIG_INSTALL= |
| 48 | CONFIG_UNINSTALL= |
| 49 | |
| 50 | dnl Set up for gettext. |
| 51 | ZW_GNU_GETTEXT_SISTER_DIR |
| 52 | |
| 53 | localedir='${datadir}/locale' |
| 54 | AC_SUBST(localedir) |
| 55 | |
| 56 | if test x"$USE_NLS" = xyes; then |
| 57 | CONFIG_ALL="$CONFIG_ALL all-po" |
| 58 | CONFIG_CLEAN="$CONFIG_CLEAN clean-po" |
| 59 | CONFIG_INSTALL="$CONFIG_INSTALL install-po" |
| 60 | CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po" |
| 61 | fi |
| 62 | |
| 63 | gl_INIT |
| 64 | |
| 65 | # For Makefile dependencies. |
| 66 | GNULIB_STDINT_H= |
| 67 | if test x"$STDINT_H" != x; then |
| 68 | GNULIB_STDINT_H=gnulib/$STDINT_H |
| 69 | fi |
| 70 | AC_SUBST(GNULIB_STDINT_H) |
| 71 | |
| 72 | PACKAGE=gdb |
| 73 | AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ]) |
| 74 | AC_SUBST(PACKAGE) |
| 75 | |
| 76 | # GDB does not use automake, but gnulib does. This line lets us |
| 77 | # generate its Makefile.in. |
| 78 | AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define]) |
| 79 | |
| 80 | debugdir=${libdir}/debug |
| 81 | |
| 82 | AC_ARG_WITH(separate-debug-dir, |
| 83 | [ --with-separate-debug-dir=path Look for global separate debug info in this path [LIBDIR/debug]], |
| 84 | [debugdir="${withval}"]) |
| 85 | |
| 86 | AC_DEFINE_DIR(DEBUGDIR, debugdir, |
| 87 | [Global directory for separate debug files. ]) |
| 88 | #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"), |
| 89 | |
| 90 | if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then |
| 91 | if test "x$prefix" = xNONE; then |
| 92 | test_prefix=/usr/local |
| 93 | else |
| 94 | test_prefix=$prefix |
| 95 | fi |
| 96 | else |
| 97 | test_prefix=$exec_prefix |
| 98 | fi |
| 99 | case ${debugdir} in |
| 100 | "${test_prefix}"|"${test_prefix}/"*|\ |
| 101 | '${exec_prefix}'|'${exec_prefix}/'*) |
| 102 | AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.]) |
| 103 | ;; |
| 104 | esac |
| 105 | |
| 106 | AC_CONFIG_SUBDIRS(doc testsuite) |
| 107 | |
| 108 | # Check whether to support alternative target configurations |
| 109 | AC_ARG_ENABLE(targets, |
| 110 | [ --enable-targets alternative target configurations], |
| 111 | [case "${enableval}" in |
| 112 | yes | "") AC_ERROR(enable-targets option must specify target names or 'all') |
| 113 | ;; |
| 114 | no) enable_targets= ;; |
| 115 | *) enable_targets=$enableval ;; |
| 116 | esac]) |
| 117 | |
| 118 | # Check whether to enable 64-bit support on 32-bit hosts |
| 119 | AC_ARG_ENABLE(64-bit-bfd, |
| 120 | [ --enable-64-bit-bfd 64-bit support (on hosts with narrower word sizes)], |
| 121 | [case "${enableval}" in |
| 122 | yes) want64=true ;; |
| 123 | no) want64=false ;; |
| 124 | *) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;; |
| 125 | esac],[want64=false])dnl |
| 126 | |
| 127 | # Provide defaults for some variables set by the per-host and per-target |
| 128 | # configuration. |
| 129 | gdb_host_obs=posix-hdep.o |
| 130 | |
| 131 | if test "${target}" = "${host}"; then |
| 132 | gdb_native=yes |
| 133 | else |
| 134 | gdb_native=no |
| 135 | fi |
| 136 | |
| 137 | . $srcdir/configure.host |
| 138 | |
| 139 | # Accumulate some settings from configure.tgt over all enabled targets |
| 140 | |
| 141 | TARGET_OBS= |
| 142 | all_targets= |
| 143 | |
| 144 | for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'` |
| 145 | do |
| 146 | if test "$targ_alias" = "all"; then |
| 147 | all_targets=true |
| 148 | else |
| 149 | # Canonicalize the secondary target names. |
| 150 | result=`$ac_config_sub $targ_alias 2>/dev/null` |
| 151 | if test -n "$result"; then |
| 152 | targ=$result |
| 153 | else |
| 154 | targ=$targ_alias |
| 155 | fi |
| 156 | |
| 157 | . ${srcdir}/configure.tgt |
| 158 | |
| 159 | # Target-specific object files |
| 160 | for i in ${gdb_target_obs}; do |
| 161 | case " $TARGET_OBS " in |
| 162 | *" ${i} "*) ;; |
| 163 | *) |
| 164 | TARGET_OBS="$TARGET_OBS ${i}" |
| 165 | ;; |
| 166 | esac |
| 167 | done |
| 168 | |
| 169 | # Check whether this target needs 64-bit CORE_ADDR |
| 170 | if test x${want64} = xfalse; then |
| 171 | . ${srcdir}/../bfd/config.bfd |
| 172 | fi |
| 173 | fi |
| 174 | done |
| 175 | |
| 176 | if test x${all_targets} = xtrue; then |
| 177 | |
| 178 | # We want all 64-bit targets if we either: |
| 179 | # - run on a 64-bit host or |
| 180 | # - already require 64-bit support for some other target or |
| 181 | # - the --enable-64-bit-bfd option was supplied |
| 182 | # Otherwise we only support all 32-bit targets. |
| 183 | # |
| 184 | # NOTE: This test must be in sync with the corresponding |
| 185 | # tests in BFD! |
| 186 | |
| 187 | if test x${want64} = xfalse; then |
| 188 | AC_CHECK_SIZEOF(long) |
| 189 | if test "x${ac_cv_sizeof_long}" = "x8"; then |
| 190 | want64=true |
| 191 | fi |
| 192 | fi |
| 193 | if test x${want64} = xtrue; then |
| 194 | TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)' |
| 195 | else |
| 196 | TARGET_OBS='$(ALL_TARGET_OBS)' |
| 197 | fi |
| 198 | fi |
| 199 | |
| 200 | AC_SUBST(TARGET_OBS) |
| 201 | |
| 202 | # For other settings, only the main target counts. |
| 203 | gdb_sim= |
| 204 | gdb_osabi= |
| 205 | build_gdbserver= |
| 206 | targ=$target; . ${srcdir}/configure.tgt |
| 207 | |
| 208 | # Fetch the default architecture and default target vector from BFD. |
| 209 | targ=$target; . $srcdir/../bfd/config.bfd |
| 210 | |
| 211 | # We only want the first architecture, so strip off the others if |
| 212 | # there is more than one. |
| 213 | targ_archs=`echo $targ_archs | sed 's/ .*//'` |
| 214 | |
| 215 | if test "x$targ_archs" != x; then |
| 216 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs, |
| 217 | [Define to BFD's default architecture. ]) |
| 218 | fi |
| 219 | if test "x$targ_defvec" != x; then |
| 220 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec, |
| 221 | [Define to BFD's default target vector. ]) |
| 222 | fi |
| 223 | |
| 224 | # The CLI cannot be disabled yet, but may be in the future. |
| 225 | |
| 226 | # Enable CLI. |
| 227 | AC_ARG_ENABLE(gdbcli, |
| 228 | [ --disable-gdbcli disable command-line interface (CLI)], |
| 229 | [case $enableval in |
| 230 | yes) |
| 231 | ;; |
| 232 | no) |
| 233 | AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;; |
| 234 | *) |
| 235 | AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;; |
| 236 | esac], |
| 237 | [enable_gdbcli=yes]) |
| 238 | if test x"$enable_gdbcli" = xyes; then |
| 239 | if test -d $srcdir/cli; then |
| 240 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)" |
| 241 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)" |
| 242 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)" |
| 243 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)" |
| 244 | fi |
| 245 | fi |
| 246 | |
| 247 | # Enable MI. |
| 248 | AC_ARG_ENABLE(gdbmi, |
| 249 | [ --disable-gdbmi disable machine-interface (MI)], |
| 250 | [case $enableval in |
| 251 | yes | no) |
| 252 | ;; |
| 253 | *) |
| 254 | AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;; |
| 255 | esac], |
| 256 | [enable_gdbmi=yes]) |
| 257 | if test x"$enable_gdbmi" = xyes; then |
| 258 | if test -d $srcdir/mi; then |
| 259 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)" |
| 260 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)" |
| 261 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)" |
| 262 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)" |
| 263 | fi |
| 264 | fi |
| 265 | |
| 266 | # Enable TUI. |
| 267 | AC_ARG_ENABLE(tui, |
| 268 | [ --enable-tui enable full-screen terminal user interface (TUI)], |
| 269 | [case $enableval in |
| 270 | yes | no | auto) |
| 271 | ;; |
| 272 | *) |
| 273 | AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;; |
| 274 | esac],enable_tui=auto) |
| 275 | |
| 276 | # Enable gdbtk. |
| 277 | AC_ARG_ENABLE(gdbtk, |
| 278 | [ --enable-gdbtk enable gdbtk graphical user interface (GUI)], |
| 279 | [case $enableval in |
| 280 | yes | no) |
| 281 | ;; |
| 282 | *) |
| 283 | AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;; |
| 284 | esac], |
| 285 | [if test -d $srcdir/gdbtk; then |
| 286 | enable_gdbtk=yes |
| 287 | else |
| 288 | enable_gdbtk=no |
| 289 | fi]) |
| 290 | # We unconditionally disable gdbtk tests on selected platforms. |
| 291 | case $host_os in |
| 292 | go32* | windows*) |
| 293 | AC_MSG_WARN([gdbtk isn't supported on $host; disabling]) |
| 294 | enable_gdbtk=no ;; |
| 295 | esac |
| 296 | |
| 297 | # Libunwind support. |
| 298 | AC_ARG_WITH(libunwind, |
| 299 | [ --with-libunwind Use libunwind frame unwinding support], |
| 300 | [case "${withval}" in |
| 301 | yes) enable_libunwind=yes ;; |
| 302 | no) enable_libunwind=no ;; |
| 303 | *) AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;; |
| 304 | esac],[ |
| 305 | AC_CHECK_HEADERS(libunwind.h) |
| 306 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 307 | if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then |
| 308 | enable_libunwind=yes; |
| 309 | fi |
| 310 | ]) |
| 311 | |
| 312 | if test x"$enable_libunwind" = xyes; then |
| 313 | AC_CHECK_HEADERS(libunwind.h) |
| 314 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 315 | AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.]) |
| 316 | CONFIG_OBS="$CONFIG_OBS libunwind-frame.o" |
| 317 | CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o" |
| 318 | CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c" |
| 319 | fi |
| 320 | |
| 321 | # Profiling support. |
| 322 | AC_ARG_ENABLE(profiling, |
| 323 | [ --enable-profiling enable profiling of GDB], |
| 324 | [case $enableval in |
| 325 | yes | no) |
| 326 | ;; |
| 327 | *) |
| 328 | AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;; |
| 329 | esac], |
| 330 | [enable_profiling=no]) |
| 331 | |
| 332 | AC_CHECK_FUNCS(monstartup _mcleanup) |
| 333 | AC_CACHE_CHECK([for _etext], ac_cv_var__etext, |
| 334 | [AC_TRY_LINK( |
| 335 | [#include <stdlib.h> |
| 336 | extern char _etext; |
| 337 | ], |
| 338 | [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)]) |
| 339 | if test $ac_cv_var__etext = yes; then |
| 340 | AC_DEFINE(HAVE__ETEXT, 1, |
| 341 | [Define to 1 if your system has the _etext variable. ]) |
| 342 | fi |
| 343 | AC_CACHE_CHECK([for etext], ac_cv_var_etext, |
| 344 | [AC_TRY_LINK( |
| 345 | [#include <stdlib.h> |
| 346 | extern char etext; |
| 347 | ], |
| 348 | [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)]) |
| 349 | if test $ac_cv_var_etext = yes; then |
| 350 | AC_DEFINE(HAVE_ETEXT, 1, |
| 351 | [Define to 1 if your system has the etext variable. ]) |
| 352 | fi |
| 353 | if test "$enable_profiling" = yes ; then |
| 354 | if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then |
| 355 | AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup) |
| 356 | fi |
| 357 | PROFILE_CFLAGS=-pg |
| 358 | OLD_CFLAGS="$CFLAGS" |
| 359 | CFLAGS="$CFLAGS $PROFILE_CFLAGS" |
| 360 | |
| 361 | AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg, |
| 362 | [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes, |
| 363 | ac_cv_cc_supports_pg=no)]) |
| 364 | |
| 365 | if test $ac_cv_cc_supports_pg = no; then |
| 366 | AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg) |
| 367 | fi |
| 368 | |
| 369 | CFLAGS="$OLD_CFLAGS" |
| 370 | fi |
| 371 | |
| 372 | ACX_PKGVERSION([GDB]) |
| 373 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 374 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 375 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 376 | |
| 377 | # --------------------- # |
| 378 | # Checks for programs. # |
| 379 | # --------------------- # |
| 380 | |
| 381 | AC_PROG_AWK |
| 382 | AC_PROG_INSTALL |
| 383 | AC_PROG_LN_S |
| 384 | AC_PROG_RANLIB |
| 385 | AC_PROG_YACC |
| 386 | |
| 387 | AC_CHECK_TOOL(AR, ar) |
| 388 | AC_CHECK_TOOL(DLLTOOL, dlltool) |
| 389 | AC_CHECK_TOOL(WINDRES, windres) |
| 390 | |
| 391 | # Needed for GNU/Hurd. |
| 392 | AC_CHECK_TOOL(MIG, mig) |
| 393 | |
| 394 | # ---------------------- # |
| 395 | # Checks for libraries. # |
| 396 | # ---------------------- # |
| 397 | |
| 398 | # We might need to link with -lm; most simulators need it. |
| 399 | AC_CHECK_LIB(m, main) |
| 400 | |
| 401 | # We need to link with -lw to get `wctype' on Solaris before Solaris |
| 402 | # 2.6. Solaris 2.6 and beyond have this function in libc, and have a |
| 403 | # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1 |
| 404 | # is known to have this problem). Therefore we avoid libw if we can. |
| 405 | AC_CHECK_FUNC(wctype, [], |
| 406 | [AC_CHECK_LIB(w, wctype)]) |
| 407 | |
| 408 | # Some systems (e.g. Solaris) have `gethostbyname' in libnsl. |
| 409 | AC_SEARCH_LIBS(gethostbyname, nsl) |
| 410 | |
| 411 | # Some systems (e.g. Solaris) have `socketpair' in libsocket. |
| 412 | AC_SEARCH_LIBS(socketpair, socket) |
| 413 | |
| 414 | # Link in zlib if we can. This allows us to read compressed debug sections. |
| 415 | AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)]) |
| 416 | |
| 417 | # For the TUI, we need enhanced curses functionality. |
| 418 | # |
| 419 | # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied |
| 420 | # curses library because the latter might not provide all the |
| 421 | # functionality we need. However, this leads to problems on systems |
| 422 | # where the linker searches /usr/local/lib, but the compiler doesn't |
| 423 | # search /usr/local/include, if ncurses is installed in /usr/local. A |
| 424 | # default installation of ncurses on alpha*-dec-osf* will lead to such |
| 425 | # a situation. |
| 426 | AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses]) |
| 427 | |
| 428 | # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c). |
| 429 | AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl]) |
| 430 | |
| 431 | # Since GDB uses Readline, we need termcap functionality. In many |
| 432 | # cases this will be provided by the curses library, but some systems |
| 433 | # have a seperate termcap library, or no curses library at all. |
| 434 | |
| 435 | case $host_os in |
| 436 | cygwin*) |
| 437 | if test -d $srcdir/libtermcap; then |
| 438 | LIBS="../libtermcap/libtermcap.a $LIBS" |
| 439 | ac_cv_search_tgetent="../libtermcap/libtermcap.a" |
| 440 | fi ;; |
| 441 | go32* | *djgpp*) |
| 442 | ac_cv_search_tgetent="none required" |
| 443 | ;; |
| 444 | *mingw32*) |
| 445 | ac_cv_search_tgetent="none required" |
| 446 | CONFIG_OBS="$CONFIG_OBS win32-termcap.o" |
| 447 | ;; |
| 448 | esac |
| 449 | |
| 450 | # These are the libraries checked by Readline. |
| 451 | AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses]) |
| 452 | |
| 453 | if test "$ac_cv_search_tgetent" = no; then |
| 454 | AC_MSG_ERROR([no termcap library found]) |
| 455 | fi |
| 456 | |
| 457 | AC_ARG_WITH([system-readline], |
| 458 | [AS_HELP_STRING([--with-system-readline], |
| 459 | [use installed readline library])]) |
| 460 | |
| 461 | if test "$with_system_readline" = yes; then |
| 462 | READLINE=-lreadline |
| 463 | READLINE_DEPS= |
| 464 | READLINE_CFLAGS= |
| 465 | else |
| 466 | READLINE='$(READLINE_DIR)/libreadline.a' |
| 467 | READLINE_DEPS='$(READLINE)' |
| 468 | READLINE_CFLAGS='-I$(READLINE_SRC)/..' |
| 469 | fi |
| 470 | AC_SUBST(READLINE) |
| 471 | AC_SUBST(READLINE_DEPS) |
| 472 | AC_SUBST(READLINE_CFLAGS) |
| 473 | |
| 474 | AC_ARG_WITH(expat, |
| 475 | AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]), |
| 476 | [], [with_expat=auto]) |
| 477 | AC_MSG_CHECKING([whether to use expat]) |
| 478 | AC_MSG_RESULT([$with_expat]) |
| 479 | |
| 480 | if test "${with_expat}" = no; then |
| 481 | AC_MSG_WARN([expat support disabled; some features may be unavailable.]) |
| 482 | HAVE_LIBEXPAT=no |
| 483 | else |
| 484 | AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"], |
| 485 | [XML_Parser p = XML_ParserCreate (0);]) |
| 486 | if test "$HAVE_LIBEXPAT" != yes; then |
| 487 | if test "$with_expat" = yes; then |
| 488 | AC_MSG_ERROR([expat is missing or unusable]) |
| 489 | else |
| 490 | AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.]) |
| 491 | fi |
| 492 | else |
| 493 | save_LIBS=$LIBS |
| 494 | LIBS="$LIBS $LIBEXPAT" |
| 495 | AC_CHECK_FUNCS(XML_StopParser) |
| 496 | LIBS=$save_LIBS |
| 497 | fi |
| 498 | fi |
| 499 | |
| 500 | # ------------------------- # |
| 501 | # Checks for header files. # |
| 502 | # ------------------------- # |
| 503 | |
| 504 | AC_HEADER_DIRENT |
| 505 | AC_HEADER_STAT |
| 506 | AC_HEADER_STDC |
| 507 | AC_CHECK_HEADERS(nlist.h) |
| 508 | AC_CHECK_HEADERS(link.h, [], [], |
| 509 | [#if HAVE_SYS_TYPES_H |
| 510 | # include <sys/types.h> |
| 511 | #endif |
| 512 | #if HAVE_NLIST_H |
| 513 | # include <nlist.h> |
| 514 | #endif |
| 515 | ]) |
| 516 | AC_CHECK_HEADERS(machine/reg.h) |
| 517 | AC_CHECK_HEADERS(poll.h sys/poll.h) |
| 518 | AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h) |
| 519 | AC_CHECK_HEADERS(signal.h) |
| 520 | AC_CHECK_HEADERS(stddef.h) |
| 521 | AC_CHECK_HEADERS(stdlib.h) |
| 522 | AC_CHECK_HEADERS(string.h memory.h strings.h) |
| 523 | AC_CHECK_HEADERS(sys/fault.h) |
| 524 | AC_CHECK_HEADERS(sys/file.h) |
| 525 | AC_CHECK_HEADERS(sys/filio.h) |
| 526 | AC_CHECK_HEADERS(sys/ioctl.h) |
| 527 | AC_CHECK_HEADERS(sys/param.h) |
| 528 | AC_CHECK_HEADERS(sys/resource.h) |
| 529 | AC_CHECK_HEADERS(sys/proc.h, [], [], |
| 530 | [#if HAVE_SYS_PARAM_H |
| 531 | # include <sys/param.h> |
| 532 | #endif |
| 533 | ]) |
| 534 | AC_CHECK_HEADERS(sys/procfs.h) |
| 535 | AC_CHECK_HEADERS(sys/ptrace.h ptrace.h) |
| 536 | AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h) |
| 537 | AC_CHECK_HEADERS(sys/select.h) |
| 538 | AC_CHECK_HEADERS(sys/syscall.h) |
| 539 | AC_CHECK_HEADERS(sys/types.h) |
| 540 | AC_CHECK_HEADERS(sys/user.h, [], [], |
| 541 | [#if HAVE_SYS_PARAM_H |
| 542 | # include <sys/param.h> |
| 543 | #endif |
| 544 | ]) |
| 545 | AC_CHECK_HEADERS(sys/wait.h wait.h) |
| 546 | AC_CHECK_HEADERS(termios.h termio.h sgtty.h) |
| 547 | AC_CHECK_HEADERS(unistd.h) |
| 548 | |
| 549 | # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash |
| 550 | # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to |
| 551 | # think that we don't have <curses.h> if we're using GCC. |
| 552 | case $host_os in |
| 553 | solaris2.[[789]]) |
| 554 | if test "$GCC" = yes; then |
| 555 | AC_DEFINE(_MSE_INT_H, 1, |
| 556 | [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on |
| 557 | Solaris 2.[789] when using GCC. ]) |
| 558 | fi ;; |
| 559 | esac |
| 560 | AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h) |
| 561 | AC_CHECK_HEADERS(ncurses/term.h) |
| 562 | AC_CHECK_HEADERS(term.h, [], [], |
| 563 | [#if HAVE_CURSES_H |
| 564 | # include <curses.h> |
| 565 | #endif |
| 566 | ]) |
| 567 | |
| 568 | # Check for HP/UX 64-bit shared library support |
| 569 | AC_CHECK_HEADERS(elf_hp.h) |
| 570 | |
| 571 | # FIXME: kettenis/20030102: In most cases we include these |
| 572 | # unconditionally, so what's the point in checking these? |
| 573 | AC_CHECK_HEADERS(ctype.h time.h) |
| 574 | |
| 575 | # ------------------------- # |
| 576 | # Checks for declarations. # |
| 577 | # ------------------------- # |
| 578 | |
| 579 | AC_CHECK_DECLS([free, malloc, realloc]) |
| 580 | AC_CHECK_DECLS([strerror, strstr]) |
| 581 | AC_CHECK_DECLS([getopt, snprintf, vsnprintf]) |
| 582 | |
| 583 | # ----------------------- # |
| 584 | # Checks for structures. # |
| 585 | # ----------------------- # |
| 586 | |
| 587 | AC_CHECK_MEMBERS([struct stat.st_blocks]) |
| 588 | AC_CHECK_MEMBERS([struct stat.st_blksize]) |
| 589 | |
| 590 | # ------------------ # |
| 591 | # Checks for types. # |
| 592 | # ------------------ # |
| 593 | |
| 594 | AC_TYPE_SIGNAL |
| 595 | AC_CHECK_TYPES(socklen_t, [], [], |
| 596 | [#include <sys/types.h> |
| 597 | #include <sys/socket.h> |
| 598 | ]) |
| 599 | |
| 600 | # ------------------------------------- # |
| 601 | # Checks for compiler characteristics. # |
| 602 | # ------------------------------------- # |
| 603 | |
| 604 | AC_C_CONST |
| 605 | AC_C_INLINE |
| 606 | AC_C_BIGENDIAN |
| 607 | |
| 608 | # ------------------------------ # |
| 609 | # Checks for library functions. # |
| 610 | # ------------------------------ # |
| 611 | |
| 612 | AC_FUNC_ALLOCA |
| 613 | AC_FUNC_MMAP |
| 614 | AC_FUNC_VFORK |
| 615 | AC_CHECK_FUNCS(canonicalize_file_name realpath) |
| 616 | AC_CHECK_FUNCS(getrusage) |
| 617 | AC_CHECK_FUNCS(getuid getgid) |
| 618 | AC_CHECK_FUNCS(poll) |
| 619 | AC_CHECK_FUNCS(pread64) |
| 620 | AC_CHECK_FUNCS(sbrk) |
| 621 | AC_CHECK_FUNCS(setpgid setpgrp setsid) |
| 622 | AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask) |
| 623 | AC_CHECK_FUNCS(socketpair) |
| 624 | AC_CHECK_FUNCS(syscall) |
| 625 | AC_CHECK_FUNCS(ttrace) |
| 626 | AC_CHECK_FUNCS(wborder) |
| 627 | |
| 628 | # Check the return and argument types of ptrace. No canned test for |
| 629 | # this, so roll our own. |
| 630 | gdb_ptrace_headers=' |
| 631 | #if HAVE_SYS_TYPES_H |
| 632 | # include <sys/types.h> |
| 633 | #endif |
| 634 | #if HAVE_SYS_PTRACE_H |
| 635 | # include <sys/ptrace.h> |
| 636 | #endif |
| 637 | #if HAVE_UNISTD_H |
| 638 | # include <unistd.h> |
| 639 | #endif |
| 640 | ' |
| 641 | # There is no point in checking if we don't have a prototype. |
| 642 | AC_CHECK_DECLS(ptrace, [], [ |
| 643 | : ${gdb_cv_func_ptrace_ret='int'} |
| 644 | : ${gdb_cv_func_ptrace_args='int,int,long,long'} |
| 645 | ], $gdb_ptrace_headers) |
| 646 | # Check return type. Varargs (used on GNU/Linux) conflict with the |
| 647 | # empty argument list, so check for that explicitly. |
| 648 | AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret, |
| 649 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 650 | [extern long ptrace (enum __ptrace_request, ...);], |
| 651 | gdb_cv_func_ptrace_ret='long', |
| 652 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 653 | [extern int ptrace ();], |
| 654 | gdb_cv_func_ptrace_ret='int', |
| 655 | gdb_cv_func_ptrace_ret='long'))) |
| 656 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret, |
| 657 | [Define as the return type of ptrace.]) |
| 658 | # Check argument types. |
| 659 | AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [ |
| 660 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 661 | [extern long ptrace (enum __ptrace_request, ...);], |
| 662 | [gdb_cv_func_ptrace_args='int,int,long,long'],[ |
| 663 | for gdb_arg1 in 'int' 'long'; do |
| 664 | for gdb_arg2 in 'pid_t' 'int' 'long'; do |
| 665 | for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do |
| 666 | for gdb_arg4 in 'int' 'long'; do |
| 667 | AC_TRY_COMPILE($gdb_ptrace_headers, [ |
| 668 | extern $gdb_cv_func_ptrace_ret |
| 669 | ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4); |
| 670 | ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4"; |
| 671 | break 4;]) |
| 672 | for gdb_arg5 in 'int *' 'int' 'long'; do |
| 673 | AC_TRY_COMPILE($gdb_ptrace_headers, [ |
| 674 | extern $gdb_cv_func_ptrace_ret |
| 675 | ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5); |
| 676 | ], [ |
| 677 | gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5"; |
| 678 | break 5;]) |
| 679 | done |
| 680 | done |
| 681 | done |
| 682 | done |
| 683 | done |
| 684 | # Provide a safe default value. |
| 685 | : ${gdb_cv_func_ptrace_args='int,int,long,long'} |
| 686 | ])]) |
| 687 | ac_save_IFS=$IFS; IFS=',' |
| 688 | set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'` |
| 689 | IFS=$ac_save_IFS |
| 690 | shift |
| 691 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3], |
| 692 | [Define to the type of arg 3 for ptrace.]) |
| 693 | if test -n "$[5]"; then |
| 694 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5], |
| 695 | [Define to the type of arg 5 for ptrace.]) |
| 696 | fi |
| 697 | |
| 698 | dnl AC_FUNC_SETPGRP does not work when cross compiling |
| 699 | dnl Instead, assume we will have a prototype for setpgrp if cross compiling. |
| 700 | if test "$cross_compiling" = no; then |
| 701 | AC_FUNC_SETPGRP |
| 702 | else |
| 703 | AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void, |
| 704 | [AC_TRY_COMPILE([ |
| 705 | #include <unistd.h> |
| 706 | ], [ |
| 707 | if (setpgrp(1,1) == -1) |
| 708 | exit (0); |
| 709 | else |
| 710 | exit (1); |
| 711 | ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)]) |
| 712 | if test $ac_cv_func_setpgrp_void = yes; then |
| 713 | AC_DEFINE(SETPGRP_VOID, 1) |
| 714 | fi |
| 715 | fi |
| 716 | |
| 717 | # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do |
| 718 | # since sigsetjmp might only be defined as a macro. |
| 719 | AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp, |
| 720 | [AC_TRY_COMPILE([ |
| 721 | #include <setjmp.h> |
| 722 | ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);], |
| 723 | gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)]) |
| 724 | if test $gdb_cv_func_sigsetjmp = yes; then |
| 725 | AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ]) |
| 726 | fi |
| 727 | |
| 728 | # Assume we'll default to using the included libiberty regex. |
| 729 | gdb_use_included_regex=yes |
| 730 | |
| 731 | # However, if the system regex is GNU regex, then default to *not* |
| 732 | # using the included regex. |
| 733 | AC_CACHE_CHECK( |
| 734 | [for GNU regex], |
| 735 | [gdb_cv_have_gnu_regex], |
| 736 | [AC_TRY_COMPILE( |
| 737 | [#include <gnu-versions.h>], |
| 738 | [#define REGEX_INTERFACE_VERSION 1 |
| 739 | #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION |
| 740 | # error "Version mismatch" |
| 741 | #endif], |
| 742 | gdb_cv_have_gnu_regex=yes, |
| 743 | gdb_cv_have_gnu_regex=no)]) |
| 744 | if test $gdb_cv_have_gnu_regex = yes; then |
| 745 | gdb_use_included_regex=no |
| 746 | fi |
| 747 | |
| 748 | AC_ARG_WITH(included-regex, |
| 749 | [ --without-included-regex don't use included regex; this is the default |
| 750 | on systems with version 2 of the GNU C library |
| 751 | (use with caution on other system)], |
| 752 | gdb_with_regex=$withval, |
| 753 | gdb_with_regex=$gdb_use_included_regex) |
| 754 | if test "$gdb_with_regex" = yes; then |
| 755 | AC_DEFINE(USE_INCLUDED_REGEX, 1, |
| 756 | [Define to 1 if the regex included in libiberty should be used.]) |
| 757 | fi |
| 758 | |
| 759 | # Check if <sys/proc.h> defines `struct thread' with a td_pcb member. |
| 760 | AC_CHECK_MEMBERS([struct thread.td_pcb], [], [], |
| 761 | [#include <sys/param.h> |
| 762 | #include <sys/proc.h> |
| 763 | ]) |
| 764 | |
| 765 | # See if <sys/lwp.h> defines `struct lwp`. |
| 766 | AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp, |
| 767 | [AC_TRY_COMPILE([#include <sys/param.h> |
| 768 | #include <sys/lwp.h>], [struct lwp l;], |
| 769 | gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)]) |
| 770 | if test $gdb_cv_struct_lwp = yes; then |
| 771 | AC_DEFINE(HAVE_STRUCT_LWP, 1, |
| 772 | [Define to 1 if your system has struct lwp.]) |
| 773 | fi |
| 774 | |
| 775 | # See if <machine/reg.h> degines `struct reg'. |
| 776 | AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg, |
| 777 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 778 | #include <machine/reg.h>], [struct reg r;], |
| 779 | gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)]) |
| 780 | if test $gdb_cv_struct_reg = yes; then |
| 781 | AC_DEFINE(HAVE_STRUCT_REG, 1, |
| 782 | [Define to 1 if your system has struct reg in <machine/reg.h>.]) |
| 783 | fi |
| 784 | |
| 785 | # See if <machine/reg.h> supports the %fs and %gs i386 segment registers. |
| 786 | # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'. |
| 787 | AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [], |
| 788 | [#include <machine/reg.h>]) |
| 789 | |
| 790 | # See if <sys/ptrace.h> provides the PTRACE_GETREGS request. |
| 791 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 792 | AC_CACHE_VAL(gdb_cv_have_ptrace_getregs, |
| 793 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 794 | [PTRACE_GETREGS;], |
| 795 | [gdb_cv_have_ptrace_getregs=yes], |
| 796 | [gdb_cv_have_ptrace_getregs=no])]) |
| 797 | AC_MSG_RESULT($gdb_cv_have_ptrace_getregs) |
| 798 | if test $gdb_cv_have_ptrace_getregs = yes; then |
| 799 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 800 | [Define if sys/ptrace.h defines the PTRACE_GETREGS request.]) |
| 801 | fi |
| 802 | |
| 803 | # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request. |
| 804 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 805 | AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs, |
| 806 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 807 | [PTRACE_GETFPXREGS;], |
| 808 | [gdb_cv_have_ptrace_getfpxregs=yes], |
| 809 | [gdb_cv_have_ptrace_getfpxregs=no])]) |
| 810 | AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs) |
| 811 | if test $gdb_cv_have_ptrace_getfpxregs = yes; then |
| 812 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 813 | [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.]) |
| 814 | fi |
| 815 | |
| 816 | # See if <sys/ptrace.h> provides the PT_GETDBREGS request. |
| 817 | AC_MSG_CHECKING(for PT_GETDBREGS) |
| 818 | AC_CACHE_VAL(gdb_cv_have_pt_getdbregs, |
| 819 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 820 | #include <sys/ptrace.h>], |
| 821 | [PT_GETDBREGS;], |
| 822 | [gdb_cv_have_pt_getdbregs=yes], |
| 823 | [gdb_cv_have_pt_getdbregs=no])]) |
| 824 | AC_MSG_RESULT($gdb_cv_have_pt_getdbregs) |
| 825 | if test $gdb_cv_have_pt_getdbregs = yes; then |
| 826 | AC_DEFINE(HAVE_PT_GETDBREGS, 1, |
| 827 | [Define if sys/ptrace.h defines the PT_GETDBREGS request.]) |
| 828 | fi |
| 829 | |
| 830 | # See if <sys/ptrace.h> provides the PT_GETXMMREGS request. |
| 831 | AC_MSG_CHECKING(for PT_GETXMMREGS) |
| 832 | AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs, |
| 833 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 834 | #include <sys/ptrace.h>], |
| 835 | [PT_GETXMMREGS;], |
| 836 | [gdb_cv_have_pt_getxmmregs=yes], |
| 837 | [gdb_cv_have_pt_getxmmregs=no])]) |
| 838 | AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs) |
| 839 | if test $gdb_cv_have_pt_getxmmregs = yes; then |
| 840 | AC_DEFINE(HAVE_PT_GETXMMREGS, 1, |
| 841 | [Define if sys/ptrace.h defines the PT_GETXMMREGS request.]) |
| 842 | fi |
| 843 | |
| 844 | # Detect which type of /proc is in use, such as for Unixware or Solaris. |
| 845 | |
| 846 | if test "${target}" = "${host}"; then |
| 847 | case "${host}" in |
| 848 | *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* ) |
| 849 | AC_DEFINE(NEW_PROC_API, 1, |
| 850 | [Define if you want to use new multi-fd /proc interface |
| 851 | (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).]) |
| 852 | ;; |
| 853 | *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*) |
| 854 | AC_DEFINE(NEW_PROC_API, 1, |
| 855 | [Define if you want to use new multi-fd /proc interface |
| 856 | (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).]) |
| 857 | ;; |
| 858 | mips-sgi-irix5*) |
| 859 | # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5. |
| 860 | AC_DEFINE([_KMEMUSER], 1, |
| 861 | [Define to 1 so <sys/proc.h> gets a definition of anon_hdl. Works |
| 862 | around a <sys/proc.h> problem on IRIX 5.]) |
| 863 | ;; |
| 864 | esac |
| 865 | fi |
| 866 | |
| 867 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 868 | BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t) |
| 869 | BFD_HAVE_SYS_PROCFS_TYPE(prrun_t) |
| 870 | BFD_HAVE_SYS_PROCFS_TYPE(gregset_t) |
| 871 | BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t) |
| 872 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 873 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 874 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t) |
| 875 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t) |
| 876 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 877 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 878 | BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t) |
| 879 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t) |
| 880 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t) |
| 881 | BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t) |
| 882 | |
| 883 | |
| 884 | dnl Check for broken prfpregset_t type |
| 885 | |
| 886 | dnl For Linux/i386, glibc 2.1.3 was released with a bogus |
| 887 | dnl prfpregset_t type (it's a typedef for the pointer to a struct |
| 888 | dnl instead of the struct itself). We detect this here, and work |
| 889 | dnl around it in gdb_proc_service.h. |
| 890 | |
| 891 | if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then |
| 892 | AC_MSG_CHECKING(whether prfpregset_t type is broken) |
| 893 | AC_CACHE_VAL(gdb_cv_prfpregset_t_broken, |
| 894 | [AC_TRY_RUN([#include <sys/procfs.h> |
| 895 | int main () |
| 896 | { |
| 897 | if (sizeof (prfpregset_t) == sizeof (void *)) |
| 898 | return 1; |
| 899 | return 0; |
| 900 | }], |
| 901 | gdb_cv_prfpregset_t_broken=no, |
| 902 | gdb_cv_prfpregset_t_broken=yes, |
| 903 | gdb_cv_prfpregset_t_broken=yes)]) |
| 904 | AC_MSG_RESULT($gdb_cv_prfpregset_t_broken) |
| 905 | if test $gdb_cv_prfpregset_t_broken = yes; then |
| 906 | AC_DEFINE(PRFPREGSET_T_BROKEN, 1, |
| 907 | [Define if the prfpregset_t type is broken.]) |
| 908 | fi |
| 909 | fi |
| 910 | |
| 911 | dnl Check for PIOCSET ioctl entry |
| 912 | |
| 913 | AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h) |
| 914 | AC_CACHE_VAL(gdb_cv_have_procfs_piocset, |
| 915 | [AC_TRY_COMPILE([#include <unistd.h> |
| 916 | #include <sys/types.h> |
| 917 | #include <sys/procfs.h> |
| 918 | ], [ |
| 919 | int dummy;; |
| 920 | dummy = ioctl(0, PIOCSET, &dummy); |
| 921 | ], |
| 922 | gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)]) |
| 923 | AC_MSG_RESULT($gdb_cv_have_procfs_piocset) |
| 924 | if test $gdb_cv_have_procfs_piocset = yes; then |
| 925 | AC_DEFINE(HAVE_PROCFS_PIOCSET, 1, |
| 926 | [Define if ioctl argument PIOCSET is available.]) |
| 927 | fi |
| 928 | fi |
| 929 | |
| 930 | dnl For native ports (host == target), check to see what kind of |
| 931 | dnl legacy link.h support is needed. (See solib-legacy.c.) |
| 932 | if test ${host} = ${target} ; then |
| 933 | dnl Check for struct link_map with l_ members which are indicative |
| 934 | dnl of SVR4-like shared libraries |
| 935 | |
| 936 | AC_MSG_CHECKING(for member l_addr in struct link_map) |
| 937 | AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members, |
| 938 | [AC_TRY_COMPILE([#include <link.h>], |
| 939 | [struct link_map lm; (void) lm.l_addr;], |
| 940 | gdb_cv_have_struct_link_map_with_l_members=yes, |
| 941 | gdb_cv_have_struct_link_map_with_l_members=no)]) |
| 942 | AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members) |
| 943 | if test $gdb_cv_have_struct_link_map_with_l_members = yes; then |
| 944 | AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1, |
| 945 | [Define if <link.h> exists and defines struct link_map which has |
| 946 | members with an ``l_'' prefix. (For Solaris, SVR4, and |
| 947 | SVR4-like systems.)]) |
| 948 | fi |
| 949 | |
| 950 | dnl Check for struct link_map with lm_ members which are indicative |
| 951 | dnl of SunOS-like shared libraries |
| 952 | |
| 953 | AC_MSG_CHECKING(for member lm_addr in struct link_map) |
| 954 | AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members, |
| 955 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 956 | #include <link.h>], |
| 957 | [struct link_map lm; (void) lm.lm_addr;], |
| 958 | gdb_cv_have_struct_link_map_with_lm_members=yes, |
| 959 | gdb_cv_have_struct_link_map_with_lm_members=no)]) |
| 960 | AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members) |
| 961 | if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then |
| 962 | AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1, |
| 963 | [Define if <link.h> exists and defines struct link_map which has |
| 964 | members with an ``lm_'' prefix. (For SunOS.)]) |
| 965 | fi |
| 966 | |
| 967 | dnl Check for struct so_map with som_ members which are found on |
| 968 | dnl some *BSD systems. |
| 969 | |
| 970 | AC_MSG_CHECKING(for member som_addr in struct so_map) |
| 971 | AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members, |
| 972 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 973 | #ifdef HAVE_NLIST_H |
| 974 | #include <nlist.h> |
| 975 | #endif |
| 976 | #include <link.h>], |
| 977 | [struct so_map lm; (void) lm.som_addr;], |
| 978 | gdb_cv_have_struct_so_map_with_som_members=yes, |
| 979 | gdb_cv_have_struct_so_map_with_som_members=no)]) |
| 980 | AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members) |
| 981 | if test $gdb_cv_have_struct_so_map_with_som_members = yes; then |
| 982 | AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1, |
| 983 | [Define if <link.h> exists and defines a struct so_map which has |
| 984 | members with an ``som_'' prefix. (Found on older *BSD systems.)]) |
| 985 | fi |
| 986 | |
| 987 | dnl Check for struct link_map32 type, which allows a 64-bit Solaris |
| 988 | dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries. |
| 989 | |
| 990 | AC_MSG_CHECKING(for struct link_map32 in sys/link.h) |
| 991 | AC_CACHE_VAL(gdb_cv_have_struct_link_map32, |
| 992 | [AC_TRY_COMPILE([#define _SYSCALL32 |
| 993 | #include <sys/link.h>], [struct link_map32 l;], |
| 994 | gdb_cv_have_struct_link_map32=yes, |
| 995 | gdb_cv_have_struct_link_map32=no)]) |
| 996 | AC_MSG_RESULT($gdb_cv_have_struct_link_map32) |
| 997 | if test $gdb_cv_have_struct_link_map32 = yes; then |
| 998 | AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1, |
| 999 | [Define if <sys/link.h> has struct link_map32]) |
| 1000 | AC_DEFINE(_SYSCALL32, 1, |
| 1001 | [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)]) |
| 1002 | fi |
| 1003 | fi |
| 1004 | |
| 1005 | # Check if the compiler supports the `long long' type. |
| 1006 | |
| 1007 | AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long, |
| 1008 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM( |
| 1009 | [[extern long long foo;]], |
| 1010 | [[switch (foo & 2) { case 0: return 1; }]])], |
| 1011 | gdb_cv_c_long_long=yes, |
| 1012 | gdb_cv_c_long_long=no)]) |
| 1013 | if test $gdb_cv_c_long_long = yes; then |
| 1014 | AC_DEFINE(CC_HAS_LONG_LONG, 1, |
| 1015 | [Define to 1 if the compiler supports long long.]) |
| 1016 | fi |
| 1017 | |
| 1018 | # Check if the compiler and runtime support printing long longs. |
| 1019 | |
| 1020 | AC_CACHE_CHECK([for long long support in printf], |
| 1021 | gdb_cv_printf_has_long_long, |
| 1022 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1023 | [[char buf[32]; |
| 1024 | long long l = 0; |
| 1025 | l = (l << 16) + 0x0123; |
| 1026 | l = (l << 16) + 0x4567; |
| 1027 | l = (l << 16) + 0x89ab; |
| 1028 | l = (l << 16) + 0xcdef; |
| 1029 | sprintf (buf, "0x%016llx", l); |
| 1030 | return (strcmp ("0x0123456789abcdef", buf));]])], |
| 1031 | gdb_cv_printf_has_long_long=yes, |
| 1032 | gdb_cv_printf_has_long_long=no, |
| 1033 | gdb_cv_printf_has_long_long=no)]) |
| 1034 | if test $gdb_cv_printf_has_long_long = yes; then |
| 1035 | AC_DEFINE(PRINTF_HAS_LONG_LONG, 1, |
| 1036 | [Define to 1 if the "%ll" format works to print long longs.]) |
| 1037 | fi |
| 1038 | |
| 1039 | # Check if the compiler and runtime support printing decfloats. |
| 1040 | |
| 1041 | AC_CACHE_CHECK([for decfloat support in printf], |
| 1042 | gdb_cv_printf_has_decfloat, |
| 1043 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1044 | [[char buf[64]; |
| 1045 | _Decimal32 d32 = 1.2345df; |
| 1046 | _Decimal64 d64 = 1.2345dd; |
| 1047 | _Decimal128 d128 = 1.2345dl; |
| 1048 | sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128); |
| 1049 | return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])], |
| 1050 | gdb_cv_printf_has_decfloat=yes, |
| 1051 | gdb_cv_printf_has_decfloat=no, |
| 1052 | gdb_cv_printf_has_decfloat=no)]) |
| 1053 | if test $gdb_cv_printf_has_decfloat = yes; then |
| 1054 | AC_DEFINE(PRINTF_HAS_DECFLOAT, 1, |
| 1055 | [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.]) |
| 1056 | fi |
| 1057 | |
| 1058 | # Check if the compiler supports the `long double' type. We can't use |
| 1059 | # AC_C_LONG_DOUBLE because that one does additional checks on the |
| 1060 | # constants defined in <float.h> that fail on some systems, |
| 1061 | # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6. |
| 1062 | |
| 1063 | AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double, |
| 1064 | [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])], |
| 1065 | gdb_cv_c_long_double=yes, |
| 1066 | gdb_cv_c_long_double=no)]) |
| 1067 | if test $gdb_cv_c_long_double = yes; then |
| 1068 | AC_DEFINE(HAVE_LONG_DOUBLE, 1, |
| 1069 | [Define to 1 if the compiler supports long double.]) |
| 1070 | fi |
| 1071 | |
| 1072 | # Check if the compiler and runtime support printing long doubles. |
| 1073 | |
| 1074 | AC_CACHE_CHECK([for long double support in printf], |
| 1075 | gdb_cv_printf_has_long_double, |
| 1076 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1077 | [[char buf[16]; |
| 1078 | long double f = 3.141592653; |
| 1079 | sprintf (buf, "%Lg", f); |
| 1080 | return (strncmp ("3.14159", buf, 7));]])], |
| 1081 | gdb_cv_printf_has_long_double=yes, |
| 1082 | gdb_cv_printf_has_long_double=no, |
| 1083 | gdb_cv_printf_has_long_double=no)]) |
| 1084 | if test $gdb_cv_printf_has_long_double = yes; then |
| 1085 | AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1, |
| 1086 | [Define to 1 if the "%Lg" format works to print long doubles.]) |
| 1087 | fi |
| 1088 | |
| 1089 | # Check if the compiler and runtime support scanning long doubles. |
| 1090 | |
| 1091 | AC_CACHE_CHECK([for long double support in scanf], |
| 1092 | gdb_cv_scanf_has_long_double, |
| 1093 | [AC_RUN_IFELSE([AC_LANG_PROGRAM( |
| 1094 | [[#include <stdio.h>]], |
| 1095 | [[char *buf = "3.141592653"; |
| 1096 | long double f = 0; |
| 1097 | sscanf (buf, "%Lg", &f); |
| 1098 | return !(f > 3.14159 && f < 3.14160);]])], |
| 1099 | gdb_cv_scanf_has_long_double=yes, |
| 1100 | gdb_cv_scanf_has_long_double=no, |
| 1101 | gdb_cv_scanf_has_long_double=no)]) |
| 1102 | if test $gdb_cv_scanf_has_long_double = yes; then |
| 1103 | AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1, |
| 1104 | [Define to 1 if the "%Lg" format works to scan long doubles.]) |
| 1105 | fi |
| 1106 | |
| 1107 | case ${host_os} in |
| 1108 | aix*) |
| 1109 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| 1110 | SAVE_LDFLAGS=$LDFLAGS |
| 1111 | |
| 1112 | case $GCC in |
| 1113 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| 1114 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| 1115 | esac |
| 1116 | |
| 1117 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| 1118 | AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=]) |
| 1119 | LDFLAGS="${SAVE_LDFLAGS}" |
| 1120 | ]) |
| 1121 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}" |
| 1122 | ;; |
| 1123 | esac |
| 1124 | |
| 1125 | |
| 1126 | dnl For certain native configurations, we need to check whether thread |
| 1127 | dnl support can be built in or not. |
| 1128 | dnl |
| 1129 | dnl Note that we only want this if we are both native (host == target), |
| 1130 | dnl and not doing a canadian cross build (build == host). |
| 1131 | |
| 1132 | if test ${build} = ${host} -a ${host} = ${target} ; then |
| 1133 | case ${host_os} in |
| 1134 | hpux*) |
| 1135 | AC_MSG_CHECKING(for HPUX/OSF thread support) |
| 1136 | if test -f /usr/include/dce/cma_config.h ; then |
| 1137 | if test "$GCC" = "yes" ; then |
| 1138 | AC_MSG_RESULT(yes) |
| 1139 | AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1, |
| 1140 | [Define if you have HPUX threads]) |
| 1141 | CONFIG_OBS="${CONFIG_OBS} hpux-thread.o" |
| 1142 | CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c" |
| 1143 | else |
| 1144 | AC_MSG_RESULT(no (suppressed because you are not using GCC)) |
| 1145 | fi |
| 1146 | else |
| 1147 | AC_MSG_RESULT(no) |
| 1148 | fi |
| 1149 | ;; |
| 1150 | solaris*) |
| 1151 | # See if thread_db library is around for Solaris thread debugging. |
| 1152 | # Note that we must explicitly test for version 1 of the library |
| 1153 | # because version 0 (present on Solaris 2.4 or earlier) doesn't have |
| 1154 | # the same API. |
| 1155 | AC_MSG_CHECKING(for Solaris thread debugging library) |
| 1156 | if test -f /usr/lib/libthread_db.so.1 ; then |
| 1157 | AC_MSG_RESULT(yes) |
| 1158 | AC_DEFINE(HAVE_THREAD_DB_LIB, 1, |
| 1159 | [Define if using Solaris thread debugging.]) |
| 1160 | CONFIG_OBS="${CONFIG_OBS} sol-thread.o" |
| 1161 | CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c" |
| 1162 | AC_CHECK_LIB(dl, dlopen) |
| 1163 | if test "$GCC" = "yes" ; then |
| 1164 | # The GNU linker requires the -export-dynamic option to make |
| 1165 | # all symbols visible in the dynamic symbol table. |
| 1166 | hold_ldflags=$LDFLAGS |
| 1167 | AC_MSG_CHECKING(for the ld -export-dynamic flag) |
| 1168 | LDFLAGS="${LDFLAGS} -Wl,-export-dynamic" |
| 1169 | AC_TRY_LINK(, [int i;], found=yes, found=no) |
| 1170 | LDFLAGS=$hold_ldflags |
| 1171 | AC_MSG_RESULT($found) |
| 1172 | if test $found = yes; then |
| 1173 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic" |
| 1174 | fi |
| 1175 | fi |
| 1176 | # Sun randomly tweaked the prototypes in <proc_service.h> |
| 1177 | # at one point. |
| 1178 | AC_MSG_CHECKING(if <proc_service.h> is old) |
| 1179 | AC_CACHE_VAL(gdb_cv_proc_service_is_old,[ |
| 1180 | AC_TRY_COMPILE([ |
| 1181 | #include <proc_service.h> |
| 1182 | ps_err_e ps_pdwrite |
| 1183 | (struct ps_prochandle*, psaddr_t, const void*, size_t); |
| 1184 | ],, gdb_cv_proc_service_is_old=no, |
| 1185 | gdb_cv_proc_service_is_old=yes) |
| 1186 | ]) |
| 1187 | AC_MSG_RESULT($gdb_cv_proc_service_is_old) |
| 1188 | if test $gdb_cv_proc_service_is_old = yes; then |
| 1189 | AC_DEFINE(PROC_SERVICE_IS_OLD, 1, |
| 1190 | [Define if <proc_service.h> on solaris uses int instead of |
| 1191 | size_t, and assorted other type changes.]) |
| 1192 | fi |
| 1193 | else |
| 1194 | AC_MSG_RESULT(no) |
| 1195 | fi |
| 1196 | ;; |
| 1197 | aix*) |
| 1198 | AC_MSG_CHECKING(for AiX thread debugging library) |
| 1199 | AC_CACHE_VAL(gdb_cv_have_aix_thread_debug, |
| 1200 | [AC_TRY_COMPILE([#include <sys/pthdebug.h>], |
| 1201 | [#ifndef PTHDB_VERSION_3 |
| 1202 | #error |
| 1203 | #endif], |
| 1204 | gdb_cv_have_aix_thread_debug=yes, |
| 1205 | gdb_cv_have_aix_thread_debug=no)]) |
| 1206 | AC_MSG_RESULT($gdb_cv_have_aix_thread_debug) |
| 1207 | if test $gdb_cv_have_aix_thread_debug = yes; then |
| 1208 | CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c" |
| 1209 | CONFIG_OBS="${CONFIG_OBS} aix-thread.o" |
| 1210 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug" |
| 1211 | fi |
| 1212 | ;; |
| 1213 | esac |
| 1214 | AC_SUBST(CONFIG_LDFLAGS) |
| 1215 | fi |
| 1216 | |
| 1217 | dnl See if we have a thread_db header file that has TD_NOTALLOC and |
| 1218 | dnl other error codes. |
| 1219 | if test "x$ac_cv_header_thread_db_h" = "xyes"; then |
| 1220 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC], |
| 1221 | gdb_cv_thread_db_h_has_td_notalloc, |
| 1222 | AC_TRY_COMPILE( |
| 1223 | [#include <thread_db.h>], |
| 1224 | [int i = TD_NOTALLOC;], |
| 1225 | gdb_cv_thread_db_h_has_td_notalloc=yes, |
| 1226 | gdb_cv_thread_db_h_has_td_notalloc=no |
| 1227 | ) |
| 1228 | ) |
| 1229 | AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION], |
| 1230 | gdb_cv_thread_db_h_has_td_version, |
| 1231 | AC_TRY_COMPILE( |
| 1232 | [#include <thread_db.h>], |
| 1233 | [int i = TD_VERSION;], |
| 1234 | gdb_cv_thread_db_h_has_td_version=yes, |
| 1235 | gdb_cv_thread_db_h_has_td_version=no |
| 1236 | ) |
| 1237 | ) |
| 1238 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS], |
| 1239 | gdb_cv_thread_db_h_has_td_notls, |
| 1240 | AC_TRY_COMPILE( |
| 1241 | [#include <thread_db.h>], |
| 1242 | [int i = TD_NOTLS;], |
| 1243 | gdb_cv_thread_db_h_has_td_notls=yes, |
| 1244 | gdb_cv_thread_db_h_has_td_notls=no |
| 1245 | ) |
| 1246 | ) |
| 1247 | fi |
| 1248 | if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then |
| 1249 | AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1, |
| 1250 | [Define if <thread_db.h> has the TD_NOTALLOC error code.]) |
| 1251 | fi |
| 1252 | if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then |
| 1253 | AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1, |
| 1254 | [Define if <thread_db.h> has the TD_VERSION error code.]) |
| 1255 | fi |
| 1256 | if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then |
| 1257 | AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1, |
| 1258 | [Define if <thread_db.h> has the TD_NOTLS error code.]) |
| 1259 | fi |
| 1260 | |
| 1261 | dnl See if we have a sys/syscall header file that has __NR_tkill. |
| 1262 | if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then |
| 1263 | AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill], |
| 1264 | gdb_cv_sys_syscall_h_has_tkill, |
| 1265 | AC_TRY_COMPILE( |
| 1266 | [#include <sys/syscall.h>], |
| 1267 | [int i = __NR_tkill;], |
| 1268 | gdb_cv_sys_syscall_h_has_tkill=yes, |
| 1269 | gdb_cv_sys_syscall_h_has_tkill=no |
| 1270 | ) |
| 1271 | ) |
| 1272 | fi |
| 1273 | dnl See if we can issue tkill syscall. |
| 1274 | if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then |
| 1275 | AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.]) |
| 1276 | fi |
| 1277 | |
| 1278 | dnl Check if we can disable the virtual address space randomization. |
| 1279 | dnl The functionality of setarch -R. |
| 1280 | AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>]) |
| 1281 | define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [ |
| 1282 | # if !HAVE_DECL_ADDR_NO_RANDOMIZE |
| 1283 | # define ADDR_NO_RANDOMIZE 0x0040000 |
| 1284 | # endif |
| 1285 | /* Test the flag could be set and stays set. */ |
| 1286 | personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE); |
| 1287 | if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE)) |
| 1288 | return 1])]) |
| 1289 | AC_RUN_IFELSE([PERSONALITY_TEST], |
| 1290 | [have_personality=true], |
| 1291 | [have_personality=false], |
| 1292 | [AC_LINK_IFELSE([PERSONALITY_TEST], |
| 1293 | [have_personality=true], |
| 1294 | [have_personality=false])]) |
| 1295 | if $have_personality |
| 1296 | then |
| 1297 | AC_DEFINE([HAVE_PERSONALITY], 1, |
| 1298 | [Define if you support the personality syscall.]) |
| 1299 | fi |
| 1300 | |
| 1301 | dnl Handle optional features that can be enabled. |
| 1302 | |
| 1303 | AC_ARG_WITH(sysroot, |
| 1304 | [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.], |
| 1305 | [ |
| 1306 | case ${with_sysroot} in |
| 1307 | yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;; |
| 1308 | *) TARGET_SYSTEM_ROOT=$with_sysroot ;; |
| 1309 | esac |
| 1310 | |
| 1311 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"' |
| 1312 | |
| 1313 | if test "x$prefix" = xNONE; then |
| 1314 | test_prefix=/usr/local |
| 1315 | else |
| 1316 | test_prefix=$prefix |
| 1317 | fi |
| 1318 | if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then |
| 1319 | test_exec_prefix=$test_prefix |
| 1320 | else |
| 1321 | test_exec_prefix=$exec_prefix |
| 1322 | fi |
| 1323 | case ${TARGET_SYSTEM_ROOT} in |
| 1324 | "${test_prefix}"|"${test_prefix}/"*|\ |
| 1325 | "${test_exec_prefix}"|"${test_exec_prefix}/"*|\ |
| 1326 | '${prefix}'|'${prefix}/'*|\ |
| 1327 | '${exec_prefix}'|'${exec_prefix}/'*) |
| 1328 | t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE" |
| 1329 | TARGET_SYSTEM_ROOT_DEFINE="$t" |
| 1330 | ;; |
| 1331 | esac |
| 1332 | ], [ |
| 1333 | TARGET_SYSTEM_ROOT= |
| 1334 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"' |
| 1335 | ]) |
| 1336 | AC_SUBST(TARGET_SYSTEM_ROOT) |
| 1337 | AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE) |
| 1338 | |
| 1339 | AC_ARG_ENABLE(werror, |
| 1340 | [ --enable-werror treat compile warnings as errors], |
| 1341 | [case "${enableval}" in |
| 1342 | yes | y) ERROR_ON_WARNING="yes" ;; |
| 1343 | no | n) ERROR_ON_WARNING="no" ;; |
| 1344 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;; |
| 1345 | esac]) |
| 1346 | |
| 1347 | # Enable -Werror by default when using gcc |
| 1348 | if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then |
| 1349 | ERROR_ON_WARNING=yes |
| 1350 | fi |
| 1351 | |
| 1352 | WERROR_CFLAGS="" |
| 1353 | if test "${ERROR_ON_WARNING}" = yes ; then |
| 1354 | WERROR_CFLAGS="-Werror" |
| 1355 | fi |
| 1356 | |
| 1357 | # The entries after -Wno-pointer-sign are disabled warnings which may |
| 1358 | # be enabled in the future, which can not currently be used to build |
| 1359 | # GDB. |
| 1360 | # NOTE: If you change this list, remember to update |
| 1361 | # gdb/doc/gdbint.texinfo. |
| 1362 | build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \ |
| 1363 | -Wformat-nonliteral -Wno-pointer-sign \ |
| 1364 | -Wno-unused -Wno-switch -Wno-char-subscripts" |
| 1365 | |
| 1366 | # Enable -Wno-format by default when using gcc on mingw since many |
| 1367 | # GCC versions complain about %I64. |
| 1368 | case "${host}" in |
| 1369 | *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;; |
| 1370 | esac |
| 1371 | |
| 1372 | AC_ARG_ENABLE(build-warnings, |
| 1373 | [ --enable-build-warnings Enable build-time compiler warnings if gcc is used], |
| 1374 | [case "${enableval}" in |
| 1375 | yes) ;; |
| 1376 | no) build_warnings="-w";; |
| 1377 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1378 | build_warnings="${build_warnings} ${t}";; |
| 1379 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1380 | build_warnings="${t} ${build_warnings}";; |
| 1381 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 1382 | esac |
| 1383 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 1384 | echo "Setting compiler warning flags = $build_warnings" 6>&1 |
| 1385 | fi])dnl |
| 1386 | AC_ARG_ENABLE(gdb-build-warnings, |
| 1387 | [ --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used], |
| 1388 | [case "${enableval}" in |
| 1389 | yes) ;; |
| 1390 | no) build_warnings="-w";; |
| 1391 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1392 | build_warnings="${build_warnings} ${t}";; |
| 1393 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1394 | build_warnings="${t} ${build_warnings}";; |
| 1395 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 1396 | esac |
| 1397 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 1398 | echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1 |
| 1399 | fi])dnl |
| 1400 | WARN_CFLAGS="" |
| 1401 | if test "x${build_warnings}" != x -a "x$GCC" = xyes |
| 1402 | then |
| 1403 | AC_MSG_CHECKING(compiler warning flags) |
| 1404 | # Separate out the -Werror flag as some files just cannot be |
| 1405 | # compiled with it enabled. |
| 1406 | for w in ${build_warnings}; do |
| 1407 | case $w in |
| 1408 | -Werr*) WERROR_CFLAGS=-Werror ;; |
| 1409 | *) # Check that GCC accepts it |
| 1410 | saved_CFLAGS="$CFLAGS" |
| 1411 | CFLAGS="$CFLAGS $w" |
| 1412 | AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",) |
| 1413 | CFLAGS="$saved_CFLAGS" |
| 1414 | esac |
| 1415 | done |
| 1416 | AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS}) |
| 1417 | fi |
| 1418 | AC_SUBST(WARN_CFLAGS) |
| 1419 | AC_SUBST(WERROR_CFLAGS) |
| 1420 | |
| 1421 | # In the Cygwin environment, we need some additional flags. |
| 1422 | AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin, |
| 1423 | [AC_EGREP_CPP(lose, [ |
| 1424 | #if defined (__CYGWIN__) || defined (__CYGWIN32__) |
| 1425 | lose |
| 1426 | #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])]) |
| 1427 | |
| 1428 | |
| 1429 | dnl Figure out which of the many generic ser-*.c files the _host_ supports. |
| 1430 | SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o" |
| 1431 | case ${host} in |
| 1432 | *go32* ) SER_HARDWIRE=ser-go32.o ;; |
| 1433 | *djgpp* ) SER_HARDWIRE=ser-go32.o ;; |
| 1434 | *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;; |
| 1435 | esac |
| 1436 | AC_SUBST(SER_HARDWIRE) |
| 1437 | |
| 1438 | # libreadline needs libuser32.a in a cygwin environment |
| 1439 | WIN32LIBS= |
| 1440 | if test x$gdb_cv_os_cygwin = xyes; then |
| 1441 | WIN32LIBS="-luser32" |
| 1442 | case "${target}" in |
| 1443 | *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp" |
| 1444 | ;; |
| 1445 | esac |
| 1446 | fi |
| 1447 | |
| 1448 | # The ser-tcp.c module requires sockets. |
| 1449 | case ${host} in |
| 1450 | *mingw32*) |
| 1451 | AC_DEFINE(USE_WIN32API, 1, |
| 1452 | [Define if we should use the Windows API, instead of the |
| 1453 | POSIX API. On Windows, we use the Windows API when |
| 1454 | building for MinGW, but the POSIX API when building |
| 1455 | for Cygwin.]) |
| 1456 | WIN32LIBS="$WIN32LIBS -lws2_32" |
| 1457 | ;; |
| 1458 | esac |
| 1459 | AC_SUBST(WIN32LIBS) |
| 1460 | |
| 1461 | # Add ELF support to GDB, but only if BFD includes ELF support. |
| 1462 | OLD_CFLAGS=$CFLAGS |
| 1463 | OLD_LDFLAGS=$LDFLAGS |
| 1464 | OLD_LIBS=$LIBS |
| 1465 | CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd" |
| 1466 | LDFLAGS="$LDFLAGS -L../bfd -L../libiberty" |
| 1467 | intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'` |
| 1468 | LIBS="-lbfd -liberty $intl $LIBS" |
| 1469 | AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf, |
| 1470 | [AC_TRY_LINK( |
| 1471 | [#include <stdlib.h> |
| 1472 | #include "bfd.h" |
| 1473 | #include "elf-bfd.h" |
| 1474 | ], |
| 1475 | [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ], |
| 1476 | gdb_cv_var_elf=yes, gdb_cv_var_elf=no)]) |
| 1477 | if test $gdb_cv_var_elf = yes; then |
| 1478 | CONFIG_OBS="$CONFIG_OBS elfread.o" |
| 1479 | AC_DEFINE(HAVE_ELF, 1, |
| 1480 | [Define if ELF support should be included.]) |
| 1481 | fi |
| 1482 | CFLAGS=$OLD_CFLAGS |
| 1483 | LDFLAGS=$OLD_LDFLAGS |
| 1484 | LIBS=$OLD_LIBS |
| 1485 | |
| 1486 | # Add any host-specific objects to GDB. |
| 1487 | CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}" |
| 1488 | |
| 1489 | LIBGUI="../libgui/src/libgui.a" |
| 1490 | GUI_CFLAGS_X="-I${srcdir}/../libgui/src" |
| 1491 | AC_SUBST(LIBGUI) |
| 1492 | AC_SUBST(GUI_CFLAGS_X) |
| 1493 | |
| 1494 | WIN32LDAPP= |
| 1495 | AC_SUBST(WIN32LIBS) |
| 1496 | AC_SUBST(WIN32LDAPP) |
| 1497 | |
| 1498 | case "${host}" in |
| 1499 | *-*-cygwin* | *-*-mingw* ) |
| 1500 | configdir="win" |
| 1501 | ;; |
| 1502 | *) |
| 1503 | configdir="unix" |
| 1504 | ;; |
| 1505 | esac |
| 1506 | |
| 1507 | GDBTKLIBS= |
| 1508 | if test "${enable_gdbtk}" = "yes"; then |
| 1509 | |
| 1510 | # Gdbtk must have an absolute path to srcdir in order to run |
| 1511 | # properly when not installed. |
| 1512 | here=`pwd` |
| 1513 | cd ${srcdir} |
| 1514 | GDBTK_SRC_DIR=`pwd` |
| 1515 | cd $here |
| 1516 | |
| 1517 | SC_PATH_TCLCONFIG |
| 1518 | if test -z "${no_tcl}"; then |
| 1519 | SC_LOAD_TCLCONFIG |
| 1520 | |
| 1521 | # Check for in-tree tcl |
| 1522 | here=`pwd` |
| 1523 | cd ${srcdir}/.. |
| 1524 | topdir=`pwd` |
| 1525 | cd ${here} |
| 1526 | |
| 1527 | intree="no" |
| 1528 | if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then |
| 1529 | intree="yes" |
| 1530 | fi |
| 1531 | |
| 1532 | # Find Tcl private headers |
| 1533 | if test x"${intree}" = xno; then |
| 1534 | CY_AC_TCL_PRIVATE_HEADERS |
| 1535 | TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}" |
| 1536 | TCL_LIBRARY="${TCL_LIB_SPEC}" |
| 1537 | TCL_DEPS="" |
| 1538 | else |
| 1539 | # If building tcl in the same src tree, private headers |
| 1540 | # are not needed, but we need to be sure to use the right |
| 1541 | # headers library |
| 1542 | TCL_INCLUDE="-I${TCL_SRC_DIR}/generic" |
| 1543 | TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}" |
| 1544 | TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}" |
| 1545 | fi |
| 1546 | AC_SUBST(TCL_INCLUDE) |
| 1547 | AC_SUBST(TCL_LIBRARY) |
| 1548 | AC_SUBST(TCL_DEPS) |
| 1549 | |
| 1550 | # If $no_tk is nonempty, then we can't do Tk, and there is no |
| 1551 | # point to doing Tcl. |
| 1552 | if test -z "${no_tk}"; then |
| 1553 | SC_PATH_TKCONFIG |
| 1554 | SC_LOAD_TKCONFIG |
| 1555 | |
| 1556 | # Check for in-tree Tk |
| 1557 | intree="no" |
| 1558 | if test "${TK_SRC_DIR}" = "${topdir}/tk"; then |
| 1559 | intree="yes" |
| 1560 | fi |
| 1561 | |
| 1562 | # Find Tk private headers |
| 1563 | if test x"${intree}" = xno; then |
| 1564 | CY_AC_TK_PRIVATE_HEADERS |
| 1565 | TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}" |
| 1566 | TK_LIBRARY=${TK_LIB_SPEC} |
| 1567 | TK_DEPS="" |
| 1568 | else |
| 1569 | TK_INCLUDE="-I${TK_SRC_DIR}/generic" |
| 1570 | TK_LIBRARY="${TK_BUILD_LIB_SPEC}" |
| 1571 | TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}" |
| 1572 | fi |
| 1573 | AC_SUBST(TK_INCLUDE) |
| 1574 | AC_SUBST(TK_LIBRARY) |
| 1575 | AC_SUBST(TK_DEPS) |
| 1576 | AC_SUBST(TK_XINCLUDES) |
| 1577 | |
| 1578 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)" |
| 1579 | |
| 1580 | # Include some libraries that Tcl and Tk want. |
| 1581 | TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)' |
| 1582 | # Yes, the ordering seems wrong here. But it isn't. |
| 1583 | # TK_LIBS is the list of libraries that need to be linked |
| 1584 | # after Tcl/Tk. Note that this isn't put into LIBS. If it |
| 1585 | # were in LIBS then any link tests after this point would |
| 1586 | # try to include things like `$(LIBGUI)', which wouldn't work. |
| 1587 | GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}" |
| 1588 | |
| 1589 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)" |
| 1590 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)" |
| 1591 | CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)" |
| 1592 | CONFIG_ALL="${CONFIG_ALL} all-gdbtk" |
| 1593 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk" |
| 1594 | CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk" |
| 1595 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk" |
| 1596 | |
| 1597 | if test x$gdb_cv_os_cygwin = xyes; then |
| 1598 | WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32" |
| 1599 | WIN32LDAPP="-Wl,--subsystem,console" |
| 1600 | CONFIG_OBS="${CONFIG_OBS} gdbres.o" |
| 1601 | fi |
| 1602 | fi |
| 1603 | fi |
| 1604 | |
| 1605 | AC_CONFIG_SUBDIRS(gdbtk) |
| 1606 | fi |
| 1607 | |
| 1608 | AC_SUBST(X_CFLAGS) |
| 1609 | AC_SUBST(X_LDFLAGS) |
| 1610 | AC_SUBST(X_LIBS) |
| 1611 | AC_SUBST(GDBTKLIBS) |
| 1612 | AC_SUBST(GDBTK_CFLAGS) |
| 1613 | AC_SUBST(GDBTK_SRC_DIR) |
| 1614 | |
| 1615 | AC_PATH_X |
| 1616 | |
| 1617 | # Check whether we should enable the TUI, but only do so if we really |
| 1618 | # can. |
| 1619 | if test x"$enable_tui" != xno; then |
| 1620 | if test -d $srcdir/tui; then |
| 1621 | if test "$ac_cv_search_waddstr" != no; then |
| 1622 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)" |
| 1623 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)" |
| 1624 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)" |
| 1625 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)" |
| 1626 | CONFIG_ALL="${CONFIG_ALL} all-tui" |
| 1627 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui" |
| 1628 | CONFIG_INSTALL="${CONFIG_INSTALL} install-tui" |
| 1629 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui" |
| 1630 | else |
| 1631 | if test x"$enable_tui" = xyes; then |
| 1632 | AC_MSG_ERROR([no enhanced curses library found; disable TUI]) |
| 1633 | else |
| 1634 | AC_MSG_WARN([no enhanced curses library found; disabling TUI]) |
| 1635 | fi |
| 1636 | fi |
| 1637 | fi |
| 1638 | fi |
| 1639 | |
| 1640 | # Unlike the sim directory, whether a simulator is linked is controlled by |
| 1641 | # presence of a gdb_sim definition in the target configure.tgt entry. |
| 1642 | # This code just checks for a few cases where we'd like to ignore those |
| 1643 | # definitions, even when they're present in the '.mt' file. These cases |
| 1644 | # are when --disable-sim is specified, or if the simulator directory is |
| 1645 | # not part of the source tree. |
| 1646 | # |
| 1647 | AC_ARG_ENABLE(sim, |
| 1648 | [ --enable-sim Link gdb with simulator], |
| 1649 | [echo "enable_sim = $enable_sim"; |
| 1650 | echo "enableval = ${enableval}"; |
| 1651 | case "${enableval}" in |
| 1652 | yes) ignore_sim=false ;; |
| 1653 | no) ignore_sim=true ;; |
| 1654 | *) ignore_sim=false ;; |
| 1655 | esac], |
| 1656 | [ignore_sim=false]) |
| 1657 | |
| 1658 | if test ! -d "${srcdir}/../sim"; then |
| 1659 | ignore_sim=true |
| 1660 | fi |
| 1661 | |
| 1662 | SIM= |
| 1663 | SIM_OBS= |
| 1664 | if test "${ignore_sim}" = "false"; then |
| 1665 | if test x"${gdb_sim}" != x ; then |
| 1666 | SIM="${gdb_sim}" |
| 1667 | SIM_OBS="remote-sim.o" |
| 1668 | AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.]) |
| 1669 | fi |
| 1670 | fi |
| 1671 | AC_SUBST(SIM) |
| 1672 | AC_SUBST(SIM_OBS) |
| 1673 | |
| 1674 | AC_SUBST(ENABLE_CFLAGS) |
| 1675 | AC_SUBST(PROFILE_CFLAGS) |
| 1676 | |
| 1677 | AC_SUBST(CONFIG_OBS) |
| 1678 | AC_SUBST(CONFIG_DEPS) |
| 1679 | AC_SUBST(CONFIG_SRCS) |
| 1680 | AC_SUBST(CONFIG_ALL) |
| 1681 | AC_SUBST(CONFIG_CLEAN) |
| 1682 | AC_SUBST(CONFIG_INSTALL) |
| 1683 | AC_SUBST(CONFIG_UNINSTALL) |
| 1684 | |
| 1685 | # List of host floatformats. |
| 1686 | AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat]) |
| 1687 | AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat]) |
| 1688 | AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat]) |
| 1689 | |
| 1690 | # target_subdir is used by the testsuite to find the target libraries. |
| 1691 | target_subdir= |
| 1692 | if test "${host}" != "${target}"; then |
| 1693 | target_subdir="${target_alias}/" |
| 1694 | fi |
| 1695 | AC_SUBST(target_subdir) |
| 1696 | |
| 1697 | frags= |
| 1698 | if test "${gdb_native}" = "yes"; then |
| 1699 | host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh |
| 1700 | if test ! -f ${host_makefile_frag}; then |
| 1701 | AC_MSG_ERROR("*** Gdb does not support native target ${host}") |
| 1702 | fi |
| 1703 | frags="$frags $host_makefile_frag" |
| 1704 | else |
| 1705 | host_makefile_frag=/dev/null |
| 1706 | fi |
| 1707 | |
| 1708 | AC_SUBST_FILE(host_makefile_frag) |
| 1709 | AC_SUBST(frags) |
| 1710 | |
| 1711 | changequote(,)dnl |
| 1712 | if test "${gdb_native}" = "yes"; then |
| 1713 | # We pick this up from the host configuration file (.mh) because we |
| 1714 | # do not have a native configuration Makefile fragment. |
| 1715 | nativefile=`sed -n ' |
| 1716 | s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1717 | ' ${host_makefile_frag}` |
| 1718 | fi |
| 1719 | changequote([,]) |
| 1720 | |
| 1721 | if test x"${gdb_osabi}" != x ; then |
| 1722 | AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi, |
| 1723 | [Define to the default OS ABI for this configuration.]) |
| 1724 | fi |
| 1725 | |
| 1726 | # Enable multi-ice-gdb-server. |
| 1727 | AC_ARG_ENABLE(multi-ice, |
| 1728 | [ --enable-multi-ice build the multi-ice-gdb-server], |
| 1729 | [case $enableval in |
| 1730 | yes | no) |
| 1731 | ;; |
| 1732 | *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;; |
| 1733 | esac]) |
| 1734 | if test "x$enable_multi_ice" = xyes; then |
| 1735 | AC_CONFIG_SUBDIRS(multi-ice) |
| 1736 | fi |
| 1737 | |
| 1738 | # We only build gdbserver automatically in a native configuration. |
| 1739 | if test "$gdb_native" = "yes"; then |
| 1740 | AC_MSG_CHECKING(whether gdbserver is supported on this host) |
| 1741 | if test "x$build_gdbserver" = xyes; then |
| 1742 | AC_MSG_RESULT(yes) |
| 1743 | AC_CONFIG_SUBDIRS(gdbserver) |
| 1744 | else |
| 1745 | AC_MSG_RESULT(no) |
| 1746 | fi |
| 1747 | fi |
| 1748 | |
| 1749 | # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link |
| 1750 | # to an empty version. |
| 1751 | |
| 1752 | files= |
| 1753 | links= |
| 1754 | |
| 1755 | rm -f nm.h |
| 1756 | nm_h="" |
| 1757 | if test "${nativefile}" != ""; then |
| 1758 | nm_h=nm.h |
| 1759 | case "${nativefile}" in |
| 1760 | nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;; |
| 1761 | * ) GDB_NM_FILE="${nativefile}" |
| 1762 | esac |
| 1763 | files="${files} ${GDB_NM_FILE}" |
| 1764 | links="${links} nm.h" |
| 1765 | AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile]) |
| 1766 | fi |
| 1767 | AC_SUBST(nm_h) |
| 1768 | |
| 1769 | AC_LINK_FILES($files, $links) |
| 1770 | |
| 1771 | dnl Check for exe extension set on certain hosts (e.g. Win32) |
| 1772 | AC_EXEEXT |
| 1773 | |
| 1774 | dnl Detect the character set used by this host. |
| 1775 | |
| 1776 | dnl At the moment, we just assume it's ISO-8859-1 (which is a |
| 1777 | dnl superset of ASCII containing the characters needed for French, |
| 1778 | dnl German, Spanish, Italian, and possibly others), but if were |
| 1779 | dnl *were* to support any host character sets other than ISO-8859-1, |
| 1780 | dnl here's where we'd detect it. |
| 1781 | AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1", |
| 1782 | [Define to be a string naming the default host character set.]) |
| 1783 | |
| 1784 | AM_ICONV |
| 1785 | |
| 1786 | AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile, |
| 1787 | [ |
| 1788 | dnl Autoconf doesn't provide a mechanism for modifying definitions |
| 1789 | dnl provided by makefile fragments. |
| 1790 | dnl |
| 1791 | |
| 1792 | changequote(,)dnl |
| 1793 | sed -e '/^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp |
| 1794 | mv -f Makefile.tmp Makefile |
| 1795 | changequote([,])dnl |
| 1796 | |
| 1797 | |
| 1798 | case x$CONFIG_HEADERS in |
| 1799 | xconfig.h:config.in) |
| 1800 | echo > stamp-h ;; |
| 1801 | esac |
| 1802 | ], |
| 1803 | [ |
| 1804 | gdb_host_cpu=$gdb_host_cpu |
| 1805 | nativefile=$nativefile |
| 1806 | ]) |
| 1807 | |
| 1808 | exit 0 |