| 1 | dnl Autoconf configure script for GDB server. |
| 2 | dnl Copyright (C) 2000-2020 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | AC_INIT(server.c) |
| 22 | AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h]) |
| 23 | |
| 24 | AM_MAINTAINER_MODE |
| 25 | |
| 26 | AC_PROG_CC |
| 27 | AC_PROG_CXX |
| 28 | AC_GNU_SOURCE |
| 29 | AC_SYS_LARGEFILE |
| 30 | |
| 31 | AC_CANONICAL_SYSTEM |
| 32 | |
| 33 | AC_PROG_INSTALL |
| 34 | AC_CHECK_TOOL(AR, ar) |
| 35 | AC_PROG_RANLIB |
| 36 | |
| 37 | AC_ARG_PROGRAM |
| 38 | |
| 39 | # We require a C++11 compiler. Check if one is available, and if |
| 40 | # necessary, set CXX_DIALECT to some -std=xxx switch. |
| 41 | AX_CXX_COMPILE_STDCXX(11, , mandatory) |
| 42 | |
| 43 | AC_HEADER_STDC |
| 44 | |
| 45 | # Set the 'development' global. |
| 46 | . $srcdir/../../bfd/development.sh |
| 47 | |
| 48 | GDB_AC_SELFTEST([ |
| 49 | srv_selftest_objs="gdbsupport/selftest.o" |
| 50 | ]) |
| 51 | |
| 52 | ACX_NONCANONICAL_TARGET |
| 53 | ACX_NONCANONICAL_HOST |
| 54 | |
| 55 | # Dependency checking. |
| 56 | ZW_CREATE_DEPDIR |
| 57 | |
| 58 | # Create sub-directories for objects and dependencies. |
| 59 | CONFIG_SRC_SUBDIR="arch gdbsupport" |
| 60 | AC_SUBST(CONFIG_SRC_SUBDIR) |
| 61 | |
| 62 | AC_CONFIG_COMMANDS([gdbdepdir],[ |
| 63 | for subdir in ${CONFIG_SRC_SUBDIR} |
| 64 | do |
| 65 | $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR |
| 66 | done], |
| 67 | [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"]) |
| 68 | |
| 69 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 70 | |
| 71 | gnulib_extra_configure_args= |
| 72 | # If large-file support is disabled, make sure gnulib does the same. |
| 73 | if test "$enable_largefile" = no; then |
| 74 | gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile" |
| 75 | fi |
| 76 | |
| 77 | # Configure gnulib. We can't use AC_CONFIG_SUBDIRS as that'd expect |
| 78 | # to find the the source subdir to be configured directly under |
| 79 | # gdbserver/. We need to build gnulib under some other directory not |
| 80 | # "gnulib", to avoid the problem of both GDB and GDBserver wanting to |
| 81 | # build it in the same directory, when building in the source dir. |
| 82 | ACX_CONFIGURE_DIR(["../../gnulib"], ["build-gnulib-gdbserver"], |
| 83 | ["$gnulib_extra_configure_args"]) |
| 84 | |
| 85 | ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"]) |
| 86 | |
| 87 | AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl |
| 88 | proc_service.h sys/procfs.h linux/elf.h dnl |
| 89 | fcntl.h signal.h sys/file.h dnl |
| 90 | sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl |
| 91 | netinet/tcp.h arpa/inet.h) |
| 92 | AC_FUNC_FORK |
| 93 | AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns) |
| 94 | |
| 95 | GDB_AC_COMMON |
| 96 | |
| 97 | # Check the return and argument types of ptrace. |
| 98 | GDB_AC_PTRACE |
| 99 | |
| 100 | # Check for UST |
| 101 | ustlibs="" |
| 102 | ustinc="" |
| 103 | |
| 104 | AC_ARG_WITH(ust, [ --with-ust=PATH Specify prefix directory for the installed UST package |
| 105 | Equivalent to --with-ust-include=PATH/include |
| 106 | plus --with-ust-lib=PATH/lib]) |
| 107 | AC_ARG_WITH(ust_include, [ --with-ust-include=PATH Specify directory for installed UST include files]) |
| 108 | AC_ARG_WITH(ust_lib, [ --with-ust-lib=PATH Specify the directory for the installed UST library]) |
| 109 | |
| 110 | case $with_ust in |
| 111 | no) |
| 112 | ustlibs= |
| 113 | ustinc= |
| 114 | ;; |
| 115 | "" | yes) |
| 116 | ustlibs=" -lust " |
| 117 | ustinc="" |
| 118 | ;; |
| 119 | *) |
| 120 | ustlibs="-L$with_ust/lib -lust" |
| 121 | ustinc="-I$with_ust/include " |
| 122 | ;; |
| 123 | esac |
| 124 | if test "x$with_ust_include" != x; then |
| 125 | ustinc="-I$with_ust_include " |
| 126 | fi |
| 127 | if test "x$with_ust_lib" != x; then |
| 128 | ustlibs="-L$with_ust_lib -lust" |
| 129 | fi |
| 130 | |
| 131 | if test "x$with_ust" != "xno"; then |
| 132 | saved_CFLAGS="$CFLAGS" |
| 133 | CFLAGS="$CFLAGS $ustinc" |
| 134 | AC_MSG_CHECKING([for ust]) |
| 135 | AC_TRY_COMPILE([ |
| 136 | #define CONFIG_UST_GDB_INTEGRATION |
| 137 | #include <ust/ust.h> |
| 138 | ],[], |
| 139 | [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])], |
| 140 | [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ]) |
| 141 | CFLAGS="$saved_CFLAGS" |
| 142 | fi |
| 143 | |
| 144 | # Flags needed for UST |
| 145 | AC_SUBST(ustlibs) |
| 146 | AC_SUBST(ustinc) |
| 147 | |
| 148 | AM_GDB_WARNINGS |
| 149 | |
| 150 | dnl dladdr is glibc-specific. It is used by thread-db.c but only for |
| 151 | dnl debugging messages. It lives in -ldl which is handled below so we don't |
| 152 | dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here. Instead we just temporarily |
| 153 | dnl augment LIBS. |
| 154 | old_LIBS="$LIBS" |
| 155 | LIBS="$LIBS -ldl" |
| 156 | AC_CHECK_FUNCS(dladdr) |
| 157 | LIBS="$old_LIBS" |
| 158 | |
| 159 | libiberty_INIT |
| 160 | |
| 161 | AC_CHECK_DECLS([perror, vasprintf, vsnprintf]) |
| 162 | |
| 163 | AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize]) |
| 164 | |
| 165 | # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers. |
| 166 | # Older amd64 Linux's don't have the fs_base and gs_base members of |
| 167 | # `struct user_regs_struct'. |
| 168 | AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base], |
| 169 | [], [], [#include <sys/types.h> |
| 170 | #include <sys/user.h>]) |
| 171 | |
| 172 | |
| 173 | AC_CHECK_TYPES(socklen_t, [], [], |
| 174 | [#include <sys/types.h> |
| 175 | #include <sys/socket.h> |
| 176 | ]) |
| 177 | |
| 178 | case "${target}" in |
| 179 | *-android*) |
| 180 | # Starting with NDK version 9, <elf.h> actually includes definitions |
| 181 | # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes |
| 182 | # <sys/exec_elf.h> which defines some of the ELF types incorrectly, |
| 183 | # leading to conflicts with the defintions from <linux/elf.h>. |
| 184 | # This makes it impossible for us to include both <elf.h> and |
| 185 | # <linux/elf.h>, which means that, in practice, we do not have |
| 186 | # access to Elf32_auxv_t and Elf64_auxv_t on this platform. |
| 187 | # Therefore, do not try to auto-detect availability, as it would |
| 188 | # get it wrong on this platform. |
| 189 | ;; |
| 190 | *) |
| 191 | AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [], |
| 192 | #include <elf.h> |
| 193 | ) |
| 194 | esac |
| 195 | |
| 196 | ACX_PKGVERSION([GDB]) |
| 197 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 198 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 199 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 200 | |
| 201 | # Check for various supplementary target information (beyond the |
| 202 | # triplet) which might affect the choices in configure.srv. |
| 203 | case "${target}" in |
| 204 | changequote(,)dnl |
| 205 | i[34567]86-*-linux*) |
| 206 | changequote([,])dnl |
| 207 | AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64], |
| 208 | [save_CPPFLAGS="$CPPFLAGS" |
| 209 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 210 | AC_EGREP_CPP([got it], [ |
| 211 | #if __x86_64__ |
| 212 | got it |
| 213 | #endif |
| 214 | ], [gdb_cv_i386_is_x86_64=yes], |
| 215 | [gdb_cv_i386_is_x86_64=no]) |
| 216 | CPPFLAGS="$save_CPPFLAGS"]) |
| 217 | ;; |
| 218 | |
| 219 | x86_64-*-linux*) |
| 220 | AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32], |
| 221 | [save_CPPFLAGS="$CPPFLAGS" |
| 222 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 223 | AC_EGREP_CPP([got it], [ |
| 224 | #if __x86_64__ && __ILP32__ |
| 225 | got it |
| 226 | #endif |
| 227 | ], [gdb_cv_x86_is_x32=yes], |
| 228 | [gdb_cv_x86_is_x32=no]) |
| 229 | CPPFLAGS="$save_CPPFLAGS"]) |
| 230 | ;; |
| 231 | |
| 232 | m68k-*-*) |
| 233 | AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire], |
| 234 | [save_CPPFLAGS="$CPPFLAGS" |
| 235 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 236 | AC_EGREP_CPP([got it], [ |
| 237 | #ifdef __mcoldfire__ |
| 238 | got it |
| 239 | #endif |
| 240 | ], [gdb_cv_m68k_is_coldfire=yes], |
| 241 | [gdb_cv_m68k_is_coldfire=no]) |
| 242 | CPPFLAGS="$save_CPPFLAGS"]) |
| 243 | ;; |
| 244 | esac |
| 245 | |
| 246 | . ${srcdir}/configure.srv |
| 247 | |
| 248 | if test "${srv_mingwce}" = "yes"; then |
| 249 | LIBS="$LIBS -lws2" |
| 250 | elif test "${srv_mingw}" = "yes"; then |
| 251 | # WIN32APILIBS is set by GDB_AC_COMMON. |
| 252 | LIBS="$LIBS $WIN32APILIBS" |
| 253 | elif test "${srv_qnx}" = "yes"; then |
| 254 | LIBS="$LIBS -lsocket" |
| 255 | elif test "${srv_lynxos}" = "yes"; then |
| 256 | LIBS="$LIBS -lnetinet" |
| 257 | fi |
| 258 | |
| 259 | if test "${srv_linux_usrregs}" = "yes"; then |
| 260 | AC_DEFINE(HAVE_LINUX_USRREGS, 1, |
| 261 | [Define if the target supports PTRACE_PEEKUSR for register ] |
| 262 | [access.]) |
| 263 | fi |
| 264 | |
| 265 | if test "${srv_linux_regsets}" = "yes"; then |
| 266 | AC_DEFINE(HAVE_LINUX_REGSETS, 1, |
| 267 | [Define if the target supports register sets.]) |
| 268 | |
| 269 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 270 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs, |
| 271 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 272 | [PTRACE_GETREGS;], |
| 273 | [gdbsrv_cv_have_ptrace_getregs=yes], |
| 274 | [gdbsrv_cv_have_ptrace_getregs=no])]) |
| 275 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs) |
| 276 | if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then |
| 277 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 278 | [Define if the target supports PTRACE_GETREGS for register ] |
| 279 | [access.]) |
| 280 | fi |
| 281 | |
| 282 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 283 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs, |
| 284 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 285 | [PTRACE_GETFPXREGS;], |
| 286 | [gdbsrv_cv_have_ptrace_getfpxregs=yes], |
| 287 | [gdbsrv_cv_have_ptrace_getfpxregs=no])]) |
| 288 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs) |
| 289 | if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then |
| 290 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 291 | [Define if the target supports PTRACE_GETFPXREGS for extended ] |
| 292 | [register access.]) |
| 293 | fi |
| 294 | fi |
| 295 | |
| 296 | if test "${srv_linux_btrace}" = "yes"; then |
| 297 | AC_DEFINE(HAVE_LINUX_BTRACE, 1, |
| 298 | [Define if the target supports branch tracing.]) |
| 299 | fi |
| 300 | |
| 301 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 302 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 303 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 304 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 305 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 306 | BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t) |
| 307 | fi |
| 308 | |
| 309 | dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h. |
| 310 | if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then |
| 311 | GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t) |
| 312 | fi |
| 313 | |
| 314 | dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h. |
| 315 | if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then |
| 316 | GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t) |
| 317 | fi |
| 318 | |
| 319 | dnl Check for libdl, but do not add it to LIBS as only gdbserver |
| 320 | dnl needs it (and gdbreplay doesn't). |
| 321 | old_LIBS="$LIBS" |
| 322 | AC_CHECK_LIB(dl, dlopen) |
| 323 | LIBS="$old_LIBS" |
| 324 | |
| 325 | srv_thread_depfiles= |
| 326 | srv_libs= |
| 327 | |
| 328 | if test "$srv_linux_thread_db" = "yes"; then |
| 329 | if test "$ac_cv_lib_dl_dlopen" = "yes"; then |
| 330 | srv_libs="-ldl" |
| 331 | AC_MSG_CHECKING(for the dynamic export flag) |
| 332 | old_LDFLAGS="$LDFLAGS" |
| 333 | # Older GNU ld supports --export-dynamic but --dynamic-list may not be |
| 334 | # supported there. |
| 335 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 336 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 337 | AC_TRY_LINK([], [], |
| 338 | [found="-Wl,--dynamic-list" |
| 339 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'], |
| 340 | [RDYNAMIC="-rdynamic" |
| 341 | LDFLAGS="$old_LDFLAGS $RDYNAMIC" |
| 342 | AC_TRY_LINK([], [], |
| 343 | [found="-rdynamic"], |
| 344 | [found="no" |
| 345 | RDYNAMIC=""])]) |
| 346 | AC_SUBST(RDYNAMIC) |
| 347 | LDFLAGS="$old_LDFLAGS" |
| 348 | AC_MSG_RESULT($found) |
| 349 | else |
| 350 | srv_libs="-lthread_db" |
| 351 | fi |
| 352 | |
| 353 | srv_thread_depfiles="thread-db.o proc-service.o" |
| 354 | AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.]) |
| 355 | AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version, |
| 356 | [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;], |
| 357 | [gdbsrv_cv_have_td_version=yes], |
| 358 | [gdbsrv_cv_have_td_version=no])]) |
| 359 | if test "$gdbsrv_cv_have_td_version" = yes; then |
| 360 | AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.]) |
| 361 | fi |
| 362 | fi |
| 363 | |
| 364 | AC_ARG_WITH(libthread-db, |
| 365 | AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]), |
| 366 | [srv_libthread_db_path="${withval}" |
| 367 | srv_libs="$srv_libthread_db_path" |
| 368 | ]) |
| 369 | |
| 370 | if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then |
| 371 | AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.]) |
| 372 | fi |
| 373 | |
| 374 | if test "$srv_xmlfiles" != ""; then |
| 375 | srv_xmlbuiltin="xml-builtin.o" |
| 376 | AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.]) |
| 377 | |
| 378 | tmp_xmlfiles=$srv_xmlfiles |
| 379 | srv_xmlfiles="" |
| 380 | for f in $tmp_xmlfiles; do |
| 381 | srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f" |
| 382 | done |
| 383 | fi |
| 384 | |
| 385 | GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_selftest_objs" |
| 386 | GDBSERVER_LIBS="$srv_libs" |
| 387 | |
| 388 | dnl Check whether the target supports __sync_*_compare_and_swap. |
| 389 | AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap], |
| 390 | gdbsrv_cv_have_sync_builtins, [ |
| 391 | AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);], |
| 392 | gdbsrv_cv_have_sync_builtins=yes, |
| 393 | gdbsrv_cv_have_sync_builtins=no)]) |
| 394 | if test "$gdbsrv_cv_have_sync_builtins" = yes; then |
| 395 | AC_DEFINE(HAVE_SYNC_BUILTINS, 1, |
| 396 | [Define to 1 if the target supports __sync_*_compare_and_swap]) |
| 397 | fi |
| 398 | |
| 399 | dnl Check for -fvisibility=hidden support in the compiler. |
| 400 | saved_cflags="$CFLAGS" |
| 401 | CFLAGS="$CFLAGS -fvisibility=hidden" |
| 402 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], |
| 403 | [gdbsrv_cv_have_visibility_hidden=yes], |
| 404 | [gdbsrv_cv_have_visibility_hidden=no]) |
| 405 | CFLAGS="$saved_cflags" |
| 406 | |
| 407 | dnl Check if we can disable the virtual address space randomization. |
| 408 | dnl The functionality of setarch -R. |
| 409 | AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>]) |
| 410 | define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [ |
| 411 | # if !HAVE_DECL_ADDR_NO_RANDOMIZE |
| 412 | # define ADDR_NO_RANDOMIZE 0x0040000 |
| 413 | # endif |
| 414 | /* Test the flag could be set and stays set. */ |
| 415 | personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE); |
| 416 | if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE)) |
| 417 | return 1])]) |
| 418 | AC_RUN_IFELSE([PERSONALITY_TEST], |
| 419 | [gdbsrv_cv_have_personality=true], |
| 420 | [gdbsrv_cv_have_personality=false], |
| 421 | [AC_LINK_IFELSE([PERSONALITY_TEST], |
| 422 | [gdbsrv_cv_have_personality=true], |
| 423 | [gdbsrv_cv_have_personality=false])]) |
| 424 | if $gdbsrv_cv_have_personality |
| 425 | then |
| 426 | AC_DEFINE([HAVE_PERSONALITY], 1, |
| 427 | [Define if you support the personality syscall.]) |
| 428 | fi |
| 429 | |
| 430 | |
| 431 | IPA_DEPFILES="" |
| 432 | extra_libraries="" |
| 433 | |
| 434 | # check whether to enable the inprocess agent |
| 435 | if test "$ipa_obj" != "" \ |
| 436 | -a "$gdbsrv_cv_have_sync_builtins" = yes \ |
| 437 | -a "$gdbsrv_cv_have_visibility_hidden" = yes; then |
| 438 | have_ipa=true |
| 439 | else |
| 440 | have_ipa=false |
| 441 | fi |
| 442 | |
| 443 | AC_ARG_ENABLE(inprocess-agent, |
| 444 | AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]), |
| 445 | [case "$enableval" in |
| 446 | yes) want_ipa=true ;; |
| 447 | no) want_ipa=false ;; |
| 448 | *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;; |
| 449 | esac], |
| 450 | [want_ipa=$have_ipa]) |
| 451 | |
| 452 | if $want_ipa ; then |
| 453 | if $have_ipa ; then |
| 454 | IPA_DEPFILES="$ipa_obj" |
| 455 | extra_libraries="$extra_libraries libinproctrace.so" |
| 456 | else |
| 457 | AC_MSG_ERROR([inprocess agent not supported for this target]) |
| 458 | fi |
| 459 | fi |
| 460 | |
| 461 | AC_SUBST(GDBSERVER_DEPFILES) |
| 462 | AC_SUBST(GDBSERVER_LIBS) |
| 463 | AC_SUBST(srv_xmlbuiltin) |
| 464 | AC_SUBST(srv_xmlfiles) |
| 465 | AC_SUBST(IPA_DEPFILES) |
| 466 | AC_SUBST(extra_libraries) |
| 467 | |
| 468 | GNULIB=build-gnulib-gdbserver/import |
| 469 | |
| 470 | GNULIB_STDINT_H= |
| 471 | if test x"$STDINT_H" != x; then |
| 472 | GNULIB_STDINT_H=$GNULIB/$STDINT_H |
| 473 | fi |
| 474 | AC_SUBST(GNULIB_STDINT_H) |
| 475 | |
| 476 | AC_CONFIG_FILES([Makefile]) |
| 477 | |
| 478 | AC_OUTPUT |