| 1 | # Expect script for common symbol tests |
| 2 | # Copyright 2003, 2005, 2006, 2007, 2008 Free Software Foundation, Inc. |
| 3 | # |
| 4 | # This file is part of the GNU Binutils. |
| 5 | # |
| 6 | # This program is free software; you can redistribute it and/or modify |
| 7 | # it under the terms of the GNU General Public License as published by |
| 8 | # the Free Software Foundation; either version 3 of the License, or |
| 9 | # (at your option) any later version. |
| 10 | # |
| 11 | # This program is distributed in the hope that it will be useful, |
| 12 | # but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | # GNU General Public License for more details. |
| 15 | # |
| 16 | # You should have received a copy of the GNU General Public License |
| 17 | # along with this program; if not, write to the Free Software |
| 18 | # Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston, |
| 19 | # MA 02110-1301, USA. |
| 20 | # |
| 21 | # Written by H.J. Lu (hjl@gnu.org) |
| 22 | # |
| 23 | |
| 24 | # Make sure that ld correctly handles common symbols in ELF. |
| 25 | |
| 26 | # This test can only be run on ELF platforms. |
| 27 | if ![is_elf_format] { |
| 28 | return |
| 29 | } |
| 30 | |
| 31 | proc test_sort_common {} { |
| 32 | global exec_output |
| 33 | global objdump |
| 34 | global srcdir |
| 35 | global subdir |
| 36 | global as |
| 37 | global ld |
| 38 | |
| 39 | set test "--sort-common (descending)" |
| 40 | |
| 41 | verbose "Check to see that --sort-common sorts in descending alignment" |
| 42 | |
| 43 | # We do not run the sort common tests for the DLX target because we know that the linker |
| 44 | # will seg-fault. The built-in DLX linker script requires that there be something in the |
| 45 | # .text section and our sort-common.s file does not provide anything. |
| 46 | if [istarget dlx-*-*] { |
| 47 | untested "$test" |
| 48 | return 0 |
| 49 | } |
| 50 | |
| 51 | if { ![ld_assemble $as $srcdir/$subdir/sort-common.s tmpdir/sort-common.o] } { |
| 52 | unresolved "$test" |
| 53 | return 0 |
| 54 | } |
| 55 | |
| 56 | if { ![ld_simple_link $ld tmpdir/sort-common.dx "--sort-common=descending tmpdir/sort-common.o"] } { |
| 57 | fail "$test" |
| 58 | return 0 |
| 59 | } |
| 60 | |
| 61 | send_log "$objdump --syms tmpdir/sort-common.dx | grep var | sort\n" |
| 62 | set exec_output [run_host_cmd "$objdump" "--syms tmpdir/sort-common.dx | grep var | sort"] |
| 63 | |
| 64 | # Don't know why, but the CR ports fail this test. |
| 65 | setup_xfail "cr16-*-*" "crx-*-*" |
| 66 | |
| 67 | # Note: The second regexp is for targets which put small commons in a .sbss |
| 68 | # section and large commons in a .bss section. |
| 69 | if { ![regexp ".*var_16.*var_8.*var_4.*var_2.*var_1.*" $exec_output] |
| 70 | && ![regexp ".*sbss.*var_8.*var_4.*var_2.*var_1.*bss.*var_16.*" $exec_output] } { |
| 71 | fail $test |
| 72 | } else { |
| 73 | pass $test |
| 74 | } |
| 75 | |
| 76 | set test "--sort-common (ascending)" |
| 77 | |
| 78 | verbose "Check to see that --sort-common=ascending sorts in ascending alignment" |
| 79 | |
| 80 | if { ![ld_simple_link $ld tmpdir/sort-common.ax "--sort-common=ascending tmpdir/sort-common.o"] } { |
| 81 | fail "$test" |
| 82 | return 0 |
| 83 | } |
| 84 | |
| 85 | send_log "$objdump --syms tmpdir/sort-common.ax | grep var | sort\n" |
| 86 | set exec_output [run_host_cmd "$objdump" "--syms tmpdir/sort-common.ax | grep var | sort"] |
| 87 | |
| 88 | if {![regexp ".*var_1.*var_2.*var_4.*var_8.*var_16.*" $exec_output]} { |
| 89 | fail $test |
| 90 | return 0 |
| 91 | } |
| 92 | |
| 93 | pass $test |
| 94 | return 1 |
| 95 | } |
| 96 | |
| 97 | test_sort_common |
| 98 | |
| 99 | set test1 "size/aligment change of common symbols" |
| 100 | set test1w1 "$test1 (warning 1)" |
| 101 | set test1w2 "$test1 (warning 2)" |
| 102 | set test1c1 "$test1 (change 1)" |
| 103 | set test1c2 "$test1 (change 2)" |
| 104 | |
| 105 | if { ![is_remote host] && [which $CC] == 0 } { |
| 106 | untested $test1w1 |
| 107 | untested $test1w2 |
| 108 | untested $test1c1 |
| 109 | untested $test1c2 |
| 110 | return |
| 111 | } |
| 112 | if { [istarget score-*-*] } { |
| 113 | untested $test1w1 |
| 114 | untested $test1w2 |
| 115 | untested $test1c1 |
| 116 | untested $test1c2 |
| 117 | return |
| 118 | } |
| 119 | |
| 120 | proc dump_common1 { testname } { |
| 121 | global exec_output |
| 122 | global READELF |
| 123 | |
| 124 | send_log "$READELF --syms tmpdir/common1.o | grep foo\n" |
| 125 | set exec_output [run_host_cmd "$READELF" "--syms tmpdir/common1.o | grep foo"] |
| 126 | |
| 127 | if { ![regexp "(\[ \]*)(\[0-9\]+):(\[ \]*)(\[0\]*)80(\[ \]+)4(\[ \]+)(COMMON|OBJECT)(\[ \]+)GLOBAL(\[ \]+)DEFAULT(\[ \]+)(PRC\\\[0xff03\\\]|COM|SCOM)(\[ \]+)_?foo2" $exec_output] |
| 128 | || ![regexp "(\[ \]*)(\[0-9\]+):(\[ \]*)(\[0-9\]+)(\[ \]+)21(\[ \]+)OBJECT(\[ \]+)GLOBAL(\[ \]+)DEFAULT(\[ \]+)(\[0-9\]+)(\[ \]+)_?foo1" $exec_output] } { |
| 129 | verbose $exec_output |
| 130 | fail $testname |
| 131 | return 0 |
| 132 | } |
| 133 | |
| 134 | return 1 |
| 135 | } |
| 136 | |
| 137 | proc stt_common_test { options testname } { |
| 138 | global exec_output |
| 139 | global READELF |
| 140 | global ld |
| 141 | |
| 142 | set options "$options tmpdir/common1a.o" |
| 143 | |
| 144 | if { ! [ld_simple_link $ld tmpdir/common.exe $options] } { |
| 145 | unresolved $testname |
| 146 | return 0 |
| 147 | } |
| 148 | |
| 149 | send_log "$READELF --syms tmpdir/common.exe | grep foo\n" |
| 150 | set exec_output [run_host_cmd "$READELF" "--syms tmpdir/common.exe | grep foo"] |
| 151 | |
| 152 | if {![regexp "(\[ \]*)(\[0-9\]+):(\[ \]*)(\[0-9\]+)(\[ \]+)(\[0-9\]+)(\[ \]+)COMMON(\[ \]+)GLOBAL(\[ \]+)DEFAULT(\[ \]+)(\[0-9\]+)(\[ \]+)_?foo2" $exec_output] } { |
| 153 | fail $testname |
| 154 | return 0 |
| 155 | } |
| 156 | |
| 157 | pass $testname |
| 158 | return 1 |
| 159 | } |
| 160 | |
| 161 | # Check to see if the assembler is generating symbols with the STT_COMMON type. |
| 162 | proc assembler_generates_commons {} { |
| 163 | global exec_output |
| 164 | global READELF |
| 165 | |
| 166 | verbose "Check to see if STT_COMMON symbols are being generated:" |
| 167 | set exec_output [run_host_cmd "$READELF" "--syms tmpdir/common1a.o | grep foo"] |
| 168 | |
| 169 | if { ![regexp "(\[ \]*)(\[0-9\]+):(\[ \]*)(\[0\]*)80(\[ \]+).(\[ \]+)COMMON(\[ \]+)GLOBAL(\[ \]+)DEFAULT(\[ \]+)(PRC\\\[0xff03\\\]|COM|SCOM)(\[ \]+)_?foo2" $exec_output] } { |
| 170 | verbose "STT_COMMON not generated" |
| 171 | return 0 |
| 172 | } |
| 173 | |
| 174 | verbose "STT_COMMON's are generated" |
| 175 | return 1 |
| 176 | } |
| 177 | |
| 178 | |
| 179 | if { ![ld_compile "$CC $CFLAGS" $srcdir/$subdir/common1a.c tmpdir/common1a.o] |
| 180 | || ![ld_compile "$CC $CFLAGS" $srcdir/$subdir/common1b.c tmpdir/common1b.o] } { |
| 181 | unresolved $test1 |
| 182 | return |
| 183 | } |
| 184 | |
| 185 | global ld |
| 186 | global link_output |
| 187 | |
| 188 | if { [ld_simple_link $ld tmpdir/common1.o "-r tmpdir/common1a.o tmpdir/common1b.o"] } { |
| 189 | unresolved $test1w1 |
| 190 | return |
| 191 | } |
| 192 | |
| 193 | # This test fails on MIPS because the backend sets type_change_ok. |
| 194 | # The size change warning is suppressed. |
| 195 | if {[istarget mips*-*-*]} { |
| 196 | if { ![regexp "Warning: alignment (\[0-9\]+) of symbol \`_?foo1\' in tmpdir/common1b.o is smaller than 64 in tmpdir/common1a.o" $link_output] } { |
| 197 | fail $test1w1 |
| 198 | } else { |
| 199 | pass $test1w1 |
| 200 | } |
| 201 | } else { |
| 202 | if { ![regexp "Warning: alignment (\[0-9\]+) of symbol \`_?foo1\' in tmpdir/common1b.o is smaller than 64 in tmpdir/common1a.o" $link_output] |
| 203 | || ![regexp "Warning: size of symbol \`_?foo1\' changed from 2 in tmpdir/common1a.o to 21 in tmpdir/common1b.o" $link_output] } { |
| 204 | fail $test1w1 |
| 205 | } else { |
| 206 | pass $test1w1 |
| 207 | } |
| 208 | } |
| 209 | |
| 210 | if { [dump_common1 $test1c1] } { |
| 211 | pass $test1c1 |
| 212 | } |
| 213 | |
| 214 | if { [ld_simple_link $ld tmpdir/common1.o "-r tmpdir/common1b.o tmpdir/common1a.o"] } { |
| 215 | unresolved $test1w2 |
| 216 | return |
| 217 | } |
| 218 | |
| 219 | if { ![regexp "Warning: alignment (\[0-9\]+) of symbol \`_?foo1\' in tmpdir/common1b.o is smaller than 64 in tmpdir/common1a.o" $link_output] } { |
| 220 | fail $test1w2 |
| 221 | } else { |
| 222 | pass $test1w2 |
| 223 | } |
| 224 | |
| 225 | if { [dump_common1 $test1c2] } { |
| 226 | pass $test1c2 |
| 227 | } |
| 228 | |
| 229 | # |
| 230 | # The following tests are for when we are generating STT_COMMON symbols only. |
| 231 | # |
| 232 | |
| 233 | if { ![assembler_generates_commons] } { |
| 234 | return |
| 235 | } |
| 236 | |
| 237 | stt_common_test "-static -e 0" "static link of common symbols" |
| 238 | stt_common_test "-shared" "shared link of common symbols" |
| 239 | stt_common_test "-pie" "position independent link of common symbols" |
| 240 | |