| 1 | dnl Autoconf configure script for GDB server. |
| 2 | dnl Copyright (C) 2000-2013 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | AC_PREREQ(2.59)dnl |
| 22 | |
| 23 | AC_INIT(server.c) |
| 24 | AC_CONFIG_HEADER(config.h:config.in) |
| 25 | |
| 26 | AM_MAINTAINER_MODE |
| 27 | |
| 28 | AC_PROG_CC |
| 29 | AC_GNU_SOURCE |
| 30 | AC_SYS_LARGEFILE |
| 31 | |
| 32 | AC_CANONICAL_SYSTEM |
| 33 | |
| 34 | AC_PROG_INSTALL |
| 35 | AC_PROG_RANLIB |
| 36 | |
| 37 | AC_ARG_PROGRAM |
| 38 | |
| 39 | AC_HEADER_STDC |
| 40 | AC_HEADER_DIRENT |
| 41 | |
| 42 | AC_FUNC_ALLOCA |
| 43 | |
| 44 | # Dependency checking. |
| 45 | ZW_CREATE_DEPDIR |
| 46 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 47 | |
| 48 | # Check for the 'make' the user wants to use. |
| 49 | AC_CHECK_PROGS(MAKE, make) |
| 50 | MAKE_IS_GNU= |
| 51 | case "`$MAKE --version 2>&1 | sed 1q`" in |
| 52 | *GNU*) |
| 53 | MAKE_IS_GNU=yes |
| 54 | ;; |
| 55 | esac |
| 56 | AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes) |
| 57 | AC_PROG_MAKE_SET |
| 58 | |
| 59 | # Configure gnulib. We can't use AC_CONFIG_SUBDIRS as that'd expect |
| 60 | # to find the the source subdir to be configured directly under |
| 61 | # gdbserver/. We need to build gnulib under some other directory not |
| 62 | # "gnulib", to avoid the problem of both GDB and GDBserver wanting to |
| 63 | # build it in the same directory, when building in the source dir. |
| 64 | ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"]) |
| 65 | |
| 66 | AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl |
| 67 | proc_service.h sys/procfs.h thread_db.h linux/elf.h dnl |
| 68 | stdlib.h unistd.h dnl |
| 69 | errno.h fcntl.h signal.h sys/file.h malloc.h dnl |
| 70 | sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl |
| 71 | netinet/tcp.h arpa/inet.h sys/wait.h wait.h sys/un.h dnl |
| 72 | linux/perf_event.h) |
| 73 | AC_CHECK_FUNCS(pread pwrite pread64 readlink) |
| 74 | AC_REPLACE_FUNCS(vasprintf vsnprintf) |
| 75 | |
| 76 | # Check for UST |
| 77 | ustlibs="" |
| 78 | ustinc="" |
| 79 | |
| 80 | AC_ARG_WITH(ust, [ --with-ust=PATH Specify prefix directory for the installed UST package |
| 81 | Equivalent to --with-ust-include=PATH/include |
| 82 | plus --with-ust-lib=PATH/lib]) |
| 83 | AC_ARG_WITH(ust_include, [ --with-ust-include=PATH Specify directory for installed UST include files]) |
| 84 | AC_ARG_WITH(ust_lib, [ --with-ust-lib=PATH Specify the directory for the installed UST library]) |
| 85 | |
| 86 | case $with_ust in |
| 87 | no) |
| 88 | ustlibs= |
| 89 | ustinc= |
| 90 | ;; |
| 91 | "" | yes) |
| 92 | ustlibs=" -lust " |
| 93 | ustinc="" |
| 94 | ;; |
| 95 | *) |
| 96 | ustlibs="-L$with_ust/lib -lust" |
| 97 | ustinc="-I$with_ust/include " |
| 98 | ;; |
| 99 | esac |
| 100 | if test "x$with_ust_include" != x; then |
| 101 | ustinc="-I$with_ust_include " |
| 102 | fi |
| 103 | if test "x$with_ust_lib" != x; then |
| 104 | ustlibs="-L$with_ust_lib -lust" |
| 105 | fi |
| 106 | |
| 107 | if test "x$with_ust" != "xno"; then |
| 108 | saved_CFLAGS="$CFLAGS" |
| 109 | CFLAGS="$CFLAGS $ustinc" |
| 110 | AC_MSG_CHECKING([for ust]) |
| 111 | AC_TRY_COMPILE([ |
| 112 | #define CONFIG_UST_GDB_INTEGRATION |
| 113 | #include <ust/ust.h> |
| 114 | ],[], |
| 115 | [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])], |
| 116 | [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ]) |
| 117 | CFLAGS="$saved_CFLAGS" |
| 118 | fi |
| 119 | |
| 120 | # Flags needed for UST |
| 121 | AC_SUBST(ustlibs) |
| 122 | AC_SUBST(ustinc) |
| 123 | |
| 124 | AC_ARG_ENABLE(werror, |
| 125 | AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]), |
| 126 | [case "${enableval}" in |
| 127 | yes | y) ERROR_ON_WARNING="yes" ;; |
| 128 | no | n) ERROR_ON_WARNING="no" ;; |
| 129 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;; |
| 130 | esac]) |
| 131 | |
| 132 | # Enable -Werror by default when using gcc |
| 133 | if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then |
| 134 | ERROR_ON_WARNING=yes |
| 135 | fi |
| 136 | |
| 137 | WERROR_CFLAGS="" |
| 138 | if test "${ERROR_ON_WARNING}" = yes ; then |
| 139 | WERROR_CFLAGS="-Werror" |
| 140 | fi |
| 141 | |
| 142 | build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \ |
| 143 | -Wformat-nonliteral -Wno-char-subscripts -Wempty-body" |
| 144 | |
| 145 | WARN_CFLAGS="" |
| 146 | if test "x$GCC" = xyes |
| 147 | then |
| 148 | AC_MSG_CHECKING(compiler warning flags) |
| 149 | # Separate out the -Werror flag as some files just cannot be |
| 150 | # compiled with it enabled. |
| 151 | for w in ${build_warnings}; do |
| 152 | case $w in |
| 153 | -Werr*) WERROR_CFLAGS=-Werror ;; |
| 154 | *) # Check that GCC accepts it |
| 155 | saved_CFLAGS="$CFLAGS" |
| 156 | CFLAGS="$CFLAGS $w" |
| 157 | AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",) |
| 158 | CFLAGS="$saved_CFLAGS" |
| 159 | esac |
| 160 | done |
| 161 | AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS}) |
| 162 | fi |
| 163 | AC_SUBST(WARN_CFLAGS) |
| 164 | AC_SUBST(WERROR_CFLAGS) |
| 165 | |
| 166 | dnl dladdr is glibc-specific. It is used by thread-db.c but only for |
| 167 | dnl debugging messages. It lives in -ldl which is handled below so we don't |
| 168 | dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here. Instead we just temporarily |
| 169 | dnl augment LIBS. |
| 170 | old_LIBS="$LIBS" |
| 171 | LIBS="$LIBS -ldl" |
| 172 | AC_CHECK_FUNCS(dladdr) |
| 173 | LIBS="$old_LIBS" |
| 174 | |
| 175 | have_errno=no |
| 176 | AC_MSG_CHECKING(for errno) |
| 177 | AC_TRY_LINK([ |
| 178 | #if HAVE_ERRNO_H |
| 179 | #include <errno.h> |
| 180 | #endif], [static int x; x = errno;], |
| 181 | [AC_MSG_RESULT(yes - in errno.h); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) have_errno=yes]) |
| 182 | if test $have_errno = no; then |
| 183 | AC_TRY_LINK([ |
| 184 | #if HAVE_ERRNO_H |
| 185 | #include <errno.h> |
| 186 | #endif], [extern int errno; static int x; x = errno;], |
| 187 | [AC_MSG_RESULT(yes - must define); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) AC_DEFINE(MUST_DEFINE_ERRNO, 1, [Checking if errno must be defined])], |
| 188 | [AC_MSG_RESULT(no)]) |
| 189 | fi |
| 190 | |
| 191 | AC_CHECK_DECLS([strerror, strstr, perror, vasprintf, vsnprintf]) |
| 192 | |
| 193 | AC_CHECK_TYPES(socklen_t, [], [], |
| 194 | [#include <sys/types.h> |
| 195 | #include <sys/socket.h> |
| 196 | ]) |
| 197 | |
| 198 | AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [], |
| 199 | #include <elf.h> |
| 200 | ) |
| 201 | |
| 202 | ACX_PKGVERSION([GDB]) |
| 203 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 204 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 205 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 206 | |
| 207 | # Check for various supplementary target information (beyond the |
| 208 | # triplet) which might affect the choices in configure.srv. |
| 209 | case "${target}" in |
| 210 | changequote(,)dnl |
| 211 | i[34567]86-*-linux*) |
| 212 | changequote([,])dnl |
| 213 | AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64], |
| 214 | [save_CPPFLAGS="$CPPFLAGS" |
| 215 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 216 | AC_EGREP_CPP([got it], [ |
| 217 | #if __x86_64__ |
| 218 | got it |
| 219 | #endif |
| 220 | ], [gdb_cv_i386_is_x86_64=yes], |
| 221 | [gdb_cv_i386_is_x86_64=no]) |
| 222 | CPPFLAGS="$save_CPPFLAGS"]) |
| 223 | ;; |
| 224 | m68k-*-*) |
| 225 | AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire], |
| 226 | [save_CPPFLAGS="$CPPFLAGS" |
| 227 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 228 | AC_EGREP_CPP([got it], [ |
| 229 | #ifdef __mcoldfire__ |
| 230 | got it |
| 231 | #endif |
| 232 | ], [gdb_cv_m68k_is_coldfire=yes], |
| 233 | [gdb_cv_m68k_is_coldfire=no]) |
| 234 | CPPFLAGS="$save_CPPFLAGS"]) |
| 235 | ;; |
| 236 | esac |
| 237 | |
| 238 | . ${srcdir}/configure.srv |
| 239 | |
| 240 | if test "${srv_mingwce}" = "yes"; then |
| 241 | LIBS="$LIBS -lws2" |
| 242 | elif test "${srv_mingw}" = "yes"; then |
| 243 | LIBS="$LIBS -lws2_32" |
| 244 | elif test "${srv_qnx}" = "yes"; then |
| 245 | LIBS="$LIBS -lsocket" |
| 246 | elif test "${srv_lynxos}" = "yes"; then |
| 247 | LIBS="$LIBS -lnetinet" |
| 248 | fi |
| 249 | |
| 250 | if test "${srv_mingw}" = "yes"; then |
| 251 | AC_DEFINE(USE_WIN32API, 1, |
| 252 | [Define if we should use the Windows API, instead of the |
| 253 | POSIX API. On Windows, we use the Windows API when |
| 254 | building for MinGW, but the POSIX API when building |
| 255 | for Cygwin.]) |
| 256 | fi |
| 257 | |
| 258 | if test "${srv_linux_usrregs}" = "yes"; then |
| 259 | AC_DEFINE(HAVE_LINUX_USRREGS, 1, |
| 260 | [Define if the target supports PTRACE_PEEKUSR for register ] |
| 261 | [access.]) |
| 262 | fi |
| 263 | |
| 264 | if test "${srv_linux_regsets}" = "yes"; then |
| 265 | AC_DEFINE(HAVE_LINUX_REGSETS, 1, |
| 266 | [Define if the target supports register sets.]) |
| 267 | |
| 268 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 269 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs, |
| 270 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 271 | [PTRACE_GETREGS;], |
| 272 | [gdbsrv_cv_have_ptrace_getregs=yes], |
| 273 | [gdbsrv_cv_have_ptrace_getregs=no])]) |
| 274 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs) |
| 275 | if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then |
| 276 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 277 | [Define if the target supports PTRACE_GETREGS for register ] |
| 278 | [access.]) |
| 279 | fi |
| 280 | |
| 281 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 282 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs, |
| 283 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 284 | [PTRACE_GETFPXREGS;], |
| 285 | [gdbsrv_cv_have_ptrace_getfpxregs=yes], |
| 286 | [gdbsrv_cv_have_ptrace_getfpxregs=no])]) |
| 287 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs) |
| 288 | if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then |
| 289 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 290 | [Define if the target supports PTRACE_GETFPXREGS for extended ] |
| 291 | [register access.]) |
| 292 | fi |
| 293 | fi |
| 294 | |
| 295 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 296 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 297 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 298 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 299 | BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t) |
| 300 | fi |
| 301 | |
| 302 | dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h. |
| 303 | if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then |
| 304 | GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t) |
| 305 | fi |
| 306 | |
| 307 | dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h. |
| 308 | if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then |
| 309 | GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t) |
| 310 | fi |
| 311 | |
| 312 | dnl Check for libdl, but do not add it to LIBS as only gdbserver |
| 313 | dnl needs it (and gdbreplay doesn't). |
| 314 | old_LIBS="$LIBS" |
| 315 | AC_CHECK_LIB(dl, dlopen) |
| 316 | LIBS="$old_LIBS" |
| 317 | |
| 318 | srv_thread_depfiles= |
| 319 | srv_libs= |
| 320 | USE_THREAD_DB= |
| 321 | |
| 322 | if test "$srv_linux_thread_db" = "yes"; then |
| 323 | if test "$ac_cv_lib_dl_dlopen" = "yes"; then |
| 324 | srv_libs="-ldl" |
| 325 | AC_MSG_CHECKING(for the dynamic export flag) |
| 326 | old_LDFLAGS="$LDFLAGS" |
| 327 | # Older GNU ld supports --export-dynamic but --dynamic-list may not be |
| 328 | # supported there. |
| 329 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 330 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 331 | AC_TRY_LINK([], [], |
| 332 | [found="-Wl,--dynamic-list" |
| 333 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'], |
| 334 | [RDYNAMIC="-rdynamic" |
| 335 | LDFLAGS="$old_LDFLAGS $RDYNAMIC" |
| 336 | AC_TRY_LINK([], [], |
| 337 | [found="-rdynamic"], |
| 338 | [found="no" |
| 339 | RDYNAMIC=""])]) |
| 340 | AC_SUBST(RDYNAMIC) |
| 341 | LDFLAGS="$old_LDFLAGS" |
| 342 | AC_MSG_RESULT($found) |
| 343 | else |
| 344 | srv_libs="-lthread_db" |
| 345 | fi |
| 346 | |
| 347 | srv_thread_depfiles="thread-db.o proc-service.o" |
| 348 | USE_THREAD_DB="-DUSE_THREAD_DB" |
| 349 | AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version, |
| 350 | [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;], |
| 351 | [gdbsrv_cv_have_td_version=yes], |
| 352 | [gdbsrv_cv_have_td_version=no])]) |
| 353 | if test $gdbsrv_cv_have_td_version = yes; then |
| 354 | AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.]) |
| 355 | fi |
| 356 | fi |
| 357 | |
| 358 | AC_ARG_WITH(libthread-db, |
| 359 | AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]), |
| 360 | [srv_libthread_db_path="${withval}" |
| 361 | srv_libs="$srv_libthread_db_path" |
| 362 | ]) |
| 363 | |
| 364 | if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then |
| 365 | AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.]) |
| 366 | fi |
| 367 | |
| 368 | if test "$srv_xmlfiles" != ""; then |
| 369 | srv_xmlbuiltin="xml-builtin.o" |
| 370 | AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.]) |
| 371 | |
| 372 | tmp_xmlfiles=$srv_xmlfiles |
| 373 | srv_xmlfiles="" |
| 374 | for f in $tmp_xmlfiles; do |
| 375 | srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f" |
| 376 | done |
| 377 | fi |
| 378 | |
| 379 | GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles" |
| 380 | GDBSERVER_LIBS="$srv_libs" |
| 381 | |
| 382 | dnl Check whether the target supports __sync_*_compare_and_swap. |
| 383 | AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap], |
| 384 | gdbsrv_cv_have_sync_builtins, [ |
| 385 | AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);], |
| 386 | gdbsrv_cv_have_sync_builtins=yes, |
| 387 | gdbsrv_cv_have_sync_builtins=no)]) |
| 388 | if test $gdbsrv_cv_have_sync_builtins = yes; then |
| 389 | AC_DEFINE(HAVE_SYNC_BUILTINS, 1, |
| 390 | [Define to 1 if the target supports __sync_*_compare_and_swap]) |
| 391 | fi |
| 392 | |
| 393 | dnl Check for -fvisibility=hidden support in the compiler. |
| 394 | saved_cflags="$CFLAGS" |
| 395 | CFLAGS="$CFLAGS -fvisibility=hidden" |
| 396 | AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), |
| 397 | [gdbsrv_cv_have_visibility_hidden=yes], |
| 398 | [gdbsrv_cv_have_visibility_hidden=no]) |
| 399 | CFLAGS="$saved_cflags" |
| 400 | |
| 401 | dnl Check if we can disable the virtual address space randomization. |
| 402 | dnl The functionality of setarch -R. |
| 403 | AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>]) |
| 404 | define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [ |
| 405 | # if !HAVE_DECL_ADDR_NO_RANDOMIZE |
| 406 | # define ADDR_NO_RANDOMIZE 0x0040000 |
| 407 | # endif |
| 408 | /* Test the flag could be set and stays set. */ |
| 409 | personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE); |
| 410 | if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE)) |
| 411 | return 1])]) |
| 412 | AC_RUN_IFELSE([PERSONALITY_TEST], |
| 413 | [gdbsrv_cv_have_personality=true], |
| 414 | [gdbsrv_cv_have_personality=false], |
| 415 | [AC_LINK_IFELSE([PERSONALITY_TEST], |
| 416 | [gdbsrv_cv_have_personality=true], |
| 417 | [gdbsrv_cv_have_personality=false])]) |
| 418 | if $gdbsrv_cv_have_personality |
| 419 | then |
| 420 | AC_DEFINE([HAVE_PERSONALITY], 1, |
| 421 | [Define if you support the personality syscall.]) |
| 422 | fi |
| 423 | |
| 424 | |
| 425 | IPA_DEPFILES="" |
| 426 | extra_libraries="" |
| 427 | |
| 428 | # check whether to enable the inprocess agent |
| 429 | if test "$ipa_obj" != "" \ |
| 430 | -a "$gdbsrv_cv_have_sync_builtins" = yes \ |
| 431 | -a "$gdbsrv_cv_have_visibility_hidden" = yes; then |
| 432 | have_ipa=true |
| 433 | else |
| 434 | have_ipa=false |
| 435 | fi |
| 436 | |
| 437 | AC_ARG_ENABLE(inprocess-agent, |
| 438 | AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]), |
| 439 | [case "$enableval" in |
| 440 | yes) want_ipa=true ;; |
| 441 | no) want_ipa=false ;; |
| 442 | *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;; |
| 443 | esac], |
| 444 | [want_ipa=$have_ipa]) |
| 445 | |
| 446 | if $want_ipa ; then |
| 447 | if $have_ipa ; then |
| 448 | IPA_DEPFILES="$ipa_obj" |
| 449 | extra_libraries="$extra_libraries libinproctrace.so" |
| 450 | else |
| 451 | AC_MSG_ERROR([inprocess agent not supported for this target]) |
| 452 | fi |
| 453 | fi |
| 454 | |
| 455 | AC_SUBST(GDBSERVER_DEPFILES) |
| 456 | AC_SUBST(GDBSERVER_LIBS) |
| 457 | AC_SUBST(USE_THREAD_DB) |
| 458 | AC_SUBST(srv_xmlbuiltin) |
| 459 | AC_SUBST(srv_xmlfiles) |
| 460 | AC_SUBST(IPA_DEPFILES) |
| 461 | AC_SUBST(extra_libraries) |
| 462 | |
| 463 | GNULIB=build-gnulib-gdbserver/import |
| 464 | |
| 465 | GNULIB_STDINT_H= |
| 466 | if test x"$STDINT_H" != x; then |
| 467 | GNULIB_STDINT_H=$GNULIB/$STDINT_H |
| 468 | fi |
| 469 | AC_SUBST(GNULIB_STDINT_H) |
| 470 | |
| 471 | AC_OUTPUT(Makefile, |
| 472 | [case x$CONFIG_HEADERS in |
| 473 | xconfig.h:config.in) |
| 474 | echo > stamp-h ;; |
| 475 | esac |
| 476 | ]) |