| 1 | dnl Autoconf configure script for GDB server. |
| 2 | dnl Copyright (C) 2000-2020 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | AC_INIT(server.cc) |
| 22 | AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h]) |
| 23 | |
| 24 | AM_MAINTAINER_MODE |
| 25 | |
| 26 | AC_PROG_CC |
| 27 | AC_PROG_CXX |
| 28 | AC_GNU_SOURCE |
| 29 | AC_SYS_LARGEFILE |
| 30 | AM_PROG_INSTALL_STRIP |
| 31 | |
| 32 | AC_CANONICAL_SYSTEM |
| 33 | |
| 34 | AC_PROG_INSTALL |
| 35 | AC_CHECK_TOOL(AR, ar) |
| 36 | AC_PROG_RANLIB |
| 37 | |
| 38 | AC_ARG_PROGRAM |
| 39 | |
| 40 | # We require a C++11 compiler. Check if one is available, and if |
| 41 | # necessary, set CXX_DIALECT to some -std=xxx switch. |
| 42 | AX_CXX_COMPILE_STDCXX(11, , mandatory) |
| 43 | |
| 44 | AC_HEADER_STDC |
| 45 | |
| 46 | # Set the 'development' global. |
| 47 | . $srcdir/../bfd/development.sh |
| 48 | |
| 49 | GDB_AC_SELFTEST([ |
| 50 | srv_selftest_objs="gdbsupport/selftest.o" |
| 51 | ]) |
| 52 | |
| 53 | ACX_NONCANONICAL_TARGET |
| 54 | ACX_NONCANONICAL_HOST |
| 55 | |
| 56 | # Dependency checking. |
| 57 | ZW_CREATE_DEPDIR |
| 58 | |
| 59 | # Create sub-directories for objects and dependencies. |
| 60 | CONFIG_SRC_SUBDIR="arch gdbsupport nat target" |
| 61 | AC_SUBST(CONFIG_SRC_SUBDIR) |
| 62 | |
| 63 | AC_CONFIG_COMMANDS([gdbdepdir],[ |
| 64 | for subdir in ${CONFIG_SRC_SUBDIR} |
| 65 | do |
| 66 | $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR |
| 67 | done], |
| 68 | [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"]) |
| 69 | |
| 70 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 71 | |
| 72 | AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl |
| 73 | sys/procfs.h linux/elf.h dnl |
| 74 | fcntl.h signal.h sys/file.h dnl |
| 75 | sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl |
| 76 | netinet/tcp.h arpa/inet.h) |
| 77 | AC_FUNC_FORK |
| 78 | AC_CHECK_FUNCS(pread pwrite pread64) |
| 79 | |
| 80 | GDB_AC_COMMON |
| 81 | |
| 82 | # Check the return and argument types of ptrace. |
| 83 | GDB_AC_PTRACE |
| 84 | |
| 85 | # Check for UST |
| 86 | ustlibs="" |
| 87 | ustinc="" |
| 88 | |
| 89 | AC_ARG_WITH(ust, [ --with-ust=PATH Specify prefix directory for the installed UST package |
| 90 | Equivalent to --with-ust-include=PATH/include |
| 91 | plus --with-ust-lib=PATH/lib]) |
| 92 | AC_ARG_WITH(ust_include, [ --with-ust-include=PATH Specify directory for installed UST include files]) |
| 93 | AC_ARG_WITH(ust_lib, [ --with-ust-lib=PATH Specify the directory for the installed UST library]) |
| 94 | |
| 95 | case $with_ust in |
| 96 | no) |
| 97 | ustlibs= |
| 98 | ustinc= |
| 99 | ;; |
| 100 | "" | yes) |
| 101 | ustlibs=" -lust " |
| 102 | ustinc="" |
| 103 | ;; |
| 104 | *) |
| 105 | ustlibs="-L$with_ust/lib -lust" |
| 106 | ustinc="-I$with_ust/include " |
| 107 | ;; |
| 108 | esac |
| 109 | if test "x$with_ust_include" != x; then |
| 110 | ustinc="-I$with_ust_include " |
| 111 | fi |
| 112 | if test "x$with_ust_lib" != x; then |
| 113 | ustlibs="-L$with_ust_lib -lust" |
| 114 | fi |
| 115 | |
| 116 | if test "x$with_ust" != "xno"; then |
| 117 | saved_CFLAGS="$CFLAGS" |
| 118 | CFLAGS="$CFLAGS $ustinc" |
| 119 | AC_MSG_CHECKING([for ust]) |
| 120 | AC_TRY_COMPILE([ |
| 121 | #define CONFIG_UST_GDB_INTEGRATION |
| 122 | #include <ust/ust.h> |
| 123 | ],[], |
| 124 | [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])], |
| 125 | [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ]) |
| 126 | CFLAGS="$saved_CFLAGS" |
| 127 | fi |
| 128 | |
| 129 | # Flags needed for UST |
| 130 | AC_SUBST(ustlibs) |
| 131 | AC_SUBST(ustinc) |
| 132 | |
| 133 | AM_GDB_WARNINGS |
| 134 | |
| 135 | dnl dladdr is glibc-specific. It is used by thread-db.c but only for |
| 136 | dnl debugging messages. It lives in -ldl which is handled below so we don't |
| 137 | dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here. Instead we just temporarily |
| 138 | dnl augment LIBS. |
| 139 | old_LIBS="$LIBS" |
| 140 | LIBS="$LIBS -ldl" |
| 141 | AC_CHECK_FUNCS(dladdr) |
| 142 | LIBS="$old_LIBS" |
| 143 | |
| 144 | libiberty_INIT |
| 145 | |
| 146 | AC_CHECK_DECLS([perror, vasprintf, vsnprintf]) |
| 147 | |
| 148 | # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers. |
| 149 | # Older amd64 Linux's don't have the fs_base and gs_base members of |
| 150 | # `struct user_regs_struct'. |
| 151 | AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base], |
| 152 | [], [], [#include <sys/types.h> |
| 153 | #include <sys/user.h>]) |
| 154 | |
| 155 | |
| 156 | AC_CHECK_TYPES(socklen_t, [], [], |
| 157 | [#include <sys/types.h> |
| 158 | #include <sys/socket.h> |
| 159 | ]) |
| 160 | |
| 161 | case "${target}" in |
| 162 | *-android*) |
| 163 | # Starting with NDK version 9, <elf.h> actually includes definitions |
| 164 | # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes |
| 165 | # <sys/exec_elf.h> which defines some of the ELF types incorrectly, |
| 166 | # leading to conflicts with the defintions from <linux/elf.h>. |
| 167 | # This makes it impossible for us to include both <elf.h> and |
| 168 | # <linux/elf.h>, which means that, in practice, we do not have |
| 169 | # access to Elf32_auxv_t and Elf64_auxv_t on this platform. |
| 170 | # Therefore, do not try to auto-detect availability, as it would |
| 171 | # get it wrong on this platform. |
| 172 | ;; |
| 173 | *) |
| 174 | AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [], |
| 175 | #include <elf.h> |
| 176 | ) |
| 177 | esac |
| 178 | |
| 179 | ACX_PKGVERSION([GDB]) |
| 180 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 181 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 182 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 183 | |
| 184 | # Check for various supplementary target information (beyond the |
| 185 | # triplet) which might affect the choices in configure.srv. |
| 186 | case "${target}" in |
| 187 | changequote(,)dnl |
| 188 | i[34567]86-*-linux*) |
| 189 | changequote([,])dnl |
| 190 | AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64], |
| 191 | [save_CPPFLAGS="$CPPFLAGS" |
| 192 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 193 | AC_EGREP_CPP([got it], [ |
| 194 | #if __x86_64__ |
| 195 | got it |
| 196 | #endif |
| 197 | ], [gdb_cv_i386_is_x86_64=yes], |
| 198 | [gdb_cv_i386_is_x86_64=no]) |
| 199 | CPPFLAGS="$save_CPPFLAGS"]) |
| 200 | ;; |
| 201 | |
| 202 | x86_64-*-linux*) |
| 203 | AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32], |
| 204 | [save_CPPFLAGS="$CPPFLAGS" |
| 205 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 206 | AC_EGREP_CPP([got it], [ |
| 207 | #if __x86_64__ && __ILP32__ |
| 208 | got it |
| 209 | #endif |
| 210 | ], [gdb_cv_x86_is_x32=yes], |
| 211 | [gdb_cv_x86_is_x32=no]) |
| 212 | CPPFLAGS="$save_CPPFLAGS"]) |
| 213 | ;; |
| 214 | |
| 215 | m68k-*-*) |
| 216 | AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire], |
| 217 | [save_CPPFLAGS="$CPPFLAGS" |
| 218 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 219 | AC_EGREP_CPP([got it], [ |
| 220 | #ifdef __mcoldfire__ |
| 221 | got it |
| 222 | #endif |
| 223 | ], [gdb_cv_m68k_is_coldfire=yes], |
| 224 | [gdb_cv_m68k_is_coldfire=no]) |
| 225 | CPPFLAGS="$save_CPPFLAGS"]) |
| 226 | ;; |
| 227 | esac |
| 228 | |
| 229 | . ${srcdir}/configure.srv |
| 230 | |
| 231 | if test "${srv_mingwce}" = "yes"; then |
| 232 | LIBS="$LIBS -lws2" |
| 233 | elif test "${srv_mingw}" = "yes"; then |
| 234 | # WIN32APILIBS is set by GDB_AC_COMMON. |
| 235 | LIBS="$LIBS $WIN32APILIBS" |
| 236 | elif test "${srv_qnx}" = "yes"; then |
| 237 | LIBS="$LIBS -lsocket" |
| 238 | elif test "${srv_lynxos}" = "yes"; then |
| 239 | LIBS="$LIBS -lnetinet" |
| 240 | fi |
| 241 | |
| 242 | if test "${srv_linux_usrregs}" = "yes"; then |
| 243 | AC_DEFINE(HAVE_LINUX_USRREGS, 1, |
| 244 | [Define if the target supports PTRACE_PEEKUSR for register ] |
| 245 | [access.]) |
| 246 | fi |
| 247 | |
| 248 | if test "${srv_linux_regsets}" = "yes"; then |
| 249 | AC_DEFINE(HAVE_LINUX_REGSETS, 1, |
| 250 | [Define if the target supports register sets.]) |
| 251 | |
| 252 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 253 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs, |
| 254 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 255 | [PTRACE_GETREGS;], |
| 256 | [gdbsrv_cv_have_ptrace_getregs=yes], |
| 257 | [gdbsrv_cv_have_ptrace_getregs=no])]) |
| 258 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs) |
| 259 | if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then |
| 260 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 261 | [Define if the target supports PTRACE_GETREGS for register ] |
| 262 | [access.]) |
| 263 | fi |
| 264 | |
| 265 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 266 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs, |
| 267 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 268 | [PTRACE_GETFPXREGS;], |
| 269 | [gdbsrv_cv_have_ptrace_getfpxregs=yes], |
| 270 | [gdbsrv_cv_have_ptrace_getfpxregs=no])]) |
| 271 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs) |
| 272 | if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then |
| 273 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 274 | [Define if the target supports PTRACE_GETFPXREGS for extended ] |
| 275 | [register access.]) |
| 276 | fi |
| 277 | fi |
| 278 | |
| 279 | if test "${srv_linux_btrace}" = "yes"; then |
| 280 | AC_DEFINE(HAVE_LINUX_BTRACE, 1, |
| 281 | [Define if the target supports branch tracing.]) |
| 282 | fi |
| 283 | |
| 284 | dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h. |
| 285 | if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then |
| 286 | GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t) |
| 287 | fi |
| 288 | |
| 289 | dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h. |
| 290 | if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then |
| 291 | GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t) |
| 292 | fi |
| 293 | |
| 294 | dnl Check for libdl, but do not add it to LIBS as only gdbserver |
| 295 | dnl needs it (and gdbreplay doesn't). |
| 296 | old_LIBS="$LIBS" |
| 297 | AC_CHECK_LIB(dl, dlopen) |
| 298 | LIBS="$old_LIBS" |
| 299 | |
| 300 | srv_thread_depfiles= |
| 301 | srv_libs= |
| 302 | |
| 303 | if test "$srv_linux_thread_db" = "yes"; then |
| 304 | if test "$ac_cv_lib_dl_dlopen" = "yes"; then |
| 305 | srv_libs="-ldl" |
| 306 | AC_MSG_CHECKING(for the dynamic export flag) |
| 307 | old_LDFLAGS="$LDFLAGS" |
| 308 | # Older GNU ld supports --export-dynamic but --dynamic-list may not be |
| 309 | # supported there. |
| 310 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 311 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 312 | AC_TRY_LINK([], [], |
| 313 | [found="-Wl,--dynamic-list" |
| 314 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'], |
| 315 | [RDYNAMIC="-rdynamic" |
| 316 | LDFLAGS="$old_LDFLAGS $RDYNAMIC" |
| 317 | AC_TRY_LINK([], [], |
| 318 | [found="-rdynamic"], |
| 319 | [found="no" |
| 320 | RDYNAMIC=""])]) |
| 321 | AC_SUBST(RDYNAMIC) |
| 322 | LDFLAGS="$old_LDFLAGS" |
| 323 | AC_MSG_RESULT($found) |
| 324 | else |
| 325 | srv_libs="-lthread_db" |
| 326 | fi |
| 327 | |
| 328 | srv_thread_depfiles="thread-db.o proc-service.o" |
| 329 | AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.]) |
| 330 | AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version, |
| 331 | [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;], |
| 332 | [gdbsrv_cv_have_td_version=yes], |
| 333 | [gdbsrv_cv_have_td_version=no])]) |
| 334 | if test "$gdbsrv_cv_have_td_version" = yes; then |
| 335 | AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.]) |
| 336 | fi |
| 337 | fi |
| 338 | |
| 339 | AC_ARG_WITH(libthread-db, |
| 340 | AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]), |
| 341 | [srv_libthread_db_path="${withval}" |
| 342 | srv_libs="$srv_libthread_db_path" |
| 343 | ]) |
| 344 | |
| 345 | if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then |
| 346 | AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.]) |
| 347 | fi |
| 348 | |
| 349 | if test "$srv_xmlfiles" != ""; then |
| 350 | srv_xmlbuiltin="xml-builtin.o" |
| 351 | AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.]) |
| 352 | |
| 353 | tmp_xmlfiles=$srv_xmlfiles |
| 354 | srv_xmlfiles="" |
| 355 | for f in $tmp_xmlfiles; do |
| 356 | srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f" |
| 357 | done |
| 358 | fi |
| 359 | |
| 360 | GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_selftest_objs" |
| 361 | GDBSERVER_LIBS="$srv_libs" |
| 362 | |
| 363 | dnl Check whether the target supports __sync_*_compare_and_swap. |
| 364 | AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap], |
| 365 | gdbsrv_cv_have_sync_builtins, [ |
| 366 | AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);], |
| 367 | gdbsrv_cv_have_sync_builtins=yes, |
| 368 | gdbsrv_cv_have_sync_builtins=no)]) |
| 369 | if test "$gdbsrv_cv_have_sync_builtins" = yes; then |
| 370 | AC_DEFINE(HAVE_SYNC_BUILTINS, 1, |
| 371 | [Define to 1 if the target supports __sync_*_compare_and_swap]) |
| 372 | fi |
| 373 | |
| 374 | dnl Check for -fvisibility=hidden support in the compiler. |
| 375 | saved_cflags="$CFLAGS" |
| 376 | CFLAGS="$CFLAGS -fvisibility=hidden" |
| 377 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], |
| 378 | [gdbsrv_cv_have_visibility_hidden=yes], |
| 379 | [gdbsrv_cv_have_visibility_hidden=no]) |
| 380 | CFLAGS="$saved_cflags" |
| 381 | |
| 382 | IPA_DEPFILES="" |
| 383 | extra_libraries="" |
| 384 | |
| 385 | # check whether to enable the inprocess agent |
| 386 | if test "$ipa_obj" != "" \ |
| 387 | -a "$gdbsrv_cv_have_sync_builtins" = yes \ |
| 388 | -a "$gdbsrv_cv_have_visibility_hidden" = yes; then |
| 389 | have_ipa=true |
| 390 | else |
| 391 | have_ipa=false |
| 392 | fi |
| 393 | |
| 394 | AC_ARG_ENABLE(inprocess-agent, |
| 395 | AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]), |
| 396 | [case "$enableval" in |
| 397 | yes) want_ipa=true ;; |
| 398 | no) want_ipa=false ;; |
| 399 | *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;; |
| 400 | esac], |
| 401 | [want_ipa=$have_ipa]) |
| 402 | |
| 403 | if $want_ipa ; then |
| 404 | if $have_ipa ; then |
| 405 | IPA_DEPFILES="$ipa_obj" |
| 406 | extra_libraries="$extra_libraries libinproctrace.so" |
| 407 | else |
| 408 | AC_MSG_ERROR([inprocess agent not supported for this target]) |
| 409 | fi |
| 410 | fi |
| 411 | |
| 412 | AC_SUBST(GDBSERVER_DEPFILES) |
| 413 | AC_SUBST(GDBSERVER_LIBS) |
| 414 | AC_SUBST(srv_xmlbuiltin) |
| 415 | AC_SUBST(srv_xmlfiles) |
| 416 | AC_SUBST(IPA_DEPFILES) |
| 417 | AC_SUBST(extra_libraries) |
| 418 | |
| 419 | GNULIB=../gnulib/import |
| 420 | |
| 421 | GNULIB_STDINT_H= |
| 422 | if test x"$STDINT_H" != x; then |
| 423 | GNULIB_STDINT_H=$GNULIB/$STDINT_H |
| 424 | fi |
| 425 | AC_SUBST(GNULIB_STDINT_H) |
| 426 | |
| 427 | AC_CONFIG_FILES([Makefile]) |
| 428 | |
| 429 | AC_OUTPUT |