arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74 #ifdef CONFIG_SMP
  75         percpu PT_LOAD FLAGS(6);        /* RW_ */
  76 #endif
  77         init PT_LOAD FLAGS(7);          /* RWE */
  78 #endif
  79         note PT_NOTE FLAGS(0);          /* ___ */
  80 }
  81
  82 SECTIONS
  83 {
  84 #ifdef CONFIG_X86_32
  85         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  86         phys_startup_32 = startup_32 - LOAD_OFFSET;
  87 #else
  88         . = __START_KERNEL;
  89         phys_startup_64 = startup_64 - LOAD_OFFSET;
  90 #endif
  91
  92         /* Text and read-only data */
  93         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  94                 _text = .;
  95                 /* bootstrapping code */
  96                 HEAD_TEXT
  97                 . = ALIGN(8);
  98                 _stext = .;
  99                 TEXT_TEXT
 100                 SCHED_TEXT
 101                 LOCK_TEXT
 102                 KPROBES_TEXT
 103                 ENTRY_TEXT
 104                 IRQENTRY_TEXT
 105                 *(.fixup)
 106                 *(.gnu.warning)
 107                 /* End of text section */
 108                 _etext = .;
 109         } :text = 0x9090
 110
 111         NOTES :text :note
 112
 113         EXCEPTION_TABLE(16) :text = 0x9090
 114
 115 #if defined(CONFIG_DEBUG_RODATA)
 116         /* .text should occupy whole number of pages */
 117         . = ALIGN(PAGE_SIZE);
 118 #endif
 119         X64_ALIGN_DEBUG_RODATA_BEGIN
 120         RO_DATA(PAGE_SIZE)
 121         X64_ALIGN_DEBUG_RODATA_END
 122
 123         /* Data */
 124         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 125                 /* Start of data section */
 126                 _sdata = .;
 127
 128                 /* init_task */
 129                 INIT_TASK_DATA(THREAD_SIZE)
 130
 131 #ifdef CONFIG_X86_32
 132                 /* 32 bit has nosave before _edata */
 133                 NOSAVE_DATA
 134 #endif
 135
 136                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 137
 138                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 139
 140                 DATA_DATA
 141                 CONSTRUCTORS
 142
 143                 /* rarely changed data like cpu maps */
 144                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 145
 146                 /* End of data section */
 147                 _edata = .;
 148         } :data
 149
 150 #ifdef CONFIG_X86_64
 151
 152         . = ALIGN(PAGE_SIZE);
 153         __vvar_page = .;
 154
 155         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 156                 /* work around gold bug 13023 */
 157                 __vvar_beginning_hack = .;
 158
 159                 /* Place all vvars at the offsets in asm/vvar.h. */
 160 #define EMIT_VVAR(name, offset)                         \
 161                 . = __vvar_beginning_hack + offset;     \
 162                 *(.vvar_ ## name)
 163 #define __VVAR_KERNEL_LDS
 164 #include <asm/vvar.h>
 165 #undef __VVAR_KERNEL_LDS
 166 #undef EMIT_VVAR
 167
 168         } :data
 169
 170        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 171
 172 #endif /* CONFIG_X86_64 */
 173
 174         /* Init code and data - will be freed after init */
 175         . = ALIGN(PAGE_SIZE);
 176         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 177                 __init_begin = .; /* paired with __init_end */
 178         }
 179
 180 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 181         /*
 182          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 183          * output PHDR, so the next output section - .init.text - should
 184          * start another segment - init.
 185          */
 186         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 187 #endif
 188
 189         INIT_TEXT_SECTION(PAGE_SIZE)
 190 #ifdef CONFIG_X86_64
 191         :init
 192 #endif
 193
 194         INIT_DATA_SECTION(16)
 195
 196         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 197                 __x86_cpu_dev_start = .;
 198                 *(.x86_cpu_dev.init)
 199                 __x86_cpu_dev_end = .;
 200         }
 201
 202         /*
 203          * start address and size of operations which during runtime
 204          * can be patched with virtualization friendly instructions or
 205          * baremetal native ones. Think page table operations.
 206          * Details in paravirt_types.h
 207          */
 208         . = ALIGN(8);
 209         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 210                 __parainstructions = .;
 211                 *(.parainstructions)
 212                 __parainstructions_end = .;
 213         }
 214
 215         /*
 216          * struct alt_inst entries. From the header (alternative.h):
 217          * "Alternative instructions for different CPU types or capabilities"
 218          * Think locking instructions on spinlocks.
 219          */
 220         . = ALIGN(8);
 221         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 222                 __alt_instructions = .;
 223                 *(.altinstructions)
 224                 __alt_instructions_end = .;
 225         }
 226
 227         /*
 228          * And here are the replacement instructions. The linker sticks
 229          * them as binary blobs. The .altinstructions has enough data to
 230          * get the address and the length of them to patch the kernel safely.
 231          */
 232         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 233                 *(.altinstr_replacement)
 234         }
 235
 236         /*
 237          * struct iommu_table_entry entries are injected in this section.
 238          * It is an array of IOMMUs which during run time gets sorted depending
 239          * on its dependency order. After rootfs_initcall is complete
 240          * this section can be safely removed.
 241          */
 242         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 243                 __iommu_table = .;
 244                 *(.iommu_table)
 245                 __iommu_table_end = .;
 246         }
 247
 248         . = ALIGN(8);
 249         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 250                 __apicdrivers = .;
 251                 *(.apicdrivers);
 252                 __apicdrivers_end = .;
 253         }
 254
 255         . = ALIGN(8);
 256         /*
 257          * .exit.text is discard at runtime, not link time, to deal with
 258          *  references from .altinstructions and .eh_frame
 259          */
 260         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 261                 EXIT_TEXT
 262         }
 263
 264         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 265                 EXIT_DATA
 266         }
 267
 268 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 269         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 270 #endif
 271
 272         . = ALIGN(PAGE_SIZE);
 273
 274         /* freed after init ends here */
 275         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 276                 __init_end = .;
 277         }
 278
 279         /*
 280          * smp_locks might be freed after init
 281          * start/end must be page aligned
 282          */
 283         . = ALIGN(PAGE_SIZE);
 284         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 285                 __smp_locks = .;
 286                 *(.smp_locks)
 287                 . = ALIGN(PAGE_SIZE);
 288                 __smp_locks_end = .;
 289         }
 290
 291 #ifdef CONFIG_X86_64
 292         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 293                 NOSAVE_DATA
 294         }
 295 #endif
 296
 297         /* BSS */
 298         . = ALIGN(PAGE_SIZE);
 299         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 300                 __bss_start = .;
 301                 *(.bss..page_aligned)
 302                 *(.bss)
 303                 . = ALIGN(PAGE_SIZE);
 304                 __bss_stop = .;
 305         }
 306
 307         . = ALIGN(PAGE_SIZE);
 308         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 309                 __brk_base = .;
 310                 . += 64 * 1024;         /* 64k alignment slop space */
 311                 *(.brk_reservation)     /* areas brk users have reserved */
 312                 __brk_limit = .;
 313         }
 314
 315         _end = .;
 316
 317         STABS_DEBUG
 318         DWARF_DEBUG
 319
 320         /* Sections to be discarded */
 321         DISCARDS
 322         /DISCARD/ : { *(.eh_frame) }
 323 }
 324
 325
 326 #ifdef CONFIG_X86_32
 327 /*
 328  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 329  */
 330 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 331            "kernel image bigger than KERNEL_IMAGE_SIZE");
 332 #else
 333 /*
 334  * Per-cpu symbols which need to be offset from __per_cpu_load
 335  * for the boot processor.
 336  */
 337 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 338 INIT_PER_CPU(gdt_page);
 339 INIT_PER_CPU(irq_stack_union);
 340
 341 /*
 342  * Build-time check on the image size:
 343  */
 344 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 345            "kernel image bigger than KERNEL_IMAGE_SIZE");
 346
 347 #ifdef CONFIG_SMP
 348 . = ASSERT((irq_stack_union == 0),
 349            "irq_stack_union is not at start of per-cpu area");
 350 #endif
 351
 352 #endif /* CONFIG_X86_32 */
 353
 354 #ifdef CONFIG_KEXEC
 355 #include <asm/kexec.h>
 356
 357 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 358            "kexec control code size is too big");
 359 #endif
 360