arch/x86/boot/compressed/vmlinux.lds.S

   1 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
   2
   3 #undef i386
   4
   5 #ifdef CONFIG_X86_64
   6 OUTPUT_ARCH(i386:x86-64)
   7 ENTRY(startup_64)
   8 #else
   9 OUTPUT_ARCH(i386)
  10 ENTRY(startup_32)
  11 #endif
  12
  13 SECTIONS
  14 {
  15         /* Be careful parts of head_64.S assume startup_32 is at
  16          * address 0.
  17          */
  18         . = 0;
  19         .text.head : {
  20                 _head = . ;
  21                 *(.text.head)
  22                 _ehead = . ;
  23         }
  24         .rodata.compressed : {
  25                 *(.rodata.compressed)
  26         }
  27         .text : {
  28                 _text = .;      /* Text */
  29                 *(.text)
  30                 *(.text.*)
  31                 _etext = . ;
  32         }
  33         .rodata : {
  34                 _rodata = . ;
  35                 *(.rodata)       /* read-only data */
  36                 *(.rodata.*)
  37                 _erodata = . ;
  38         }
  39         .data : {
  40                 _data = . ;
  41                 *(.data)
  42                 *(.data.*)
  43                 _edata = . ;
  44         }
  45         .bss : {
  46                 _bss = . ;
  47                 *(.bss)
  48                 *(.bss.*)
  49                 *(COMMON)
  50 #ifdef CONFIG_X86_64
  51                 . = ALIGN(8);
  52                 _end_before_pgt = . ;
  53                 . = ALIGN(4096);
  54                 pgtable = . ;
  55                 . = . + 4096 * 6;
  56 #endif
  57                 _ebss = .;
  58         }
  59 }