2 * linux/arch/x86_64/entry.S
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
10 * entry.S contains the system-call and fault low-level handling routines.
12 * Some of this is documented in Documentation/x86/entry_64.txt
14 * NOTE: This code handles signal-recognition, which happens every time
15 * after an interrupt and after each system call.
17 * A note on terminology:
18 * - iret frame: Architecture defined interrupt frame from SS to RIP
19 * at the top of the kernel process stack.
22 * - ENTRY/END Define functions in the symbol table.
23 * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
24 * - idtentry - Define exception entry points.
27 #include <linux/linkage.h>
28 #include <asm/segment.h>
29 #include <asm/cache.h>
30 #include <asm/errno.h>
32 #include <asm/asm-offsets.h>
34 #include <asm/unistd.h>
35 #include <asm/thread_info.h>
36 #include <asm/hw_irq.h>
37 #include <asm/page_types.h>
38 #include <asm/irqflags.h>
39 #include <asm/paravirt.h>
40 #include <asm/percpu.h>
42 #include <asm/context_tracking.h>
44 #include <asm/pgtable_types.h>
45 #include <linux/err.h>
47 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
48 #include <linux/elf-em.h>
49 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
50 #define __AUDIT_ARCH_64BIT 0x80000000
51 #define __AUDIT_ARCH_LE 0x40000000
54 .section .entry.text, "ax"
57 #ifdef CONFIG_PARAVIRT
58 ENTRY(native_usergs_sysret64)
61 ENDPROC(native_usergs_sysret64)
62 #endif /* CONFIG_PARAVIRT */
65 .macro TRACE_IRQS_IRETQ
66 #ifdef CONFIG_TRACE_IRQFLAGS
67 bt $9,EFLAGS(%rsp) /* interrupts off? */
75 * When dynamic function tracer is enabled it will add a breakpoint
76 * to all locations that it is about to modify, sync CPUs, update
77 * all the code, sync CPUs, then remove the breakpoints. In this time
78 * if lockdep is enabled, it might jump back into the debug handler
79 * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
81 * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
82 * make sure the stack pointer does not get reset back to the top
83 * of the debug stack, and instead just reuses the current stack.
85 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
87 .macro TRACE_IRQS_OFF_DEBUG
88 call debug_stack_set_zero
90 call debug_stack_reset
93 .macro TRACE_IRQS_ON_DEBUG
94 call debug_stack_set_zero
96 call debug_stack_reset
99 .macro TRACE_IRQS_IRETQ_DEBUG
100 bt $9,EFLAGS(%rsp) /* interrupts off? */
107 # define TRACE_IRQS_OFF_DEBUG TRACE_IRQS_OFF
108 # define TRACE_IRQS_ON_DEBUG TRACE_IRQS_ON
109 # define TRACE_IRQS_IRETQ_DEBUG TRACE_IRQS_IRETQ
113 * 64bit SYSCALL instruction entry. Up to 6 arguments in registers.
115 * 64bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
116 * then loads new ss, cs, and rip from previously programmed MSRs.
117 * rflags gets masked by a value from another MSR (so CLD and CLAC
118 * are not needed). SYSCALL does not save anything on the stack
119 * and does not change rsp.
121 * Registers on entry:
122 * rax system call number
124 * r11 saved rflags (note: r11 is callee-clobbered register in C ABI)
128 * r10 arg3 (needs to be moved to rcx to conform to C ABI)
131 * (note: r12-r15,rbp,rbx are callee-preserved in C ABI)
133 * Only called from user space.
135 * When user can change pt_regs->foo always force IRET. That is because
136 * it deals with uncanonical addresses better. SYSRET has trouble
137 * with them due to bugs in both AMD and Intel CPUs.
142 * Interrupts are off on entry.
143 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
144 * it is too small to ever cause noticeable irq latency.
148 * A hypervisor implementation might want to use a label
149 * after the swapgs, so that it can do the swapgs
150 * for the guest and jump here on syscall.
152 GLOBAL(system_call_after_swapgs)
154 movq %rsp,PER_CPU_VAR(rsp_scratch)
155 movq PER_CPU_VAR(cpu_current_top_of_stack),%rsp
157 /* Construct struct pt_regs on stack */
158 pushq $__USER_DS /* pt_regs->ss */
159 pushq PER_CPU_VAR(rsp_scratch) /* pt_regs->sp */
161 * Re-enable interrupts.
162 * We use 'rsp_scratch' as a scratch space, hence irq-off block above
163 * must execute atomically in the face of possible interrupt-driven
164 * task preemption. We must enable interrupts only after we're done
165 * with using rsp_scratch:
167 ENABLE_INTERRUPTS(CLBR_NONE)
168 pushq %r11 /* pt_regs->flags */
169 pushq $__USER_CS /* pt_regs->cs */
170 pushq %rcx /* pt_regs->ip */
171 pushq %rax /* pt_regs->orig_ax */
172 pushq %rdi /* pt_regs->di */
173 pushq %rsi /* pt_regs->si */
174 pushq %rdx /* pt_regs->dx */
175 pushq %rcx /* pt_regs->cx */
176 pushq $-ENOSYS /* pt_regs->ax */
177 pushq %r8 /* pt_regs->r8 */
178 pushq %r9 /* pt_regs->r9 */
179 pushq %r10 /* pt_regs->r10 */
180 pushq %r11 /* pt_regs->r11 */
181 sub $(6*8),%rsp /* pt_regs->bp,bx,r12-15 not saved */
183 testl $_TIF_WORK_SYSCALL_ENTRY, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
185 system_call_fastpath:
186 #if __SYSCALL_MASK == ~0
187 cmpq $__NR_syscall_max,%rax
189 andl $__SYSCALL_MASK,%eax
190 cmpl $__NR_syscall_max,%eax
192 ja 1f /* return -ENOSYS (already in pt_regs->ax) */
194 call *sys_call_table(,%rax,8)
198 * Syscall return path ending with SYSRET (fast path).
199 * Has incompletely filled pt_regs.
203 * We do not frame this tiny irq-off block with TRACE_IRQS_OFF/ON,
204 * it is too small to ever cause noticeable irq latency.
206 DISABLE_INTERRUPTS(CLBR_NONE)
209 * We must check ti flags with interrupts (or at least preemption)
210 * off because we must *never* return to userspace without
211 * processing exit work that is enqueued if we're preempted here.
212 * In particular, returning to userspace with any of the one-shot
213 * flags (TIF_NOTIFY_RESUME, TIF_USER_RETURN_NOTIFY, etc) set is
216 testl $_TIF_ALLWORK_MASK, ASM_THREAD_INFO(TI_flags, %rsp, SIZEOF_PTREGS)
217 jnz int_ret_from_sys_call_irqs_off /* Go to the slow path */
219 RESTORE_C_REGS_EXCEPT_RCX_R11
221 movq EFLAGS(%rsp),%r11
224 * 64bit SYSRET restores rip from rcx,
225 * rflags from r11 (but RF and VM bits are forced to 0),
226 * cs and ss are loaded from MSRs.
227 * Restoration of rflags re-enables interrupts.
229 * NB: On AMD CPUs with the X86_BUG_SYSRET_SS_ATTRS bug, the ss
230 * descriptor is not reinitialized. This means that we should
231 * avoid SYSRET with SS == NULL, which could happen if we schedule,
232 * exit the kernel, and re-enter using an interrupt vector. (All
233 * interrupt entries on x86_64 set SS to NULL.) We prevent that
234 * from happening by reloading SS in __switch_to. (Actually
235 * detecting the failure in 64-bit userspace is tricky but can be
240 /* Do syscall entry tracing */
243 movl $AUDIT_ARCH_X86_64, %esi
244 call syscall_trace_enter_phase1
246 jnz tracesys_phase2 /* if needed, run the slow path */
247 RESTORE_C_REGS_EXCEPT_RAX /* else restore clobbered regs */
248 movq ORIG_RAX(%rsp), %rax
249 jmp system_call_fastpath /* and return to the fast path */
254 movl $AUDIT_ARCH_X86_64, %esi
256 call syscall_trace_enter_phase2
259 * Reload registers from stack in case ptrace changed them.
260 * We don't reload %rax because syscall_trace_entry_phase2() returned
261 * the value it wants us to use in the table lookup.
263 RESTORE_C_REGS_EXCEPT_RAX
265 #if __SYSCALL_MASK == ~0
266 cmpq $__NR_syscall_max,%rax
268 andl $__SYSCALL_MASK,%eax
269 cmpl $__NR_syscall_max,%eax
271 ja 1f /* return -ENOSYS (already in pt_regs->ax) */
272 movq %r10,%rcx /* fixup for C */
273 call *sys_call_table(,%rax,8)
276 /* Use IRET because user could have changed pt_regs->foo */
279 * Syscall return path ending with IRET.
280 * Has correct iret frame.
282 GLOBAL(int_ret_from_sys_call)
283 DISABLE_INTERRUPTS(CLBR_NONE)
284 int_ret_from_sys_call_irqs_off: /* jumps come here from the irqs-off SYSRET path */
286 movl $_TIF_ALLWORK_MASK,%edi
287 /* edi: mask to check */
288 GLOBAL(int_with_check)
290 GET_THREAD_INFO(%rcx)
291 movl TI_flags(%rcx),%edx
294 andl $~TS_COMPAT,TI_status(%rcx)
297 /* Either reschedule or signal or syscall exit tracking needed. */
298 /* First do a reschedule test. */
299 /* edx: work, edi: workmask */
301 bt $TIF_NEED_RESCHED,%edx
304 ENABLE_INTERRUPTS(CLBR_NONE)
308 DISABLE_INTERRUPTS(CLBR_NONE)
312 /* handle signals and tracing -- both require a full pt_regs */
315 ENABLE_INTERRUPTS(CLBR_NONE)
317 /* Check for syscall exit trace */
318 testl $_TIF_WORK_SYSCALL_EXIT,%edx
321 leaq 8(%rsp),%rdi # &ptregs -> arg1
322 call syscall_trace_leave
324 andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
328 testl $_TIF_DO_NOTIFY_MASK,%edx
330 movq %rsp,%rdi # &ptregs -> arg1
331 xorl %esi,%esi # oldset -> arg2
332 call do_notify_resume
333 1: movl $_TIF_WORK_MASK,%edi
336 DISABLE_INTERRUPTS(CLBR_NONE)
341 /* The IRETQ could re-enable interrupts: */
342 DISABLE_INTERRUPTS(CLBR_ANY)
346 * Try to use SYSRET instead of IRET if we're returning to
347 * a completely clean 64-bit userspace context.
351 cmpq %rcx,%r11 /* RCX == RIP */
352 jne opportunistic_sysret_failed
355 * On Intel CPUs, SYSRET with non-canonical RCX/RIP will #GP
356 * in kernel space. This essentially lets the user take over
357 * the kernel, since userspace controls RSP.
359 * If width of "canonical tail" ever becomes variable, this will need
360 * to be updated to remain correct on both old and new CPUs.
362 .ifne __VIRTUAL_MASK_SHIFT - 47
363 .error "virtual address width changed -- SYSRET checks need update"
365 /* Change top 16 bits to be the sign-extension of 47th bit */
366 shl $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
367 sar $(64 - (__VIRTUAL_MASK_SHIFT+1)), %rcx
368 /* If this changed %rcx, it was not canonical */
370 jne opportunistic_sysret_failed
372 cmpq $__USER_CS,CS(%rsp) /* CS must match SYSRET */
373 jne opportunistic_sysret_failed
376 cmpq %r11,EFLAGS(%rsp) /* R11 == RFLAGS */
377 jne opportunistic_sysret_failed
380 * SYSRET can't restore RF. SYSRET can restore TF, but unlike IRET,
381 * restoring TF results in a trap from userspace immediately after
382 * SYSRET. This would cause an infinite loop whenever #DB happens
383 * with register state that satisfies the opportunistic SYSRET
384 * conditions. For example, single-stepping this user code:
386 * movq $stuck_here,%rcx
391 * would never get past 'stuck_here'.
393 testq $(X86_EFLAGS_RF|X86_EFLAGS_TF), %r11
394 jnz opportunistic_sysret_failed
396 /* nothing to check for RSP */
398 cmpq $__USER_DS,SS(%rsp) /* SS must match SYSRET */
399 jne opportunistic_sysret_failed
402 * We win! This label is here just for ease of understanding
403 * perf profiles. Nothing jumps here.
405 syscall_return_via_sysret:
406 /* rcx and r11 are already restored (see code above) */
407 RESTORE_C_REGS_EXCEPT_RCX_R11
411 opportunistic_sysret_failed:
413 jmp restore_c_regs_and_iret
417 .macro FORK_LIKE func
433 /* exec failed, can use fast SYSRET code path in this case */
436 /* must use IRET code path (pt_regs->cs may have changed) */
440 jmp int_ret_from_sys_call
443 * Remaining execve stubs are only 7 bytes long.
444 * ENTRY() often aligns to 16 bytes, which in this case has no benefits.
447 GLOBAL(stub_execveat)
449 jmp return_from_execve
452 #if defined(CONFIG_X86_X32_ABI) || defined(CONFIG_IA32_EMULATION)
454 GLOBAL(stub_x32_execve)
455 GLOBAL(stub32_execve)
456 call compat_sys_execve
457 jmp return_from_execve
461 GLOBAL(stub_x32_execveat)
462 GLOBAL(stub32_execveat)
463 call compat_sys_execveat
464 jmp return_from_execve
466 END(stub_x32_execveat)
470 * sigreturn is special because it needs to restore all registers on return.
471 * This cannot be done with SYSRET, so use the IRET return path instead.
473 ENTRY(stub_rt_sigreturn)
475 * SAVE_EXTRA_REGS result is not normally needed:
476 * sigreturn overwrites all pt_regs->GPREGS.
477 * But sigreturn can fail (!), and there is no easy way to detect that.
478 * To make sure RESTORE_EXTRA_REGS doesn't restore garbage on error,
479 * we SAVE_EXTRA_REGS here.
482 call sys_rt_sigreturn
487 jmp int_ret_from_sys_call
488 END(stub_rt_sigreturn)
490 #ifdef CONFIG_X86_X32_ABI
491 ENTRY(stub_x32_rt_sigreturn)
493 call sys32_x32_rt_sigreturn
495 END(stub_x32_rt_sigreturn)
499 * A newly forked process directly context switches into this address.
501 * rdi: prev task we switched from
505 LOCK ; btr $TIF_FORK,TI_flags(%r8)
508 popfq # reset kernel eflags
510 call schedule_tail # rdi: 'prev' task parameter
514 testb $3, CS(%rsp) # from kernel_thread?
517 * By the time we get here, we have no idea whether our pt_regs,
518 * ti flags, and ti status came from the 64-bit SYSCALL fast path,
519 * the slow path, or one of the ia32entry paths.
520 * Use IRET code path to return, since it can safely handle
523 jnz int_ret_from_sys_call
525 /* We came from kernel_thread */
526 /* nb: we depend on RESTORE_EXTRA_REGS above */
531 jmp int_ret_from_sys_call
535 * Build the entry stubs with some assembler magic.
536 * We pack 1 stub into every 8-byte block.
539 ENTRY(irq_entries_start)
540 vector=FIRST_EXTERNAL_VECTOR
541 .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
542 pushq $(~vector+0x80) /* Note: always in signed byte range */
547 END(irq_entries_start)
550 * Interrupt entry/exit.
552 * Interrupt entry points save only callee clobbered registers in fast path.
554 * Entry runs with interrupts off.
557 /* 0(%rsp): ~(interrupt number) */
558 .macro interrupt func
561 * Since nothing in interrupt handling code touches r12...r15 members
562 * of "struct pt_regs", and since interrupts can nest, we can save
563 * four stack slots and simultaneously provide
564 * an unwind-friendly stack layout by saving "truncated" pt_regs
565 * exactly up to rbp slot, without these members.
567 ALLOC_PT_GPREGS_ON_STACK -RBP
569 /* this goes to 0(%rsp) for unwinder, not for saving the value: */
570 SAVE_EXTRA_REGS_RBP -RBP
572 leaq -RBP(%rsp),%rdi /* arg1 for \func (pointer to pt_regs) */
574 testb $3, CS-RBP(%rsp)
579 * Save previous stack pointer, optionally switch to interrupt stack.
580 * irq_count is used to check if a CPU is already on an interrupt stack
581 * or not. While this is essentially redundant with preempt_count it is
582 * a little cheaper to use a separate counter in the PDA (short of
583 * moving irq_enter into assembly, which would be too much work)
586 incl PER_CPU_VAR(irq_count)
587 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
589 /* We entered an interrupt context - irqs are off: */
596 * The interrupt stubs push (~vector+0x80) onto the stack and
597 * then jump to common_interrupt.
599 .p2align CONFIG_X86_L1_CACHE_SHIFT
602 addq $-0x80,(%rsp) /* Adjust vector to [-256,-1] range */
604 /* 0(%rsp): old RSP */
606 DISABLE_INTERRUPTS(CLBR_NONE)
608 decl PER_CPU_VAR(irq_count)
610 /* Restore saved previous stack */
612 /* return code expects complete pt_regs - adjust rsp accordingly: */
617 /* Interrupt came from user space */
619 GET_THREAD_INFO(%rcx)
621 * %rcx: thread info. Interrupts off.
623 retint_with_reschedule:
624 movl $_TIF_WORK_MASK,%edi
627 movl TI_flags(%rcx),%edx
631 retint_swapgs: /* return to user-space */
633 * The iretq could re-enable interrupts:
635 DISABLE_INTERRUPTS(CLBR_ANY)
639 jmp restore_c_regs_and_iret
641 /* Returning to kernel space */
643 #ifdef CONFIG_PREEMPT
644 /* Interrupts are off */
645 /* Check if we need preemption */
646 bt $9,EFLAGS(%rsp) /* interrupts were off? */
648 0: cmpl $0,PER_CPU_VAR(__preempt_count)
650 call preempt_schedule_irq
655 * The iretq could re-enable interrupts:
660 * At this label, code paths which return to kernel and to user,
661 * which come from interrupts/exception and from syscalls, merge.
663 restore_c_regs_and_iret:
665 REMOVE_PT_GPREGS_FROM_STACK 8
670 * Are we returning to a stack segment from the LDT? Note: in
671 * 64-bit mode SS:RSP on the exception stack is always valid.
673 #ifdef CONFIG_X86_ESPFIX64
674 testb $4,(SS-RIP)(%rsp)
675 jnz native_irq_return_ldt
678 .global native_irq_return_iret
679 native_irq_return_iret:
681 * This may fault. Non-paranoid faults on return to userspace are
682 * handled by fixup_bad_iret. These include #SS, #GP, and #NP.
683 * Double-faults due to espfix64 are handled in do_double_fault.
684 * Other faults here are fatal.
688 #ifdef CONFIG_X86_ESPFIX64
689 native_irq_return_ldt:
693 movq PER_CPU_VAR(espfix_waddr),%rdi
694 movq %rax,(0*8)(%rdi) /* RAX */
695 movq (2*8)(%rsp),%rax /* RIP */
696 movq %rax,(1*8)(%rdi)
697 movq (3*8)(%rsp),%rax /* CS */
698 movq %rax,(2*8)(%rdi)
699 movq (4*8)(%rsp),%rax /* RFLAGS */
700 movq %rax,(3*8)(%rdi)
701 movq (6*8)(%rsp),%rax /* SS */
702 movq %rax,(5*8)(%rdi)
703 movq (5*8)(%rsp),%rax /* RSP */
704 movq %rax,(4*8)(%rdi)
705 andl $0xffff0000,%eax
707 orq PER_CPU_VAR(espfix_stack),%rax
711 jmp native_irq_return_iret
714 /* edi: workmask, edx: work */
716 bt $TIF_NEED_RESCHED,%edx
719 ENABLE_INTERRUPTS(CLBR_NONE)
723 GET_THREAD_INFO(%rcx)
724 DISABLE_INTERRUPTS(CLBR_NONE)
729 testl $_TIF_DO_NOTIFY_MASK,%edx
732 ENABLE_INTERRUPTS(CLBR_NONE)
734 movq $-1,ORIG_RAX(%rsp)
735 xorl %esi,%esi # oldset
736 movq %rsp,%rdi # &pt_regs
737 call do_notify_resume
739 DISABLE_INTERRUPTS(CLBR_NONE)
741 GET_THREAD_INFO(%rcx)
742 jmp retint_with_reschedule
744 END(common_interrupt)
749 .macro apicinterrupt3 num sym do_sym
759 #ifdef CONFIG_TRACING
760 #define trace(sym) trace_##sym
761 #define smp_trace(sym) smp_trace_##sym
763 .macro trace_apicinterrupt num sym
764 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
767 .macro trace_apicinterrupt num sym do_sym
771 .macro apicinterrupt num sym do_sym
772 apicinterrupt3 \num \sym \do_sym
773 trace_apicinterrupt \num \sym
777 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
778 irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
779 apicinterrupt3 REBOOT_VECTOR \
780 reboot_interrupt smp_reboot_interrupt
784 apicinterrupt3 UV_BAU_MESSAGE \
785 uv_bau_message_intr1 uv_bau_message_interrupt
787 apicinterrupt LOCAL_TIMER_VECTOR \
788 apic_timer_interrupt smp_apic_timer_interrupt
789 apicinterrupt X86_PLATFORM_IPI_VECTOR \
790 x86_platform_ipi smp_x86_platform_ipi
792 #ifdef CONFIG_HAVE_KVM
793 apicinterrupt3 POSTED_INTR_VECTOR \
794 kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
797 #ifdef CONFIG_X86_MCE_THRESHOLD
798 apicinterrupt THRESHOLD_APIC_VECTOR \
799 threshold_interrupt smp_threshold_interrupt
802 #ifdef CONFIG_X86_THERMAL_VECTOR
803 apicinterrupt THERMAL_APIC_VECTOR \
804 thermal_interrupt smp_thermal_interrupt
808 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
809 call_function_single_interrupt smp_call_function_single_interrupt
810 apicinterrupt CALL_FUNCTION_VECTOR \
811 call_function_interrupt smp_call_function_interrupt
812 apicinterrupt RESCHEDULE_VECTOR \
813 reschedule_interrupt smp_reschedule_interrupt
816 apicinterrupt ERROR_APIC_VECTOR \
817 error_interrupt smp_error_interrupt
818 apicinterrupt SPURIOUS_APIC_VECTOR \
819 spurious_interrupt smp_spurious_interrupt
821 #ifdef CONFIG_IRQ_WORK
822 apicinterrupt IRQ_WORK_VECTOR \
823 irq_work_interrupt smp_irq_work_interrupt
827 * Exception entry points.
829 #define CPU_TSS_IST(x) PER_CPU_VAR(cpu_tss) + (TSS_ist + ((x) - 1) * 8)
831 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
834 .if \shift_ist != -1 && \paranoid == 0
835 .error "using shift_ist requires paranoid=1"
839 PARAVIRT_ADJUST_EXCEPTION_FRAME
841 .ifeq \has_error_code
842 pushq $-1 /* ORIG_RAX: no syscall to restart */
845 ALLOC_PT_GPREGS_ON_STACK
849 testb $3, CS(%rsp) /* If coming from userspace, switch */
856 /* returned flag: ebx=0: need swapgs on exit, ebx=1: don't need it */
860 TRACE_IRQS_OFF_DEBUG /* reload IDT in case of recursion */
866 movq %rsp,%rdi /* pt_regs pointer */
869 movq ORIG_RAX(%rsp),%rsi /* get error code */
870 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
872 xorl %esi,%esi /* no error code */
876 subq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
882 addq $EXCEPTION_STKSZ, CPU_TSS_IST(\shift_ist)
885 /* these procedures expect "no swapgs" flag in ebx */
894 * Paranoid entry from userspace. Switch stacks and treat it
895 * as a normal entry. This means that paranoid handlers
896 * run in real process context if user_mode(regs).
902 movq %rsp,%rdi /* pt_regs pointer */
904 movq %rax,%rsp /* switch stack */
906 movq %rsp,%rdi /* pt_regs pointer */
909 movq ORIG_RAX(%rsp),%rsi /* get error code */
910 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
912 xorl %esi,%esi /* no error code */
917 jmp error_exit /* %ebx: no swapgs flag */
922 #ifdef CONFIG_TRACING
923 .macro trace_idtentry sym do_sym has_error_code:req
924 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
925 idtentry \sym \do_sym has_error_code=\has_error_code
928 .macro trace_idtentry sym do_sym has_error_code:req
929 idtentry \sym \do_sym has_error_code=\has_error_code
933 idtentry divide_error do_divide_error has_error_code=0
934 idtentry overflow do_overflow has_error_code=0
935 idtentry bounds do_bounds has_error_code=0
936 idtentry invalid_op do_invalid_op has_error_code=0
937 idtentry device_not_available do_device_not_available has_error_code=0
938 idtentry double_fault do_double_fault has_error_code=1 paranoid=2
939 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
940 idtentry invalid_TSS do_invalid_TSS has_error_code=1
941 idtentry segment_not_present do_segment_not_present has_error_code=1
942 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
943 idtentry coprocessor_error do_coprocessor_error has_error_code=0
944 idtentry alignment_check do_alignment_check has_error_code=1
945 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
948 /* Reload gs selector with exception handling */
949 /* edi: new selector */
950 ENTRY(native_load_gs_index)
952 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
956 2: mfence /* workaround */
960 END(native_load_gs_index)
962 _ASM_EXTABLE(gs_change,bad_gs)
964 /* running with kernelgs */
966 SWAPGS /* switch back to user gs */
972 /* Call softirq on interrupt stack. Interrupts are off. */
973 ENTRY(do_softirq_own_stack)
976 incl PER_CPU_VAR(irq_count)
977 cmove PER_CPU_VAR(irq_stack_ptr),%rsp
978 push %rbp # backlink for old unwinder
981 decl PER_CPU_VAR(irq_count)
983 END(do_softirq_own_stack)
986 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
989 * A note on the "critical region" in our callback handler.
990 * We want to avoid stacking callback handlers due to events occurring
991 * during handling of the last event. To do this, we keep events disabled
992 * until we've done all processing. HOWEVER, we must enable events before
993 * popping the stack frame (can't be done atomically) and so it would still
994 * be possible to get enough handler activations to overflow the stack.
995 * Although unlikely, bugs of that kind are hard to track down, so we'd
996 * like to avoid the possibility.
997 * So, on entry to the handler we detect whether we interrupted an
998 * existing activation in its critical region -- if so, we pop the current
999 * activation and restart the handler using the previous one.
1001 ENTRY(xen_do_hypervisor_callback) # do_hypervisor_callback(struct *pt_regs)
1003 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1004 * see the correct pointer to the pt_regs
1006 movq %rdi, %rsp # we don't return, adjust the stack frame
1007 11: incl PER_CPU_VAR(irq_count)
1009 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1010 pushq %rbp # backlink for old unwinder
1011 call xen_evtchn_do_upcall
1013 decl PER_CPU_VAR(irq_count)
1014 #ifndef CONFIG_PREEMPT
1015 call xen_maybe_preempt_hcall
1018 END(xen_do_hypervisor_callback)
1021 * Hypervisor uses this for application faults while it executes.
1022 * We get here for two reasons:
1023 * 1. Fault while reloading DS, ES, FS or GS
1024 * 2. Fault while executing IRET
1025 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1026 * registers that could be reloaded and zeroed the others.
1027 * Category 2 we fix up by killing the current process. We cannot use the
1028 * normal Linux return path in this case because if we use the IRET hypercall
1029 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1030 * We distinguish between categories by comparing each saved segment register
1031 * with its current contents: any discrepancy means we in category 1.
1033 ENTRY(xen_failsafe_callback)
1046 /* All segments match their saved values => Category 2 (Bad IRET). */
1053 jmp general_protection
1054 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1058 pushq $-1 /* orig_ax = -1 => not a system call */
1059 ALLOC_PT_GPREGS_ON_STACK
1063 END(xen_failsafe_callback)
1065 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1066 xen_hvm_callback_vector xen_evtchn_do_upcall
1068 #endif /* CONFIG_XEN */
1070 #if IS_ENABLED(CONFIG_HYPERV)
1071 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1072 hyperv_callback_vector hyperv_vector_handler
1073 #endif /* CONFIG_HYPERV */
1075 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1076 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1077 idtentry stack_segment do_stack_segment has_error_code=1
1079 idtentry xen_debug do_debug has_error_code=0
1080 idtentry xen_int3 do_int3 has_error_code=0
1081 idtentry xen_stack_segment do_stack_segment has_error_code=1
1083 idtentry general_protection do_general_protection has_error_code=1
1084 trace_idtentry page_fault do_page_fault has_error_code=1
1085 #ifdef CONFIG_KVM_GUEST
1086 idtentry async_page_fault do_async_page_fault has_error_code=1
1088 #ifdef CONFIG_X86_MCE
1089 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1093 * Save all registers in pt_regs, and switch gs if needed.
1094 * Use slow, but surefire "are we in kernel?" check.
1095 * Return: ebx=0: need swapgs on exit, ebx=1: otherwise
1097 ENTRY(paranoid_entry)
1102 movl $MSR_GS_BASE,%ecx
1105 js 1f /* negative -> in kernel */
1112 * "Paranoid" exit path from exception stack. This is invoked
1113 * only on return from non-NMI IST interrupts that came
1114 * from kernel space.
1116 * We may be returning to very strange contexts (e.g. very early
1117 * in syscall entry), so checking for preemption here would
1118 * be complicated. Fortunately, we there's no good reason
1119 * to try to handle preemption here.
1121 /* On entry, ebx is "no swapgs" flag (1: don't need swapgs, 0: need it) */
1122 ENTRY(paranoid_exit)
1123 DISABLE_INTERRUPTS(CLBR_NONE)
1124 TRACE_IRQS_OFF_DEBUG
1125 testl %ebx,%ebx /* swapgs needed? */
1126 jnz paranoid_exit_no_swapgs
1129 jmp paranoid_exit_restore
1130 paranoid_exit_no_swapgs:
1131 TRACE_IRQS_IRETQ_DEBUG
1132 paranoid_exit_restore:
1135 REMOVE_PT_GPREGS_FROM_STACK 8
1140 * Save all registers in pt_regs, and switch gs if needed.
1141 * Return: ebx=0: need swapgs on exit, ebx=1: otherwise
1148 testb $3, CS+8(%rsp)
1149 jz error_kernelspace
1157 * There are two places in the kernel that can potentially fault with
1158 * usergs. Handle them here. B stepping K8s sometimes report a
1159 * truncated RIP for IRET exceptions returning to compat mode. Check
1160 * for these here too.
1164 leaq native_irq_return_iret(%rip),%rcx
1165 cmpq %rcx,RIP+8(%rsp)
1167 movl %ecx,%eax /* zero extend */
1168 cmpq %rax,RIP+8(%rsp)
1170 cmpq $gs_change,RIP+8(%rsp)
1175 /* Fix truncated RIP */
1176 movq %rcx,RIP+8(%rsp)
1184 decl %ebx /* Return to usergs */
1189 /* On entry, ebx is "no swapgs" flag (1: don't need swapgs, 0: need it) */
1193 DISABLE_INTERRUPTS(CLBR_NONE)
1200 /* Runs on exception stack */
1202 PARAVIRT_ADJUST_EXCEPTION_FRAME
1204 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1205 * the iretq it performs will take us out of NMI context.
1206 * This means that we can have nested NMIs where the next
1207 * NMI is using the top of the stack of the previous NMI. We
1208 * can't let it execute because the nested NMI will corrupt the
1209 * stack of the previous NMI. NMI handlers are not re-entrant
1212 * To handle this case we do the following:
1213 * Check the a special location on the stack that contains
1214 * a variable that is set when NMIs are executing.
1215 * The interrupted task's stack is also checked to see if it
1217 * If the variable is not set and the stack is not the NMI
1219 * o Set the special variable on the stack
1220 * o Copy the interrupt frame into a "saved" location on the stack
1221 * o Copy the interrupt frame into a "copy" location on the stack
1222 * o Continue processing the NMI
1223 * If the variable is set or the previous stack is the NMI stack:
1224 * o Modify the "copy" location to jump to the repeate_nmi
1225 * o return back to the first NMI
1227 * Now on exit of the first NMI, we first clear the stack variable
1228 * The NMI stack will tell any nested NMIs at that point that it is
1229 * nested. Then we pop the stack normally with iret, and if there was
1230 * a nested NMI that updated the copy interrupt stack frame, a
1231 * jump will be made to the repeat_nmi code that will handle the second
1235 /* Use %rdx as our temp variable throughout */
1239 * If %cs was not the kernel segment, then the NMI triggered in user
1240 * space, which means it is definitely not nested.
1242 cmpl $__KERNEL_CS, 16(%rsp)
1246 * Check the special variable on the stack to see if NMIs are
1253 * Now test if the previous stack was an NMI stack.
1254 * We need the double check. We check the NMI stack to satisfy the
1255 * race when the first NMI clears the variable before returning.
1256 * We check the variable because the first NMI could be in a
1257 * breakpoint routine using a breakpoint stack.
1260 /* Compare the NMI stack (rdx) with the stack we came from (4*8(%rsp)) */
1261 cmpq %rdx, 4*8(%rsp)
1262 /* If the stack pointer is above the NMI stack, this is a normal NMI */
1264 subq $EXCEPTION_STKSZ, %rdx
1265 cmpq %rdx, 4*8(%rsp)
1266 /* If it is below the NMI stack, it is a normal NMI */
1268 /* Ah, it is within the NMI stack, treat it as nested */
1272 * Do nothing if we interrupted the fixup in repeat_nmi.
1273 * It's about to repeat the NMI handler, so we are fine
1274 * with ignoring this one.
1276 movq $repeat_nmi, %rdx
1279 movq $end_repeat_nmi, %rdx
1284 /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1285 leaq -1*8(%rsp), %rdx
1287 leaq -10*8(%rsp), %rdx
1294 /* Put stack back */
1300 /* No need to check faults here */
1305 * Because nested NMIs will use the pushed location that we
1306 * stored in rdx, we must keep that space available.
1307 * Here's what our stack frame will look like:
1308 * +-------------------------+
1310 * | original Return RSP |
1311 * | original RFLAGS |
1314 * +-------------------------+
1315 * | temp storage for rdx |
1316 * +-------------------------+
1317 * | NMI executing variable |
1318 * +-------------------------+
1320 * | copied Return RSP |
1324 * +-------------------------+
1326 * | Saved Return RSP |
1330 * +-------------------------+
1332 * +-------------------------+
1334 * The saved stack frame is used to fix up the copied stack frame
1335 * that a nested NMI may change to make the interrupted NMI iret jump
1336 * to the repeat_nmi. The original stack frame and the temp storage
1337 * is also used by nested NMIs and can not be trusted on exit.
1339 /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1342 /* Set the NMI executing variable on the stack. */
1346 * Leave room for the "copied" frame
1350 /* Copy the stack frame to the Saved frame */
1355 /* Everything up to here is safe from nested NMIs */
1358 * If there was a nested NMI, the first NMI's iret will return
1359 * here. But NMIs are still enabled and we can take another
1360 * nested NMI. The nested NMI checks the interrupted RIP to see
1361 * if it is between repeat_nmi and end_repeat_nmi, and if so
1362 * it will just return, as we are about to repeat an NMI anyway.
1363 * This makes it safe to copy to the stack frame that a nested
1368 * Update the stack variable to say we are still in NMI (the update
1369 * is benign for the non-repeat case, where 1 was pushed just above
1370 * to this very stack slot).
1374 /* Make another copy, this one may be modified by nested NMIs */
1383 * Everything below this point can be preempted by a nested
1384 * NMI if the first NMI took an exception and reset our iret stack
1385 * so that we repeat another NMI.
1387 pushq $-1 /* ORIG_RAX: no syscall to restart */
1388 ALLOC_PT_GPREGS_ON_STACK
1391 * Use paranoid_entry to handle SWAPGS, but no need to use paranoid_exit
1392 * as we should not be calling schedule in NMI context.
1393 * Even with normal interrupts enabled. An NMI should not be
1394 * setting NEED_RESCHED or anything that normal interrupts and
1395 * exceptions might do.
1400 * Save off the CR2 register. If we take a page fault in the NMI then
1401 * it could corrupt the CR2 value. If the NMI preempts a page fault
1402 * handler before it was able to read the CR2 register, and then the
1403 * NMI itself takes a page fault, the page fault that was preempted
1404 * will read the information from the NMI page fault and not the
1405 * origin fault. Save it off and restore it if it changes.
1406 * Use the r12 callee-saved register.
1410 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1415 /* Did the NMI take a page fault? Restore cr2 if it did */
1421 testl %ebx,%ebx /* swapgs needed? */
1428 /* Pop the extra iret frame at once */
1429 REMOVE_PT_GPREGS_FROM_STACK 6*8
1431 /* Clear the NMI executing stack variable */
1436 ENTRY(ignore_sysret)