| | 1 | dnl Autoconf configure script for GDB, the GNU debugger. |
| | 2 | dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004 |
| | 3 | dnl Free Software Foundation, Inc. |
| | 4 | dnl |
| | 5 | dnl This file is part of GDB. |
| | 6 | dnl |
| | 7 | dnl This program is free software; you can redistribute it and/or modify |
| | 8 | dnl it under the terms of the GNU General Public License as published by |
| | 9 | dnl the Free Software Foundation; either version 2 of the License, or |
| | 10 | dnl (at your option) any later version. |
| | 11 | dnl |
| | 12 | dnl This program is distributed in the hope that it will be useful, |
| | 13 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| | 14 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| | 15 | dnl GNU General Public License for more details. |
| | 16 | dnl |
| | 17 | dnl You should have received a copy of the GNU General Public License |
| | 18 | dnl along with this program; if not, write to the Free Software |
| | 19 | dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| | 20 | |
| | 21 | dnl Process this file with autoconf to produce a configure script. |
| | 22 | |
| | 23 | AC_PREREQ(2.13)dnl |
| | 24 | AC_INIT(main.c) |
| | 25 | AC_CONFIG_HEADER(config.h:config.in) |
| | 26 | AM_MAINTAINER_MODE |
| | 27 | |
| | 28 | AC_PROG_CC |
| | 29 | AC_GNU_SOURCE |
| | 30 | AC_AIX |
| | 31 | AC_ISC_POSIX |
| | 32 | AM_PROG_CC_STDC |
| | 33 | |
| | 34 | AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..) |
| | 35 | AC_CANONICAL_SYSTEM |
| | 36 | |
| | 37 | # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13 |
| | 38 | # doesn't support cross-compilation, but the one from Autoconf 2.5x |
| | 39 | # does. Override RANLIB here (i.e. before running AC_PROG_RANLIB) to |
| | 40 | # deal with the lossage. Note that CY_GNU_GETTEXT currently calls |
| | 41 | # AC_PROG_RANLIB. This can be removed when we switch to Autoconf |
| | 42 | # 2.5x. |
| | 43 | AC_CHECK_TOOL(RANLIB, ranlib, :) |
| | 44 | |
| | 45 | dnl Set up for gettext. PACKAGE is used when we call bindtextdomain. |
| | 46 | ALL_LINGUAS= |
| | 47 | CY_GNU_GETTEXT |
| | 48 | AC_DEFINE(PACKAGE, "gdb", [Name of this package. ]) |
| | 49 | |
| | 50 | debugdir=${libdir}/debug |
| | 51 | |
| | 52 | AC_ARG_WITH(separate-debug-dir, |
| | 53 | [ --with-separate-debug-dir=path Look for global separate debug info in this path [LIBDIR/debug]], |
| | 54 | [debugdir="${withval}"]) |
| | 55 | |
| | 56 | AC_DEFINE_DIR(DEBUGDIR, debugdir, |
| | 57 | [Global directory for separate debug files. ]) |
| | 58 | #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"), |
| | 59 | |
| | 60 | dnl List of object files added by configure. |
| | 61 | |
| | 62 | CONFIG_OBS= |
| | 63 | CONFIG_DEPS= |
| | 64 | CONFIG_SRCS= |
| | 65 | ENABLE_CFLAGS= |
| | 66 | CONFIG_ALL= |
| | 67 | CONFIG_CLEAN= |
| | 68 | CONFIG_INSTALL= |
| | 69 | CONFIG_UNINSTALL= |
| | 70 | |
| | 71 | AC_CONFIG_SUBDIRS(doc testsuite) |
| | 72 | configdirs= |
| | 73 | |
| | 74 | . $srcdir/configure.host |
| | 75 | |
| | 76 | . $srcdir/configure.tgt |
| | 77 | |
| | 78 | # Fetch the default architecture and default target vector from BFD. |
| | 79 | targ=$target; . $srcdir/../bfd/config.bfd |
| | 80 | |
| | 81 | # We only want the first architecture, so strip off the others if |
| | 82 | # there is more than one. |
| | 83 | targ_archs=`echo $targ_archs | sed 's/ .*//'` |
| | 84 | |
| | 85 | if test "x$targ_archs" != x; then |
| | 86 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs, |
| | 87 | [Define to BFD's default architecture. ]) |
| | 88 | fi |
| | 89 | if test "x$targ_defvec" != x; then |
| | 90 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec, |
| | 91 | [Define to BFD's default target vector. ]) |
| | 92 | fi |
| | 93 | |
| | 94 | AC_ARG_PROGRAM |
| | 95 | |
| | 96 | # The CLI cannot be disabled yet, but may be in the future. |
| | 97 | |
| | 98 | # Enable CLI. |
| | 99 | AC_ARG_ENABLE(gdbcli, |
| | 100 | [ --disable-gdbcli disable command-line interface (CLI)], |
| | 101 | [case $enableval in |
| | 102 | yes) |
| | 103 | ;; |
| | 104 | no) |
| | 105 | AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;; |
| | 106 | *) |
| | 107 | AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;; |
| | 108 | esac], |
| | 109 | [enable_gdbcli=yes]) |
| | 110 | if test x"$enable_gdbcli" = xyes; then |
| | 111 | if test -d $srcdir/cli; then |
| | 112 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)" |
| | 113 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)" |
| | 114 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)" |
| | 115 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)" |
| | 116 | fi |
| | 117 | fi |
| | 118 | |
| | 119 | # Enable MI. |
| | 120 | AC_ARG_ENABLE(gdbmi, |
| | 121 | [ --disable-gdbmi disable machine-interface (MI)], |
| | 122 | [case $enableval in |
| | 123 | yes | no) |
| | 124 | ;; |
| | 125 | *) |
| | 126 | AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;; |
| | 127 | esac], |
| | 128 | [enable_gdbmi=yes]) |
| | 129 | if test x"$enable_gdbmi" = xyes; then |
| | 130 | if test -d $srcdir/mi; then |
| | 131 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)" |
| | 132 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)" |
| | 133 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)" |
| | 134 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)" |
| | 135 | fi |
| | 136 | fi |
| | 137 | |
| | 138 | # Enable TUI. |
| | 139 | AC_ARG_ENABLE(tui, |
| | 140 | [ --enable-tui enable full-screen terminal user interface (TUI)], |
| | 141 | [case $enableval in |
| | 142 | yes | no) |
| | 143 | ;; |
| | 144 | *) |
| | 145 | AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;; |
| | 146 | esac],enable_tui=yes) |
| | 147 | if test x"$enable_tui" = xyes; then |
| | 148 | if test -d $srcdir/tui; then |
| | 149 | if test "$ac_cv_search_initscr" != no -a "$ac_cv_search_wborder" != no; then |
| | 150 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)" |
| | 151 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)" |
| | 152 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)" |
| | 153 | CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)" |
| | 154 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)" |
| | 155 | CONFIG_ALL="${CONFIG_ALL} all-tui" |
| | 156 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui" |
| | 157 | CONFIG_INSTALL="${CONFIG_INSTALL} install-tui" |
| | 158 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui" |
| | 159 | fi |
| | 160 | fi |
| | 161 | fi |
| | 162 | |
| | 163 | # Enable gdbtk. |
| | 164 | AC_ARG_ENABLE(gdbtk, |
| | 165 | [ --enable-gdbtk enable gdbtk graphical user interface (GUI)], |
| | 166 | [case $enableval in |
| | 167 | yes | no) |
| | 168 | ;; |
| | 169 | *) |
| | 170 | AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;; |
| | 171 | esac], |
| | 172 | [if test -d $srcdir/gdbtk; then |
| | 173 | enable_gdbtk=yes |
| | 174 | else |
| | 175 | enable_gdbtk=no |
| | 176 | fi]) |
| | 177 | # We unconditionally disable gdbtk tests on selected platforms. |
| | 178 | case $host_os in |
| | 179 | go32* | windows*) |
| | 180 | AC_MSG_WARN([gdbtk isn't supported on $host; disabling]) |
| | 181 | enable_gdbtk=no ;; |
| | 182 | esac |
| | 183 | |
| | 184 | # Libunwind support. |
| | 185 | AC_ARG_WITH(libunwind, |
| | 186 | [ --with-libunwind Use libunwind frame unwinding support], |
| | 187 | [case "${withval}" in |
| | 188 | yes) enable_libunwind=yes ;; |
| | 189 | no) enable_libunwind=no ;; |
| | 190 | *) AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;; |
| | 191 | esac],[ |
| | 192 | AC_CHECK_HEADERS(libunwind.h) |
| | 193 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| | 194 | if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then |
| | 195 | enable_libunwind=yes; |
| | 196 | fi |
| | 197 | ]) |
| | 198 | |
| | 199 | if test x"$enable_libunwind" = xyes; then |
| | 200 | AC_CHECK_HEADERS(libunwind.h) |
| | 201 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| | 202 | AC_DEFINE(HAVE_LIBUNWIND, 1) |
| | 203 | CONFIG_OBS="$CONFIG_OBS libunwind-frame.o" |
| | 204 | CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o" |
| | 205 | CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c" |
| | 206 | fi |
| | 207 | |
| | 208 | # Profiling support. |
| | 209 | AC_ARG_ENABLE(profiling, |
| | 210 | [ --enable-profiling enable profiling of GDB], |
| | 211 | [case $enableval in |
| | 212 | yes | no) |
| | 213 | ;; |
| | 214 | *) |
| | 215 | AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;; |
| | 216 | esac], |
| | 217 | [enable_profiling=no]) |
| | 218 | |
| | 219 | AC_CHECK_FUNCS(monstartup _mcleanup) |
| | 220 | AC_CACHE_CHECK([for _etext], ac_cv_var__etext, |
| | 221 | [AC_TRY_LINK( |
| | 222 | [#include <stdlib.h> |
| | 223 | extern char _etext; |
| | 224 | ], |
| | 225 | [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)]) |
| | 226 | if test $ac_cv_var__etext = yes; then |
| | 227 | AC_DEFINE(HAVE__ETEXT, 1, |
| | 228 | [Define to 1 if your system has the _etext variable. ]) |
| | 229 | fi |
| | 230 | if test "$enable_profiling" = yes ; then |
| | 231 | if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then |
| | 232 | AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup) |
| | 233 | fi |
| | 234 | PROFILE_CFLAGS=-pg |
| | 235 | OLD_CFLAGS="$CFLAGS" |
| | 236 | CFLAGS="$CFLAGS $PROFILE_CFLAGS" |
| | 237 | |
| | 238 | AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg, |
| | 239 | [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes, |
| | 240 | ac_cv_cc_supports_pg=no)]) |
| | 241 | |
| | 242 | if test $ac_cv_cc_supports_pg = no; then |
| | 243 | AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg) |
| | 244 | fi |
| | 245 | |
| | 246 | CFLAGS="$OLD_CFLAGS" |
| | 247 | fi |
| | 248 | |
| | 249 | # --------------------- # |
| | 250 | # Checks for programs. # |
| | 251 | # --------------------- # |
| | 252 | |
| | 253 | AC_PROG_AWK |
| | 254 | AC_PROG_INSTALL |
| | 255 | AC_PROG_LN_S |
| | 256 | AC_PROG_RANLIB |
| | 257 | AC_PROG_YACC |
| | 258 | |
| | 259 | AC_CHECK_TOOL(AR, ar) |
| | 260 | AC_CHECK_TOOL(DLLTOOL, dlltool) |
| | 261 | AC_CHECK_TOOL(WINDRES, windres) |
| | 262 | |
| | 263 | # Needed for GNU/Hurd. |
| | 264 | AC_CHECK_TOOL(MIG, mig) |
| | 265 | |
| | 266 | # ---------------------- # |
| | 267 | # Checks for libraries. # |
| | 268 | # ---------------------- # |
| | 269 | |
| | 270 | # We might need to link with -lm; most simulators need it. |
| | 271 | AC_CHECK_LIB(m, main) |
| | 272 | |
| | 273 | # We need to link with -lw to get `wctype' on Solaris before Solaris |
| | 274 | # 2.6. Solaris 2.6 and beyond have this function in libc, and have a |
| | 275 | # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1 |
| | 276 | # is known to have this problem). Therefore we avoid libw if we can. |
| | 277 | AC_CHECK_FUNC(wctype, [], |
| | 278 | [AC_CHECK_LIB(w, wctype)]) |
| | 279 | |
| | 280 | # Some systems (e.g. Solaris) have `gethostbyname' in libnsl. |
| | 281 | AC_SEARCH_LIBS(gethostbyname, nsl) |
| | 282 | |
| | 283 | # Some systems (e.g. Solaris) have `socketpair' in libsocket. |
| | 284 | AC_SEARCH_LIBS(socketpair, socket) |
| | 285 | |
| | 286 | # Since GDB uses Readline, we need termcap functionality, so we need |
| | 287 | # to find a library that provides that. When GDB is configured with |
| | 288 | # the TUI, we need full curses functionality. |
| | 289 | |
| | 290 | case $host_os in |
| | 291 | cygwin*) |
| | 292 | if test -d $srcdir/libtermcap; then |
| | 293 | LIBS="../libtermcap/libtermcap.a $LIBS" |
| | 294 | ac_cv_search_tgetent="../libtermcap/libtermcap.a" |
| | 295 | fi ;; |
| | 296 | go32* | *djgpp*) |
| | 297 | ac_cv_search_tgetent="none required" |
| | 298 | ;; |
| | 299 | aix*) |
| | 300 | # Readline prefers curses over termcap on AIX. |
| | 301 | # ??? Why? |
| | 302 | AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap]) |
| | 303 | ;; |
| | 304 | esac |
| | 305 | |
| | 306 | # Note: We used to check for libtermlib and libterminfo too, but |
| | 307 | # Readline doesn't, so I think we're safe with leaving them out. |
| | 308 | AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses]) |
| | 309 | |
| | 310 | if test "$ac_cv_search_tgetent" = no; then |
| | 311 | AC_MSG_ERROR([no termcap library found]) |
| | 312 | fi |
| | 313 | |
| | 314 | # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over |
| | 315 | # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host |
| | 316 | # Makefile fragments. That's why we need to have `Hcurses' before |
| | 317 | # `curses'. I don't see why we should use HP curses if a more |
| | 318 | # standard curses is available, except that according to HP's |
| | 319 | # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on |
| | 320 | # HP-UX 10.10 and 10.20. |
| | 321 | |
| | 322 | # FIXME: ncurses does not work on native alphaev68-dec-osf5.1, |
| | 323 | # and probably other platforms. AC_SEARCH_LIBS finds the library |
| | 324 | # in a place such as /usr/local/lib/libncurses.a, but does not |
| | 325 | # do anything to look for the matching include files. |
| | 326 | # -- chastain 2004-05-01 |
| | 327 | |
| | 328 | AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses pdcurses], [], |
| | 329 | [AC_MSG_WARN([no curses library found])]) |
| | 330 | |
| | 331 | # Check whether the wborder function is provided by the curses |
| | 332 | # library detected above. In certain implementations such as |
| | 333 | # the HP/UX Hcurses for instance, this function is provided by an |
| | 334 | # additional library. So if we did not find this function inside |
| | 335 | # the curses library, try some alternate libraries we know might |
| | 336 | # provide it. |
| | 337 | AC_SEARCH_LIBS(wborder, [cur_colr], [], |
| | 338 | [AC_MSG_WARN([wborder function not found, tui will be disabled])]) |
| | 339 | |
| | 340 | # ------------------------- # |
| | 341 | # Checks for header files. # |
| | 342 | # ------------------------- # |
| | 343 | |
| | 344 | AC_HEADER_DIRENT |
| | 345 | AC_HEADER_STAT |
| | 346 | AC_HEADER_STDC |
| | 347 | AC_CHECK_HEADERS(link.h) |
| | 348 | AC_CHECK_HEADERS(machine/reg.h) |
| | 349 | AC_CHECK_HEADERS(nlist.h) |
| | 350 | AC_CHECK_HEADERS(poll.h sys/poll.h) |
| | 351 | AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h) |
| | 352 | AC_CHECK_HEADERS(stddef.h) |
| | 353 | AC_CHECK_HEADERS(stdlib.h) |
| | 354 | AC_CHECK_HEADERS(stdint.h) |
| | 355 | AC_CHECK_HEADERS(string.h memory.h strings.h) |
| | 356 | AC_CHECK_HEADERS(sys/fault.h) |
| | 357 | AC_CHECK_HEADERS(sys/file.h) |
| | 358 | AC_CHECK_HEADERS(sys/filio.h) |
| | 359 | AC_CHECK_HEADERS(sys/ioctl.h) |
| | 360 | AC_CHECK_HEADERS(sys/param.h) |
| | 361 | AC_CHECK_HEADERS(sys/proc.h) |
| | 362 | AC_CHECK_HEADERS(sys/procfs.h) |
| | 363 | AC_CHECK_HEADERS(sys/ptrace.h ptrace.h) |
| | 364 | AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h) |
| | 365 | AC_CHECK_HEADERS(sys/select.h) |
| | 366 | AC_CHECK_HEADERS(sys/syscall.h) |
| | 367 | AC_CHECK_HEADERS(sys/user.h) |
| | 368 | AC_CHECK_HEADERS(sys/wait.h wait.h) |
| | 369 | AC_CHECK_HEADERS(termios.h termio.h sgtty.h) |
| | 370 | AC_CHECK_HEADERS(unistd.h) |
| | 371 | |
| | 372 | # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash |
| | 373 | # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to |
| | 374 | # think that we don't have <curses.h> if we're using GCC. |
| | 375 | case $host_os in |
| | 376 | solaris2.[[78]]) |
| | 377 | if test "$GCC" = yes; then |
| | 378 | AC_DEFINE(_MSE_INT_H, 1, |
| | 379 | [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on |
| | 380 | Solaris 2.[78] when using GCC. ]]) |
| | 381 | fi ;; |
| | 382 | esac |
| | 383 | AC_CHECK_HEADERS(curses.h ncurses.h term.h) |
| | 384 | |
| | 385 | # FIXME: kettenis/20030102: In most cases we include these |
| | 386 | # unconditionally, so what's the point in checking these? |
| | 387 | AC_CHECK_HEADERS(ctype.h time.h) |
| | 388 | |
| | 389 | dnl Check for struct stat with an st_blocks member |
| | 390 | AC_MSG_CHECKING(for member st_blocks in struct stat) |
| | 391 | AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member, |
| | 392 | [AC_TRY_COMPILE([#include <sys/types.h> |
| | 393 | #include <sys/stat.h>], |
| | 394 | [struct stat st; (void) st.st_blocks;], |
| | 395 | gdb_cv_have_struct_stat_with_st_blocks_member=yes, |
| | 396 | gdb_cv_have_struct_stat_with_st_blocks_member=no)]) |
| | 397 | AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member) |
| | 398 | if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then |
| | 399 | AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS) |
| | 400 | fi |
| | 401 | # ------------------------- # |
| | 402 | # Checks for declarations. # |
| | 403 | # ------------------------- # |
| | 404 | |
| | 405 | gcc_AC_CHECK_DECLS(getopt) |
| | 406 | |
| | 407 | # ------------------ # |
| | 408 | # Checks for types. # |
| | 409 | # ------------------ # |
| | 410 | |
| | 411 | AC_TYPE_SIGNAL |
| | 412 | |
| | 413 | # ------------------------------------- # |
| | 414 | # Checks for compiler characteristics. # |
| | 415 | # ------------------------------------- # |
| | 416 | |
| | 417 | AC_C_CONST |
| | 418 | AC_C_INLINE |
| | 419 | |
| | 420 | # ------------------------------ # |
| | 421 | # Checks for library functions. # |
| | 422 | # ------------------------------ # |
| | 423 | |
| | 424 | AC_FUNC_ALLOCA |
| | 425 | AC_FUNC_MMAP |
| | 426 | AC_FUNC_VFORK |
| | 427 | AC_CHECK_FUNCS(canonicalize_file_name realpath) |
| | 428 | AC_CHECK_FUNCS(poll) |
| | 429 | AC_CHECK_FUNCS(pread64) |
| | 430 | AC_CHECK_FUNCS(sbrk) |
| | 431 | AC_CHECK_FUNCS(setpgid setpgrp) |
| | 432 | AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask) |
| | 433 | AC_CHECK_FUNCS(socketpair) |
| | 434 | AC_CHECK_FUNCS(syscall) |
| | 435 | |
| | 436 | dnl AC_FUNC_SETPGRP does not work when cross compiling |
| | 437 | dnl Instead, assume we will have a prototype for setpgrp if cross compiling. |
| | 438 | if test "$cross_compiling" = no; then |
| | 439 | AC_FUNC_SETPGRP |
| | 440 | else |
| | 441 | AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void, |
| | 442 | [AC_TRY_COMPILE([ |
| | 443 | #include <unistd.h> |
| | 444 | ], [ |
| | 445 | if (setpgrp(1,1) == -1) |
| | 446 | exit (0); |
| | 447 | else |
| | 448 | exit (1); |
| | 449 | ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)]) |
| | 450 | if test $ac_cv_func_setpgrp_void = yes; then |
| | 451 | AC_DEFINE(SETPGRP_VOID, 1) |
| | 452 | fi |
| | 453 | fi |
| | 454 | |
| | 455 | # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do |
| | 456 | # since sigsetjmp might only be defined as a macro. |
| | 457 | AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp, |
| | 458 | [AC_TRY_COMPILE([ |
| | 459 | #include <setjmp.h> |
| | 460 | ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);], |
| | 461 | gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)]) |
| | 462 | if test $gdb_cv_func_sigsetjmp = yes; then |
| | 463 | AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ]) |
| | 464 | fi |
| | 465 | |
| | 466 | # Assume we'll default to using the included libiberty regex. |
| | 467 | gdb_use_included_regex=yes |
| | 468 | |
| | 469 | # However, if the system regex is GNU regex, then default to *not* |
| | 470 | # using the included regex. |
| | 471 | AC_CACHE_CHECK( |
| | 472 | [for GNU regex], |
| | 473 | [gdb_cv_have_gnu_regex], |
| | 474 | [AC_TRY_COMPILE( |
| | 475 | [#include <gnu-versions.h>], |
| | 476 | [#define REGEX_INTERFACE_VERSION 1 |
| | 477 | #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION |
| | 478 | # error "Version mismatch" |
| | 479 | #endif], |
| | 480 | gdb_cv_have_gnu_regex=yes, |
| | 481 | gdb_cv_have_gnu_regex=no)]) |
| | 482 | if test $gdb_cv_have_gnu_regex = yes; then |
| | 483 | gdb_use_included_regex=no |
| | 484 | fi |
| | 485 | |
| | 486 | AC_ARG_WITH(included-regex, |
| | 487 | [ --without-included-regex don't use included regex; this is the default |
| | 488 | on systems with version 2 of the GNU C library |
| | 489 | (use with caution on other system)], |
| | 490 | gdb_with_regex=$withval, |
| | 491 | gdb_with_regex=$gdb_use_included_regex) |
| | 492 | if test "$gdb_with_regex" = yes; then |
| | 493 | AC_DEFINE(USE_INCLUDED_REGEX, 1, |
| | 494 | [Define to 1 if the regex included in libiberty should be used.]) |
| | 495 | fi |
| | 496 | |
| | 497 | # See if <machine/reg.h> degines `struct reg'. |
| | 498 | AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg, |
| | 499 | [AC_TRY_COMPILE([#include <sys/types.h> |
| | 500 | #include <machine/reg.h>], [struct reg r;], |
| | 501 | gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)]) |
| | 502 | if test $gdb_cv_struct_reg = yes; then |
| | 503 | AC_DEFINE(HAVE_STRUCT_REG, 1, |
| | 504 | [Define to 1 if your system has struct reg in <machine/reg.h>.]) |
| | 505 | fi |
| | 506 | |
| | 507 | # See if <machine/reg.h> supports the %fs and %gs i386 segment registers. |
| | 508 | # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'. |
| | 509 | AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs, |
| | 510 | [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;], |
| | 511 | gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)]) |
| | 512 | if test $gdb_cv_struct_reg_r_fs = yes; then |
| | 513 | AC_DEFINE(HAVE_STRUCT_REG_R_FS) |
| | 514 | fi |
| | 515 | AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs, |
| | 516 | [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;], |
| | 517 | gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)]) |
| | 518 | if test $gdb_cv_struct_reg_r_gs = yes; then |
| | 519 | AC_DEFINE(HAVE_STRUCT_REG_R_GS) |
| | 520 | fi |
| | 521 | |
| | 522 | # See if <sys/ptrace.h> provides the PTRACE_GETREGS request. |
| | 523 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| | 524 | AC_CACHE_VAL(gdb_cv_have_ptrace_getregs, |
| | 525 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| | 526 | [PTRACE_GETREGS;], |
| | 527 | [gdb_cv_have_ptrace_getregs=yes], |
| | 528 | [gdb_cv_have_ptrace_getregs=no])]) |
| | 529 | AC_MSG_RESULT($gdb_cv_have_ptrace_getregs) |
| | 530 | if test $gdb_cv_have_ptrace_getregs = yes; then |
| | 531 | AC_DEFINE(HAVE_PTRACE_GETREGS) |
| | 532 | fi |
| | 533 | |
| | 534 | # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request. |
| | 535 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| | 536 | AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs, |
| | 537 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| | 538 | [PTRACE_GETFPXREGS;], |
| | 539 | [gdb_cv_have_ptrace_getfpxregs=yes], |
| | 540 | [gdb_cv_have_ptrace_getfpxregs=no])]) |
| | 541 | AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs) |
| | 542 | if test $gdb_cv_have_ptrace_getfpxregs = yes; then |
| | 543 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS) |
| | 544 | fi |
| | 545 | |
| | 546 | # See if <sys/ptrace.h> provides the PT_GETDBREGS request. |
| | 547 | AC_MSG_CHECKING(for PT_GETDBREGS) |
| | 548 | AC_CACHE_VAL(gdb_cv_have_pt_getdbregs, |
| | 549 | [AC_TRY_COMPILE([#include <sys/types.h> |
| | 550 | #include <sys/ptrace.h>], |
| | 551 | [PT_GETDBREGS;], |
| | 552 | [gdb_cv_have_pt_getdbregs=yes], |
| | 553 | [gdb_cv_have_pt_getdbregs=no])]) |
| | 554 | AC_MSG_RESULT($gdb_cv_have_pt_getdbregs) |
| | 555 | if test $gdb_cv_have_pt_getdbregs = yes; then |
| | 556 | AC_DEFINE(HAVE_PT_GETDBREGS) |
| | 557 | fi |
| | 558 | |
| | 559 | # See if <sys/ptrace.h> provides the PT_GETXMMREGS request. |
| | 560 | AC_MSG_CHECKING(for PT_GETXMMREGS) |
| | 561 | AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs, |
| | 562 | [AC_TRY_COMPILE([#include <sys/types.h> |
| | 563 | #include <sys/ptrace.h>], |
| | 564 | [PT_GETXMMREGS;], |
| | 565 | [gdb_cv_have_pt_getxmmregs=yes], |
| | 566 | [gdb_cv_have_pt_getxmmregs=no])]) |
| | 567 | AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs) |
| | 568 | if test $gdb_cv_have_pt_getxmmregs = yes; then |
| | 569 | AC_DEFINE(HAVE_PT_GETXMMREGS) |
| | 570 | fi |
| | 571 | |
| | 572 | # See if stdint.h provides the uintptr_t type. |
| | 573 | # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this. |
| | 574 | AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t, |
| | 575 | [AC_TRY_COMPILE( |
| | 576 | [#include <stdint.h>], |
| | 577 | [uintptr_t foo = 0;], |
| | 578 | gdb_cv_have_uintptr_t=yes, |
| | 579 | gdb_cv_have_uintptr_t=no)]) |
| | 580 | if test $gdb_cv_have_uintptr_t = yes; then |
| | 581 | AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.]) |
| | 582 | fi |
| | 583 | |
| | 584 | BFD_NEED_DECLARATION(malloc) |
| | 585 | BFD_NEED_DECLARATION(realloc) |
| | 586 | BFD_NEED_DECLARATION(free) |
| | 587 | BFD_NEED_DECLARATION(strerror) |
| | 588 | BFD_NEED_DECLARATION(strdup) |
| | 589 | BFD_NEED_DECLARATION(strstr) |
| | 590 | BFD_NEED_DECLARATION(canonicalize_file_name) |
| | 591 | |
| | 592 | # The following save_state_t checkery is only necessary for HPUX |
| | 593 | # versions earlier than 10.20. When those fade from memory, this |
| | 594 | # could be expunged. --jsm 1999-03-22 |
| | 595 | |
| | 596 | AC_MSG_CHECKING(for HPUX save_state structure) |
| | 597 | AC_EGREP_HEADER(save_state_t, machine/save_state.h, |
| | 598 | gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no) |
| | 599 | AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes, |
| | 600 | gdb_cv_hpux_sswide=no) |
| | 601 | if test $gdb_cv_hpux_savestate = yes |
| | 602 | then |
| | 603 | AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1) |
| | 604 | fi |
| | 605 | if test $gdb_cv_hpux_sswide = yes |
| | 606 | then |
| | 607 | AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1) |
| | 608 | fi |
| | 609 | AC_MSG_RESULT($gdb_cv_hpux_sswide) |
| | 610 | |
| | 611 | |
| | 612 | # If we are configured native on GNU/Linux, work around problems with |
| | 613 | # sys/procfs.h |
| | 614 | # Also detect which type of /proc is in use, such as for Unixware or Solaris. |
| | 615 | |
| | 616 | if test "${target}" = "${host}"; then |
| | 617 | case "${host}" in |
| | 618 | i[[3456]]86-*-linux*) |
| | 619 | AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2) |
| | 620 | AC_DEFINE(sys_quotactl) |
| | 621 | ;; |
| | 622 | ia64-*-aix*) |
| | 623 | AC_DEFINE(NEW_PROC_API) |
| | 624 | ;; |
| | 625 | *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* ) |
| | 626 | AC_DEFINE(NEW_PROC_API) |
| | 627 | ;; |
| | 628 | *-*-solaris2.[[6789]]) |
| | 629 | AC_DEFINE(NEW_PROC_API) |
| | 630 | ;; |
| | 631 | mips-sgi-irix5*) |
| | 632 | # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5. |
| | 633 | AC_DEFINE([_KMEMUSER], 1) |
| | 634 | ;; |
| | 635 | esac |
| | 636 | fi |
| | 637 | |
| | 638 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| | 639 | BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t) |
| | 640 | BFD_HAVE_SYS_PROCFS_TYPE(prrun_t) |
| | 641 | BFD_HAVE_SYS_PROCFS_TYPE(gregset_t) |
| | 642 | BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t) |
| | 643 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| | 644 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| | 645 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t) |
| | 646 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t) |
| | 647 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| | 648 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| | 649 | BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t) |
| | 650 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t) |
| | 651 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t) |
| | 652 | BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t) |
| | 653 | |
| | 654 | |
| | 655 | dnl Check for broken prfpregset_t type |
| | 656 | |
| | 657 | dnl For Linux/i386, glibc 2.1.3 was released with a bogus |
| | 658 | dnl prfpregset_t type (it's a typedef for the pointer to a struct |
| | 659 | dnl instead of the struct itself). We detect this here, and work |
| | 660 | dnl around it in gdb_proc_service.h. |
| | 661 | |
| | 662 | if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then |
| | 663 | AC_MSG_CHECKING(whether prfpregset_t type is broken) |
| | 664 | AC_CACHE_VAL(gdb_cv_prfpregset_t_broken, |
| | 665 | [AC_TRY_RUN([#include <sys/procfs.h> |
| | 666 | int main () |
| | 667 | { |
| | 668 | if (sizeof (prfpregset_t) == sizeof (void *)) |
| | 669 | return 1; |
| | 670 | return 0; |
| | 671 | }], |
| | 672 | gdb_cv_prfpregset_t_broken=no, |
| | 673 | gdb_cv_prfpregset_t_broken=yes, |
| | 674 | gdb_cv_prfpregset_t_broken=yes)]) |
| | 675 | AC_MSG_RESULT($gdb_cv_prfpregset_t_broken) |
| | 676 | if test $gdb_cv_prfpregset_t_broken = yes; then |
| | 677 | AC_DEFINE(PRFPREGSET_T_BROKEN) |
| | 678 | fi |
| | 679 | fi |
| | 680 | |
| | 681 | dnl Check for PIOCSET ioctl entry |
| | 682 | |
| | 683 | AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h) |
| | 684 | AC_CACHE_VAL(gdb_cv_have_procfs_piocset, |
| | 685 | [AC_TRY_COMPILE([#include <unistd.h> |
| | 686 | #include <sys/types.h> |
| | 687 | #include <sys/procfs.h> |
| | 688 | ], [ |
| | 689 | int dummy;; |
| | 690 | dummy = ioctl(0, PIOCSET, &dummy); |
| | 691 | ], |
| | 692 | gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)]) |
| | 693 | AC_MSG_RESULT($gdb_cv_have_procfs_piocset) |
| | 694 | if test $gdb_cv_have_procfs_piocset = yes; then |
| | 695 | AC_DEFINE(HAVE_PROCFS_PIOCSET) |
| | 696 | fi |
| | 697 | fi |
| | 698 | |
| | 699 | dnl For native ports (host == target), check to see what kind of |
| | 700 | dnl legacy link.h support is needed. (See solib-legacy.c.) |
| | 701 | if test ${host} = ${target} ; then |
| | 702 | dnl Check for struct link_map with l_ members which are indicative |
| | 703 | dnl of SVR4-like shared libraries |
| | 704 | |
| | 705 | AC_MSG_CHECKING(for member l_addr in struct link_map) |
| | 706 | AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members, |
| | 707 | [AC_TRY_COMPILE([#include <link.h>], |
| | 708 | [struct link_map lm; (void) lm.l_addr;], |
| | 709 | gdb_cv_have_struct_link_map_with_l_members=yes, |
| | 710 | gdb_cv_have_struct_link_map_with_l_members=no)]) |
| | 711 | AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members) |
| | 712 | if test $gdb_cv_have_struct_link_map_with_l_members = yes; then |
| | 713 | AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS) |
| | 714 | fi |
| | 715 | |
| | 716 | dnl Check for struct link_map with lm_ members which are indicative |
| | 717 | dnl of SunOS-like shared libraries |
| | 718 | |
| | 719 | AC_MSG_CHECKING(for member lm_addr in struct link_map) |
| | 720 | AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members, |
| | 721 | [AC_TRY_COMPILE([#include <sys/types.h> |
| | 722 | #include <link.h>], |
| | 723 | [struct link_map lm; (void) lm.lm_addr;], |
| | 724 | gdb_cv_have_struct_link_map_with_lm_members=yes, |
| | 725 | gdb_cv_have_struct_link_map_with_lm_members=no)]) |
| | 726 | AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members) |
| | 727 | if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then |
| | 728 | AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS) |
| | 729 | fi |
| | 730 | |
| | 731 | dnl Check for struct so_map with som_ members which are found on |
| | 732 | dnl some *BSD systems. |
| | 733 | |
| | 734 | AC_MSG_CHECKING(for member som_addr in struct so_map) |
| | 735 | AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members, |
| | 736 | [AC_TRY_COMPILE([#include <sys/types.h> |
| | 737 | #ifdef HAVE_NLIST_H |
| | 738 | #include <nlist.h> |
| | 739 | #endif |
| | 740 | #include <link.h>], |
| | 741 | [struct so_map lm; (void) lm.som_addr;], |
| | 742 | gdb_cv_have_struct_so_map_with_som_members=yes, |
| | 743 | gdb_cv_have_struct_so_map_with_som_members=no)]) |
| | 744 | AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members) |
| | 745 | if test $gdb_cv_have_struct_so_map_with_som_members = yes; then |
| | 746 | AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS) |
| | 747 | fi |
| | 748 | |
| | 749 | dnl Check for struct link_map32 type, which allows a 64-bit Solaris |
| | 750 | dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries. |
| | 751 | |
| | 752 | AC_MSG_CHECKING(for struct link_map32 in sys/link.h) |
| | 753 | AC_CACHE_VAL(gdb_cv_have_struct_link_map32, |
| | 754 | [AC_TRY_COMPILE([#define _SYSCALL32 |
| | 755 | #include <sys/link.h>], [struct link_map32 l;], |
| | 756 | gdb_cv_have_struct_link_map32=yes, |
| | 757 | gdb_cv_have_struct_link_map32=no)]) |
| | 758 | AC_MSG_RESULT($gdb_cv_have_struct_link_map32) |
| | 759 | if test $gdb_cv_have_struct_link_map32 = yes; then |
| | 760 | AC_DEFINE(HAVE_STRUCT_LINK_MAP32) |
| | 761 | AC_DEFINE(_SYSCALL32) |
| | 762 | fi |
| | 763 | fi |
| | 764 | |
| | 765 | dnl See if compiler supports "long long" type. |
| | 766 | |
| | 767 | AC_MSG_CHECKING(for long long support in compiler) |
| | 768 | AC_CACHE_VAL(gdb_cv_c_long_long, |
| | 769 | [AC_TRY_COMPILE(, [ |
| | 770 | extern long long foo; |
| | 771 | switch (foo & 2) { case 0: return 1; } |
| | 772 | ], |
| | 773 | gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)]) |
| | 774 | AC_MSG_RESULT($gdb_cv_c_long_long) |
| | 775 | if test $gdb_cv_c_long_long = yes; then |
| | 776 | AC_DEFINE(CC_HAS_LONG_LONG) |
| | 777 | fi |
| | 778 | |
| | 779 | dnl See if the compiler and runtime support printing long long |
| | 780 | |
| | 781 | AC_MSG_CHECKING(for long long support in printf) |
| | 782 | AC_CACHE_VAL(gdb_cv_printf_has_long_long, |
| | 783 | [AC_TRY_RUN([ |
| | 784 | int main () { |
| | 785 | char buf[32]; |
| | 786 | long long l = 0; |
| | 787 | l = (l << 16) + 0x0123; |
| | 788 | l = (l << 16) + 0x4567; |
| | 789 | l = (l << 16) + 0x89ab; |
| | 790 | l = (l << 16) + 0xcdef; |
| | 791 | sprintf (buf, "0x%016llx", l); |
| | 792 | return (strcmp ("0x0123456789abcdef", buf)); |
| | 793 | }], |
| | 794 | gdb_cv_printf_has_long_long=yes, |
| | 795 | gdb_cv_printf_has_long_long=no, |
| | 796 | gdb_cv_printf_has_long_long=no)]) |
| | 797 | if test $gdb_cv_printf_has_long_long = yes; then |
| | 798 | AC_DEFINE(PRINTF_HAS_LONG_LONG) |
| | 799 | fi |
| | 800 | AC_MSG_RESULT($gdb_cv_printf_has_long_long) |
| | 801 | |
| | 802 | dnl See if compiler supports "long double" type. Can't use AC_C_LONG_DOUBLE |
| | 803 | dnl because autoconf complains about cross-compilation issues. However, this |
| | 804 | dnl code uses the same variables as the macro for compatibility. |
| | 805 | |
| | 806 | AC_MSG_CHECKING(for long double support in compiler) |
| | 807 | AC_CACHE_VAL(ac_cv_c_long_double, |
| | 808 | [AC_TRY_COMPILE(, [long double foo;], |
| | 809 | ac_cv_c_long_double=yes, ac_cv_c_long_double=no)]) |
| | 810 | AC_MSG_RESULT($ac_cv_c_long_double) |
| | 811 | if test $ac_cv_c_long_double = yes; then |
| | 812 | AC_DEFINE(HAVE_LONG_DOUBLE) |
| | 813 | fi |
| | 814 | |
| | 815 | dnl See if the compiler and runtime support printing long doubles |
| | 816 | |
| | 817 | AC_MSG_CHECKING(for long double support in printf) |
| | 818 | AC_CACHE_VAL(gdb_cv_printf_has_long_double, |
| | 819 | [AC_TRY_RUN([ |
| | 820 | int main () { |
| | 821 | char buf[16]; |
| | 822 | long double f = 3.141592653; |
| | 823 | sprintf (buf, "%Lg", f); |
| | 824 | return (strncmp ("3.14159", buf, 7)); |
| | 825 | }], |
| | 826 | gdb_cv_printf_has_long_double=yes, |
| | 827 | gdb_cv_printf_has_long_double=no, |
| | 828 | gdb_cv_printf_has_long_double=no)]) |
| | 829 | if test $gdb_cv_printf_has_long_double = yes; then |
| | 830 | AC_DEFINE(PRINTF_HAS_LONG_DOUBLE) |
| | 831 | fi |
| | 832 | AC_MSG_RESULT($gdb_cv_printf_has_long_double) |
| | 833 | |
| | 834 | dnl See if the compiler and runtime support scanning long doubles |
| | 835 | |
| | 836 | AC_MSG_CHECKING(for long double support in scanf) |
| | 837 | AC_CACHE_VAL(gdb_cv_scanf_has_long_double, |
| | 838 | [AC_TRY_RUN([ |
| | 839 | int main () { |
| | 840 | char *buf = "3.141592653"; |
| | 841 | long double f = 0; |
| | 842 | sscanf (buf, "%Lg", &f); |
| | 843 | return !(f > 3.14159 && f < 3.14160); |
| | 844 | }], |
| | 845 | gdb_cv_scanf_has_long_double=yes, |
| | 846 | gdb_cv_scanf_has_long_double=no, |
| | 847 | gdb_cv_scanf_has_long_double=no)]) |
| | 848 | if test $gdb_cv_scanf_has_long_double = yes; then |
| | 849 | AC_DEFINE(SCANF_HAS_LONG_DOUBLE) |
| | 850 | fi |
| | 851 | AC_MSG_RESULT($gdb_cv_scanf_has_long_double) |
| | 852 | |
| | 853 | case ${host_os} in |
| | 854 | aix*) |
| | 855 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| | 856 | SAVE_LDFLAGS=$LDFLAGS |
| | 857 | |
| | 858 | case $GCC in |
| | 859 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| | 860 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| | 861 | esac |
| | 862 | |
| | 863 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| | 864 | AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=]) |
| | 865 | LDFLAGS="${SAVE_LDFLAGS}" |
| | 866 | ]) |
| | 867 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}" |
| | 868 | ;; |
| | 869 | esac |
| | 870 | |
| | 871 | |
| | 872 | dnl For certain native configurations, we need to check whether thread |
| | 873 | dnl support can be built in or not. |
| | 874 | dnl |
| | 875 | dnl Note that we only want this if we are both native (host == target), |
| | 876 | dnl and not doing a canadian cross build (build == host). |
| | 877 | |
| | 878 | if test ${build} = ${host} -a ${host} = ${target} ; then |
| | 879 | case ${host_os} in |
| | 880 | hpux*) |
| | 881 | AC_MSG_CHECKING(for HPUX/OSF thread support) |
| | 882 | if test -f /usr/include/dce/cma_config.h ; then |
| | 883 | if test "$GCC" = "yes" ; then |
| | 884 | AC_MSG_RESULT(yes) |
| | 885 | AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT) |
| | 886 | CONFIG_OBS="${CONFIG_OBS} hpux-thread.o" |
| | 887 | CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c" |
| | 888 | else |
| | 889 | AC_MSG_RESULT(no (suppressed because you are not using GCC)) |
| | 890 | fi |
| | 891 | else |
| | 892 | AC_MSG_RESULT(no) |
| | 893 | fi |
| | 894 | ;; |
| | 895 | solaris*) |
| | 896 | # See if thread_db library is around for Solaris thread debugging. |
| | 897 | # Note that we must explicitly test for version 1 of the library |
| | 898 | # because version 0 (present on Solaris 2.4 or earlier) doesn't have |
| | 899 | # the same API. |
| | 900 | AC_MSG_CHECKING(for Solaris thread debugging library) |
| | 901 | if test -f /usr/lib/libthread_db.so.1 ; then |
| | 902 | AC_MSG_RESULT(yes) |
| | 903 | AC_DEFINE(HAVE_THREAD_DB_LIB) |
| | 904 | CONFIG_OBS="${CONFIG_OBS} sol-thread.o" |
| | 905 | CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c" |
| | 906 | AC_CHECK_LIB(dl, dlopen) |
| | 907 | if test "$GCC" = "yes" ; then |
| | 908 | # The GNU linker requires the -export-dynamic option to make |
| | 909 | # all symbols visible in the dynamic symbol table. |
| | 910 | hold_ldflags=$LDFLAGS |
| | 911 | AC_MSG_CHECKING(for the ld -export-dynamic flag) |
| | 912 | LDFLAGS="${LDFLAGS} -Wl,-export-dynamic" |
| | 913 | AC_TRY_LINK(, [int i;], found=yes, found=no) |
| | 914 | LDFLAGS=$hold_ldflags |
| | 915 | AC_MSG_RESULT($found) |
| | 916 | if test $found = yes; then |
| | 917 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic" |
| | 918 | fi |
| | 919 | fi |
| | 920 | # Sun randomly tweaked the prototypes in <proc_service.h> |
| | 921 | # at one point. |
| | 922 | AC_MSG_CHECKING(if <proc_service.h> is old) |
| | 923 | AC_CACHE_VAL(gdb_cv_proc_service_is_old,[ |
| | 924 | AC_TRY_COMPILE([ |
| | 925 | #include <proc_service.h> |
| | 926 | ps_err_e ps_pdwrite |
| | 927 | (struct ps_prochandle*, psaddr_t, const void*, size_t); |
| | 928 | ],, gdb_cv_proc_service_is_old=no, |
| | 929 | gdb_cv_proc_service_is_old=yes) |
| | 930 | ]) |
| | 931 | AC_MSG_RESULT($gdb_cv_proc_service_is_old) |
| | 932 | if test $gdb_cv_proc_service_is_old = yes; then |
| | 933 | AC_DEFINE(PROC_SERVICE_IS_OLD) |
| | 934 | fi |
| | 935 | else |
| | 936 | AC_MSG_RESULT(no) |
| | 937 | fi |
| | 938 | ;; |
| | 939 | aix*) |
| | 940 | AC_MSG_CHECKING(for AiX thread debugging library) |
| | 941 | AC_CACHE_VAL(gdb_cv_have_aix_thread_debug, |
| | 942 | [AC_TRY_COMPILE([#include <sys/pthdebug.h>], |
| | 943 | [#ifndef PTHDB_VERSION_3 |
| | 944 | #error |
| | 945 | #endif], |
| | 946 | gdb_cv_have_aix_thread_debug=yes, |
| | 947 | gdb_cv_have_aix_thread_debug=no)]) |
| | 948 | AC_MSG_RESULT($gdb_cv_have_aix_thread_debug) |
| | 949 | if test $gdb_cv_have_aix_thread_debug = yes; then |
| | 950 | CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c" |
| | 951 | CONFIG_OBS="${CONFIG_OBS} aix-thread.o" |
| | 952 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug" |
| | 953 | fi |
| | 954 | ;; |
| | 955 | esac |
| | 956 | AC_SUBST(CONFIG_LDFLAGS) |
| | 957 | fi |
| | 958 | |
| | 959 | dnl See if we have a thread_db header file that has TD_NOTALLOC. |
| | 960 | if test "x$ac_cv_header_thread_db_h" = "xyes"; then |
| | 961 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC], |
| | 962 | gdb_cv_thread_db_h_has_td_notalloc, |
| | 963 | AC_TRY_COMPILE( |
| | 964 | [#include <thread_db.h>], |
| | 965 | [int i = TD_NOTALLOC;], |
| | 966 | gdb_cv_thread_db_h_has_td_notalloc=yes, |
| | 967 | gdb_cv_thread_db_h_has_td_notalloc=no |
| | 968 | ) |
| | 969 | ) |
| | 970 | fi |
| | 971 | if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then |
| | 972 | AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1, |
| | 973 | [Define if <thread_db.h> has the TD_NOTALLOC error code.]) |
| | 974 | fi |
| | 975 | |
| | 976 | dnl See if we have a sys/syscall header file that has __NR_tkill. |
| | 977 | if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then |
| | 978 | AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill], |
| | 979 | gdb_cv_sys_syscall_h_has_tkill, |
| | 980 | AC_TRY_COMPILE( |
| | 981 | [#include <sys/syscall.h>], |
| | 982 | [int i = __NR_tkill;], |
| | 983 | gdb_cv_sys_syscall_h_has_tkill=yes, |
| | 984 | gdb_cv_sys_syscall_h_has_tkill=no |
| | 985 | ) |
| | 986 | ) |
| | 987 | fi |
| | 988 | dnl See if we can issue tkill syscall. |
| | 989 | if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then |
| | 990 | AC_DEFINE(HAVE_TKILL_SYSCALL, 1, |
| | 991 | [Define if we can use the tkill syscall.]) |
| | 992 | fi |
| | 993 | |
| | 994 | dnl Handle optional features that can be enabled. |
| | 995 | |
| | 996 | AC_ARG_WITH(sysroot, |
| | 997 | [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.], |
| | 998 | [ |
| | 999 | case ${with_sysroot} in |
| | 1000 | yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;; |
| | 1001 | *) TARGET_SYSTEM_ROOT=$with_sysroot ;; |
| | 1002 | esac |
| | 1003 | |
| | 1004 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"' |
| | 1005 | |
| | 1006 | if test "x$exec_prefix" = xNONE; then |
| | 1007 | if test "x$prefix" = xNONE; then |
| | 1008 | test_prefix=/usr/local |
| | 1009 | else |
| | 1010 | test_prefix=$prefix |
| | 1011 | fi |
| | 1012 | else |
| | 1013 | test_prefix=$exec_prefix |
| | 1014 | fi |
| | 1015 | case ${TARGET_SYSTEM_ROOT} in |
| | 1016 | "${test_prefix}"|"${test_prefix}/"*|\ |
| | 1017 | '${exec_prefix}'|'${exec_prefix}/'*) |
| | 1018 | t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE" |
| | 1019 | TARGET_SYSTEM_ROOT_DEFINE="$t" |
| | 1020 | ;; |
| | 1021 | esac |
| | 1022 | ], [ |
| | 1023 | TARGET_SYSTEM_ROOT= |
| | 1024 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"' |
| | 1025 | ]) |
| | 1026 | AC_SUBST(TARGET_SYSTEM_ROOT) |
| | 1027 | AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE) |
| | 1028 | |
| | 1029 | # NOTE: Don't add -Wall or -Wunused, they both include |
| | 1030 | # -Wunused-parameter which reports bogus warnings. |
| | 1031 | # NOTE: If you add to this list, remember to update |
| | 1032 | # gdb/doc/gdbint.texinfo. |
| | 1033 | build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \ |
| | 1034 | -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \ |
| | 1035 | -Wunused-label -Wunused-function" |
| | 1036 | # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs |
| | 1037 | # -Wunused-function -Wunused-variable -Wunused-value |
| | 1038 | # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual |
| | 1039 | # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes |
| | 1040 | # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls |
| | 1041 | # -Woverloaded-virtual -Winline -Werror" |
| | 1042 | AC_ARG_ENABLE(build-warnings, |
| | 1043 | [ --enable-build-warnings Enable build-time compiler warnings if gcc is used], |
| | 1044 | [case "${enableval}" in |
| | 1045 | yes) ;; |
| | 1046 | no) build_warnings="-w";; |
| | 1047 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| | 1048 | build_warnings="${build_warnings} ${t}";; |
| | 1049 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| | 1050 | build_warnings="${t} ${build_warnings}";; |
| | 1051 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| | 1052 | esac |
| | 1053 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| | 1054 | echo "Setting compiler warning flags = $build_warnings" 6>&1 |
| | 1055 | fi])dnl |
| | 1056 | AC_ARG_ENABLE(gdb-build-warnings, |
| | 1057 | [ --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used], |
| | 1058 | [case "${enableval}" in |
| | 1059 | yes) ;; |
| | 1060 | no) build_warnings="-w";; |
| | 1061 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| | 1062 | build_warnings="${build_warnings} ${t}";; |
| | 1063 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| | 1064 | build_warnings="${t} ${build_warnings}";; |
| | 1065 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| | 1066 | esac |
| | 1067 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| | 1068 | echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1 |
| | 1069 | fi])dnl |
| | 1070 | WARN_CFLAGS="" |
| | 1071 | WERROR_CFLAGS="" |
| | 1072 | if test "x${build_warnings}" != x -a "x$GCC" = xyes |
| | 1073 | then |
| | 1074 | AC_MSG_CHECKING(compiler warning flags) |
| | 1075 | # Separate out the -Werror flag as some files just cannot be |
| | 1076 | # compiled with it enabled. |
| | 1077 | for w in ${build_warnings}; do |
| | 1078 | case $w in |
| | 1079 | -Werr*) WERROR_CFLAGS=-Werror ;; |
| | 1080 | *) # Check that GCC accepts it |
| | 1081 | saved_CFLAGS="$CFLAGS" |
| | 1082 | CFLAGS="$CFLAGS $w" |
| | 1083 | AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",) |
| | 1084 | CFLAGS="$saved_CFLAGS" |
| | 1085 | esac |
| | 1086 | done |
| | 1087 | AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS}) |
| | 1088 | fi |
| | 1089 | AC_SUBST(WARN_CFLAGS) |
| | 1090 | AC_SUBST(WERROR_CFLAGS) |
| | 1091 | |
| | 1092 | # In the Cygwin environment, we need some additional flags. |
| | 1093 | AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin, |
| | 1094 | [AC_EGREP_CPP(lose, [ |
| | 1095 | #if defined (__CYGWIN__) || defined (__CYGWIN32__) |
| | 1096 | lose |
| | 1097 | #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])]) |
| | 1098 | |
| | 1099 | |
| | 1100 | dnl Figure out which of the many generic ser-*.c files the _host_ supports. |
| | 1101 | SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o" |
| | 1102 | case ${host} in |
| | 1103 | *go32* ) SER_HARDWIRE=ser-go32.o ;; |
| | 1104 | *djgpp* ) SER_HARDWIRE=ser-go32.o ;; |
| | 1105 | esac |
| | 1106 | AC_SUBST(SER_HARDWIRE) |
| | 1107 | |
| | 1108 | # libreadline needs libuser32.a in a cygwin environment |
| | 1109 | WIN32LIBS= |
| | 1110 | if test x$gdb_cv_os_cygwin = xyes; then |
| | 1111 | WIN32LIBS="-luser32" |
| | 1112 | case "${target}" in |
| | 1113 | *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp" |
| | 1114 | ;; |
| | 1115 | esac |
| | 1116 | fi |
| | 1117 | AC_SUBST(WIN32LIBS) |
| | 1118 | |
| | 1119 | LIBGUI="../libgui/src/libgui.a" |
| | 1120 | GUI_CFLAGS_X="-I${srcdir}/../libgui/src" |
| | 1121 | AC_SUBST(LIBGUI) |
| | 1122 | AC_SUBST(GUI_CFLAGS_X) |
| | 1123 | |
| | 1124 | WIN32LDAPP= |
| | 1125 | AC_SUBST(WIN32LIBS) |
| | 1126 | AC_SUBST(WIN32LDAPP) |
| | 1127 | |
| | 1128 | configdir="unix" |
| | 1129 | |
| | 1130 | GDBTKLIBS= |
| | 1131 | if test "${enable_gdbtk}" = "yes"; then |
| | 1132 | |
| | 1133 | # Gdbtk must have an absolute path to srcdir in order to run |
| | 1134 | # properly when not installed. |
| | 1135 | here=`pwd` |
| | 1136 | cd ${srcdir} |
| | 1137 | GDBTK_SRC_DIR=`pwd` |
| | 1138 | cd $here |
| | 1139 | |
| | 1140 | CY_AC_PATH_TCLCONFIG |
| | 1141 | if test -z "${no_tcl}"; then |
| | 1142 | CY_AC_LOAD_TCLCONFIG |
| | 1143 | CY_AC_PATH_TKCONFIG |
| | 1144 | |
| | 1145 | # now look for Tcl library stuff |
| | 1146 | |
| | 1147 | case "${host}" in |
| | 1148 | *-*-cygwin*) |
| | 1149 | tcldir=../tcl/win/ |
| | 1150 | ;; |
| | 1151 | *) |
| | 1152 | tcldir=../tcl/unix/ |
| | 1153 | ;; |
| | 1154 | esac |
| | 1155 | |
| | 1156 | TCL_DEPS="${tcldir}${TCL_LIB_FILE}" |
| | 1157 | |
| | 1158 | # If $no_tk is nonempty, then we can't do Tk, and there is no |
| | 1159 | # point to doing Tcl. |
| | 1160 | if test -z "${no_tk}"; then |
| | 1161 | CY_AC_LOAD_TKCONFIG |
| | 1162 | CY_AC_PATH_TCLH |
| | 1163 | CY_AC_PATH_TKH |
| | 1164 | CY_AC_PATH_ITCLH |
| | 1165 | CY_AC_PATH_ITKH |
| | 1166 | |
| | 1167 | |
| | 1168 | # now look for Tk library stuff |
| | 1169 | |
| | 1170 | case "${host}" in |
| | 1171 | *-*-cygwin*) |
| | 1172 | tkdir=../tk/win/ |
| | 1173 | ;; |
| | 1174 | *) |
| | 1175 | tkdir=../tk/unix/ |
| | 1176 | ;; |
| | 1177 | esac |
| | 1178 | |
| | 1179 | TK_DEPS="${tkdir}${TK_LIB_FILE}" |
| | 1180 | |
| | 1181 | # now look for Itcl library stuff |
| | 1182 | |
| | 1183 | CY_AC_PATH_ITCLCONFIG |
| | 1184 | if test -z "${no_itcl}"; then |
| | 1185 | CY_AC_LOAD_ITCLCONFIG |
| | 1186 | |
| | 1187 | ITCLLIB="${ITCL_BUILD_LIB_SPEC}" |
| | 1188 | ITCL_DEPS="${ITCL_LIB_FULL_PATH}" |
| | 1189 | fi |
| | 1190 | |
| | 1191 | |
| | 1192 | # now look for Itk library stuff |
| | 1193 | CY_AC_PATH_ITKCONFIG |
| | 1194 | if test -z "${no_itcl}"; then |
| | 1195 | CY_AC_LOAD_ITKCONFIG |
| | 1196 | |
| | 1197 | ITKLIB="${ITK_BUILD_LIB_SPEC}" |
| | 1198 | ITK_DEPS="${ITK_LIB_FULL_PATH}" |
| | 1199 | fi |
| | 1200 | |
| | 1201 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)" |
| | 1202 | # Tcl/Tk 8.1 require -fwritable strings. I don't |
| | 1203 | # know whether 8.2 will or not, but I bet it will. |
| | 1204 | # I don't have to worry about 7.x since we don't support it. |
| | 1205 | GDBTK_CFLAGS="" |
| | 1206 | if test "$GCC" = "yes"; then |
| | 1207 | if test "$TCL_VERSION" != "8.0" ; then |
| | 1208 | GDBTK_CFLAGS="-fwritable-strings" |
| | 1209 | fi |
| | 1210 | fi |
| | 1211 | |
| | 1212 | # Include some libraries that Tcl and Tk want. |
| | 1213 | TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)' |
| | 1214 | # Yes, the ordering seems wrong here. But it isn't. |
| | 1215 | # TK_LIBS is the list of libraries that need to be linked |
| | 1216 | # after Tcl/Tk. Note that this isn't put into LIBS. If it |
| | 1217 | # were in LIBS then any link tests after this point would |
| | 1218 | # try to include things like `$(LIBGUI)', which wouldn't work. |
| | 1219 | GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}" |
| | 1220 | |
| | 1221 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)" |
| | 1222 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)" |
| | 1223 | CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)" |
| | 1224 | CONFIG_ALL="${CONFIG_ALL} all-gdbtk" |
| | 1225 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk" |
| | 1226 | CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk" |
| | 1227 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk" |
| | 1228 | |
| | 1229 | if test x$gdb_cv_os_cygwin = xyes; then |
| | 1230 | WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32" |
| | 1231 | WIN32LDAPP="-Wl,--subsystem,console" |
| | 1232 | CONFIG_OBS="${CONFIG_OBS} gdbres.o" |
| | 1233 | fi |
| | 1234 | fi |
| | 1235 | fi |
| | 1236 | |
| | 1237 | configdirs="${configdirs} gdbtk" |
| | 1238 | fi |
| | 1239 | |
| | 1240 | AC_SUBST(X_CFLAGS) |
| | 1241 | AC_SUBST(X_LDFLAGS) |
| | 1242 | AC_SUBST(X_LIBS) |
| | 1243 | AC_SUBST(TCL_DEPS) |
| | 1244 | AC_SUBST(TK_DEPS) |
| | 1245 | AC_SUBST(ITCLLIB) |
| | 1246 | AC_SUBST(ITCL_DEPS) |
| | 1247 | AC_SUBST(ITKLIB) |
| | 1248 | AC_SUBST(ITK_DEPS) |
| | 1249 | AC_SUBST(GDBTKLIBS) |
| | 1250 | AC_SUBST(GDBTK_CFLAGS) |
| | 1251 | AC_SUBST(GDBTK_SRC_DIR) |
| | 1252 | |
| | 1253 | AC_PATH_X |
| | 1254 | |
| | 1255 | |
| | 1256 | # Unlike the sim directory, whether a simulator is linked is controlled by |
| | 1257 | # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file. |
| | 1258 | # This code just checks for a few cases where we'd like to ignore those |
| | 1259 | # definitions, even when they're present in the '.mt' file. These cases |
| | 1260 | # are when --disable-sim is specified, or if the simulator directory is |
| | 1261 | # not part of the source tree. |
| | 1262 | # |
| | 1263 | AC_ARG_ENABLE(sim, |
| | 1264 | [ --enable-sim Link gdb with simulator], |
| | 1265 | [echo "enable_sim = $enable_sim"; |
| | 1266 | echo "enableval = ${enableval}"; |
| | 1267 | case "${enableval}" in |
| | 1268 | yes) ignore_sim=false ;; |
| | 1269 | no) ignore_sim=true ;; |
| | 1270 | *) ignore_sim=false ;; |
| | 1271 | esac], |
| | 1272 | [ignore_sim=false]) |
| | 1273 | |
| | 1274 | if test ! -d "${srcdir}/../sim"; then |
| | 1275 | ignore_sim=true |
| | 1276 | fi |
| | 1277 | |
| | 1278 | if test "${ignore_sim}" = "true"; then |
| | 1279 | IGNORE_SIM="SIM=" |
| | 1280 | IGNORE_SIM_OBS="SIM_OBS=" |
| | 1281 | else |
| | 1282 | IGNORE_SIM="" |
| | 1283 | IGNORE_SIM_OBS="" |
| | 1284 | AC_DEFINE(WITH_SIM) |
| | 1285 | fi |
| | 1286 | AC_SUBST(IGNORE_SIM) |
| | 1287 | AC_SUBST(IGNORE_SIM_OBS) |
| | 1288 | |
| | 1289 | AC_SUBST(ENABLE_CFLAGS) |
| | 1290 | AC_SUBST(PROFILE_CFLAGS) |
| | 1291 | |
| | 1292 | AC_SUBST(CONFIG_OBS) |
| | 1293 | AC_SUBST(CONFIG_DEPS) |
| | 1294 | AC_SUBST(CONFIG_SRCS) |
| | 1295 | AC_SUBST(CONFIG_ALL) |
| | 1296 | AC_SUBST(CONFIG_CLEAN) |
| | 1297 | AC_SUBST(CONFIG_INSTALL) |
| | 1298 | AC_SUBST(CONFIG_UNINSTALL) |
| | 1299 | |
| | 1300 | # target_subdir is used by the testsuite to find the target libraries. |
| | 1301 | target_subdir= |
| | 1302 | if test "${host}" != "${target}"; then |
| | 1303 | target_subdir="${target_alias}/" |
| | 1304 | fi |
| | 1305 | AC_SUBST(target_subdir) |
| | 1306 | |
| | 1307 | frags= |
| | 1308 | host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh |
| | 1309 | if test ! -f ${host_makefile_frag}; then |
| | 1310 | # When building a native debuger the .mh file containing things |
| | 1311 | # like NATDEPFILES is needed. Cross debuggers don't need .mh |
| | 1312 | # since it no longer contains anything useful. |
| | 1313 | if test "${target}" = "${host}"; then |
| | 1314 | AC_MSG_ERROR("*** Gdb does not support native target ${host}") |
| | 1315 | else |
| | 1316 | host_makefile_frag=/dev/null |
| | 1317 | fi |
| | 1318 | fi |
| | 1319 | frags="$frags $host_makefile_frag" |
| | 1320 | |
| | 1321 | target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt |
| | 1322 | if test ! -f ${target_makefile_frag}; then |
| | 1323 | AC_MSG_ERROR("*** Gdb does not support target ${target}") |
| | 1324 | fi |
| | 1325 | frags="$frags $target_makefile_frag" |
| | 1326 | |
| | 1327 | AC_SUBST_FILE(host_makefile_frag) |
| | 1328 | AC_SUBST_FILE(target_makefile_frag) |
| | 1329 | AC_SUBST(frags) |
| | 1330 | |
| | 1331 | changequote(,)dnl |
| | 1332 | hostfile=`sed -n ' |
| | 1333 | s/XM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| | 1334 | ' ${host_makefile_frag}` |
| | 1335 | |
| | 1336 | targetfile=`sed -n ' |
| | 1337 | s/TM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| | 1338 | ' ${target_makefile_frag}` |
| | 1339 | |
| | 1340 | if test "${target}" = "${host}"; then |
| | 1341 | # We pick this up from the host configuration file (.mh) because we |
| | 1342 | # do not have a native configuration Makefile fragment. |
| | 1343 | nativefile=`sed -n ' |
| | 1344 | s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| | 1345 | ' ${host_makefile_frag}` |
| | 1346 | fi |
| | 1347 | changequote([,]) |
| | 1348 | |
| | 1349 | if test x"${gdb_osabi}" != x ; then |
| | 1350 | AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi, |
| | 1351 | [Define to the default OS ABI for this configuration.]) |
| | 1352 | fi |
| | 1353 | |
| | 1354 | # Enable multi-ice-gdb-server. |
| | 1355 | AC_ARG_ENABLE(multi-ice, |
| | 1356 | [ --enable-multi-ice build the multi-ice-gdb-server], |
| | 1357 | [case $enableval in |
| | 1358 | yes | no) |
| | 1359 | ;; |
| | 1360 | *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;; |
| | 1361 | esac]) |
| | 1362 | if test "x$enable_multi_ice" = xyes; then |
| | 1363 | configdirs="$configdirs multi-ice" |
| | 1364 | fi |
| | 1365 | |
| | 1366 | # We only build gdbserver automatically if host and target are the same. |
| | 1367 | if test "x$target" = "x$host"; then |
| | 1368 | AC_MSG_CHECKING(whether gdbserver is supported on this host) |
| | 1369 | if test "x$build_gdbserver" = xyes; then |
| | 1370 | configdirs="$configdirs gdbserver" |
| | 1371 | AC_MSG_RESULT(yes) |
| | 1372 | else |
| | 1373 | AC_MSG_RESULT(no) |
| | 1374 | fi |
| | 1375 | fi |
| | 1376 | |
| | 1377 | AC_CONFIG_SUBDIRS($configdirs) |
| | 1378 | |
| | 1379 | # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile |
| | 1380 | # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty |
| | 1381 | # version. |
| | 1382 | |
| | 1383 | files= |
| | 1384 | links= |
| | 1385 | |
| | 1386 | rm -f xm.h |
| | 1387 | xm_h="" |
| | 1388 | if test "${hostfile}" != ""; then |
| | 1389 | xm_h=xm.h |
| | 1390 | GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" |
| | 1391 | files="${files} ${GDB_XM_FILE}" |
| | 1392 | links="${links} xm.h" |
| | 1393 | AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE}) |
| | 1394 | fi |
| | 1395 | AC_SUBST(xm_h) |
| | 1396 | |
| | 1397 | rm -f tm.h |
| | 1398 | tm_h="" |
| | 1399 | if test "${targetfile}" != ""; then |
| | 1400 | tm_h=tm.h |
| | 1401 | GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" |
| | 1402 | files="${files} ${GDB_TM_FILE}" |
| | 1403 | links="${links} tm.h" |
| | 1404 | AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE}) |
| | 1405 | fi |
| | 1406 | AC_SUBST(tm_h) |
| | 1407 | |
| | 1408 | rm -f nm.h |
| | 1409 | nm_h="" |
| | 1410 | if test "${nativefile}" != ""; then |
| | 1411 | nm_h=nm.h |
| | 1412 | GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" |
| | 1413 | files="${files} ${GDB_NM_FILE}" |
| | 1414 | links="${links} nm.h" |
| | 1415 | AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE}) |
| | 1416 | fi |
| | 1417 | AC_SUBST(nm_h) |
| | 1418 | |
| | 1419 | AC_LINK_FILES($files, $links) |
| | 1420 | |
| | 1421 | dnl Check for exe extension set on certain hosts (e.g. Win32) |
| | 1422 | AC_EXEEXT |
| | 1423 | |
| | 1424 | dnl Detect the character set used by this host. |
| | 1425 | |
| | 1426 | dnl At the moment, we just assume it's ISO-8859-1 (which is a |
| | 1427 | dnl superset of ASCII containing the characters needed for French, |
| | 1428 | dnl German, Spanish, Italian, and possibly others), but if were |
| | 1429 | dnl *were* to support any host character sets other than ISO-8859-1, |
| | 1430 | dnl here's where we'd detect it. |
| | 1431 | AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1", |
| | 1432 | [Define to be a string naming the default host character set.]) |
| | 1433 | |
| | 1434 | AM_ICONV |
| | 1435 | |
| | 1436 | AC_OUTPUT(Makefile .gdbinit:gdbinit.in, |
| | 1437 | [ |
| | 1438 | dnl Autoconf doesn't provide a mechanism for modifying definitions |
| | 1439 | dnl provided by makefile fragments. |
| | 1440 | dnl |
| | 1441 | if test "${nativefile}" = ""; then |
| | 1442 | < Makefile \ |
| | 1443 | sed -e '/^NATDEPFILES[[ ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \ |
| | 1444 | -e '/^NATDEPFILES[[ ]]*=/s/^/# /' \ |
| | 1445 | | sed -e '/^\(NATDEPFILES[[ ]]*[[+]]=[[ ]]*\)/s//# \1/' \ |
| | 1446 | > Makefile.tem |
| | 1447 | mv -f Makefile.tem Makefile |
| | 1448 | fi |
| | 1449 | |
| | 1450 | changequote(,)dnl |
| | 1451 | sed -e '/^TM_FILE[ ]*=/s,^TM_FILE[ ]*=[ ]*,&config/'"${gdb_target_cpu}"'/, |
| | 1452 | /^XM_FILE[ ]*=/s,^XM_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/, |
| | 1453 | /^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp |
| | 1454 | mv -f Makefile.tmp Makefile |
| | 1455 | changequote([,])dnl |
| | 1456 | |
| | 1457 | |
| | 1458 | case x$CONFIG_HEADERS in |
| | 1459 | xconfig.h:config.in) |
| | 1460 | echo > stamp-h ;; |
| | 1461 | esac |
| | 1462 | ], |
| | 1463 | [ |
| | 1464 | gdb_host_cpu=$gdb_host_cpu |
| | 1465 | gdb_target_cpu=$gdb_target_cpu |
| | 1466 | nativefile=$nativefile |
| | 1467 | ]) |
| | 1468 | |
| | 1469 | exit 0 |
projects / deliverable / binutils-gdb.git / blame_incremental