| 1 | dnl Autoconf configure script for GDB, the GNU debugger. |
| 2 | dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004 |
| 3 | dnl Free Software Foundation, Inc. |
| 4 | dnl |
| 5 | dnl This file is part of GDB. |
| 6 | dnl |
| 7 | dnl This program is free software; you can redistribute it and/or modify |
| 8 | dnl it under the terms of the GNU General Public License as published by |
| 9 | dnl the Free Software Foundation; either version 2 of the License, or |
| 10 | dnl (at your option) any later version. |
| 11 | dnl |
| 12 | dnl This program is distributed in the hope that it will be useful, |
| 13 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 14 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 15 | dnl GNU General Public License for more details. |
| 16 | dnl |
| 17 | dnl You should have received a copy of the GNU General Public License |
| 18 | dnl along with this program; if not, write to the Free Software |
| 19 | dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 20 | |
| 21 | dnl Process this file with autoconf to produce a configure script. |
| 22 | |
| 23 | AC_PREREQ(2.13)dnl |
| 24 | AC_INIT(main.c) |
| 25 | AC_CONFIG_HEADER(config.h:config.in) |
| 26 | AM_MAINTAINER_MODE |
| 27 | |
| 28 | AC_PROG_CC |
| 29 | AC_GNU_SOURCE |
| 30 | AC_AIX |
| 31 | AC_ISC_POSIX |
| 32 | AM_PROG_CC_STDC |
| 33 | |
| 34 | AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..) |
| 35 | AC_CANONICAL_SYSTEM |
| 36 | |
| 37 | # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13 |
| 38 | # doesn't support cross-compilation, but the one from Autoconf 2.5x |
| 39 | # does. Override RANLIB here (i.e. before running AC_PROG_RANLIB) to |
| 40 | # deal with the lossage. Note that CY_GNU_GETTEXT currently calls |
| 41 | # AC_PROG_RANLIB. This can be removed when we switch to Autoconf |
| 42 | # 2.5x. |
| 43 | AC_CHECK_TOOL(RANLIB, ranlib, :) |
| 44 | |
| 45 | dnl List of object files and targets accumulated by configure. |
| 46 | |
| 47 | CONFIG_OBS= |
| 48 | CONFIG_DEPS= |
| 49 | CONFIG_SRCS= |
| 50 | ENABLE_CFLAGS= |
| 51 | |
| 52 | CONFIG_ALL= |
| 53 | CONFIG_CLEAN= |
| 54 | CONFIG_INSTALL= |
| 55 | CONFIG_UNINSTALL= |
| 56 | |
| 57 | dnl Set up for gettext. PACKAGE is used when we call bindtextdomain. |
| 58 | |
| 59 | CY_GNU_GETTEXT |
| 60 | |
| 61 | localedir='${datadir}/locale' |
| 62 | AC_SUBST(localedir) |
| 63 | |
| 64 | if test "x$POSUB" != x; then |
| 65 | |
| 66 | dnl Lifted from GCC's config/gettext.m4. |
| 67 | AC_MSG_CHECKING(for catalogs to be installed) |
| 68 | # Look for .po and .gmo files in the source directory. |
| 69 | CATALOGS= AC_SUBST(CATALOGS) |
| 70 | XLINGUAS= |
| 71 | for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do |
| 72 | # If there aren't any .gmo files the shell will give us the |
| 73 | # literal string "../path/to/srcdir/po/*.gmo" which has to be |
| 74 | # weeded out. |
| 75 | case "$cat" in *\**) |
| 76 | continue;; |
| 77 | esac |
| 78 | # The quadruple backslash is collapsed to a double backslash |
| 79 | # by the backticks, then collapsed again by the double quotes, |
| 80 | # leaving us with one backslash in the sed expression (right |
| 81 | # before the dot that mustn't act as a wildcard). |
| 82 | cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"` |
| 83 | lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"` |
| 84 | # The user is allowed to set LINGUAS to a list of languages to |
| 85 | # install catalogs for. If it's empty that means "all of them." |
| 86 | if test "x$LINGUAS" = x; then |
| 87 | CATALOGS="$CATALOGS $cat" |
| 88 | XLINGUAS="$XLINGUAS $lang" |
| 89 | else |
| 90 | case "$LINGUAS" in *$lang*) |
| 91 | CATALOGS="$CATALOGS $cat" |
| 92 | XLINGUAS="$XLINGUAS $lang" |
| 93 | ;; |
| 94 | esac |
| 95 | fi |
| 96 | done |
| 97 | LINGUAS="$XLINGUAS" |
| 98 | AC_MSG_RESULT($LINGUAS) |
| 99 | |
| 100 | CONFIG_ALL="$CONFIG_ALL all-po" |
| 101 | CONFIG_CLEAN="$CONFIG_CLEAN clean-po" |
| 102 | CONFIG_INSTALL="$CONFIG_INSTALL install-po" |
| 103 | CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po" |
| 104 | fi |
| 105 | |
| 106 | PACKAGE=gdb |
| 107 | AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ]) |
| 108 | AC_SUBST(PACKAGE) |
| 109 | |
| 110 | debugdir=${libdir}/debug |
| 111 | |
| 112 | AC_ARG_WITH(separate-debug-dir, |
| 113 | [ --with-separate-debug-dir=path Look for global separate debug info in this path [LIBDIR/debug]], |
| 114 | [debugdir="${withval}"]) |
| 115 | |
| 116 | AC_DEFINE_DIR(DEBUGDIR, debugdir, |
| 117 | [Global directory for separate debug files. ]) |
| 118 | #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"), |
| 119 | |
| 120 | AC_CONFIG_SUBDIRS(doc testsuite) |
| 121 | configdirs= |
| 122 | |
| 123 | . $srcdir/configure.host |
| 124 | |
| 125 | . $srcdir/configure.tgt |
| 126 | |
| 127 | # Fetch the default architecture and default target vector from BFD. |
| 128 | targ=$target; . $srcdir/../bfd/config.bfd |
| 129 | |
| 130 | # We only want the first architecture, so strip off the others if |
| 131 | # there is more than one. |
| 132 | targ_archs=`echo $targ_archs | sed 's/ .*//'` |
| 133 | |
| 134 | if test "x$targ_archs" != x; then |
| 135 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs, |
| 136 | [Define to BFD's default architecture. ]) |
| 137 | fi |
| 138 | if test "x$targ_defvec" != x; then |
| 139 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec, |
| 140 | [Define to BFD's default target vector. ]) |
| 141 | fi |
| 142 | |
| 143 | AC_ARG_PROGRAM |
| 144 | |
| 145 | # The CLI cannot be disabled yet, but may be in the future. |
| 146 | |
| 147 | # Enable CLI. |
| 148 | AC_ARG_ENABLE(gdbcli, |
| 149 | [ --disable-gdbcli disable command-line interface (CLI)], |
| 150 | [case $enableval in |
| 151 | yes) |
| 152 | ;; |
| 153 | no) |
| 154 | AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;; |
| 155 | *) |
| 156 | AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;; |
| 157 | esac], |
| 158 | [enable_gdbcli=yes]) |
| 159 | if test x"$enable_gdbcli" = xyes; then |
| 160 | if test -d $srcdir/cli; then |
| 161 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)" |
| 162 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)" |
| 163 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)" |
| 164 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)" |
| 165 | fi |
| 166 | fi |
| 167 | |
| 168 | # Enable MI. |
| 169 | AC_ARG_ENABLE(gdbmi, |
| 170 | [ --disable-gdbmi disable machine-interface (MI)], |
| 171 | [case $enableval in |
| 172 | yes | no) |
| 173 | ;; |
| 174 | *) |
| 175 | AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;; |
| 176 | esac], |
| 177 | [enable_gdbmi=yes]) |
| 178 | if test x"$enable_gdbmi" = xyes; then |
| 179 | if test -d $srcdir/mi; then |
| 180 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)" |
| 181 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)" |
| 182 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)" |
| 183 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)" |
| 184 | fi |
| 185 | fi |
| 186 | |
| 187 | # Enable TUI. |
| 188 | AC_ARG_ENABLE(tui, |
| 189 | [ --enable-tui enable full-screen terminal user interface (TUI)], |
| 190 | [case $enableval in |
| 191 | yes | no) |
| 192 | ;; |
| 193 | *) |
| 194 | AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;; |
| 195 | esac],enable_tui=yes) |
| 196 | if test x"$enable_tui" = xyes; then |
| 197 | if test -d $srcdir/tui; then |
| 198 | if test "$ac_cv_search_initscr" != no -a "$ac_cv_search_wborder" != no; then |
| 199 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)" |
| 200 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)" |
| 201 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)" |
| 202 | CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)" |
| 203 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)" |
| 204 | CONFIG_ALL="${CONFIG_ALL} all-tui" |
| 205 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui" |
| 206 | CONFIG_INSTALL="${CONFIG_INSTALL} install-tui" |
| 207 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui" |
| 208 | fi |
| 209 | fi |
| 210 | fi |
| 211 | |
| 212 | # Enable gdbtk. |
| 213 | AC_ARG_ENABLE(gdbtk, |
| 214 | [ --enable-gdbtk enable gdbtk graphical user interface (GUI)], |
| 215 | [case $enableval in |
| 216 | yes | no) |
| 217 | ;; |
| 218 | *) |
| 219 | AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;; |
| 220 | esac], |
| 221 | [if test -d $srcdir/gdbtk; then |
| 222 | enable_gdbtk=yes |
| 223 | else |
| 224 | enable_gdbtk=no |
| 225 | fi]) |
| 226 | # We unconditionally disable gdbtk tests on selected platforms. |
| 227 | case $host_os in |
| 228 | go32* | windows*) |
| 229 | AC_MSG_WARN([gdbtk isn't supported on $host; disabling]) |
| 230 | enable_gdbtk=no ;; |
| 231 | esac |
| 232 | |
| 233 | # Libunwind support. |
| 234 | AC_ARG_WITH(libunwind, |
| 235 | [ --with-libunwind Use libunwind frame unwinding support], |
| 236 | [case "${withval}" in |
| 237 | yes) enable_libunwind=yes ;; |
| 238 | no) enable_libunwind=no ;; |
| 239 | *) AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;; |
| 240 | esac],[ |
| 241 | AC_CHECK_HEADERS(libunwind.h) |
| 242 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 243 | if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then |
| 244 | enable_libunwind=yes; |
| 245 | fi |
| 246 | ]) |
| 247 | |
| 248 | if test x"$enable_libunwind" = xyes; then |
| 249 | AC_CHECK_HEADERS(libunwind.h) |
| 250 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 251 | AC_DEFINE(HAVE_LIBUNWIND, 1) |
| 252 | CONFIG_OBS="$CONFIG_OBS libunwind-frame.o" |
| 253 | CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o" |
| 254 | CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c" |
| 255 | fi |
| 256 | |
| 257 | # Profiling support. |
| 258 | AC_ARG_ENABLE(profiling, |
| 259 | [ --enable-profiling enable profiling of GDB], |
| 260 | [case $enableval in |
| 261 | yes | no) |
| 262 | ;; |
| 263 | *) |
| 264 | AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;; |
| 265 | esac], |
| 266 | [enable_profiling=no]) |
| 267 | |
| 268 | AC_CHECK_FUNCS(monstartup _mcleanup) |
| 269 | AC_CACHE_CHECK([for _etext], ac_cv_var__etext, |
| 270 | [AC_TRY_LINK( |
| 271 | [#include <stdlib.h> |
| 272 | extern char _etext; |
| 273 | ], |
| 274 | [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)]) |
| 275 | if test $ac_cv_var__etext = yes; then |
| 276 | AC_DEFINE(HAVE__ETEXT, 1, |
| 277 | [Define to 1 if your system has the _etext variable. ]) |
| 278 | fi |
| 279 | if test "$enable_profiling" = yes ; then |
| 280 | if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then |
| 281 | AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup) |
| 282 | fi |
| 283 | PROFILE_CFLAGS=-pg |
| 284 | OLD_CFLAGS="$CFLAGS" |
| 285 | CFLAGS="$CFLAGS $PROFILE_CFLAGS" |
| 286 | |
| 287 | AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg, |
| 288 | [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes, |
| 289 | ac_cv_cc_supports_pg=no)]) |
| 290 | |
| 291 | if test $ac_cv_cc_supports_pg = no; then |
| 292 | AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg) |
| 293 | fi |
| 294 | |
| 295 | CFLAGS="$OLD_CFLAGS" |
| 296 | fi |
| 297 | |
| 298 | # --------------------- # |
| 299 | # Checks for programs. # |
| 300 | # --------------------- # |
| 301 | |
| 302 | AC_PROG_AWK |
| 303 | AC_PROG_INSTALL |
| 304 | AC_PROG_LN_S |
| 305 | AC_PROG_RANLIB |
| 306 | AC_PROG_YACC |
| 307 | |
| 308 | AC_CHECK_TOOL(AR, ar) |
| 309 | AC_CHECK_TOOL(DLLTOOL, dlltool) |
| 310 | AC_CHECK_TOOL(WINDRES, windres) |
| 311 | |
| 312 | # Needed for GNU/Hurd. |
| 313 | AC_CHECK_TOOL(MIG, mig) |
| 314 | |
| 315 | # ---------------------- # |
| 316 | # Checks for libraries. # |
| 317 | # ---------------------- # |
| 318 | |
| 319 | # We might need to link with -lm; most simulators need it. |
| 320 | AC_CHECK_LIB(m, main) |
| 321 | |
| 322 | # We need to link with -lw to get `wctype' on Solaris before Solaris |
| 323 | # 2.6. Solaris 2.6 and beyond have this function in libc, and have a |
| 324 | # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1 |
| 325 | # is known to have this problem). Therefore we avoid libw if we can. |
| 326 | AC_CHECK_FUNC(wctype, [], |
| 327 | [AC_CHECK_LIB(w, wctype)]) |
| 328 | |
| 329 | # Some systems (e.g. Solaris) have `gethostbyname' in libnsl. |
| 330 | AC_SEARCH_LIBS(gethostbyname, nsl) |
| 331 | |
| 332 | # Some systems (e.g. Solaris) have `socketpair' in libsocket. |
| 333 | AC_SEARCH_LIBS(socketpair, socket) |
| 334 | |
| 335 | # Since GDB uses Readline, we need termcap functionality, so we need |
| 336 | # to find a library that provides that. When GDB is configured with |
| 337 | # the TUI, we need full curses functionality. |
| 338 | |
| 339 | case $host_os in |
| 340 | cygwin*) |
| 341 | if test -d $srcdir/libtermcap; then |
| 342 | LIBS="../libtermcap/libtermcap.a $LIBS" |
| 343 | ac_cv_search_tgetent="../libtermcap/libtermcap.a" |
| 344 | fi ;; |
| 345 | go32* | *djgpp*) |
| 346 | ac_cv_search_tgetent="none required" |
| 347 | ;; |
| 348 | aix*) |
| 349 | # Readline prefers curses over termcap on AIX. |
| 350 | # ??? Why? |
| 351 | AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap]) |
| 352 | ;; |
| 353 | esac |
| 354 | |
| 355 | # Note: We used to check for libtermlib and libterminfo too, but |
| 356 | # Readline doesn't, so I think we're safe with leaving them out. |
| 357 | AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses]) |
| 358 | |
| 359 | if test "$ac_cv_search_tgetent" = no; then |
| 360 | AC_MSG_ERROR([no termcap library found]) |
| 361 | fi |
| 362 | |
| 363 | # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over |
| 364 | # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host |
| 365 | # Makefile fragments. That's why we need to have `Hcurses' before |
| 366 | # `curses'. I don't see why we should use HP curses if a more |
| 367 | # standard curses is available, except that according to HP's |
| 368 | # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on |
| 369 | # HP-UX 10.10 and 10.20. |
| 370 | |
| 371 | # FIXME: ncurses does not work on native alphaev68-dec-osf5.1, |
| 372 | # and probably other platforms. AC_SEARCH_LIBS finds the library |
| 373 | # in a place such as /usr/local/lib/libncurses.a, but does not |
| 374 | # do anything to look for the matching include files. |
| 375 | # -- chastain 2004-05-01 |
| 376 | |
| 377 | AC_SEARCH_LIBS(initscr, [ncurses Hcurses cursesX curses pdcurses], [], |
| 378 | [AC_MSG_WARN([no curses library found])]) |
| 379 | |
| 380 | # Check whether the wborder function is provided by the curses |
| 381 | # library detected above. In certain implementations such as |
| 382 | # the HP/UX Hcurses for instance, this function is provided by an |
| 383 | # additional library. So if we did not find this function inside |
| 384 | # the curses library, try some alternate libraries we know might |
| 385 | # provide it. |
| 386 | AC_SEARCH_LIBS(wborder, [cur_colr], [], |
| 387 | [AC_MSG_WARN([wborder function not found, tui will be disabled])]) |
| 388 | |
| 389 | # ------------------------- # |
| 390 | # Checks for header files. # |
| 391 | # ------------------------- # |
| 392 | |
| 393 | AC_HEADER_DIRENT |
| 394 | AC_HEADER_STAT |
| 395 | AC_HEADER_STDC |
| 396 | AC_CHECK_HEADERS(link.h) |
| 397 | AC_CHECK_HEADERS(machine/reg.h) |
| 398 | AC_CHECK_HEADERS(nlist.h) |
| 399 | AC_CHECK_HEADERS(poll.h sys/poll.h) |
| 400 | AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h) |
| 401 | AC_CHECK_HEADERS(stddef.h) |
| 402 | AC_CHECK_HEADERS(stdlib.h) |
| 403 | AC_CHECK_HEADERS(stdint.h) |
| 404 | AC_CHECK_HEADERS(string.h memory.h strings.h) |
| 405 | AC_CHECK_HEADERS(sys/fault.h) |
| 406 | AC_CHECK_HEADERS(sys/file.h) |
| 407 | AC_CHECK_HEADERS(sys/filio.h) |
| 408 | AC_CHECK_HEADERS(sys/ioctl.h) |
| 409 | AC_CHECK_HEADERS(sys/param.h) |
| 410 | AC_CHECK_HEADERS(sys/proc.h) |
| 411 | AC_CHECK_HEADERS(sys/procfs.h) |
| 412 | AC_CHECK_HEADERS(sys/ptrace.h ptrace.h) |
| 413 | AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h) |
| 414 | AC_CHECK_HEADERS(sys/select.h) |
| 415 | AC_CHECK_HEADERS(sys/syscall.h) |
| 416 | AC_CHECK_HEADERS(sys/types.h) |
| 417 | AC_CHECK_HEADERS(sys/user.h) |
| 418 | AC_CHECK_HEADERS(sys/wait.h wait.h) |
| 419 | AC_CHECK_HEADERS(termios.h termio.h sgtty.h) |
| 420 | AC_CHECK_HEADERS(unistd.h) |
| 421 | |
| 422 | # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash |
| 423 | # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to |
| 424 | # think that we don't have <curses.h> if we're using GCC. |
| 425 | case $host_os in |
| 426 | solaris2.[[789]]) |
| 427 | if test "$GCC" = yes; then |
| 428 | AC_DEFINE(_MSE_INT_H, 1, |
| 429 | [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on |
| 430 | Solaris 2.[789] when using GCC. ]]) |
| 431 | fi ;; |
| 432 | esac |
| 433 | AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h term.h) |
| 434 | |
| 435 | # FIXME: kettenis/20030102: In most cases we include these |
| 436 | # unconditionally, so what's the point in checking these? |
| 437 | AC_CHECK_HEADERS(ctype.h time.h) |
| 438 | |
| 439 | dnl Check for struct stat with an st_blocks member |
| 440 | AC_MSG_CHECKING(for member st_blocks in struct stat) |
| 441 | AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member, |
| 442 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 443 | #include <sys/stat.h>], |
| 444 | [struct stat st; (void) st.st_blocks;], |
| 445 | gdb_cv_have_struct_stat_with_st_blocks_member=yes, |
| 446 | gdb_cv_have_struct_stat_with_st_blocks_member=no)]) |
| 447 | AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member) |
| 448 | if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then |
| 449 | AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS) |
| 450 | fi |
| 451 | |
| 452 | # ------------------------- # |
| 453 | # Checks for declarations. # |
| 454 | # ------------------------- # |
| 455 | |
| 456 | gcc_AC_CHECK_DECLS(getopt) |
| 457 | |
| 458 | # ------------------ # |
| 459 | # Checks for types. # |
| 460 | # ------------------ # |
| 461 | |
| 462 | AC_TYPE_SIGNAL |
| 463 | |
| 464 | # ------------------------------------- # |
| 465 | # Checks for compiler characteristics. # |
| 466 | # ------------------------------------- # |
| 467 | |
| 468 | AC_C_CONST |
| 469 | AC_C_INLINE |
| 470 | |
| 471 | # ------------------------------ # |
| 472 | # Checks for library functions. # |
| 473 | # ------------------------------ # |
| 474 | |
| 475 | AC_FUNC_ALLOCA |
| 476 | AC_FUNC_MMAP |
| 477 | AC_FUNC_VFORK |
| 478 | AC_CHECK_FUNCS(canonicalize_file_name realpath) |
| 479 | AC_CHECK_FUNCS(poll) |
| 480 | AC_CHECK_FUNCS(pread64) |
| 481 | AC_CHECK_FUNCS(sbrk) |
| 482 | AC_CHECK_FUNCS(setpgid setpgrp) |
| 483 | AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask) |
| 484 | AC_CHECK_FUNCS(socketpair) |
| 485 | AC_CHECK_FUNCS(syscall) |
| 486 | AC_CHECK_FUNCS(ttrace) |
| 487 | |
| 488 | # Check the return and argument types of ptrace. No canned test for |
| 489 | # this, so roll our own. |
| 490 | gdb_ptrace_headers=' |
| 491 | #if HAVE_SYS_TYPES_H |
| 492 | # include <sys/types.h> |
| 493 | #endif |
| 494 | #if HAVE_SYS_PTRACE_H |
| 495 | # include <sys/ptrace.h> |
| 496 | #endif |
| 497 | #if HAVE_UNISTD_H |
| 498 | # include <unistd.h> |
| 499 | #endif |
| 500 | ' |
| 501 | # There is no point in checking if we don't have a prototype. |
| 502 | gcc_AC_CHECK_DECLS(ptrace, , [ |
| 503 | : ${gdb_cv_func_ptrace_ret='int'} |
| 504 | : ${gdb_cv_func_ptrace_args='int,int,long,long'} |
| 505 | ], $gdb_ptrace_headers) |
| 506 | # Check return type. |
| 507 | AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret, |
| 508 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 509 | [extern int ptrace ();], |
| 510 | gdb_cv_func_ptrace_ret='int', |
| 511 | gdb_cv_func_ptrace_ret='long')) |
| 512 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret, |
| 513 | [Define as the return type of ptrace.]) |
| 514 | # Check argument types. |
| 515 | AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [ |
| 516 | for gdb_arg1 in 'int' 'long'; do |
| 517 | for gdb_arg2 in 'pid_t' 'int' 'long'; do |
| 518 | for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do |
| 519 | for gdb_arg4 in 'int' 'long'; do |
| 520 | AC_TRY_COMPILE($gdb_ptrace_headers, [ |
| 521 | extern $gdb_cv_func_ptrace_ret |
| 522 | ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4); |
| 523 | ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4"; |
| 524 | break 4;]) |
| 525 | for gdb_arg5 in 'int *' 'int' 'long'; do |
| 526 | AC_TRY_COMPILE($gdb_ptrace_headers, [ |
| 527 | extern $gdb_cv_func_ptrace_ret |
| 528 | ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5); |
| 529 | ], [ |
| 530 | gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5"; |
| 531 | break 5;]) |
| 532 | done |
| 533 | done |
| 534 | done |
| 535 | done |
| 536 | done |
| 537 | # Provide a safe default value. |
| 538 | : ${gdb_cv_func_ptrace_args='int,int,long,long'} |
| 539 | ]) |
| 540 | ac_save_IFS=$IFS; IFS=',' |
| 541 | set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'` |
| 542 | IFS=$ac_save_IFS |
| 543 | shift |
| 544 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3], |
| 545 | [Define to the type of arg 3 for ptrace.]) |
| 546 | if test -n "$[5]"; then |
| 547 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5], |
| 548 | [Define to the type of arg 5 for ptrace.]) |
| 549 | fi |
| 550 | |
| 551 | dnl AC_FUNC_SETPGRP does not work when cross compiling |
| 552 | dnl Instead, assume we will have a prototype for setpgrp if cross compiling. |
| 553 | if test "$cross_compiling" = no; then |
| 554 | AC_FUNC_SETPGRP |
| 555 | else |
| 556 | AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void, |
| 557 | [AC_TRY_COMPILE([ |
| 558 | #include <unistd.h> |
| 559 | ], [ |
| 560 | if (setpgrp(1,1) == -1) |
| 561 | exit (0); |
| 562 | else |
| 563 | exit (1); |
| 564 | ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)]) |
| 565 | if test $ac_cv_func_setpgrp_void = yes; then |
| 566 | AC_DEFINE(SETPGRP_VOID, 1) |
| 567 | fi |
| 568 | fi |
| 569 | |
| 570 | # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do |
| 571 | # since sigsetjmp might only be defined as a macro. |
| 572 | AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp, |
| 573 | [AC_TRY_COMPILE([ |
| 574 | #include <setjmp.h> |
| 575 | ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);], |
| 576 | gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)]) |
| 577 | if test $gdb_cv_func_sigsetjmp = yes; then |
| 578 | AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ]) |
| 579 | fi |
| 580 | |
| 581 | # Assume we'll default to using the included libiberty regex. |
| 582 | gdb_use_included_regex=yes |
| 583 | |
| 584 | # However, if the system regex is GNU regex, then default to *not* |
| 585 | # using the included regex. |
| 586 | AC_CACHE_CHECK( |
| 587 | [for GNU regex], |
| 588 | [gdb_cv_have_gnu_regex], |
| 589 | [AC_TRY_COMPILE( |
| 590 | [#include <gnu-versions.h>], |
| 591 | [#define REGEX_INTERFACE_VERSION 1 |
| 592 | #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION |
| 593 | # error "Version mismatch" |
| 594 | #endif], |
| 595 | gdb_cv_have_gnu_regex=yes, |
| 596 | gdb_cv_have_gnu_regex=no)]) |
| 597 | if test $gdb_cv_have_gnu_regex = yes; then |
| 598 | gdb_use_included_regex=no |
| 599 | fi |
| 600 | |
| 601 | AC_ARG_WITH(included-regex, |
| 602 | [ --without-included-regex don't use included regex; this is the default |
| 603 | on systems with version 2 of the GNU C library |
| 604 | (use with caution on other system)], |
| 605 | gdb_with_regex=$withval, |
| 606 | gdb_with_regex=$gdb_use_included_regex) |
| 607 | if test "$gdb_with_regex" = yes; then |
| 608 | AC_DEFINE(USE_INCLUDED_REGEX, 1, |
| 609 | [Define to 1 if the regex included in libiberty should be used.]) |
| 610 | fi |
| 611 | |
| 612 | # See if <sys/proc.h> defines `struct thread' with a td_pcb member. |
| 613 | AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb, |
| 614 | [AC_TRY_COMPILE([#include <sys/param.h> |
| 615 | #include <sys/proc.h>], [struct thread td; td.td_pcb;], |
| 616 | gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)]) |
| 617 | if test $gdb_cv_struct_thread_td_pcb = yes; then |
| 618 | AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1, |
| 619 | [Define to 1 if your system has td_pcb in struct thread.]) |
| 620 | fi |
| 621 | |
| 622 | # See if <sys/lwp.h> defines `struct lwp`. |
| 623 | AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp, |
| 624 | [AC_TRY_COMPILE([#include <sys/param.h> |
| 625 | #include <sys/lwp.h>], [struct lwp l;], |
| 626 | gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)]) |
| 627 | if test $gdb_cv_struct_lwp = yes; then |
| 628 | AC_DEFINE(HAVE_STRUCT_LWP, 1, |
| 629 | [Define to 1 if your system has struct lwp.]) |
| 630 | fi |
| 631 | |
| 632 | # See if <machine/reg.h> degines `struct reg'. |
| 633 | AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg, |
| 634 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 635 | #include <machine/reg.h>], [struct reg r;], |
| 636 | gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)]) |
| 637 | if test $gdb_cv_struct_reg = yes; then |
| 638 | AC_DEFINE(HAVE_STRUCT_REG, 1, |
| 639 | [Define to 1 if your system has struct reg in <machine/reg.h>.]) |
| 640 | fi |
| 641 | |
| 642 | # See if <machine/reg.h> supports the %fs and %gs i386 segment registers. |
| 643 | # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'. |
| 644 | AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs, |
| 645 | [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;], |
| 646 | gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)]) |
| 647 | if test $gdb_cv_struct_reg_r_fs = yes; then |
| 648 | AC_DEFINE(HAVE_STRUCT_REG_R_FS) |
| 649 | fi |
| 650 | AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs, |
| 651 | [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;], |
| 652 | gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)]) |
| 653 | if test $gdb_cv_struct_reg_r_gs = yes; then |
| 654 | AC_DEFINE(HAVE_STRUCT_REG_R_GS) |
| 655 | fi |
| 656 | |
| 657 | # See if <sys/ptrace.h> provides the PTRACE_GETREGS request. |
| 658 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 659 | AC_CACHE_VAL(gdb_cv_have_ptrace_getregs, |
| 660 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 661 | [PTRACE_GETREGS;], |
| 662 | [gdb_cv_have_ptrace_getregs=yes], |
| 663 | [gdb_cv_have_ptrace_getregs=no])]) |
| 664 | AC_MSG_RESULT($gdb_cv_have_ptrace_getregs) |
| 665 | if test $gdb_cv_have_ptrace_getregs = yes; then |
| 666 | AC_DEFINE(HAVE_PTRACE_GETREGS) |
| 667 | fi |
| 668 | |
| 669 | # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request. |
| 670 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 671 | AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs, |
| 672 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 673 | [PTRACE_GETFPXREGS;], |
| 674 | [gdb_cv_have_ptrace_getfpxregs=yes], |
| 675 | [gdb_cv_have_ptrace_getfpxregs=no])]) |
| 676 | AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs) |
| 677 | if test $gdb_cv_have_ptrace_getfpxregs = yes; then |
| 678 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS) |
| 679 | fi |
| 680 | |
| 681 | # See if <sys/ptrace.h> provides the PT_GETDBREGS request. |
| 682 | AC_MSG_CHECKING(for PT_GETDBREGS) |
| 683 | AC_CACHE_VAL(gdb_cv_have_pt_getdbregs, |
| 684 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 685 | #include <sys/ptrace.h>], |
| 686 | [PT_GETDBREGS;], |
| 687 | [gdb_cv_have_pt_getdbregs=yes], |
| 688 | [gdb_cv_have_pt_getdbregs=no])]) |
| 689 | AC_MSG_RESULT($gdb_cv_have_pt_getdbregs) |
| 690 | if test $gdb_cv_have_pt_getdbregs = yes; then |
| 691 | AC_DEFINE(HAVE_PT_GETDBREGS) |
| 692 | fi |
| 693 | |
| 694 | # See if <sys/ptrace.h> provides the PT_GETXMMREGS request. |
| 695 | AC_MSG_CHECKING(for PT_GETXMMREGS) |
| 696 | AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs, |
| 697 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 698 | #include <sys/ptrace.h>], |
| 699 | [PT_GETXMMREGS;], |
| 700 | [gdb_cv_have_pt_getxmmregs=yes], |
| 701 | [gdb_cv_have_pt_getxmmregs=no])]) |
| 702 | AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs) |
| 703 | if test $gdb_cv_have_pt_getxmmregs = yes; then |
| 704 | AC_DEFINE(HAVE_PT_GETXMMREGS) |
| 705 | fi |
| 706 | |
| 707 | # See if stdint.h provides the uintptr_t type. |
| 708 | # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this. |
| 709 | AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t, |
| 710 | [AC_TRY_COMPILE( |
| 711 | [#include <stdint.h>], |
| 712 | [uintptr_t foo = 0;], |
| 713 | gdb_cv_have_uintptr_t=yes, |
| 714 | gdb_cv_have_uintptr_t=no)]) |
| 715 | if test $gdb_cv_have_uintptr_t = yes; then |
| 716 | AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.]) |
| 717 | fi |
| 718 | |
| 719 | BFD_NEED_DECLARATION(malloc) |
| 720 | BFD_NEED_DECLARATION(realloc) |
| 721 | BFD_NEED_DECLARATION(free) |
| 722 | BFD_NEED_DECLARATION(strerror) |
| 723 | BFD_NEED_DECLARATION(strdup) |
| 724 | BFD_NEED_DECLARATION(strstr) |
| 725 | BFD_NEED_DECLARATION(canonicalize_file_name) |
| 726 | |
| 727 | # The following save_state_t checkery is only necessary for HPUX |
| 728 | # versions earlier than 10.20. When those fade from memory, this |
| 729 | # could be expunged. --jsm 1999-03-22 |
| 730 | |
| 731 | AC_MSG_CHECKING(for HPUX save_state structure) |
| 732 | AC_EGREP_HEADER(save_state_t, machine/save_state.h, |
| 733 | gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no) |
| 734 | AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes, |
| 735 | gdb_cv_hpux_sswide=no) |
| 736 | if test $gdb_cv_hpux_savestate = yes |
| 737 | then |
| 738 | AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1) |
| 739 | fi |
| 740 | if test $gdb_cv_hpux_sswide = yes |
| 741 | then |
| 742 | AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1) |
| 743 | fi |
| 744 | AC_MSG_RESULT($gdb_cv_hpux_sswide) |
| 745 | |
| 746 | |
| 747 | # If we are configured native on GNU/Linux, work around problems with |
| 748 | # sys/procfs.h |
| 749 | # Also detect which type of /proc is in use, such as for Unixware or Solaris. |
| 750 | |
| 751 | if test "${target}" = "${host}"; then |
| 752 | case "${host}" in |
| 753 | i[[3456]]86-*-linux*) |
| 754 | AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2) |
| 755 | AC_DEFINE(sys_quotactl) |
| 756 | ;; |
| 757 | ia64-*-aix*) |
| 758 | AC_DEFINE(NEW_PROC_API) |
| 759 | ;; |
| 760 | *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* ) |
| 761 | AC_DEFINE(NEW_PROC_API) |
| 762 | ;; |
| 763 | *-*-solaris2.[[6789]]) |
| 764 | AC_DEFINE(NEW_PROC_API) |
| 765 | ;; |
| 766 | mips-sgi-irix5*) |
| 767 | # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5. |
| 768 | AC_DEFINE([_KMEMUSER], 1) |
| 769 | ;; |
| 770 | esac |
| 771 | fi |
| 772 | |
| 773 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 774 | BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t) |
| 775 | BFD_HAVE_SYS_PROCFS_TYPE(prrun_t) |
| 776 | BFD_HAVE_SYS_PROCFS_TYPE(gregset_t) |
| 777 | BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t) |
| 778 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 779 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 780 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t) |
| 781 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t) |
| 782 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 783 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 784 | BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t) |
| 785 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t) |
| 786 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t) |
| 787 | BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t) |
| 788 | |
| 789 | |
| 790 | dnl Check for broken prfpregset_t type |
| 791 | |
| 792 | dnl For Linux/i386, glibc 2.1.3 was released with a bogus |
| 793 | dnl prfpregset_t type (it's a typedef for the pointer to a struct |
| 794 | dnl instead of the struct itself). We detect this here, and work |
| 795 | dnl around it in gdb_proc_service.h. |
| 796 | |
| 797 | if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then |
| 798 | AC_MSG_CHECKING(whether prfpregset_t type is broken) |
| 799 | AC_CACHE_VAL(gdb_cv_prfpregset_t_broken, |
| 800 | [AC_TRY_RUN([#include <sys/procfs.h> |
| 801 | int main () |
| 802 | { |
| 803 | if (sizeof (prfpregset_t) == sizeof (void *)) |
| 804 | return 1; |
| 805 | return 0; |
| 806 | }], |
| 807 | gdb_cv_prfpregset_t_broken=no, |
| 808 | gdb_cv_prfpregset_t_broken=yes, |
| 809 | gdb_cv_prfpregset_t_broken=yes)]) |
| 810 | AC_MSG_RESULT($gdb_cv_prfpregset_t_broken) |
| 811 | if test $gdb_cv_prfpregset_t_broken = yes; then |
| 812 | AC_DEFINE(PRFPREGSET_T_BROKEN) |
| 813 | fi |
| 814 | fi |
| 815 | |
| 816 | dnl Check for PIOCSET ioctl entry |
| 817 | |
| 818 | AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h) |
| 819 | AC_CACHE_VAL(gdb_cv_have_procfs_piocset, |
| 820 | [AC_TRY_COMPILE([#include <unistd.h> |
| 821 | #include <sys/types.h> |
| 822 | #include <sys/procfs.h> |
| 823 | ], [ |
| 824 | int dummy;; |
| 825 | dummy = ioctl(0, PIOCSET, &dummy); |
| 826 | ], |
| 827 | gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)]) |
| 828 | AC_MSG_RESULT($gdb_cv_have_procfs_piocset) |
| 829 | if test $gdb_cv_have_procfs_piocset = yes; then |
| 830 | AC_DEFINE(HAVE_PROCFS_PIOCSET) |
| 831 | fi |
| 832 | fi |
| 833 | |
| 834 | dnl For native ports (host == target), check to see what kind of |
| 835 | dnl legacy link.h support is needed. (See solib-legacy.c.) |
| 836 | if test ${host} = ${target} ; then |
| 837 | dnl Check for struct link_map with l_ members which are indicative |
| 838 | dnl of SVR4-like shared libraries |
| 839 | |
| 840 | AC_MSG_CHECKING(for member l_addr in struct link_map) |
| 841 | AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members, |
| 842 | [AC_TRY_COMPILE([#include <link.h>], |
| 843 | [struct link_map lm; (void) lm.l_addr;], |
| 844 | gdb_cv_have_struct_link_map_with_l_members=yes, |
| 845 | gdb_cv_have_struct_link_map_with_l_members=no)]) |
| 846 | AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members) |
| 847 | if test $gdb_cv_have_struct_link_map_with_l_members = yes; then |
| 848 | AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS) |
| 849 | fi |
| 850 | |
| 851 | dnl Check for struct link_map with lm_ members which are indicative |
| 852 | dnl of SunOS-like shared libraries |
| 853 | |
| 854 | AC_MSG_CHECKING(for member lm_addr in struct link_map) |
| 855 | AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members, |
| 856 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 857 | #include <link.h>], |
| 858 | [struct link_map lm; (void) lm.lm_addr;], |
| 859 | gdb_cv_have_struct_link_map_with_lm_members=yes, |
| 860 | gdb_cv_have_struct_link_map_with_lm_members=no)]) |
| 861 | AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members) |
| 862 | if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then |
| 863 | AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS) |
| 864 | fi |
| 865 | |
| 866 | dnl Check for struct so_map with som_ members which are found on |
| 867 | dnl some *BSD systems. |
| 868 | |
| 869 | AC_MSG_CHECKING(for member som_addr in struct so_map) |
| 870 | AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members, |
| 871 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 872 | #ifdef HAVE_NLIST_H |
| 873 | #include <nlist.h> |
| 874 | #endif |
| 875 | #include <link.h>], |
| 876 | [struct so_map lm; (void) lm.som_addr;], |
| 877 | gdb_cv_have_struct_so_map_with_som_members=yes, |
| 878 | gdb_cv_have_struct_so_map_with_som_members=no)]) |
| 879 | AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members) |
| 880 | if test $gdb_cv_have_struct_so_map_with_som_members = yes; then |
| 881 | AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS) |
| 882 | fi |
| 883 | |
| 884 | dnl Check for struct link_map32 type, which allows a 64-bit Solaris |
| 885 | dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries. |
| 886 | |
| 887 | AC_MSG_CHECKING(for struct link_map32 in sys/link.h) |
| 888 | AC_CACHE_VAL(gdb_cv_have_struct_link_map32, |
| 889 | [AC_TRY_COMPILE([#define _SYSCALL32 |
| 890 | #include <sys/link.h>], [struct link_map32 l;], |
| 891 | gdb_cv_have_struct_link_map32=yes, |
| 892 | gdb_cv_have_struct_link_map32=no)]) |
| 893 | AC_MSG_RESULT($gdb_cv_have_struct_link_map32) |
| 894 | if test $gdb_cv_have_struct_link_map32 = yes; then |
| 895 | AC_DEFINE(HAVE_STRUCT_LINK_MAP32) |
| 896 | AC_DEFINE(_SYSCALL32) |
| 897 | fi |
| 898 | fi |
| 899 | |
| 900 | dnl See if compiler supports "long long" type. |
| 901 | |
| 902 | AC_MSG_CHECKING(for long long support in compiler) |
| 903 | AC_CACHE_VAL(gdb_cv_c_long_long, |
| 904 | [AC_TRY_COMPILE(, [ |
| 905 | extern long long foo; |
| 906 | switch (foo & 2) { case 0: return 1; } |
| 907 | ], |
| 908 | gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)]) |
| 909 | AC_MSG_RESULT($gdb_cv_c_long_long) |
| 910 | if test $gdb_cv_c_long_long = yes; then |
| 911 | AC_DEFINE(CC_HAS_LONG_LONG) |
| 912 | fi |
| 913 | |
| 914 | dnl See if the compiler and runtime support printing long long |
| 915 | |
| 916 | AC_MSG_CHECKING(for long long support in printf) |
| 917 | AC_CACHE_VAL(gdb_cv_printf_has_long_long, |
| 918 | [AC_TRY_RUN([ |
| 919 | int main () { |
| 920 | char buf[32]; |
| 921 | long long l = 0; |
| 922 | l = (l << 16) + 0x0123; |
| 923 | l = (l << 16) + 0x4567; |
| 924 | l = (l << 16) + 0x89ab; |
| 925 | l = (l << 16) + 0xcdef; |
| 926 | sprintf (buf, "0x%016llx", l); |
| 927 | return (strcmp ("0x0123456789abcdef", buf)); |
| 928 | }], |
| 929 | gdb_cv_printf_has_long_long=yes, |
| 930 | gdb_cv_printf_has_long_long=no, |
| 931 | gdb_cv_printf_has_long_long=no)]) |
| 932 | if test $gdb_cv_printf_has_long_long = yes; then |
| 933 | AC_DEFINE(PRINTF_HAS_LONG_LONG) |
| 934 | fi |
| 935 | AC_MSG_RESULT($gdb_cv_printf_has_long_long) |
| 936 | |
| 937 | dnl See if compiler supports "long double" type. Can't use AC_C_LONG_DOUBLE |
| 938 | dnl because autoconf complains about cross-compilation issues. However, this |
| 939 | dnl code uses the same variables as the macro for compatibility. |
| 940 | |
| 941 | AC_MSG_CHECKING(for long double support in compiler) |
| 942 | AC_CACHE_VAL(ac_cv_c_long_double, |
| 943 | [AC_TRY_COMPILE(, [long double foo;], |
| 944 | ac_cv_c_long_double=yes, ac_cv_c_long_double=no)]) |
| 945 | AC_MSG_RESULT($ac_cv_c_long_double) |
| 946 | if test $ac_cv_c_long_double = yes; then |
| 947 | AC_DEFINE(HAVE_LONG_DOUBLE) |
| 948 | fi |
| 949 | |
| 950 | dnl See if the compiler and runtime support printing long doubles |
| 951 | |
| 952 | AC_MSG_CHECKING(for long double support in printf) |
| 953 | AC_CACHE_VAL(gdb_cv_printf_has_long_double, |
| 954 | [AC_TRY_RUN([ |
| 955 | int main () { |
| 956 | char buf[16]; |
| 957 | long double f = 3.141592653; |
| 958 | sprintf (buf, "%Lg", f); |
| 959 | return (strncmp ("3.14159", buf, 7)); |
| 960 | }], |
| 961 | gdb_cv_printf_has_long_double=yes, |
| 962 | gdb_cv_printf_has_long_double=no, |
| 963 | gdb_cv_printf_has_long_double=no)]) |
| 964 | if test $gdb_cv_printf_has_long_double = yes; then |
| 965 | AC_DEFINE(PRINTF_HAS_LONG_DOUBLE) |
| 966 | fi |
| 967 | AC_MSG_RESULT($gdb_cv_printf_has_long_double) |
| 968 | |
| 969 | dnl See if the compiler and runtime support scanning long doubles |
| 970 | |
| 971 | AC_MSG_CHECKING(for long double support in scanf) |
| 972 | AC_CACHE_VAL(gdb_cv_scanf_has_long_double, |
| 973 | [AC_TRY_RUN([ |
| 974 | int main () { |
| 975 | char *buf = "3.141592653"; |
| 976 | long double f = 0; |
| 977 | sscanf (buf, "%Lg", &f); |
| 978 | return !(f > 3.14159 && f < 3.14160); |
| 979 | }], |
| 980 | gdb_cv_scanf_has_long_double=yes, |
| 981 | gdb_cv_scanf_has_long_double=no, |
| 982 | gdb_cv_scanf_has_long_double=no)]) |
| 983 | if test $gdb_cv_scanf_has_long_double = yes; then |
| 984 | AC_DEFINE(SCANF_HAS_LONG_DOUBLE) |
| 985 | fi |
| 986 | AC_MSG_RESULT($gdb_cv_scanf_has_long_double) |
| 987 | |
| 988 | case ${host_os} in |
| 989 | aix*) |
| 990 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| 991 | SAVE_LDFLAGS=$LDFLAGS |
| 992 | |
| 993 | case $GCC in |
| 994 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| 995 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| 996 | esac |
| 997 | |
| 998 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| 999 | AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=]) |
| 1000 | LDFLAGS="${SAVE_LDFLAGS}" |
| 1001 | ]) |
| 1002 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}" |
| 1003 | ;; |
| 1004 | esac |
| 1005 | |
| 1006 | |
| 1007 | dnl For certain native configurations, we need to check whether thread |
| 1008 | dnl support can be built in or not. |
| 1009 | dnl |
| 1010 | dnl Note that we only want this if we are both native (host == target), |
| 1011 | dnl and not doing a canadian cross build (build == host). |
| 1012 | |
| 1013 | if test ${build} = ${host} -a ${host} = ${target} ; then |
| 1014 | case ${host_os} in |
| 1015 | hpux*) |
| 1016 | AC_MSG_CHECKING(for HPUX/OSF thread support) |
| 1017 | if test -f /usr/include/dce/cma_config.h ; then |
| 1018 | if test "$GCC" = "yes" ; then |
| 1019 | AC_MSG_RESULT(yes) |
| 1020 | AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT) |
| 1021 | CONFIG_OBS="${CONFIG_OBS} hpux-thread.o" |
| 1022 | CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c" |
| 1023 | else |
| 1024 | AC_MSG_RESULT(no (suppressed because you are not using GCC)) |
| 1025 | fi |
| 1026 | else |
| 1027 | AC_MSG_RESULT(no) |
| 1028 | fi |
| 1029 | ;; |
| 1030 | solaris*) |
| 1031 | # See if thread_db library is around for Solaris thread debugging. |
| 1032 | # Note that we must explicitly test for version 1 of the library |
| 1033 | # because version 0 (present on Solaris 2.4 or earlier) doesn't have |
| 1034 | # the same API. |
| 1035 | AC_MSG_CHECKING(for Solaris thread debugging library) |
| 1036 | if test -f /usr/lib/libthread_db.so.1 ; then |
| 1037 | AC_MSG_RESULT(yes) |
| 1038 | AC_DEFINE(HAVE_THREAD_DB_LIB) |
| 1039 | CONFIG_OBS="${CONFIG_OBS} sol-thread.o" |
| 1040 | CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c" |
| 1041 | AC_CHECK_LIB(dl, dlopen) |
| 1042 | if test "$GCC" = "yes" ; then |
| 1043 | # The GNU linker requires the -export-dynamic option to make |
| 1044 | # all symbols visible in the dynamic symbol table. |
| 1045 | hold_ldflags=$LDFLAGS |
| 1046 | AC_MSG_CHECKING(for the ld -export-dynamic flag) |
| 1047 | LDFLAGS="${LDFLAGS} -Wl,-export-dynamic" |
| 1048 | AC_TRY_LINK(, [int i;], found=yes, found=no) |
| 1049 | LDFLAGS=$hold_ldflags |
| 1050 | AC_MSG_RESULT($found) |
| 1051 | if test $found = yes; then |
| 1052 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic" |
| 1053 | fi |
| 1054 | fi |
| 1055 | # Sun randomly tweaked the prototypes in <proc_service.h> |
| 1056 | # at one point. |
| 1057 | AC_MSG_CHECKING(if <proc_service.h> is old) |
| 1058 | AC_CACHE_VAL(gdb_cv_proc_service_is_old,[ |
| 1059 | AC_TRY_COMPILE([ |
| 1060 | #include <proc_service.h> |
| 1061 | ps_err_e ps_pdwrite |
| 1062 | (struct ps_prochandle*, psaddr_t, const void*, size_t); |
| 1063 | ],, gdb_cv_proc_service_is_old=no, |
| 1064 | gdb_cv_proc_service_is_old=yes) |
| 1065 | ]) |
| 1066 | AC_MSG_RESULT($gdb_cv_proc_service_is_old) |
| 1067 | if test $gdb_cv_proc_service_is_old = yes; then |
| 1068 | AC_DEFINE(PROC_SERVICE_IS_OLD) |
| 1069 | fi |
| 1070 | else |
| 1071 | AC_MSG_RESULT(no) |
| 1072 | fi |
| 1073 | ;; |
| 1074 | aix*) |
| 1075 | AC_MSG_CHECKING(for AiX thread debugging library) |
| 1076 | AC_CACHE_VAL(gdb_cv_have_aix_thread_debug, |
| 1077 | [AC_TRY_COMPILE([#include <sys/pthdebug.h>], |
| 1078 | [#ifndef PTHDB_VERSION_3 |
| 1079 | #error |
| 1080 | #endif], |
| 1081 | gdb_cv_have_aix_thread_debug=yes, |
| 1082 | gdb_cv_have_aix_thread_debug=no)]) |
| 1083 | AC_MSG_RESULT($gdb_cv_have_aix_thread_debug) |
| 1084 | if test $gdb_cv_have_aix_thread_debug = yes; then |
| 1085 | CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c" |
| 1086 | CONFIG_OBS="${CONFIG_OBS} aix-thread.o" |
| 1087 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug" |
| 1088 | fi |
| 1089 | ;; |
| 1090 | esac |
| 1091 | AC_SUBST(CONFIG_LDFLAGS) |
| 1092 | fi |
| 1093 | |
| 1094 | dnl See if we have a thread_db header file that has TD_NOTALLOC. |
| 1095 | if test "x$ac_cv_header_thread_db_h" = "xyes"; then |
| 1096 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC], |
| 1097 | gdb_cv_thread_db_h_has_td_notalloc, |
| 1098 | AC_TRY_COMPILE( |
| 1099 | [#include <thread_db.h>], |
| 1100 | [int i = TD_NOTALLOC;], |
| 1101 | gdb_cv_thread_db_h_has_td_notalloc=yes, |
| 1102 | gdb_cv_thread_db_h_has_td_notalloc=no |
| 1103 | ) |
| 1104 | ) |
| 1105 | fi |
| 1106 | if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then |
| 1107 | AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1, |
| 1108 | [Define if <thread_db.h> has the TD_NOTALLOC error code.]) |
| 1109 | fi |
| 1110 | |
| 1111 | dnl See if we have a sys/syscall header file that has __NR_tkill. |
| 1112 | if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then |
| 1113 | AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill], |
| 1114 | gdb_cv_sys_syscall_h_has_tkill, |
| 1115 | AC_TRY_COMPILE( |
| 1116 | [#include <sys/syscall.h>], |
| 1117 | [int i = __NR_tkill;], |
| 1118 | gdb_cv_sys_syscall_h_has_tkill=yes, |
| 1119 | gdb_cv_sys_syscall_h_has_tkill=no |
| 1120 | ) |
| 1121 | ) |
| 1122 | fi |
| 1123 | dnl See if we can issue tkill syscall. |
| 1124 | if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then |
| 1125 | AC_DEFINE(HAVE_TKILL_SYSCALL, 1, |
| 1126 | [Define if we can use the tkill syscall.]) |
| 1127 | fi |
| 1128 | |
| 1129 | dnl Handle optional features that can be enabled. |
| 1130 | |
| 1131 | AC_ARG_WITH(sysroot, |
| 1132 | [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.], |
| 1133 | [ |
| 1134 | case ${with_sysroot} in |
| 1135 | yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;; |
| 1136 | *) TARGET_SYSTEM_ROOT=$with_sysroot ;; |
| 1137 | esac |
| 1138 | |
| 1139 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"' |
| 1140 | |
| 1141 | if test "x$exec_prefix" = xNONE; then |
| 1142 | if test "x$prefix" = xNONE; then |
| 1143 | test_prefix=/usr/local |
| 1144 | else |
| 1145 | test_prefix=$prefix |
| 1146 | fi |
| 1147 | else |
| 1148 | test_prefix=$exec_prefix |
| 1149 | fi |
| 1150 | case ${TARGET_SYSTEM_ROOT} in |
| 1151 | "${test_prefix}"|"${test_prefix}/"*|\ |
| 1152 | '${exec_prefix}'|'${exec_prefix}/'*) |
| 1153 | t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE" |
| 1154 | TARGET_SYSTEM_ROOT_DEFINE="$t" |
| 1155 | ;; |
| 1156 | esac |
| 1157 | ], [ |
| 1158 | TARGET_SYSTEM_ROOT= |
| 1159 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"' |
| 1160 | ]) |
| 1161 | AC_SUBST(TARGET_SYSTEM_ROOT) |
| 1162 | AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE) |
| 1163 | |
| 1164 | # NOTE: Don't add -Wall or -Wunused, they both include |
| 1165 | # -Wunused-parameter which reports bogus warnings. |
| 1166 | # NOTE: If you add to this list, remember to update |
| 1167 | # gdb/doc/gdbint.texinfo. |
| 1168 | build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \ |
| 1169 | -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \ |
| 1170 | -Wunused-label -Wunused-function" |
| 1171 | # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs |
| 1172 | # -Wunused-function -Wunused-variable -Wunused-value |
| 1173 | # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual |
| 1174 | # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes |
| 1175 | # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls |
| 1176 | # -Woverloaded-virtual -Winline -Werror" |
| 1177 | AC_ARG_ENABLE(build-warnings, |
| 1178 | [ --enable-build-warnings Enable build-time compiler warnings if gcc is used], |
| 1179 | [case "${enableval}" in |
| 1180 | yes) ;; |
| 1181 | no) build_warnings="-w";; |
| 1182 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1183 | build_warnings="${build_warnings} ${t}";; |
| 1184 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1185 | build_warnings="${t} ${build_warnings}";; |
| 1186 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 1187 | esac |
| 1188 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 1189 | echo "Setting compiler warning flags = $build_warnings" 6>&1 |
| 1190 | fi])dnl |
| 1191 | AC_ARG_ENABLE(gdb-build-warnings, |
| 1192 | [ --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used], |
| 1193 | [case "${enableval}" in |
| 1194 | yes) ;; |
| 1195 | no) build_warnings="-w";; |
| 1196 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1197 | build_warnings="${build_warnings} ${t}";; |
| 1198 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1199 | build_warnings="${t} ${build_warnings}";; |
| 1200 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 1201 | esac |
| 1202 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 1203 | echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1 |
| 1204 | fi])dnl |
| 1205 | WARN_CFLAGS="" |
| 1206 | WERROR_CFLAGS="" |
| 1207 | if test "x${build_warnings}" != x -a "x$GCC" = xyes |
| 1208 | then |
| 1209 | AC_MSG_CHECKING(compiler warning flags) |
| 1210 | # Separate out the -Werror flag as some files just cannot be |
| 1211 | # compiled with it enabled. |
| 1212 | for w in ${build_warnings}; do |
| 1213 | case $w in |
| 1214 | -Werr*) WERROR_CFLAGS=-Werror ;; |
| 1215 | *) # Check that GCC accepts it |
| 1216 | saved_CFLAGS="$CFLAGS" |
| 1217 | CFLAGS="$CFLAGS $w" |
| 1218 | AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",) |
| 1219 | CFLAGS="$saved_CFLAGS" |
| 1220 | esac |
| 1221 | done |
| 1222 | AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS}) |
| 1223 | fi |
| 1224 | AC_SUBST(WARN_CFLAGS) |
| 1225 | AC_SUBST(WERROR_CFLAGS) |
| 1226 | |
| 1227 | # In the Cygwin environment, we need some additional flags. |
| 1228 | AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin, |
| 1229 | [AC_EGREP_CPP(lose, [ |
| 1230 | #if defined (__CYGWIN__) || defined (__CYGWIN32__) |
| 1231 | lose |
| 1232 | #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])]) |
| 1233 | |
| 1234 | |
| 1235 | dnl Figure out which of the many generic ser-*.c files the _host_ supports. |
| 1236 | SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o" |
| 1237 | case ${host} in |
| 1238 | *go32* ) SER_HARDWIRE=ser-go32.o ;; |
| 1239 | *djgpp* ) SER_HARDWIRE=ser-go32.o ;; |
| 1240 | esac |
| 1241 | AC_SUBST(SER_HARDWIRE) |
| 1242 | |
| 1243 | # libreadline needs libuser32.a in a cygwin environment |
| 1244 | WIN32LIBS= |
| 1245 | if test x$gdb_cv_os_cygwin = xyes; then |
| 1246 | WIN32LIBS="-luser32" |
| 1247 | case "${target}" in |
| 1248 | *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp" |
| 1249 | ;; |
| 1250 | esac |
| 1251 | fi |
| 1252 | AC_SUBST(WIN32LIBS) |
| 1253 | |
| 1254 | LIBGUI="../libgui/src/libgui.a" |
| 1255 | GUI_CFLAGS_X="-I${srcdir}/../libgui/src" |
| 1256 | AC_SUBST(LIBGUI) |
| 1257 | AC_SUBST(GUI_CFLAGS_X) |
| 1258 | |
| 1259 | WIN32LDAPP= |
| 1260 | AC_SUBST(WIN32LIBS) |
| 1261 | AC_SUBST(WIN32LDAPP) |
| 1262 | |
| 1263 | case "${host}" in |
| 1264 | *-*-cygwin*) |
| 1265 | configdir="win" |
| 1266 | ;; |
| 1267 | *) |
| 1268 | configdir="unix" |
| 1269 | ;; |
| 1270 | esac |
| 1271 | |
| 1272 | GDBTKLIBS= |
| 1273 | if test "${enable_gdbtk}" = "yes"; then |
| 1274 | |
| 1275 | # Gdbtk must have an absolute path to srcdir in order to run |
| 1276 | # properly when not installed. |
| 1277 | here=`pwd` |
| 1278 | cd ${srcdir} |
| 1279 | GDBTK_SRC_DIR=`pwd` |
| 1280 | cd $here |
| 1281 | |
| 1282 | CY_AC_PATH_TCLCONFIG |
| 1283 | if test -z "${no_tcl}"; then |
| 1284 | CY_AC_LOAD_TCLCONFIG |
| 1285 | CY_AC_PATH_TKCONFIG |
| 1286 | |
| 1287 | # now look for Tcl library stuff |
| 1288 | |
| 1289 | tcldir="../tcl/${configdir}/" |
| 1290 | |
| 1291 | TCL_DEPS="${tcldir}${TCL_LIB_FILE}" |
| 1292 | |
| 1293 | # If $no_tk is nonempty, then we can't do Tk, and there is no |
| 1294 | # point to doing Tcl. |
| 1295 | if test -z "${no_tk}"; then |
| 1296 | CY_AC_LOAD_TKCONFIG |
| 1297 | CY_AC_PATH_TCLH |
| 1298 | CY_AC_PATH_TKH |
| 1299 | CY_AC_PATH_ITCLH |
| 1300 | CY_AC_PATH_ITKH |
| 1301 | |
| 1302 | |
| 1303 | # now look for Tk library stuff |
| 1304 | |
| 1305 | tkdir="../tk/${configdir}/" |
| 1306 | |
| 1307 | TK_DEPS="${tkdir}${TK_LIB_FILE}" |
| 1308 | |
| 1309 | # now look for Itcl library stuff |
| 1310 | |
| 1311 | CY_AC_PATH_ITCLCONFIG |
| 1312 | if test -z "${no_itcl}"; then |
| 1313 | CY_AC_LOAD_ITCLCONFIG |
| 1314 | |
| 1315 | ITCLLIB="${ITCL_BUILD_LIB_SPEC}" |
| 1316 | ITCL_DEPS="${ITCL_LIB_FULL_PATH}" |
| 1317 | fi |
| 1318 | |
| 1319 | |
| 1320 | # now look for Itk library stuff |
| 1321 | CY_AC_PATH_ITKCONFIG |
| 1322 | if test -z "${no_itcl}"; then |
| 1323 | CY_AC_LOAD_ITKCONFIG |
| 1324 | |
| 1325 | ITKLIB="${ITK_BUILD_LIB_SPEC}" |
| 1326 | ITK_DEPS="${ITK_LIB_FULL_PATH}" |
| 1327 | fi |
| 1328 | |
| 1329 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)" |
| 1330 | # Tcl/Tk 8.1 require -fwritable strings. I don't |
| 1331 | # know whether 8.2 will or not, but I bet it will. |
| 1332 | # I don't have to worry about 7.x since we don't support it. |
| 1333 | GDBTK_CFLAGS="" |
| 1334 | if test "$GCC" = "yes"; then |
| 1335 | if test "$TCL_VERSION" != "8.0" ; then |
| 1336 | GDBTK_CFLAGS="-fwritable-strings" |
| 1337 | fi |
| 1338 | fi |
| 1339 | |
| 1340 | # Include some libraries that Tcl and Tk want. |
| 1341 | TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)' |
| 1342 | # Yes, the ordering seems wrong here. But it isn't. |
| 1343 | # TK_LIBS is the list of libraries that need to be linked |
| 1344 | # after Tcl/Tk. Note that this isn't put into LIBS. If it |
| 1345 | # were in LIBS then any link tests after this point would |
| 1346 | # try to include things like `$(LIBGUI)', which wouldn't work. |
| 1347 | GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}" |
| 1348 | |
| 1349 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)" |
| 1350 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)" |
| 1351 | CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)" |
| 1352 | CONFIG_ALL="${CONFIG_ALL} all-gdbtk" |
| 1353 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk" |
| 1354 | CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk" |
| 1355 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk" |
| 1356 | |
| 1357 | if test x$gdb_cv_os_cygwin = xyes; then |
| 1358 | WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32" |
| 1359 | WIN32LDAPP="-Wl,--subsystem,console" |
| 1360 | CONFIG_OBS="${CONFIG_OBS} gdbres.o" |
| 1361 | fi |
| 1362 | fi |
| 1363 | fi |
| 1364 | |
| 1365 | configdirs="${configdirs} gdbtk" |
| 1366 | fi |
| 1367 | |
| 1368 | AC_SUBST(X_CFLAGS) |
| 1369 | AC_SUBST(X_LDFLAGS) |
| 1370 | AC_SUBST(X_LIBS) |
| 1371 | AC_SUBST(TCL_DEPS) |
| 1372 | AC_SUBST(TK_DEPS) |
| 1373 | AC_SUBST(ITCLLIB) |
| 1374 | AC_SUBST(ITCL_DEPS) |
| 1375 | AC_SUBST(ITKLIB) |
| 1376 | AC_SUBST(ITK_DEPS) |
| 1377 | AC_SUBST(GDBTKLIBS) |
| 1378 | AC_SUBST(GDBTK_CFLAGS) |
| 1379 | AC_SUBST(GDBTK_SRC_DIR) |
| 1380 | |
| 1381 | AC_PATH_X |
| 1382 | |
| 1383 | |
| 1384 | # Unlike the sim directory, whether a simulator is linked is controlled by |
| 1385 | # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file. |
| 1386 | # This code just checks for a few cases where we'd like to ignore those |
| 1387 | # definitions, even when they're present in the '.mt' file. These cases |
| 1388 | # are when --disable-sim is specified, or if the simulator directory is |
| 1389 | # not part of the source tree. |
| 1390 | # |
| 1391 | AC_ARG_ENABLE(sim, |
| 1392 | [ --enable-sim Link gdb with simulator], |
| 1393 | [echo "enable_sim = $enable_sim"; |
| 1394 | echo "enableval = ${enableval}"; |
| 1395 | case "${enableval}" in |
| 1396 | yes) ignore_sim=false ;; |
| 1397 | no) ignore_sim=true ;; |
| 1398 | *) ignore_sim=false ;; |
| 1399 | esac], |
| 1400 | [ignore_sim=false]) |
| 1401 | |
| 1402 | if test ! -d "${srcdir}/../sim"; then |
| 1403 | ignore_sim=true |
| 1404 | fi |
| 1405 | |
| 1406 | if test "${ignore_sim}" = "true"; then |
| 1407 | IGNORE_SIM="SIM=" |
| 1408 | IGNORE_SIM_OBS="SIM_OBS=" |
| 1409 | else |
| 1410 | IGNORE_SIM="" |
| 1411 | IGNORE_SIM_OBS="" |
| 1412 | AC_DEFINE(WITH_SIM) |
| 1413 | fi |
| 1414 | AC_SUBST(IGNORE_SIM) |
| 1415 | AC_SUBST(IGNORE_SIM_OBS) |
| 1416 | |
| 1417 | AC_SUBST(ENABLE_CFLAGS) |
| 1418 | AC_SUBST(PROFILE_CFLAGS) |
| 1419 | |
| 1420 | AC_SUBST(CONFIG_OBS) |
| 1421 | AC_SUBST(CONFIG_DEPS) |
| 1422 | AC_SUBST(CONFIG_SRCS) |
| 1423 | AC_SUBST(CONFIG_ALL) |
| 1424 | AC_SUBST(CONFIG_CLEAN) |
| 1425 | AC_SUBST(CONFIG_INSTALL) |
| 1426 | AC_SUBST(CONFIG_UNINSTALL) |
| 1427 | |
| 1428 | # List of host floatformats. |
| 1429 | AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat]) |
| 1430 | AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat]) |
| 1431 | AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat]) |
| 1432 | |
| 1433 | # target_subdir is used by the testsuite to find the target libraries. |
| 1434 | target_subdir= |
| 1435 | if test "${host}" != "${target}"; then |
| 1436 | target_subdir="${target_alias}/" |
| 1437 | fi |
| 1438 | AC_SUBST(target_subdir) |
| 1439 | |
| 1440 | frags= |
| 1441 | host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh |
| 1442 | if test ! -f ${host_makefile_frag}; then |
| 1443 | # When building a native debuger the .mh file containing things |
| 1444 | # like NATDEPFILES is needed. Cross debuggers don't need .mh |
| 1445 | # since it no longer contains anything useful. |
| 1446 | if test "${target}" = "${host}"; then |
| 1447 | AC_MSG_ERROR("*** Gdb does not support native target ${host}") |
| 1448 | else |
| 1449 | host_makefile_frag=/dev/null |
| 1450 | fi |
| 1451 | fi |
| 1452 | frags="$frags $host_makefile_frag" |
| 1453 | |
| 1454 | target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt |
| 1455 | if test ! -f ${target_makefile_frag}; then |
| 1456 | AC_MSG_ERROR("*** Gdb does not support target ${target}") |
| 1457 | fi |
| 1458 | frags="$frags $target_makefile_frag" |
| 1459 | |
| 1460 | AC_SUBST_FILE(host_makefile_frag) |
| 1461 | AC_SUBST_FILE(target_makefile_frag) |
| 1462 | AC_SUBST(frags) |
| 1463 | |
| 1464 | changequote(,)dnl |
| 1465 | hostfile=`sed -n ' |
| 1466 | s/XM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1467 | ' ${host_makefile_frag}` |
| 1468 | |
| 1469 | targetfile=`sed -n ' |
| 1470 | s/DEPRECATED_TM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1471 | ' ${target_makefile_frag}` |
| 1472 | |
| 1473 | if test "${target}" = "${host}"; then |
| 1474 | # We pick this up from the host configuration file (.mh) because we |
| 1475 | # do not have a native configuration Makefile fragment. |
| 1476 | nativefile=`sed -n ' |
| 1477 | s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1478 | ' ${host_makefile_frag}` |
| 1479 | fi |
| 1480 | changequote([,]) |
| 1481 | |
| 1482 | if test x"${gdb_osabi}" != x ; then |
| 1483 | AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi, |
| 1484 | [Define to the default OS ABI for this configuration.]) |
| 1485 | fi |
| 1486 | |
| 1487 | # Enable multi-ice-gdb-server. |
| 1488 | AC_ARG_ENABLE(multi-ice, |
| 1489 | [ --enable-multi-ice build the multi-ice-gdb-server], |
| 1490 | [case $enableval in |
| 1491 | yes | no) |
| 1492 | ;; |
| 1493 | *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;; |
| 1494 | esac]) |
| 1495 | if test "x$enable_multi_ice" = xyes; then |
| 1496 | configdirs="$configdirs multi-ice" |
| 1497 | fi |
| 1498 | |
| 1499 | # We only build gdbserver automatically if host and target are the same. |
| 1500 | if test "x$target" = "x$host"; then |
| 1501 | AC_MSG_CHECKING(whether gdbserver is supported on this host) |
| 1502 | if test "x$build_gdbserver" = xyes; then |
| 1503 | configdirs="$configdirs gdbserver" |
| 1504 | AC_MSG_RESULT(yes) |
| 1505 | else |
| 1506 | AC_MSG_RESULT(no) |
| 1507 | fi |
| 1508 | fi |
| 1509 | |
| 1510 | AC_CONFIG_SUBDIRS($configdirs) |
| 1511 | |
| 1512 | # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or |
| 1513 | # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link |
| 1514 | # to an empty version. |
| 1515 | |
| 1516 | files= |
| 1517 | links= |
| 1518 | |
| 1519 | rm -f xm.h |
| 1520 | xm_h="" |
| 1521 | if test "${hostfile}" != ""; then |
| 1522 | xm_h=xm.h |
| 1523 | case "${hostfile}" in |
| 1524 | xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;; |
| 1525 | * ) GDB_XM_FILE="${hostfile}" |
| 1526 | esac |
| 1527 | files="${files} ${GDB_XM_FILE}" |
| 1528 | links="${links} xm.h" |
| 1529 | AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}") |
| 1530 | fi |
| 1531 | AC_SUBST(xm_h) |
| 1532 | |
| 1533 | rm -f tm.h |
| 1534 | tm_h="" |
| 1535 | if test "${targetfile}" != ""; then |
| 1536 | tm_h=tm.h |
| 1537 | case "${targetfile}" in |
| 1538 | tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;; |
| 1539 | * ) GDB_TM_FILE="${targetfile}" |
| 1540 | esac |
| 1541 | files="${files} ${GDB_TM_FILE}" |
| 1542 | links="${links} tm.h" |
| 1543 | AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}") |
| 1544 | fi |
| 1545 | AC_SUBST(tm_h) |
| 1546 | |
| 1547 | rm -f nm.h |
| 1548 | nm_h="" |
| 1549 | if test "${nativefile}" != ""; then |
| 1550 | nm_h=nm.h |
| 1551 | case "${nativefile}" in |
| 1552 | nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;; |
| 1553 | * ) GDB_NM_FILE="${nativefile}" |
| 1554 | esac |
| 1555 | files="${files} ${GDB_NM_FILE}" |
| 1556 | links="${links} nm.h" |
| 1557 | AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}") |
| 1558 | fi |
| 1559 | AC_SUBST(nm_h) |
| 1560 | |
| 1561 | AC_LINK_FILES($files, $links) |
| 1562 | |
| 1563 | dnl Check for exe extension set on certain hosts (e.g. Win32) |
| 1564 | AC_EXEEXT |
| 1565 | |
| 1566 | dnl Detect the character set used by this host. |
| 1567 | |
| 1568 | dnl At the moment, we just assume it's ISO-8859-1 (which is a |
| 1569 | dnl superset of ASCII containing the characters needed for French, |
| 1570 | dnl German, Spanish, Italian, and possibly others), but if were |
| 1571 | dnl *were* to support any host character sets other than ISO-8859-1, |
| 1572 | dnl here's where we'd detect it. |
| 1573 | AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1", |
| 1574 | [Define to be a string naming the default host character set.]) |
| 1575 | |
| 1576 | AM_ICONV |
| 1577 | |
| 1578 | AC_OUTPUT(Makefile .gdbinit:gdbinit.in, |
| 1579 | [ |
| 1580 | dnl Autoconf doesn't provide a mechanism for modifying definitions |
| 1581 | dnl provided by makefile fragments. |
| 1582 | dnl |
| 1583 | if test "${nativefile}" = ""; then |
| 1584 | < Makefile \ |
| 1585 | sed -e '/^NATDEPFILES[[ ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \ |
| 1586 | -e '/^NATDEPFILES[[ ]]*=/s/^/# /' \ |
| 1587 | | sed -e '/^\(NATDEPFILES[[ ]]*[[+]]=[[ ]]*\)/s//# \1/' \ |
| 1588 | > Makefile.tem |
| 1589 | mv -f Makefile.tem Makefile |
| 1590 | fi |
| 1591 | |
| 1592 | changequote(,)dnl |
| 1593 | sed -e '/^DEPRECATED_TM_FILE[ ]*=/s,^DEPRECATED_TM_FILE[ ]*=[ ]*,&config/'"${gdb_target_cpu}"'/, |
| 1594 | /^XM_FILE[ ]*=/s,^XM_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/, |
| 1595 | /^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp |
| 1596 | mv -f Makefile.tmp Makefile |
| 1597 | changequote([,])dnl |
| 1598 | |
| 1599 | |
| 1600 | case x$CONFIG_HEADERS in |
| 1601 | xconfig.h:config.in) |
| 1602 | echo > stamp-h ;; |
| 1603 | esac |
| 1604 | ], |
| 1605 | [ |
| 1606 | gdb_host_cpu=$gdb_host_cpu |
| 1607 | gdb_target_cpu=$gdb_target_cpu |
| 1608 | nativefile=$nativefile |
| 1609 | ]) |
| 1610 | |
| 1611 | exit 0 |