| 1 | #!/usr/bin/perl -w |
| 2 | # |
| 3 | # headers_install prepare the listed header files for use in |
| 4 | # user space and copy the files to their destination. |
| 5 | # |
| 6 | # Usage: headers_install.pl readdir installdir arch [files...] |
| 7 | # readdir: dir to open files |
| 8 | # installdir: dir to install the files |
| 9 | # arch: current architecture |
| 10 | # arch is used to force a reinstallation when the arch |
| 11 | # changes because kbuild then detect a command line change. |
| 12 | # files: list of files to check |
| 13 | # |
| 14 | # Step in preparation for users space: |
| 15 | # 1) Drop all use of compiler.h definitions |
| 16 | # 2) Drop include of compiler.h |
| 17 | # 3) Drop all sections defined out by __KERNEL__ (using unifdef) |
| 18 | |
| 19 | use strict; |
| 20 | |
| 21 | my ($readdir, $installdir, $arch, @files) = @ARGV; |
| 22 | |
| 23 | my $unifdef = "scripts/unifdef -U__KERNEL__ -D__EXPORTED_HEADERS__"; |
| 24 | |
| 25 | foreach my $file (@files) { |
| 26 | my $tmpfile = "$installdir/$file.tmp"; |
| 27 | |
| 28 | open(my $in, '<', "$readdir/$file") |
| 29 | or die "$readdir/$file: $!\n"; |
| 30 | open(my $out, '>', $tmpfile) |
| 31 | or die "$tmpfile: $!\n"; |
| 32 | while (my $line = <$in>) { |
| 33 | $line =~ s/([\s(])__user\s/$1/g; |
| 34 | $line =~ s/([\s(])__force\s/$1/g; |
| 35 | $line =~ s/([\s(])__iomem\s/$1/g; |
| 36 | $line =~ s/\s__attribute_const__\s/ /g; |
| 37 | $line =~ s/\s__attribute_const__$//g; |
| 38 | $line =~ s/\b__packed\b/__attribute__((packed))/g; |
| 39 | $line =~ s/^#include <linux\/compiler.h>//; |
| 40 | $line =~ s/(^|\s)(inline)\b/$1__$2__/g; |
| 41 | $line =~ s/(^|\s)(asm)\b(\s|[(]|$)/$1__$2__$3/g; |
| 42 | $line =~ s/(^|\s|[(])(volatile)\b(\s|[(]|$)/$1__$2__$3/g; |
| 43 | printf {$out} "%s", $line; |
| 44 | } |
| 45 | close $out; |
| 46 | close $in; |
| 47 | |
| 48 | system $unifdef . " $tmpfile > $installdir/$file"; |
| 49 | # unifdef will exit 0 on success, and will exit 1 when the |
| 50 | # file was processed successfully but no changes were made, |
| 51 | # so abort only when it's higher than that. |
| 52 | my $e = $? >> 8; |
| 53 | if ($e > 1) { |
| 54 | die "$tmpfile: $!\n"; |
| 55 | } |
| 56 | unlink $tmpfile; |
| 57 | } |
| 58 | exit 0; |