| 1 | dnl Autoconf configure script for GDB server. |
| 2 | dnl Copyright (C) 2000-2018 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | AC_INIT(server.c) |
| 22 | AC_CONFIG_HEADER(config.h:config.in) |
| 23 | |
| 24 | AM_MAINTAINER_MODE |
| 25 | |
| 26 | AC_PROG_CC |
| 27 | AC_PROG_CXX |
| 28 | AC_GNU_SOURCE |
| 29 | AC_SYS_LARGEFILE |
| 30 | |
| 31 | AC_CANONICAL_SYSTEM |
| 32 | |
| 33 | AC_PROG_INSTALL |
| 34 | AC_CHECK_TOOL(AR, ar) |
| 35 | AC_PROG_RANLIB |
| 36 | |
| 37 | AC_ARG_PROGRAM |
| 38 | |
| 39 | # We require a C++11 compiler. Check if one is available, and if |
| 40 | # necessary, set CXX_DIALECT to some -std=xxx switch. |
| 41 | AX_CXX_COMPILE_STDCXX(11, , mandatory) |
| 42 | |
| 43 | AC_HEADER_STDC |
| 44 | |
| 45 | # Set the 'development' global. |
| 46 | . $srcdir/../../bfd/development.sh |
| 47 | |
| 48 | # Enable -lmcheck by default (it provides cheap-enough memory |
| 49 | # mangling), but turn it off for releases. |
| 50 | if $development; then |
| 51 | libmcheck_default=yes |
| 52 | else |
| 53 | libmcheck_default=no |
| 54 | fi |
| 55 | GDB_AC_LIBMCHECK(${libmcheck_default}) |
| 56 | |
| 57 | GDB_AC_SELFTEST([ |
| 58 | srv_selftest_objs="common/selftest.o" |
| 59 | ]) |
| 60 | |
| 61 | ACX_NONCANONICAL_TARGET |
| 62 | ACX_NONCANONICAL_HOST |
| 63 | |
| 64 | # Dependency checking. |
| 65 | ZW_CREATE_DEPDIR |
| 66 | |
| 67 | # Create sub-directories for objects and dependencies. |
| 68 | CONFIG_SRC_SUBDIR="arch common" |
| 69 | AC_SUBST(CONFIG_SRC_SUBDIR) |
| 70 | |
| 71 | AC_CONFIG_COMMANDS([gdbdepdir],[ |
| 72 | for subdir in ${CONFIG_SRC_SUBDIR} |
| 73 | do |
| 74 | $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR |
| 75 | done], |
| 76 | [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"]) |
| 77 | |
| 78 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 79 | |
| 80 | gnulib_extra_configure_args= |
| 81 | # If large-file support is disabled, make sure gnulib does the same. |
| 82 | if test "$enable_largefile" = no; then |
| 83 | gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile" |
| 84 | fi |
| 85 | |
| 86 | # Configure gnulib. We can't use AC_CONFIG_SUBDIRS as that'd expect |
| 87 | # to find the the source subdir to be configured directly under |
| 88 | # gdbserver/. We need to build gnulib under some other directory not |
| 89 | # "gnulib", to avoid the problem of both GDB and GDBserver wanting to |
| 90 | # build it in the same directory, when building in the source dir. |
| 91 | ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"], |
| 92 | ["$gnulib_extra_configure_args"]) |
| 93 | |
| 94 | ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"]) |
| 95 | |
| 96 | AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl |
| 97 | proc_service.h sys/procfs.h linux/elf.h dnl |
| 98 | fcntl.h signal.h sys/file.h dnl |
| 99 | sys/ioctl.h netinet/in.h sys/socket.h sys/un.h netdb.h dnl |
| 100 | netinet/tcp.h arpa/inet.h) |
| 101 | AC_FUNC_FORK |
| 102 | AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns) |
| 103 | |
| 104 | GDB_AC_COMMON |
| 105 | |
| 106 | # Check the return and argument types of ptrace. |
| 107 | GDB_AC_PTRACE |
| 108 | |
| 109 | # Check for UST |
| 110 | ustlibs="" |
| 111 | ustinc="" |
| 112 | |
| 113 | AC_ARG_WITH(ust, [ --with-ust=PATH Specify prefix directory for the installed UST package |
| 114 | Equivalent to --with-ust-include=PATH/include |
| 115 | plus --with-ust-lib=PATH/lib]) |
| 116 | AC_ARG_WITH(ust_include, [ --with-ust-include=PATH Specify directory for installed UST include files]) |
| 117 | AC_ARG_WITH(ust_lib, [ --with-ust-lib=PATH Specify the directory for the installed UST library]) |
| 118 | |
| 119 | case $with_ust in |
| 120 | no) |
| 121 | ustlibs= |
| 122 | ustinc= |
| 123 | ;; |
| 124 | "" | yes) |
| 125 | ustlibs=" -lust " |
| 126 | ustinc="" |
| 127 | ;; |
| 128 | *) |
| 129 | ustlibs="-L$with_ust/lib -lust" |
| 130 | ustinc="-I$with_ust/include " |
| 131 | ;; |
| 132 | esac |
| 133 | if test "x$with_ust_include" != x; then |
| 134 | ustinc="-I$with_ust_include " |
| 135 | fi |
| 136 | if test "x$with_ust_lib" != x; then |
| 137 | ustlibs="-L$with_ust_lib -lust" |
| 138 | fi |
| 139 | |
| 140 | if test "x$with_ust" != "xno"; then |
| 141 | saved_CFLAGS="$CFLAGS" |
| 142 | CFLAGS="$CFLAGS $ustinc" |
| 143 | AC_MSG_CHECKING([for ust]) |
| 144 | AC_TRY_COMPILE([ |
| 145 | #define CONFIG_UST_GDB_INTEGRATION |
| 146 | #include <ust/ust.h> |
| 147 | ],[], |
| 148 | [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])], |
| 149 | [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ]) |
| 150 | CFLAGS="$saved_CFLAGS" |
| 151 | fi |
| 152 | |
| 153 | # Flags needed for UST |
| 154 | AC_SUBST(ustlibs) |
| 155 | AC_SUBST(ustinc) |
| 156 | |
| 157 | AM_GDB_WARNINGS |
| 158 | |
| 159 | dnl dladdr is glibc-specific. It is used by thread-db.c but only for |
| 160 | dnl debugging messages. It lives in -ldl which is handled below so we don't |
| 161 | dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here. Instead we just temporarily |
| 162 | dnl augment LIBS. |
| 163 | old_LIBS="$LIBS" |
| 164 | LIBS="$LIBS -ldl" |
| 165 | AC_CHECK_FUNCS(dladdr) |
| 166 | LIBS="$old_LIBS" |
| 167 | |
| 168 | libiberty_INIT |
| 169 | |
| 170 | AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf]) |
| 171 | |
| 172 | AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize]) |
| 173 | |
| 174 | # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers. |
| 175 | # Older amd64 Linux's don't have the fs_base and gs_base members of |
| 176 | # `struct user_regs_struct'. |
| 177 | AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base], |
| 178 | [], [], [#include <sys/types.h> |
| 179 | #include <sys/user.h>]) |
| 180 | |
| 181 | |
| 182 | AC_CHECK_TYPES(socklen_t, [], [], |
| 183 | [#include <sys/types.h> |
| 184 | #include <sys/socket.h> |
| 185 | ]) |
| 186 | |
| 187 | case "${target}" in |
| 188 | *-android*) |
| 189 | # Starting with NDK version 9, <elf.h> actually includes definitions |
| 190 | # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes |
| 191 | # <sys/exec_elf.h> which defines some of the ELF types incorrectly, |
| 192 | # leading to conflicts with the defintions from <linux/elf.h>. |
| 193 | # This makes it impossible for us to include both <elf.h> and |
| 194 | # <linux/elf.h>, which means that, in practice, we do not have |
| 195 | # access to Elf32_auxv_t and Elf64_auxv_t on this platform. |
| 196 | # Therefore, do not try to auto-detect availability, as it would |
| 197 | # get it wrong on this platform. |
| 198 | ;; |
| 199 | *) |
| 200 | AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [], |
| 201 | #include <elf.h> |
| 202 | ) |
| 203 | esac |
| 204 | |
| 205 | ACX_PKGVERSION([GDB]) |
| 206 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 207 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 208 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 209 | |
| 210 | # Check for various supplementary target information (beyond the |
| 211 | # triplet) which might affect the choices in configure.srv. |
| 212 | case "${target}" in |
| 213 | changequote(,)dnl |
| 214 | i[34567]86-*-linux*) |
| 215 | changequote([,])dnl |
| 216 | AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64], |
| 217 | [save_CPPFLAGS="$CPPFLAGS" |
| 218 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 219 | AC_EGREP_CPP([got it], [ |
| 220 | #if __x86_64__ |
| 221 | got it |
| 222 | #endif |
| 223 | ], [gdb_cv_i386_is_x86_64=yes], |
| 224 | [gdb_cv_i386_is_x86_64=no]) |
| 225 | CPPFLAGS="$save_CPPFLAGS"]) |
| 226 | ;; |
| 227 | |
| 228 | x86_64-*-linux*) |
| 229 | AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32], |
| 230 | [save_CPPFLAGS="$CPPFLAGS" |
| 231 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 232 | AC_EGREP_CPP([got it], [ |
| 233 | #if __x86_64__ && __ILP32__ |
| 234 | got it |
| 235 | #endif |
| 236 | ], [gdb_cv_x86_is_x32=yes], |
| 237 | [gdb_cv_x86_is_x32=no]) |
| 238 | CPPFLAGS="$save_CPPFLAGS"]) |
| 239 | ;; |
| 240 | |
| 241 | m68k-*-*) |
| 242 | AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire], |
| 243 | [save_CPPFLAGS="$CPPFLAGS" |
| 244 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 245 | AC_EGREP_CPP([got it], [ |
| 246 | #ifdef __mcoldfire__ |
| 247 | got it |
| 248 | #endif |
| 249 | ], [gdb_cv_m68k_is_coldfire=yes], |
| 250 | [gdb_cv_m68k_is_coldfire=no]) |
| 251 | CPPFLAGS="$save_CPPFLAGS"]) |
| 252 | ;; |
| 253 | esac |
| 254 | |
| 255 | . ${srcdir}/configure.srv |
| 256 | |
| 257 | # Add in the common host objects. |
| 258 | . ${srcdir}/../common/common.host |
| 259 | srv_host_obs="$common_host_obs" |
| 260 | |
| 261 | if test "${srv_mingwce}" = "yes"; then |
| 262 | LIBS="$LIBS -lws2" |
| 263 | elif test "${srv_mingw}" = "yes"; then |
| 264 | LIBS="$LIBS -lws2_32" |
| 265 | elif test "${srv_qnx}" = "yes"; then |
| 266 | LIBS="$LIBS -lsocket" |
| 267 | elif test "${srv_lynxos}" = "yes"; then |
| 268 | LIBS="$LIBS -lnetinet" |
| 269 | fi |
| 270 | |
| 271 | if test "${srv_mingw}" = "yes"; then |
| 272 | AC_DEFINE(USE_WIN32API, 1, |
| 273 | [Define if we should use the Windows API, instead of the |
| 274 | POSIX API. On Windows, we use the Windows API when |
| 275 | building for MinGW, but the POSIX API when building |
| 276 | for Cygwin.]) |
| 277 | fi |
| 278 | |
| 279 | if test "${srv_linux_usrregs}" = "yes"; then |
| 280 | AC_DEFINE(HAVE_LINUX_USRREGS, 1, |
| 281 | [Define if the target supports PTRACE_PEEKUSR for register ] |
| 282 | [access.]) |
| 283 | fi |
| 284 | |
| 285 | if test "${srv_linux_regsets}" = "yes"; then |
| 286 | AC_DEFINE(HAVE_LINUX_REGSETS, 1, |
| 287 | [Define if the target supports register sets.]) |
| 288 | |
| 289 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 290 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs, |
| 291 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 292 | [PTRACE_GETREGS;], |
| 293 | [gdbsrv_cv_have_ptrace_getregs=yes], |
| 294 | [gdbsrv_cv_have_ptrace_getregs=no])]) |
| 295 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs) |
| 296 | if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then |
| 297 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 298 | [Define if the target supports PTRACE_GETREGS for register ] |
| 299 | [access.]) |
| 300 | fi |
| 301 | |
| 302 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 303 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs, |
| 304 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 305 | [PTRACE_GETFPXREGS;], |
| 306 | [gdbsrv_cv_have_ptrace_getfpxregs=yes], |
| 307 | [gdbsrv_cv_have_ptrace_getfpxregs=no])]) |
| 308 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs) |
| 309 | if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then |
| 310 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 311 | [Define if the target supports PTRACE_GETFPXREGS for extended ] |
| 312 | [register access.]) |
| 313 | fi |
| 314 | fi |
| 315 | |
| 316 | if test "${srv_linux_btrace}" = "yes"; then |
| 317 | AC_DEFINE(HAVE_LINUX_BTRACE, 1, |
| 318 | [Define if the target supports branch tracing.]) |
| 319 | fi |
| 320 | |
| 321 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 322 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 323 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 324 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 325 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 326 | BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t) |
| 327 | fi |
| 328 | |
| 329 | dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h. |
| 330 | if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then |
| 331 | GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t) |
| 332 | fi |
| 333 | |
| 334 | dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h. |
| 335 | if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then |
| 336 | GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t) |
| 337 | fi |
| 338 | |
| 339 | dnl Check for libdl, but do not add it to LIBS as only gdbserver |
| 340 | dnl needs it (and gdbreplay doesn't). |
| 341 | old_LIBS="$LIBS" |
| 342 | AC_CHECK_LIB(dl, dlopen) |
| 343 | LIBS="$old_LIBS" |
| 344 | |
| 345 | srv_thread_depfiles= |
| 346 | srv_libs= |
| 347 | |
| 348 | if test "$srv_linux_thread_db" = "yes"; then |
| 349 | if test "$ac_cv_lib_dl_dlopen" = "yes"; then |
| 350 | srv_libs="-ldl" |
| 351 | AC_MSG_CHECKING(for the dynamic export flag) |
| 352 | old_LDFLAGS="$LDFLAGS" |
| 353 | # Older GNU ld supports --export-dynamic but --dynamic-list may not be |
| 354 | # supported there. |
| 355 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 356 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 357 | AC_TRY_LINK([], [], |
| 358 | [found="-Wl,--dynamic-list" |
| 359 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'], |
| 360 | [RDYNAMIC="-rdynamic" |
| 361 | LDFLAGS="$old_LDFLAGS $RDYNAMIC" |
| 362 | AC_TRY_LINK([], [], |
| 363 | [found="-rdynamic"], |
| 364 | [found="no" |
| 365 | RDYNAMIC=""])]) |
| 366 | AC_SUBST(RDYNAMIC) |
| 367 | LDFLAGS="$old_LDFLAGS" |
| 368 | AC_MSG_RESULT($found) |
| 369 | else |
| 370 | srv_libs="-lthread_db" |
| 371 | fi |
| 372 | |
| 373 | srv_thread_depfiles="thread-db.o proc-service.o" |
| 374 | AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.]) |
| 375 | AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version, |
| 376 | [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;], |
| 377 | [gdbsrv_cv_have_td_version=yes], |
| 378 | [gdbsrv_cv_have_td_version=no])]) |
| 379 | if test $gdbsrv_cv_have_td_version = yes; then |
| 380 | AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.]) |
| 381 | fi |
| 382 | fi |
| 383 | |
| 384 | AC_ARG_WITH(libthread-db, |
| 385 | AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]), |
| 386 | [srv_libthread_db_path="${withval}" |
| 387 | srv_libs="$srv_libthread_db_path" |
| 388 | ]) |
| 389 | |
| 390 | if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then |
| 391 | AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.]) |
| 392 | fi |
| 393 | |
| 394 | if test "$srv_xmlfiles" != ""; then |
| 395 | srv_xmlbuiltin="xml-builtin.o" |
| 396 | AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.]) |
| 397 | |
| 398 | tmp_xmlfiles=$srv_xmlfiles |
| 399 | srv_xmlfiles="" |
| 400 | for f in $tmp_xmlfiles; do |
| 401 | srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f" |
| 402 | done |
| 403 | fi |
| 404 | |
| 405 | GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs $srv_selftest_objs" |
| 406 | GDBSERVER_LIBS="$srv_libs" |
| 407 | |
| 408 | dnl Check whether the target supports __sync_*_compare_and_swap. |
| 409 | AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap], |
| 410 | gdbsrv_cv_have_sync_builtins, [ |
| 411 | AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);], |
| 412 | gdbsrv_cv_have_sync_builtins=yes, |
| 413 | gdbsrv_cv_have_sync_builtins=no)]) |
| 414 | if test $gdbsrv_cv_have_sync_builtins = yes; then |
| 415 | AC_DEFINE(HAVE_SYNC_BUILTINS, 1, |
| 416 | [Define to 1 if the target supports __sync_*_compare_and_swap]) |
| 417 | fi |
| 418 | |
| 419 | dnl Check for -fvisibility=hidden support in the compiler. |
| 420 | saved_cflags="$CFLAGS" |
| 421 | CFLAGS="$CFLAGS -fvisibility=hidden" |
| 422 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], |
| 423 | [gdbsrv_cv_have_visibility_hidden=yes], |
| 424 | [gdbsrv_cv_have_visibility_hidden=no]) |
| 425 | CFLAGS="$saved_cflags" |
| 426 | |
| 427 | dnl Check if we can disable the virtual address space randomization. |
| 428 | dnl The functionality of setarch -R. |
| 429 | AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>]) |
| 430 | define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [ |
| 431 | # if !HAVE_DECL_ADDR_NO_RANDOMIZE |
| 432 | # define ADDR_NO_RANDOMIZE 0x0040000 |
| 433 | # endif |
| 434 | /* Test the flag could be set and stays set. */ |
| 435 | personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE); |
| 436 | if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE)) |
| 437 | return 1])]) |
| 438 | AC_RUN_IFELSE([PERSONALITY_TEST], |
| 439 | [gdbsrv_cv_have_personality=true], |
| 440 | [gdbsrv_cv_have_personality=false], |
| 441 | [AC_LINK_IFELSE([PERSONALITY_TEST], |
| 442 | [gdbsrv_cv_have_personality=true], |
| 443 | [gdbsrv_cv_have_personality=false])]) |
| 444 | if $gdbsrv_cv_have_personality |
| 445 | then |
| 446 | AC_DEFINE([HAVE_PERSONALITY], 1, |
| 447 | [Define if you support the personality syscall.]) |
| 448 | fi |
| 449 | |
| 450 | |
| 451 | IPA_DEPFILES="" |
| 452 | extra_libraries="" |
| 453 | |
| 454 | # check whether to enable the inprocess agent |
| 455 | if test "$ipa_obj" != "" \ |
| 456 | -a "$gdbsrv_cv_have_sync_builtins" = yes \ |
| 457 | -a "$gdbsrv_cv_have_visibility_hidden" = yes; then |
| 458 | have_ipa=true |
| 459 | else |
| 460 | have_ipa=false |
| 461 | fi |
| 462 | |
| 463 | AC_ARG_ENABLE(inprocess-agent, |
| 464 | AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]), |
| 465 | [case "$enableval" in |
| 466 | yes) want_ipa=true ;; |
| 467 | no) want_ipa=false ;; |
| 468 | *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;; |
| 469 | esac], |
| 470 | [want_ipa=$have_ipa]) |
| 471 | |
| 472 | if $want_ipa ; then |
| 473 | if $have_ipa ; then |
| 474 | IPA_DEPFILES="$ipa_obj" |
| 475 | extra_libraries="$extra_libraries libinproctrace.so" |
| 476 | else |
| 477 | AC_MSG_ERROR([inprocess agent not supported for this target]) |
| 478 | fi |
| 479 | fi |
| 480 | |
| 481 | AC_SUBST(GDBSERVER_DEPFILES) |
| 482 | AC_SUBST(GDBSERVER_LIBS) |
| 483 | AC_SUBST(srv_xmlbuiltin) |
| 484 | AC_SUBST(srv_xmlfiles) |
| 485 | AC_SUBST(IPA_DEPFILES) |
| 486 | AC_SUBST(extra_libraries) |
| 487 | |
| 488 | GNULIB=build-gnulib-gdbserver/import |
| 489 | |
| 490 | GNULIB_STDINT_H= |
| 491 | if test x"$STDINT_H" != x; then |
| 492 | GNULIB_STDINT_H=$GNULIB/$STDINT_H |
| 493 | fi |
| 494 | AC_SUBST(GNULIB_STDINT_H) |
| 495 | |
| 496 | AC_CONFIG_FILES([Makefile], |
| 497 | [case x$CONFIG_HEADERS in |
| 498 | xconfig.h:config.in) |
| 499 | echo > stamp-h ;; |
| 500 | esac |
| 501 | ]) |
| 502 | |
| 503 | AC_OUTPUT |