arch/sparc64/lib/GENbzero.S

   1 /* GENbzero.S: Generic sparc64 memset/clear_user.
   2  *
   3  * Copyright (C) 2007 David S. Miller (davem@davemloft.net)
   4  */
   5 #include <asm/asi.h>
   6
   7 #define EX_ST(x,y)              \
   8 98:     x,y;                    \
   9         .section .fixup;        \
  10         .align 4;               \
  11 99:     retl;                   \
  12          mov    %o1, %o0;       \
  13         .section __ex_table,"a";\
  14         .align 4;               \
  15         .word 98b, 99b;         \
  16         .text;                  \
  17         .align 4;
  18
  19         .align  32
  20         .text
  21
  22         .globl          GENmemset
  23         .type           GENmemset, #function
  24 GENmemset:              /* %o0=buf, %o1=pat, %o2=len */
  25         and             %o1, 0xff, %o3
  26         mov             %o2, %o1
  27         sllx            %o3, 8, %g1
  28         or              %g1, %o3, %o2
  29         sllx            %o2, 16, %g1
  30         or              %g1, %o2, %o2
  31         sllx            %o2, 32, %g1
  32         ba,pt           %xcc, 1f
  33          or             %g1, %o2, %o2
  34
  35         .globl          GENbzero
  36         .type           GENbzero, #function
  37 GENbzero:
  38         clr             %o2
  39 1:      brz,pn          %o1, GENbzero_return
  40          mov            %o0, %o3
  41
  42         /* %o5: saved %asi, restored at GENbzero_done
  43          * %o4: store %asi to use
  44          */
  45         rd              %asi, %o5
  46         mov             ASI_P, %o4
  47         wr              %o4, 0x0, %asi
  48
  49 GENbzero_from_clear_user:
  50         cmp             %o1, 15
  51         bl,pn           %icc, GENbzero_tiny
  52          andcc          %o0, 0x7, %g1
  53         be,pt           %xcc, 2f
  54          mov            8, %g2
  55         sub             %g2, %g1, %g1
  56         sub             %o1, %g1, %o1
  57 1:      EX_ST(stba %o2, [%o0 + 0x00] %asi)
  58         subcc           %g1, 1, %g1
  59         bne,pt          %xcc, 1b
  60          add            %o0, 1, %o0
  61 2:      cmp             %o1, 128
  62         bl,pn           %icc, GENbzero_medium
  63          andcc          %o0, (64 - 1), %g1
  64         be,pt           %xcc, GENbzero_pre_loop
  65          mov            64, %g2
  66         sub             %g2, %g1, %g1
  67         sub             %o1, %g1, %o1
  68 1:      EX_ST(stxa %o2, [%o0 + 0x00] %asi)
  69         subcc           %g1, 8, %g1
  70         bne,pt          %xcc, 1b
  71          add            %o0, 8, %o0
  72
  73 GENbzero_pre_loop:
  74         andn            %o1, (64 - 1), %g1
  75         sub             %o1, %g1, %o1
  76 GENbzero_loop:
  77         EX_ST(stxa %o2, [%o0 + 0x00] %asi)
  78         EX_ST(stxa %o2, [%o0 + 0x08] %asi)
  79         EX_ST(stxa %o2, [%o0 + 0x10] %asi)
  80         EX_ST(stxa %o2, [%o0 + 0x18] %asi)
  81         EX_ST(stxa %o2, [%o0 + 0x20] %asi)
  82         EX_ST(stxa %o2, [%o0 + 0x28] %asi)
  83         EX_ST(stxa %o2, [%o0 + 0x30] %asi)
  84         EX_ST(stxa %o2, [%o0 + 0x38] %asi)
  85         subcc           %g1, 64, %g1
  86         bne,pt          %xcc, GENbzero_loop
  87          add            %o0, 64, %o0
  88
  89         membar          #Sync
  90         wr              %o4, 0x0, %asi
  91         brz,pn          %o1, GENbzero_done
  92 GENbzero_medium:
  93          andncc         %o1, 0x7, %g1
  94         be,pn           %xcc, 2f
  95          sub            %o1, %g1, %o1
  96 1:      EX_ST(stxa %o2, [%o0 + 0x00] %asi)
  97         subcc           %g1, 8, %g1
  98         bne,pt          %xcc, 1b
  99          add            %o0, 8, %o0
 100 2:      brz,pt          %o1, GENbzero_done
 101          nop
 102
 103 GENbzero_tiny:
 104 1:      EX_ST(stba %o2, [%o0 + 0x00] %asi)
 105         subcc           %o1, 1, %o1
 106         bne,pt          %icc, 1b
 107          add            %o0, 1, %o0
 108
 109         /* fallthrough */
 110
 111 GENbzero_done:
 112         wr              %o5, 0x0, %asi
 113
 114 GENbzero_return:
 115         retl
 116          mov            %o3, %o0
 117         .size           GENbzero, .-GENbzero
 118         .size           GENmemset, .-GENmemset
 119
 120         .globl          GENclear_user
 121         .type           GENclear_user, #function
 122 GENclear_user:          /* %o0=buf, %o1=len */
 123         rd              %asi, %o5
 124         brz,pn          %o1, GENbzero_done
 125          clr            %o3
 126         cmp             %o5, ASI_AIUS
 127         bne,pn          %icc, GENbzero
 128          clr            %o2
 129         ba,pt           %xcc, GENbzero_from_clear_user
 130          mov            ASI_AIUS, %o4
 131         .size           GENclear_user, .-GENclear_user
 132
 133 #define BRANCH_ALWAYS   0x10680000
 134 #define NOP             0x01000000
 135 #define GEN_DO_PATCH(OLD, NEW)  \
 136         sethi   %hi(NEW), %g1; \
 137         or      %g1, %lo(NEW), %g1; \
 138         sethi   %hi(OLD), %g2; \
 139         or      %g2, %lo(OLD), %g2; \
 140         sub     %g1, %g2, %g1; \
 141         sethi   %hi(BRANCH_ALWAYS), %g3; \
 142         sll     %g1, 11, %g1; \
 143         srl     %g1, 11 + 2, %g1; \
 144         or      %g3, %lo(BRANCH_ALWAYS), %g3; \
 145         or      %g3, %g1, %g3; \
 146         stw     %g3, [%g2]; \
 147         sethi   %hi(NOP), %g3; \
 148         or      %g3, %lo(NOP), %g3; \
 149         stw     %g3, [%g2 + 0x4]; \
 150         flush   %g2;
 151
 152         .globl  generic_patch_bzero
 153         .type   generic_patch_bzero,#function
 154 generic_patch_bzero:
 155         GEN_DO_PATCH(memset, GENmemset)
 156         GEN_DO_PATCH(__bzero, GENbzero)
 157         GEN_DO_PATCH(__clear_user, GENclear_user)
 158         retl
 159          nop
 160         .size   generic_patch_bzero,.-generic_patch_bzero