| 1 | dnl Process this file with autoconf to produce a configure script |
| 2 | dnl |
| 3 | AC_PREREQ(2.57) |
| 4 | AC_INIT(ldmain.c) |
| 5 | |
| 6 | AC_CANONICAL_SYSTEM |
| 7 | AC_ISC_POSIX |
| 8 | |
| 9 | changequote(,)dnl |
| 10 | BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[ ]*\([^ ]*\)[ ]*).*/\1/p' < ${srcdir}/../bfd/configure.in` |
| 11 | changequote([,])dnl |
| 12 | AM_INIT_AUTOMAKE(ld, ${BFD_VERSION}) |
| 13 | |
| 14 | AM_PROG_LIBTOOL |
| 15 | |
| 16 | AC_ARG_WITH(lib-path, [ --with-lib-path=dir1:dir2... set default LIB_PATH],LIB_PATH=$withval) |
| 17 | AC_ARG_ENABLE(targets, |
| 18 | [ --enable-targets alternative target configurations], |
| 19 | [case "${enableval}" in |
| 20 | yes | "") AC_ERROR(enable-targets option must specify target names or 'all') |
| 21 | ;; |
| 22 | no) enable_targets= ;; |
| 23 | *) enable_targets=$enableval ;; |
| 24 | esac])dnl |
| 25 | AC_ARG_ENABLE(64-bit-bfd, |
| 26 | [ --enable-64-bit-bfd 64-bit support (on hosts with narrower word sizes)], |
| 27 | [case "${enableval}" in |
| 28 | yes) want64=true ;; |
| 29 | no) want64=false ;; |
| 30 | *) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;; |
| 31 | esac],[want64=false])dnl |
| 32 | |
| 33 | AC_ARG_WITH(sysroot, |
| 34 | [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.], |
| 35 | [ |
| 36 | case ${with_sysroot} in |
| 37 | yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;; |
| 38 | *) TARGET_SYSTEM_ROOT=$with_sysroot ;; |
| 39 | esac |
| 40 | |
| 41 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"' |
| 42 | use_sysroot=yes |
| 43 | |
| 44 | if test "x$exec_prefix" = xNONE; then |
| 45 | if test "x$prefix" = xNONE; then |
| 46 | test_prefix=/usr/local |
| 47 | else |
| 48 | test_prefix=$prefix |
| 49 | fi |
| 50 | else |
| 51 | test_prefix=$exec_prefix |
| 52 | fi |
| 53 | case ${TARGET_SYSTEM_ROOT} in |
| 54 | "${test_prefix}"|"${test_prefix}/"*|\ |
| 55 | '${exec_prefix}'|'${exec_prefix}/'*) |
| 56 | t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE" |
| 57 | TARGET_SYSTEM_ROOT_DEFINE="$t" |
| 58 | ;; |
| 59 | esac |
| 60 | ], [ |
| 61 | use_sysroot=no |
| 62 | TARGET_SYSTEM_ROOT= |
| 63 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"' |
| 64 | ]) |
| 65 | AC_SUBST(use_sysroot) |
| 66 | AC_SUBST(TARGET_SYSTEM_ROOT) |
| 67 | AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE) |
| 68 | |
| 69 | dnl FIXME: The following is bfd/warning.m4 contents expanded |
| 70 | dnl When converting to current autotools, please replace with |
| 71 | dnl AM_BINUTILS_WARNINGS |
| 72 | WARN_CFLAGS="-W -Wall -Wstrict-prototypes -Wmissing-prototypes" |
| 73 | |
| 74 | AC_ARG_ENABLE(werror, |
| 75 | [ --enable-werror treat compile warnings as errors], |
| 76 | [case "${enableval}" in |
| 77 | yes | y) ERROR_ON_WARNING="yes" ;; |
| 78 | no | n) ERROR_ON_WARNING="no" ;; |
| 79 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;; |
| 80 | esac]) |
| 81 | |
| 82 | # Enable -Werror by default when using gcc |
| 83 | if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then |
| 84 | ERROR_ON_WARNING=yes |
| 85 | fi |
| 86 | |
| 87 | NO_WERROR= |
| 88 | if test "${ERROR_ON_WARNING}" = yes ; then |
| 89 | WARN_CFLAGS="$WARN_CFLAGS -Werror" |
| 90 | NO_WERROR="-Wno-error" |
| 91 | fi |
| 92 | |
| 93 | AC_ARG_ENABLE(build-warnings, |
| 94 | [ --enable-build-warnings Enable build-time compiler warnings], |
| 95 | [case "${enableval}" in |
| 96 | yes) ;; |
| 97 | no) WARN_CFLAGS="-w";; |
| 98 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 99 | WARN_CFLAGS="${WARN_CFLAGS} ${t}";; |
| 100 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 101 | WARN_CFLAGS="${t} ${WARN_CFLAGS}";; |
| 102 | *) WARN_CFLAGS=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 103 | esac]) |
| 104 | |
| 105 | if test x"$silent" != x"yes" && test x"$WARN_CFLAGS" != x""; then |
| 106 | echo "Setting warning flags = $WARN_CFLAGS" 6>&1 |
| 107 | fi |
| 108 | |
| 109 | AC_SUBST(WARN_CFLAGS) |
| 110 | AC_SUBST(NO_WERROR) |
| 111 | |
| 112 | AM_CONFIG_HEADER(config.h:config.in) |
| 113 | |
| 114 | if test -z "$target" ; then |
| 115 | AC_MSG_ERROR(Unrecognized target system type; please check config.sub.) |
| 116 | fi |
| 117 | if test -z "$host" ; then |
| 118 | AC_MSG_ERROR(Unrecognized host system type; please check config.sub.) |
| 119 | fi |
| 120 | |
| 121 | # host-specific stuff: |
| 122 | |
| 123 | AC_PROG_CC |
| 124 | AC_PROG_INSTALL |
| 125 | |
| 126 | ALL_LINGUAS="fr sv tr es da" |
| 127 | CY_GNU_GETTEXT |
| 128 | |
| 129 | AC_EXEEXT |
| 130 | |
| 131 | AC_PROG_YACC |
| 132 | AM_PROG_LEX |
| 133 | |
| 134 | AM_MAINTAINER_MODE |
| 135 | |
| 136 | . ${srcdir}/configure.host |
| 137 | |
| 138 | AC_SUBST(HDEFINES) |
| 139 | AC_SUBST(HOSTING_CRT0) |
| 140 | AC_SUBST(HOSTING_LIBS) |
| 141 | AC_SUBST(NATIVE_LIB_DIRS) |
| 142 | |
| 143 | AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h) |
| 144 | AC_CHECK_FUNCS(sbrk realpath glob) |
| 145 | AC_HEADER_DIRENT |
| 146 | |
| 147 | AC_MSG_CHECKING(for a known getopt prototype in unistd.h) |
| 148 | AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h, |
| 149 | [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);], |
| 150 | ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)]) |
| 151 | AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h) |
| 152 | if test $ld_cv_decl_getopt_unistd_h = yes; then |
| 153 | AC_DEFINE([HAVE_DECL_GETOPT], 1, |
| 154 | [Is the prototype for getopt in <unistd.h> in the expected format?]) |
| 155 | fi |
| 156 | |
| 157 | BFD_BINARY_FOPEN |
| 158 | |
| 159 | BFD_NEED_DECLARATION(strstr) |
| 160 | BFD_NEED_DECLARATION(free) |
| 161 | BFD_NEED_DECLARATION(sbrk) |
| 162 | BFD_NEED_DECLARATION(getenv) |
| 163 | BFD_NEED_DECLARATION(environ) |
| 164 | |
| 165 | # When converting linker scripts into strings for use in emulation |
| 166 | # files, use astring.sed if the compiler supports ANSI string |
| 167 | # concatenation, or ostring.sed otherwise. This is to support the |
| 168 | # broken Microsoft MSVC compiler, which limits the length of string |
| 169 | # constants, while still supporting pre-ANSI compilers which do not |
| 170 | # support string concatenation. |
| 171 | AC_MSG_CHECKING([whether ANSI C string concatenation works]) |
| 172 | AC_CACHE_VAL(ld_cv_string_concatenation, |
| 173 | [AC_TRY_COMPILE(,[char *a = "a" "a";], |
| 174 | [ld_cv_string_concatenation=yes], |
| 175 | [ld_cv_string_concatenation=no])]) |
| 176 | AC_MSG_RESULT($ld_cv_string_concatenation) |
| 177 | if test "$ld_cv_string_concatenation" = "yes"; then |
| 178 | STRINGIFY=astring.sed |
| 179 | else |
| 180 | STRINGIFY=ostring.sed |
| 181 | fi |
| 182 | AC_SUBST(STRINGIFY) |
| 183 | |
| 184 | # target-specific stuff: |
| 185 | |
| 186 | all_targets= |
| 187 | EMUL= |
| 188 | all_emuls= |
| 189 | all_emul_extras= |
| 190 | all_libpath= |
| 191 | |
| 192 | dnl We need to get an arbitrary number of tdir definitions into |
| 193 | dnl Makefile. We can't do it using AC_SUBST, because autoconf does |
| 194 | dnl not permit literal newlines in an AC_SUBST variables. So we use a |
| 195 | dnl file. |
| 196 | rm -f tdirs |
| 197 | |
| 198 | for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'` |
| 199 | do |
| 200 | if test "$targ_alias" = "all"; then |
| 201 | all_targets=true |
| 202 | else |
| 203 | # Canonicalize the secondary target names. |
| 204 | result=`$ac_config_sub $targ_alias 2>/dev/null` |
| 205 | if test -n "$result"; then |
| 206 | targ=$result |
| 207 | else |
| 208 | targ=$targ_alias |
| 209 | fi |
| 210 | |
| 211 | . ${srcdir}/configure.tgt |
| 212 | |
| 213 | if test "$targ" = "$target"; then |
| 214 | EMUL=$targ_emul |
| 215 | fi |
| 216 | |
| 217 | for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do |
| 218 | case " $all_emuls " in |
| 219 | *" e${i}.o "*) ;; |
| 220 | *) |
| 221 | all_emuls="$all_emuls e${i}.o" |
| 222 | eval result=\$tdir_$i |
| 223 | test -z "$result" && result=$targ_alias |
| 224 | echo tdir_$i=$result >> tdirs |
| 225 | ;; |
| 226 | esac |
| 227 | done |
| 228 | |
| 229 | for i in $targ_emul $targ_extra_libpath; do |
| 230 | case " $all_libpath " in |
| 231 | *" ${i} "*) ;; |
| 232 | *) |
| 233 | if test -z "$all_libpath"; then |
| 234 | all_libpath=${i} |
| 235 | else |
| 236 | all_libpath="$all_libpath ${i}" |
| 237 | fi |
| 238 | ;; |
| 239 | esac |
| 240 | done |
| 241 | |
| 242 | for i in $targ_extra_ofiles; do |
| 243 | case " $all_emul_extras " in |
| 244 | *" ${i} "*) ;; |
| 245 | *) |
| 246 | all_emul_extras="$all_emul_extras ${i}" |
| 247 | ;; |
| 248 | esac |
| 249 | done |
| 250 | fi |
| 251 | done |
| 252 | |
| 253 | AC_SUBST(EMUL) |
| 254 | |
| 255 | TDIRS=tdirs |
| 256 | AC_SUBST_FILE(TDIRS) |
| 257 | |
| 258 | dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit |
| 259 | dnl target, and in those cases we should also build the 64 bit |
| 260 | dnl emulations. |
| 261 | if test x${all_targets} = xtrue; then |
| 262 | if test x${want64} = xtrue; then |
| 263 | EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)' |
| 264 | else |
| 265 | EMULATION_OFILES='$(ALL_EMULATIONS)' |
| 266 | fi |
| 267 | EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)' |
| 268 | else |
| 269 | EMULATION_OFILES=$all_emuls |
| 270 | EMUL_EXTRA_OFILES=$all_emul_extras |
| 271 | fi |
| 272 | AC_SUBST(EMULATION_OFILES) |
| 273 | AC_SUBST(EMUL_EXTRA_OFILES) |
| 274 | AC_SUBST(LIB_PATH) |
| 275 | |
| 276 | EMULATION_LIBPATH=$all_libpath |
| 277 | AC_SUBST(EMULATION_LIBPATH) |
| 278 | |
| 279 | if test x${enable_static} = xno; then |
| 280 | TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so" |
| 281 | else |
| 282 | TESTBFDLIB="../bfd/.libs/libbfd.a" |
| 283 | fi |
| 284 | AC_SUBST(TESTBFDLIB) |
| 285 | |
| 286 | target_vendor=${target_vendor=$host_vendor} |
| 287 | case "$target_vendor" in |
| 288 | hp) EXTRA_SHLIB_EXTENSION=".sl" ;; |
| 289 | *) EXTRA_SHLIB_EXTENSION= ;; |
| 290 | esac |
| 291 | |
| 292 | case "$target_os" in |
| 293 | lynxos) EXTRA_SHLIB_EXTENSION=".a" ;; |
| 294 | esac |
| 295 | |
| 296 | if test x${EXTRA_SHLIB_EXTENSION} != x ; then |
| 297 | AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION", |
| 298 | [Additional extension a shared object might have.]) |
| 299 | fi |
| 300 | |
| 301 | AC_OUTPUT(Makefile po/Makefile.in:po/Make-in, |
| 302 | [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile]) |