arch/tile/kernel/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2 #include <asm/page.h>
   3 #include <asm/cache.h>
   4 #include <asm/thread_info.h>
   5 #include <hv/hypervisor.h>
   6
   7 /* Text loads starting from the supervisor interrupt vector address. */
   8 #define TEXT_OFFSET MEM_SV_START
   9
  10 OUTPUT_ARCH(tile)
  11 ENTRY(_start)
  12 jiffies = jiffies_64;
  13
  14 PHDRS
  15 {
  16   intrpt PT_LOAD ;
  17   text PT_LOAD ;
  18   data PT_LOAD ;
  19 }
  20 SECTIONS
  21 {
  22   /* Text is loaded with a different VA than data; start with text. */
  23   #undef LOAD_OFFSET
  24   #define LOAD_OFFSET TEXT_OFFSET
  25
  26   /* Interrupt vectors */
  27   .intrpt (LOAD_OFFSET) : AT ( 0 )   /* put at the start of physical memory */
  28   {
  29     _text = .;
  30     *(.intrpt)
  31   } :intrpt =0
  32
  33   /* Hypervisor call vectors */
  34   . = ALIGN(0x10000);
  35   .hvglue : AT (ADDR(.hvglue) - LOAD_OFFSET) {
  36     *(.hvglue)
  37   } :NONE
  38
  39   /* Now the real code */
  40   . = ALIGN(0x20000);
  41   _stext = .;
  42   .text : AT (ADDR(.text) - LOAD_OFFSET) {
  43     HEAD_TEXT
  44     SCHED_TEXT
  45     LOCK_TEXT
  46     KPROBES_TEXT
  47     IRQENTRY_TEXT
  48     SOFTIRQENTRY_TEXT
  49     __fix_text_end = .;   /* tile-cpack won't rearrange before this */
  50     ALIGN_FUNCTION();
  51     *(.hottext*)
  52     TEXT_TEXT
  53     *(.text.*)
  54     *(.coldtext*)
  55     *(.fixup)
  56     *(.gnu.warning)
  57   } :text =0
  58   _etext = .;
  59
  60   /* "Init" is divided into two areas with very different virtual addresses. */
  61   INIT_TEXT_SECTION(PAGE_SIZE)
  62
  63   /*
  64    * Some things, like the __jump_table, may contain symbol references
  65    * to __exit text, so include such text in the final image if so.
  66    * In that case we also override the _einittext from INIT_TEXT_SECTION.
  67    */
  68 #ifdef CONFIG_JUMP_LABEL
  69   .exit.text : {
  70     EXIT_TEXT
  71     _einittext = .;
  72   }
  73 #endif
  74
  75   /* Now we skip back to PAGE_OFFSET for the data. */
  76   . = (. - TEXT_OFFSET + PAGE_OFFSET);
  77   #undef LOAD_OFFSET
  78   #define LOAD_OFFSET PAGE_OFFSET
  79
  80   . = ALIGN(PAGE_SIZE);
  81   __init_begin = .;
  82   INIT_DATA_SECTION(16) :data =0
  83   PERCPU_SECTION(L2_CACHE_BYTES)
  84   . = ALIGN(PAGE_SIZE);
  85   __init_end = .;
  86
  87   _sdata = .;                   /* Start of data section */
  88   RO_DATA_SECTION(PAGE_SIZE)
  89   RW_DATA_SECTION(L2_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  90   _edata = .;
  91
  92   EXCEPTION_TABLE(L2_CACHE_BYTES)
  93   NOTES
  94
  95
  96   BSS_SECTION(8, PAGE_SIZE, 1)
  97   _end = . ;
  98
  99   STABS_DEBUG
 100   DWARF_DEBUG
 101
 102   DISCARDS
 103 }