| 1 | dnl Process this file with autoconf to produce a configure script |
| 2 | |
| 3 | AC_PREREQ(2.59) |
| 4 | AC_INIT |
| 5 | AC_CONFIG_SRCDIR([xmalloc.c]) |
| 6 | |
| 7 | # This works around the fact that libtool configuration may change LD |
| 8 | # for this particular configuration, but some shells, instead of |
| 9 | # keeping the changes in LD private, export them just because LD is |
| 10 | # exported. We don't use libtool yet, but some day we might, so... |
| 11 | ORIGINAL_LD_FOR_MULTILIBS=$LD |
| 12 | |
| 13 | dnl We use these options to decide which functions to include. |
| 14 | AC_ARG_WITH(target-subdir, |
| 15 | [ --with-target-subdir=SUBDIR Configuring in a subdirectory for target]) |
| 16 | AC_ARG_WITH(build-subdir, |
| 17 | [ --with-build-subdir=SUBDIR Configuring in a subdirectory for build]) |
| 18 | AC_ARG_WITH(cross-host, |
| 19 | [ --with-cross-host=HOST Configuring with a cross compiler]) |
| 20 | AC_ARG_WITH(newlib, |
| 21 | [ --with-newlib Configuring with newlib]) |
| 22 | |
| 23 | if test "${srcdir}" = "."; then |
| 24 | if test -n "${with_build_subdir}"; then |
| 25 | libiberty_topdir="${srcdir}/../.." |
| 26 | with_target_subdir= |
| 27 | elif test -z "${with_target_subdir}"; then |
| 28 | libiberty_topdir="${srcdir}/.." |
| 29 | else |
| 30 | if test "${with_target_subdir}" != "."; then |
| 31 | libiberty_topdir="${srcdir}/${with_multisrctop}../.." |
| 32 | else |
| 33 | libiberty_topdir="${srcdir}/${with_multisrctop}.." |
| 34 | fi |
| 35 | fi |
| 36 | else |
| 37 | libiberty_topdir="${srcdir}/.." |
| 38 | fi |
| 39 | AC_SUBST(libiberty_topdir) |
| 40 | AC_CONFIG_AUX_DIR($libiberty_topdir) |
| 41 | |
| 42 | dnl Very limited version of automake's enable-maintainer-mode |
| 43 | |
| 44 | AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles]) |
| 45 | dnl maintainer-mode is disabled by default |
| 46 | AC_ARG_ENABLE(maintainer-mode, |
| 47 | [ --enable-maintainer-mode |
| 48 | enable make rules and dependencies not useful |
| 49 | (and sometimes confusing) to the casual installer], |
| 50 | maintainer_mode=$enableval, |
| 51 | maintainer_mode=no) |
| 52 | |
| 53 | AC_MSG_RESULT($maintainer_mode) |
| 54 | |
| 55 | if test "$maintainer_mode" = "yes"; then |
| 56 | MAINT='' |
| 57 | NOTMAINT='#' |
| 58 | else |
| 59 | MAINT='#' |
| 60 | NOTMAINT='' |
| 61 | fi |
| 62 | AC_SUBST(MAINT)dnl |
| 63 | AC_SUBST(NOTMAINT)dnl |
| 64 | |
| 65 | # Do we have a single-tree copy of texinfo? Even if we do, we can't |
| 66 | # rely on it - libiberty is built before texinfo. |
| 67 | AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ) |
| 68 | if test "x$MAKEINFO" = "x"; then |
| 69 | MAKEINFO="@echo makeinfo missing; true" |
| 70 | BUILD_INFO= |
| 71 | else |
| 72 | BUILD_INFO=info |
| 73 | case "$MAKEINFO" in |
| 74 | */missing\ makeinfo*) |
| 75 | BUILD_INFO= |
| 76 | AC_MSG_WARN([ |
| 77 | *** Makeinfo is missing. Info documentation will not be built.]) |
| 78 | ;; |
| 79 | *) |
| 80 | case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in |
| 81 | x*\ [[1-3]].* ) |
| 82 | MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true" |
| 83 | BUILD_INFO= |
| 84 | AC_MSG_WARN([ |
| 85 | *** Makeinfo is too old. Info documentation will not be built.]) |
| 86 | ;; |
| 87 | esac |
| 88 | ;; |
| 89 | esac |
| 90 | fi |
| 91 | AC_SUBST(MAKEINFO) |
| 92 | AC_SUBST(BUILD_INFO) |
| 93 | |
| 94 | AC_CHECK_PROG(PERL, perl, perl, ) |
| 95 | if test x"$PERL" = x""; then |
| 96 | HAVE_PERL='#' |
| 97 | else |
| 98 | HAVE_PERL='' |
| 99 | fi |
| 100 | AC_SUBST(HAVE_PERL) |
| 101 | |
| 102 | AC_CANONICAL_HOST |
| 103 | |
| 104 | dnl When we start using automake: |
| 105 | dnl AM_INIT_AUTOMAKE(libiberty, 1.0) |
| 106 | |
| 107 | dnl These must be called before AM_PROG_LIBTOOL, because it may want |
| 108 | dnl to call AC_CHECK_PROG. |
| 109 | AC_CHECK_TOOL(AR, ar) |
| 110 | AC_CHECK_TOOL(RANLIB, ranlib, :) |
| 111 | |
| 112 | GCC_NO_EXECUTABLES |
| 113 | AC_PROG_CC |
| 114 | AC_PROG_CPP_WERROR |
| 115 | |
| 116 | if test x$GCC = xyes; then |
| 117 | ac_libiberty_warn_cflags='-W -Wall -pedantic -Wwrite-strings -Wstrict-prototypes' |
| 118 | fi |
| 119 | AC_SUBST(ac_libiberty_warn_cflags) |
| 120 | |
| 121 | AC_PROG_CC_C_O |
| 122 | # autoconf is lame and doesn't give us any substitution variable for this. |
| 123 | if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then |
| 124 | NO_MINUS_C_MINUS_O=yes |
| 125 | else |
| 126 | OUTPUT_OPTION='-o $@' |
| 127 | fi |
| 128 | AC_SUBST(NO_MINUS_C_MINUS_O) |
| 129 | AC_SUBST(OUTPUT_OPTION) |
| 130 | |
| 131 | AC_C_CONST |
| 132 | AC_C_INLINE |
| 133 | AC_C_BIGENDIAN_CROSS |
| 134 | |
| 135 | dnl When we start using libtool: |
| 136 | dnl Default to a non shared library. This may be overridden by the |
| 137 | dnl configure option --enable-shared. |
| 138 | dnl AM_DISABLE_SHARED |
| 139 | |
| 140 | dnl When we start using libtool: |
| 141 | dnl AM_PROG_LIBTOOL |
| 142 | |
| 143 | dnl When we start using automake: |
| 144 | dnl AM_CONFIG_HEADER(config.h:config.in) |
| 145 | AC_CONFIG_HEADER(config.h:config.in) |
| 146 | |
| 147 | dnl When we start using automake: |
| 148 | dnl AM_MAINTAINER_MODE |
| 149 | dnl AC_EXEEXT |
| 150 | |
| 151 | dnl When we start using automake: |
| 152 | dnl AM_PROG_INSTALL |
| 153 | AC_PROG_INSTALL |
| 154 | |
| 155 | . ${srcdir}/config.table |
| 156 | host_makefile_frag=${frag} |
| 157 | AC_SUBST_FILE(host_makefile_frag) |
| 158 | |
| 159 | # It's OK to check for header files. Although the compiler may not be |
| 160 | # able to link anything, it had better be able to at least compile |
| 161 | # something. |
| 162 | AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h) |
| 163 | AC_HEADER_SYS_WAIT |
| 164 | AC_HEADER_TIME |
| 165 | |
| 166 | libiberty_AC_DECLARE_ERRNO |
| 167 | |
| 168 | # Determine the size of an int for struct fibnode. |
| 169 | AC_CHECK_SIZEOF([int]) |
| 170 | |
| 171 | AC_CHECK_TYPE(uintptr_t, unsigned long) |
| 172 | |
| 173 | # Look for a 64-bit type. |
| 174 | AC_MSG_CHECKING([for a 64-bit type]) |
| 175 | AC_CACHE_VAL(liberty_cv_uint64, |
| 176 | [AC_TRY_COMPILE( |
| 177 | [#ifdef HAVE_STDINT_H |
| 178 | #include <stdint.h> |
| 179 | #endif], |
| 180 | [extern uint64_t foo;], |
| 181 | liberty_cv_uint64=uint64_t, |
| 182 | [AC_TRY_COMPILE( |
| 183 | [#ifdef HAVE_LIMITS_H |
| 184 | #include <limits.h> |
| 185 | #endif |
| 186 | #ifndef CHAR_BIT |
| 187 | #define CHAR_BIT 8 |
| 188 | #endif], |
| 189 | [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];], |
| 190 | liberty_cv_uint64="unsigned long", |
| 191 | [AC_TRY_COMPILE( |
| 192 | [#ifdef HAVE_LIMITS_H |
| 193 | #include <limits.h> |
| 194 | #endif |
| 195 | #ifndef CHAR_BIT |
| 196 | #define CHAR_BIT 8 |
| 197 | #endif], |
| 198 | [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];], |
| 199 | liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])]) |
| 200 | AC_MSG_RESULT($liberty_cv_uint64) |
| 201 | if test "$liberty_cv_uint64" != none; then |
| 202 | AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64, |
| 203 | [Define to an unsigned 64-bit type available in the compiler.]) |
| 204 | fi |
| 205 | |
| 206 | # Given the above check, we always have uintptr_t or a fallback |
| 207 | # definition. So define HAVE_UINTPTR_T in case any imported code |
| 208 | # relies on it. |
| 209 | AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.]) |
| 210 | |
| 211 | AC_TYPE_PID_T |
| 212 | |
| 213 | # This is the list of functions which libiberty will provide if they |
| 214 | # are not available on the host. |
| 215 | |
| 216 | funcs="asprintf" |
| 217 | funcs="$funcs atexit" |
| 218 | funcs="$funcs basename" |
| 219 | funcs="$funcs bcmp" |
| 220 | funcs="$funcs bcopy" |
| 221 | funcs="$funcs bsearch" |
| 222 | funcs="$funcs bzero" |
| 223 | funcs="$funcs calloc" |
| 224 | funcs="$funcs clock" |
| 225 | funcs="$funcs ffs" |
| 226 | funcs="$funcs getcwd" |
| 227 | funcs="$funcs getpagesize" |
| 228 | funcs="$funcs gettimeofday" |
| 229 | funcs="$funcs index" |
| 230 | funcs="$funcs insque" |
| 231 | funcs="$funcs memchr" |
| 232 | funcs="$funcs memcmp" |
| 233 | funcs="$funcs memcpy" |
| 234 | funcs="$funcs memmove" |
| 235 | funcs="$funcs mempcpy" |
| 236 | funcs="$funcs memset" |
| 237 | funcs="$funcs mkstemps" |
| 238 | funcs="$funcs putenv" |
| 239 | funcs="$funcs random" |
| 240 | funcs="$funcs rename" |
| 241 | funcs="$funcs rindex" |
| 242 | funcs="$funcs setenv" |
| 243 | funcs="$funcs snprintf" |
| 244 | funcs="$funcs sigsetmask" |
| 245 | funcs="$funcs stpcpy" |
| 246 | funcs="$funcs stpncpy" |
| 247 | funcs="$funcs strcasecmp" |
| 248 | funcs="$funcs strchr" |
| 249 | funcs="$funcs strdup" |
| 250 | funcs="$funcs strncasecmp" |
| 251 | funcs="$funcs strndup" |
| 252 | funcs="$funcs strrchr" |
| 253 | funcs="$funcs strstr" |
| 254 | funcs="$funcs strtod" |
| 255 | funcs="$funcs strtol" |
| 256 | funcs="$funcs strtoul" |
| 257 | funcs="$funcs tmpnam" |
| 258 | funcs="$funcs vasprintf" |
| 259 | funcs="$funcs vfprintf" |
| 260 | funcs="$funcs vprintf" |
| 261 | funcs="$funcs vsnprintf" |
| 262 | funcs="$funcs vsprintf" |
| 263 | funcs="$funcs waitpid" |
| 264 | |
| 265 | # Also in the old function.def file: alloca, vfork, getopt. |
| 266 | |
| 267 | vars="sys_errlist sys_nerr sys_siglist" |
| 268 | |
| 269 | checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday" |
| 270 | checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp" |
| 271 | checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking" |
| 272 | |
| 273 | # These are neither executed nor required, but they help keep |
| 274 | # autoheader happy without adding a bunch of text to acconfig.h. |
| 275 | if test "x" = "y"; then |
| 276 | AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \ |
| 277 | getcwd getpagesize gettimeofday index insque mkstemps memchr memcmp memcpy \ |
| 278 | memmove mempcpy memset putenv random rename rindex sigsetmask \ |
| 279 | strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strndup strrchr strstr \ |
| 280 | strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \ |
| 281 | vsprintf waitpid getrusage on_exit psignal strerror strsignal \ |
| 282 | sysconf times sbrk gettimeofday ffs snprintf vsnprintf \ |
| 283 | pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl wait3 wait4 \ |
| 284 | realpath canonicalize_file_name __fsetlocking) |
| 285 | AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf]) |
| 286 | AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.]) |
| 287 | AC_DEFINE(HAVE_SYS_NERR, 1, [Define if you have the sys_nerr variable.]) |
| 288 | AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.]) |
| 289 | fi |
| 290 | |
| 291 | # For each of these functions, if the host does not provide the |
| 292 | # function we want to put FN.o in LIBOBJS, and if the host does |
| 293 | # provide the function, we want to define HAVE_FN in config.h. |
| 294 | |
| 295 | setobjs= |
| 296 | CHECK= |
| 297 | target_header_dir= |
| 298 | if test -n "${with_target_subdir}"; then |
| 299 | |
| 300 | # We are being configured as a target library. AC_REPLACE_FUNCS |
| 301 | # may not work correctly, because the compiler may not be able to |
| 302 | # link executables. Note that we may still be being configured |
| 303 | # native. |
| 304 | |
| 305 | # If we are being configured for newlib, we know which functions |
| 306 | # newlib provide and which ones we will be expected to provide. |
| 307 | |
| 308 | if test "x${with_newlib}" = "xyes"; then |
| 309 | AC_LIBOBJ([asprintf]) |
| 310 | AC_LIBOBJ([basename]) |
| 311 | AC_LIBOBJ([insque]) |
| 312 | AC_LIBOBJ([random]) |
| 313 | AC_LIBOBJ([strdup]) |
| 314 | AC_LIBOBJ([vasprintf]) |
| 315 | |
| 316 | for f in $funcs; do |
| 317 | case "$f" in |
| 318 | asprintf | basename | insque | random | strdup | vasprintf) |
| 319 | ;; |
| 320 | *) |
| 321 | n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'` |
| 322 | AC_DEFINE_UNQUOTED($n) |
| 323 | ;; |
| 324 | esac |
| 325 | done |
| 326 | |
| 327 | # newlib doesnt provide any of the variables in $vars, so we |
| 328 | # dont have to check them here. |
| 329 | |
| 330 | # Of the functions in $checkfuncs, newlib only has strerror. |
| 331 | AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR) |
| 332 | |
| 333 | setobjs=yes |
| 334 | |
| 335 | fi |
| 336 | |
| 337 | # We may wish to install the target headers somewhere. |
| 338 | AC_ARG_ENABLE(install-libiberty, |
| 339 | [ --enable-install-libiberty Install headers for end users], |
| 340 | enable_install_libiberty=$enableval, |
| 341 | enable_install_libiberty=no)dnl |
| 342 | |
| 343 | # Option parsed, now set things appropriately. |
| 344 | case x"$enable_install_libiberty" in |
| 345 | xyes|x) |
| 346 | target_header_dir=libiberty |
| 347 | ;; |
| 348 | xno) |
| 349 | target_header_dir= |
| 350 | ;; |
| 351 | *) |
| 352 | # This could be sanity-checked in various ways... |
| 353 | target_header_dir="${enable_install_libiberty}" |
| 354 | ;; |
| 355 | esac |
| 356 | |
| 357 | |
| 358 | else |
| 359 | |
| 360 | # Not a target library, so we set things up to run the test suite. |
| 361 | CHECK=really-check |
| 362 | |
| 363 | fi |
| 364 | |
| 365 | AC_SUBST(CHECK) |
| 366 | AC_SUBST(target_header_dir) |
| 367 | |
| 368 | case "${host}" in |
| 369 | *-*-cygwin* | *-*-mingw*) |
| 370 | AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST) |
| 371 | AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR) |
| 372 | ;; |
| 373 | esac |
| 374 | |
| 375 | if test -z "${setobjs}"; then |
| 376 | case "${host}" in |
| 377 | |
| 378 | *-*-vxworks*) |
| 379 | # Handle VxWorks configuration specially, since on VxWorks the |
| 380 | # libraries are actually on the target board, not in the file |
| 381 | # system. |
| 382 | AC_LIBOBJ([basename]) |
| 383 | AC_LIBOBJ([getpagesize]) |
| 384 | AC_LIBOBJ([insque]) |
| 385 | AC_LIBOBJ([random]) |
| 386 | AC_LIBOBJ([strcasecmp]) |
| 387 | AC_LIBOBJ([strncasecmp]) |
| 388 | AC_LIBOBJ([strdup]) |
| 389 | AC_LIBOBJ([vfork]) |
| 390 | AC_LIBOBJ([waitpid]) |
| 391 | AC_LIBOBJ([vasprintf]) |
| 392 | for f in $funcs; do |
| 393 | case "$f" in |
| 394 | basename | getpagesize | insque | random | strcasecmp) |
| 395 | ;; |
| 396 | strncasecmp | strdup | vfork | waitpid | vasprintf) |
| 397 | ;; |
| 398 | *) |
| 399 | n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'` |
| 400 | AC_DEFINE_UNQUOTED($n) |
| 401 | ;; |
| 402 | esac |
| 403 | done |
| 404 | |
| 405 | # VxWorks doesn't provide any of the variables in $vars, so we |
| 406 | # don't have to check them here. |
| 407 | |
| 408 | # Of the functions in $checkfuncs, VxWorks only has strerror. |
| 409 | AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR) |
| 410 | |
| 411 | setobjs=yes |
| 412 | ;; |
| 413 | |
| 414 | esac |
| 415 | fi |
| 416 | |
| 417 | if test -z "${setobjs}"; then |
| 418 | |
| 419 | case "${host}" in |
| 420 | |
| 421 | *-*-cygwin*) |
| 422 | # The Cygwin library actually uses a couple of files from |
| 423 | # libiberty when it is built. If we are building a native |
| 424 | # Cygwin, and we run the tests, we will appear to have these |
| 425 | # files. However, when we go on to build winsup, we will wind up |
| 426 | # with a library which does not have the files, since they should |
| 427 | # have come from libiberty. |
| 428 | |
| 429 | # We handle this by removing the functions the winsup library |
| 430 | # provides from our shell variables, so that they appear to be |
| 431 | # missing. |
| 432 | |
| 433 | # DJ - only if we're *building* cygwin, not just building *with* cygwin |
| 434 | |
| 435 | if test -n "${with_target_subdir}" |
| 436 | then |
| 437 | funcs="`echo $funcs | sed -e 's/random//'`" |
| 438 | AC_LIBOBJ([random]) |
| 439 | vars="`echo $vars | sed -e 's/sys_siglist//'`" |
| 440 | checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`" |
| 441 | fi |
| 442 | ;; |
| 443 | |
| 444 | *-*-mingw32*) |
| 445 | # Under mingw32, sys_nerr and sys_errlist exist, but they are |
| 446 | # macros, so the test below won't find them. |
| 447 | libiberty_cv_var_sys_nerr=yes |
| 448 | libiberty_cv_var_sys_errlist=yes |
| 449 | ;; |
| 450 | |
| 451 | *-*-msdosdjgpp*) |
| 452 | # vfork and fork are stubs. |
| 453 | ac_cv_func_vfork_works=no |
| 454 | ;; |
| 455 | |
| 456 | *-*-uwin*) |
| 457 | # Under some versions of uwin, vfork is notoriously buggy and the test |
| 458 | # can hang configure; on other versions, vfork exists just as a stub. |
| 459 | # FIXME: This should be removed once vfork in uwin's runtime is fixed. |
| 460 | ac_cv_func_vfork_works=no |
| 461 | # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are |
| 462 | # macros (actually, these are imported from a DLL, but the end effect |
| 463 | # is the same), so the test below won't find them. |
| 464 | libiberty_cv_var_sys_nerr=yes |
| 465 | libiberty_cv_var_sys_errlist=yes |
| 466 | ;; |
| 467 | |
| 468 | *-*-*vms*) |
| 469 | # Under VMS, vfork works very different than on Unix. The standard test |
| 470 | # won't work, and it isn't easily adaptable. It makes more sense to |
| 471 | # just force it. |
| 472 | ac_cv_func_vfork_works=yes |
| 473 | ;; |
| 474 | |
| 475 | esac |
| 476 | |
| 477 | # We haven't set the list of objects yet. Use the standard autoconf |
| 478 | # tests. This will only work if the compiler works. |
| 479 | AC_ISC_POSIX |
| 480 | AC_REPLACE_FUNCS($funcs) |
| 481 | libiberty_AC_FUNC_C_ALLOCA |
| 482 | AC_FUNC_FORK |
| 483 | if test $ac_cv_func_vfork_works = no; then |
| 484 | AC_LIBOBJ([vfork]) |
| 485 | fi |
| 486 | # We only need _doprnt if we might use it to implement v*printf. |
| 487 | if test $ac_cv_func_vprintf != yes \ |
| 488 | || test $ac_cv_func_vfprintf != yes \ |
| 489 | || test $ac_cv_func_vsprintf != yes; then |
| 490 | AC_REPLACE_FUNCS(_doprnt) |
| 491 | else |
| 492 | AC_CHECK_FUNCS(_doprnt) |
| 493 | fi |
| 494 | |
| 495 | for v in $vars; do |
| 496 | AC_MSG_CHECKING([for $v]) |
| 497 | AC_CACHE_VAL(libiberty_cv_var_$v, |
| 498 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])], |
| 499 | [eval "libiberty_cv_var_$v=yes"], |
| 500 | [eval "libiberty_cv_var_$v=no"])]) |
| 501 | if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then |
| 502 | AC_MSG_RESULT(yes) |
| 503 | n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'` |
| 504 | AC_DEFINE_UNQUOTED($n) |
| 505 | else |
| 506 | AC_MSG_RESULT(no) |
| 507 | fi |
| 508 | done |
| 509 | |
| 510 | # special check for _system_configuration because AIX <4.3.2 do not |
| 511 | # contain the `physmem' member. |
| 512 | AC_MSG_CHECKING([for external symbol _system_configuration]) |
| 513 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]], |
| 514 | [[double x = _system_configuration.physmem;]])], |
| 515 | [AC_MSG_RESULT([yes]) |
| 516 | AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1, |
| 517 | [Define if you have the _system_configuration variable.])], |
| 518 | [AC_MSG_RESULT([no])]) |
| 519 | |
| 520 | AC_CHECK_FUNCS($checkfuncs) |
| 521 | AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf]) |
| 522 | libiberty_NEED_DECLARATION(canonicalize_file_name) |
| 523 | fi |
| 524 | |
| 525 | # Figure out which version of pexecute to use. |
| 526 | case "${host}" in |
| 527 | *-*-mingw* | *-*-winnt*) pexecute=./pex-win32.o ;; |
| 528 | *-*-msdosdjgpp*) pexecute=./pex-djgpp.o ;; |
| 529 | *-*-msdos*) pexecute=./pex-msdos.o ;; |
| 530 | *) pexecute=./pex-unix.o ;; |
| 531 | esac |
| 532 | AC_SUBST(pexecute) |
| 533 | |
| 534 | libiberty_AC_FUNC_STRNCMP |
| 535 | |
| 536 | # Install a library built with a cross compiler in $(tooldir) rather |
| 537 | # than $(libdir). |
| 538 | if test -z "${with_cross_host}"; then |
| 539 | INSTALL_DEST=libdir |
| 540 | else |
| 541 | INSTALL_DEST=tooldir |
| 542 | fi |
| 543 | AC_SUBST(INSTALL_DEST) |
| 544 | |
| 545 | m4_pattern_allow(LIBOBJS) |
| 546 | L="" |
| 547 | for l in x $LIBOBJS; do |
| 548 | case $l in |
| 549 | x) ;; |
| 550 | *) L="$L ./$l" ;; |
| 551 | esac |
| 552 | done |
| 553 | LIBOBJS="$L" |
| 554 | |
| 555 | # We need multilib support, but only if configuring for the target. |
| 556 | AC_CONFIG_FILES([Makefile testsuite/Makefile]) |
| 557 | AC_CONFIG_COMMANDS([default], |
| 558 | [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h |
| 559 | if test -n "$CONFIG_FILES"; then |
| 560 | if test -n "${with_target_subdir}"; then |
| 561 | # FIXME: We shouldn't need to set ac_file |
| 562 | ac_file=Makefile |
| 563 | LD="${ORIGINAL_LD_FOR_MULTILIBS}" |
| 564 | . ${libiberty_topdir}/config-ml.in |
| 565 | fi |
| 566 | fi]], |
| 567 | [[srcdir=${srcdir} |
| 568 | host=${host} |
| 569 | target=${target} |
| 570 | with_target_subdir=${with_target_subdir} |
| 571 | with_multisubdir=${with_multisubdir} |
| 572 | ac_configure_args="--enable-multilib ${ac_configure_args}" |
| 573 | CONFIG_SHELL=${CONFIG_SHELL-/bin/sh} |
| 574 | ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}" |
| 575 | libiberty_topdir=${libiberty_topdir} |
| 576 | ]]) |
| 577 | AC_OUTPUT |