bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.12.90)
  11 # Uncomment the next line to remove the date from the reported bfd version
  12 #is_release=y
  13
  14 changequote(,)dnl
  15 bfd_version=`echo "${VERSION}" | sed -e 's/\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\).*/\1.00\2.00\3.00\4.00\5/' -e 's/\([^\.]*\)\..*\(..\)\..*\(..\)\..*\(..\)\..*\(..\)$/\1\2\3\4\5/'`
  16 changequote([,])dnl
  17
  18 bfd_version_string="\"${VERSION}\""
  19 bfd_version_date=`sed -e 's/.*DATE //' < ${srcdir}/version.h`
  20 if test x${is_release} = x; then
  21 dnl Sad, but we can't use XSTRING here to pick up the date from version.h
  22 dnl because traditional C doesn't allow it.
  23   bfd_version_string="\"${VERSION} ${bfd_version_date}\""
  24 fi
  25 dnl Since we need to edit bfd-in3.h to get the date for bfd_version_string,
  26 dnl we may as well substitute for bfd_version_date too.  That way we don't
  27 dnl need to #include version.h
  28 AC_SUBST(bfd_version)
  29 AC_SUBST(bfd_version_date)
  30 AC_SUBST(bfd_version_string)
  31
  32 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  33 dnl to call AC_CHECK_PROG.
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_CHECK_TOOL(RANLIB, ranlib, :)
  36
  37 dnl Default to a non shared library.  This may be overridden by the
  38 dnl configure option --enable-shared.
  39 AM_DISABLE_SHARED
  40
  41 AM_PROG_LIBTOOL
  42
  43 AC_ARG_ENABLE(64-bit-bfd,
  44 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  45 [case "${enableval}" in
  46   yes)  want64=true  ;;
  47   no)   want64=false ;;
  48   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  49 esac],[want64=false])dnl
  50 AC_ARG_ENABLE(targets,
  51 [  --enable-targets        alternative target configurations],
  52 [case "${enableval}" in
  53   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  54             ;;
  55   no)       enable_targets= ;;
  56   *)        enable_targets=$enableval ;;
  57 esac])dnl
  58 AC_ARG_ENABLE(commonbfdlib,
  59 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  60 [case "${enableval}" in
  61   yes) commonbfdlib=true ;;
  62   no)  commonbfdlib=false ;;
  63   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  64 esac])dnl
  65 AC_ARG_WITH(mmap,
  66 [  --with-mmap             try using mmap for BFD input files if available],
  67 [case "${withval}" in
  68   yes)  want_mmap=true ;;
  69   no)   want_mmap=false ;;
  70   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  71 esac],[want_mmap=false])dnl
  72
  73 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  74 AC_ARG_ENABLE(build-warnings,
  75 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  76 [case "${enableval}" in
  77   yes)  ;;
  78   no)   build_warnings="-w";;
  79   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  80         build_warnings="${build_warnings} ${t}";;
  81   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  82         build_warnings="${t} ${build_warnings}";;
  83   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  84 esac
  85 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  86   echo "Setting warning flags = $build_warnings" 6>&1
  87 fi])dnl
  88 WARN_CFLAGS=""
  89 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  90     WARN_CFLAGS="${build_warnings}"
  91 fi
  92 AC_SUBST(WARN_CFLAGS)
  93
  94 AM_CONFIG_HEADER(config.h:config.in)
  95
  96 if test -z "$target" ; then
  97     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  98 fi
  99
 100 AM_MAINTAINER_MODE
 101 AC_EXEEXT
 102
 103 host64=false
 104 target64=false
 105 bfd_default_target_size=32
 106
 107 # host stuff:
 108
 109 AC_PROG_CC
 110
 111 ALL_LINGUAS="fr tr ja es sv"
 112 CY_GNU_GETTEXT
 113
 114 # Permit host specific settings.
 115 . ${srcdir}/configure.host
 116
 117 AC_SUBST(HDEFINES)
 118 AC_PROG_INSTALL
 119
 120 BFD_HOST_64BIT_LONG=0
 121 BFD_HOST_64_BIT_DEFINED=0
 122 BFD_HOST_64_BIT=
 123 BFD_HOST_U_64_BIT=
 124 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 125   BFD_HOST_64BIT_LONG=1
 126 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 127   BFD_HOST_64_BIT_DEFINED=1
 128   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 129   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 130 fi
 131 AC_SUBST(BFD_HOST_64BIT_LONG)
 132 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 133 AC_SUBST(BFD_HOST_64_BIT)
 134 AC_SUBST(BFD_HOST_U_64_BIT)
 135
 136 BFD_CC_FOR_BUILD
 137
 138 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 139 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 140 AC_HEADER_TIME
 141 AC_HEADER_DIRENT
 142 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 143
 144 BFD_BINARY_FOPEN
 145
 146 BFD_NEED_DECLARATION(strstr)
 147 BFD_NEED_DECLARATION(malloc)
 148 BFD_NEED_DECLARATION(realloc)
 149 BFD_NEED_DECLARATION(free)
 150 BFD_NEED_DECLARATION(getenv)
 151
 152 # If we are configured native, pick a core file support file.
 153 COREFILE=
 154 COREFLAG=
 155 TRAD_HEADER=
 156 if test "${target}" = "${host}"; then
 157   case "${host}" in
 158   alpha*-*-freebsd*)
 159         COREFILE=''
 160         ;;
 161   alpha*-*-linux-gnu*)
 162         COREFILE=trad-core.lo
 163         TRAD_HEADER='"hosts/alphalinux.h"'
 164         ;;
 165   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 166   alpha*-*-*)           COREFILE=osf-core.lo ;;
 167   arm-*-freebsd*)       COREFILE='' ;;
 168   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 169   arm-*-riscix)         COREFILE=trad-core.lo ;;
 170   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 171   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 172   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 173   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 174                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 175   i370-*-*)
 176         COREFILE=trad-core.lo
 177         TRAD_HEADER='"hosts/i370linux.h"'
 178         ;;
 179
 180 changequote(,)dnl
 181   i[3456]86-sequent-bsd*)
 182 changequote([,])dnl
 183         COREFILE=trad-core.lo
 184         TRAD_HEADER='"hosts/symmetry.h"'
 185         ;;
 186 changequote(,)dnl
 187   i[3456]86-sequent-sysv4*) ;;
 188   i[3456]86-sequent-sysv*)
 189 changequote([,])dnl
 190         COREFILE=trad-core.lo
 191         TRAD_HEADER='"hosts/symmetry.h"'
 192         ;;
 193 changequote(,)dnl
 194   i[3456]86-*-bsdi)
 195 changequote([,])dnl
 196         COREFILE=
 197         ;;
 198 changequote(,)dnl
 199   i[3456]86-*-bsd* | i[34567]86-*-freebsd[123] | i[34567]86-*-freebsd[123]\.* | i[34567]86-*-freebsd4\.[01234]* | i[34567]86-*-freebsd*aout*)
 200 changequote([,])dnl
 201         COREFILE=trad-core.lo
 202         TRAD_HEADER='"hosts/i386bsd.h"'
 203         ;;
 204 changequote(,)dnl
 205   i[3456]86-*-freebsd*)
 206 changequote([,])dnl
 207         COREFILE=''
 208         TRAD_HEADER='"hosts/i386bsd.h"'
 209         ;;
 210 changequote(,)dnl
 211   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 212 changequote([,])dnl
 213         COREFILE=netbsd-core.lo
 214         ;;
 215 changequote(,)dnl
 216   i[3456]86-esix-sysv3*)
 217 changequote([,])dnl
 218         COREFILE=trad-core.lo
 219         TRAD_HEADER='"hosts/esix.h"'
 220         ;;
 221 changequote(,)dnl
 222   i[3456]86-*-sco3.2v5*)
 223 changequote([,])dnl
 224         COREFILE=sco5-core.lo
 225         ;;
 226 changequote(,)dnl
 227   i[3456]86-*-sco* | i[3456]86-*-isc*)
 228 changequote([,])dnl
 229         COREFILE=trad-core.lo
 230         TRAD_HEADER='"hosts/i386sco.h"'
 231         ;;
 232 changequote(,)dnl
 233   i[3456]86-*-mach3*)
 234 changequote([,])dnl
 235         COREFILE=trad-core.lo
 236         TRAD_HEADER='"hosts/i386mach3.h"'
 237         ;;
 238 changequote(,)dnl
 239   i[3456]86-*-linux-gnu*)
 240 changequote([,])dnl
 241         COREFILE=trad-core.lo
 242         TRAD_HEADER='"hosts/i386linux.h"'
 243         ;;
 244 changequote(,)dnl
 245   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 246   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 247 changequote([,])dnl
 248   i860-*-mach3* | i860-*-osf1*)
 249         COREFILE=trad-core.lo
 250         TRAD_HEADER='"hosts/i860mach3.h"'
 251         ;;
 252   mips-dec-bsd*)
 253         COREFILE=trad-core.lo
 254         TRAD_HEADER='"hosts/mipsbsd.h"'
 255         ;;
 256   mips-dec-mach3*)
 257         COREFILE=trad-core.lo
 258         TRAD_HEADER='"hosts/mipsmach3.h"'
 259         ;;
 260   mips-*-netbsd* | mips*-*-openbsd*)
 261         COREFILE=netbsd-core.lo
 262         ;;
 263   mips-dec-*)
 264         COREFILE=trad-core.lo
 265         TRAD_HEADER='"hosts/decstation.h"'
 266         ;;
 267   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 268   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 269   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 270   mips-*-mach3*)
 271         COREFILE=trad-core.lo
 272         TRAD_HEADER='"hosts/mipsmach3.h"'
 273         ;;
 274   mips-*-sysv4*)        ;;
 275   mips-*-sysv* | mips-*-riscos*)
 276         COREFILE=trad-core.lo
 277         TRAD_HEADER='"hosts/riscos.h"'
 278         ;;
 279   mips-sony-bsd*)
 280         COREFILE=trad-core.lo
 281         TRAD_HEADER='"hosts/news-mips.h"'
 282         ;;
 283   m68*-bull*-sysv*)
 284         COREFILE=trad-core.lo
 285         TRAD_HEADER='"hosts/dpx2.h"'
 286         ;;
 287   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 288   m68*-hp-bsd*)
 289         COREFILE=trad-core.lo
 290         TRAD_HEADER='"hosts/hp300bsd.h"'
 291         ;;
 292   m68*-*-linux-gnu*)
 293         COREFILE=trad-core.lo
 294         TRAD_HEADER='"hosts/m68klinux.h"'
 295         ;;
 296   m68*-motorola-sysv*)
 297         COREFILE=trad-core.lo
 298         TRAD_HEADER='"hosts/delta68.h"'
 299         ;;
 300   m68*-sony-*)
 301         COREFILE=trad-core.lo
 302         TRAD_HEADER='"hosts/news.h"'
 303         ;;
 304   m68*-*-netbsd* | m68*-*-openbsd*)
 305         COREFILE=netbsd-core.lo
 306         ;;
 307   m68*-apple-aux*)
 308         COREFILE=trad-core.lo
 309         TRAD_HEADER='"hosts/m68kaux.h"'
 310         ;;
 311   m88*-*-sysv4*)
 312         ;;
 313   m88*-motorola-sysv*)
 314         COREFILE=ptrace-core.lo
 315         ;;
 316   m88*-*-mach3*)
 317         COREFILE=trad-core.lo
 318         TRAD_HEADER='"hosts/m88kmach3.h"'
 319         ;;
 320   ns32k-pc532-mach)
 321         COREFILE=trad-core.lo
 322         TRAD_HEADER='"hosts/pc532mach.h"'
 323         ;;
 324   ns32k-*-netbsd* | ns32k-*-openbsd*)
 325         COREFILE=netbsd-core.lo
 326         ;;
 327   rs6000-*-lynx*)
 328         COREFILE=lynx-core.lo
 329         ;;
 330   rs6000-*-aix5.* | powerpc-*-aix5.*)
 331         COREFILE=rs6000-core.lo
 332         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 333         ;;
 334 changequote(,)dnl
 335   rs6000-*-aix4.[4-9]* | powerpc-*-aix4.[4-9]* | \
 336   rs6000-*-aix4.3.[3-9]* | powerpc-*-aix4.3.[3-9]*)
 337 changequote([,])dnl
 338         COREFILE=rs6000-core.lo
 339         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 340         ;;
 341   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 342   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 343   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 344   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 345   powerpc-*-beos*)      ;;
 346   powerpc-*-freebsd*)   COREFILE='' ;;
 347   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 348   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 349   s390*-*-*)            COREFILE=trad-core.lo ;;
 350   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 351   sparc-*-netbsd* | sparc-*-openbsd*)
 352         COREFILE=netbsd-core.lo
 353         ;;
 354   tahoe-*-*)
 355         COREFILE=trad-core.lo
 356         TRAD_HEADER='"hosts/tahoe.h"'
 357         ;;
 358   vax-*-ultrix2*)
 359         COREFILE=trad-core.lo
 360         TRAD_HEADER='"hosts/vaxult2.h"'
 361         ;;
 362   vax-*-ultrix*)
 363         COREFILE=trad-core.lo
 364         TRAD_HEADER='"hosts/vaxult2.h"'
 365         ;;
 366   vax-*-*)
 367         COREFILE=trad-core.lo
 368         TRAD_HEADER='"hosts/vaxbsd.h"'
 369         ;;
 370   x86_64-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 371   esac
 372
 373   case "$COREFILE" in
 374   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 375   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 376   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 377   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 378   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 379   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 380   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 381   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 382   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 383   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 384   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 385   esac
 386
 387   # ELF corefile support has several flavors, but all of
 388   # them use something called <sys/procfs.h>
 389   AC_CHECK_HEADERS(sys/procfs.h)
 390   if test "$ac_cv_header_sys_procfs_h" = yes; then
 391     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 392     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 393     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 394     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 395     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 396     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 397     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 398     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 399     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 400     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 401     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 402     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 403     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 404     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 405     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 406     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 407   fi
 408 fi
 409 AC_SUBST(COREFILE)
 410 AC_SUBST(COREFLAG)
 411 if test -n "$TRAD_HEADER"; then
 412   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 413     [Name of host specific header file to include in trad-core.c.])
 414 fi
 415
 416 # Horrible hacks to build DLLs on Windows.
 417 WIN32LDFLAGS=
 418 WIN32LIBADD=
 419 case "${host}" in
 420 *-*-cygwin*)
 421   if test "$enable_shared" = "yes"; then
 422     WIN32LDFLAGS="-no-undefined"
 423     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 424   fi
 425   ;;
 426 *-*-linux*)
 427   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 428   # libiberty.a.
 429   case "${host}" in
 430   mips*-*-linux*)
 431     # Linux/MIPS uses PIC by default.
 432     if test "$enable_shared" = "yes"; then
 433       WIN32LIBADD="-L../libiberty -liberty"
 434     fi
 435     ;;
 436   *)
 437 changequote(,)dnl
 438     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | tail -1`
 439 changequote([,])dnl
 440     if test -n "$x"; then
 441       WIN32LIBADD="-L../libiberty/pic -liberty"
 442     fi
 443   ;;
 444   esac
 445   ;;
 446 esac
 447 AC_SUBST(WIN32LDFLAGS)
 448 AC_SUBST(WIN32LIBADD)
 449
 450 # target stuff:
 451
 452 # Canonicalize the secondary target names.
 453 if test -n "$enable_targets" ; then
 454     for targ in `echo $enable_targets | sed 's/,/ /g'`
 455     do
 456         result=`$ac_config_sub $targ 2>/dev/null`
 457         if test -n "$result" ; then
 458             canon_targets="$canon_targets $result"
 459         else
 460             # Allow targets that config.sub doesn't recognize, like "all".
 461             canon_targets="$canon_targets $targ"
 462         fi
 463     done
 464 fi
 465
 466 all_targets=false
 467 defvec=
 468 selvecs=
 469 selarchs=
 470 TDEFINES=
 471 for targ in $target $canon_targets
 472 do
 473     if test "x$targ" = "xall"; then
 474         all_targets=true
 475     else
 476         . $srcdir/config.bfd
 477         if test "x$targ" = "x$target"; then
 478             defvec=$targ_defvec
 479         fi
 480         selvecs="$selvecs $targ_defvec $targ_selvecs"
 481         selarchs="$selarchs $targ_archs"
 482         TDEFINES="$TDEFINES $targ_cflags"
 483     fi
 484 done
 485 AC_SUBST(TDEFINES)
 486
 487 # This processing still needs to be done if we're to decide properly whether
 488 # 64-bit support needs to be compiled in.  Currently, it will be included if
 489 # the default or any other explicitly requested target requires it; it
 490 # will not be included on a 32-bit host if no 64-bit target is requested, and
 491 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 492 # used.
 493
 494 # uniq the default and selected vectors in all the configured targets.
 495 f=""
 496 for i in $selvecs ; do
 497     case " $f " in
 498     *" $i "*) ;;
 499     *) f="$f $i" ;;
 500     esac
 501 done
 502 selvecs="$f"
 503
 504
 505 # uniq the architectures in all the configured targets.
 506 f=""
 507 for i in $selarchs ; do
 508     case " $f " in
 509     *" $i "*) ;;
 510     *) f="$f $i" ;;
 511     esac
 512 done
 513 selarchs="$f"
 514
 515 # Target backend .o files.
 516 tb=
 517
 518 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 519
 520 for vec in $selvecs
 521 do
 522     target_size=32
 523     case "$vec" in
 524     # This list is alphabetized to make it easy to compare
 525     # with the two vector lists in targets.c.  For the same reason,
 526     # use one entry per line, even though this leads to long lines.
 527     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 528     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 529     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 530     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 531     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 532     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 533     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 534     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 535     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 536     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 537     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 538     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 539     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 540     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 541     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 542     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 543     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 544     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 545     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 546     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 547     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 548     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 549     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 550     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 551     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 552     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 553     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 554     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 555     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 556     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 557     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 558     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 559     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 560     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 561     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 562     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 563     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 564     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 565     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 566     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 567     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 568     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 569     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 570     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 571     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 572     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 573     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 574     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 575     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 576     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32.lo $elf" ;;
 577     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32.lo $elf" ;;
 578     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 579     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 580     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 581     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 582     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 583     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 584     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 585     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 586     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 587     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 588     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 589     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 590     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 591     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 592     bfd_elf32_shblin_vec)       tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 593     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 594     bfd_elf32_shlin_vec)        tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 595     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh-nbsd.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 596     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh-nbsd.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 597     # FIXME: We include cofflink.lo not because it's needed for
 598     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 599     # which needs it but does not list it.  Should be fixed in right place.
 600     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 601     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 602     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 603     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 604     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 605     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 606     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 607     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 608     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 609     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 610     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 611     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 612     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 613     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 614     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 615     bfd_elf64_ia64_aix_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 616     bfd_elf64_ia64_aix_little_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 617     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 618     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 619     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 620     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 621     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 622     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 623     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 624     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 625     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 626     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 627     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 628     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 629     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 630     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 631     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 632     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 633     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 634     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 635     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 636     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 637     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 638     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 639     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 640     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 641     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 642     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 643     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 644     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 645     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 646     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 647     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 648     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 649     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 650     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 651     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 652     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 653     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 654     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 655     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 656     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 657     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 658     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 659     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 660     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 661     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 662     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 663     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 664     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 665     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 666     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 667     ieee_vec)                   tb="$tb ieee.lo" ;;
 668     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 669     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 670     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 671     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 672     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 673     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 674     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 675     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 676     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 677     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 678     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 679     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 680     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 681     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 682     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 683     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 684     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 685     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 686     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 687     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 688     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 689     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 690     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 691     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 692     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 693     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 694     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 695     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 696     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 697     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 698     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 699     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 700     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 701     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 702     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 703     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 704     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 705     som_vec)                    tb="$tb som.lo" ;;
 706     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 707     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 708     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 709     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 710     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 711     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 712     srec_vec)                   tb="$tb srec.lo" ;;
 713     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 714     symbolsrec_vec)             tb="$tb srec.lo" ;;
 715     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 716     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 717     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 718     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 719     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 720     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 721     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 722     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 723     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 724     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 725     versados_vec)               tb="$tb versados.lo" ;;
 726     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 727     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 728     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 729     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 730     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 731
 732     "")                 ;;
 733     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 734     esac
 735
 736     if test ${target_size} = 64; then
 737         target64=true
 738     fi
 739     if test x"${vec}" = x"${defvec}"; then
 740         bfd_default_target_size=${target_size}
 741     fi
 742 done
 743
 744 # Target architecture .o files.
 745 # A couple of CPUs use shorter file names to avoid problems on DOS
 746 # filesystems.
 747 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 748
 749 # Weed out duplicate .o files.
 750 f=""
 751 for i in $tb ; do
 752     case " $f " in
 753     *" $i "*) ;;
 754     *) f="$f $i" ;;
 755     esac
 756 done
 757 tb="$f"
 758
 759 f=""
 760 for i in $ta ; do
 761     case " $f " in
 762     *" $i "*) ;;
 763     *) f="$f $i" ;;
 764     esac
 765 done
 766 ta="$f"
 767
 768 bfd_backends="$tb"
 769 bfd_machines="$ta"
 770
 771 if test x${all_targets} = xtrue ; then
 772   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 773   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 774   selvecs=
 775   havevecs=
 776   selarchs=
 777 else    # all_targets is true
 778   # Only set these if they will be nonempty, for the clever echo.
 779   havevecs=
 780   test -n "$selvecs" &&
 781     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 782   test -n "$selvecs" &&
 783     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 784   test -n "$selarchs" &&
 785     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 786 fi      # all_targets is true
 787
 788 case ${host64}-${target64}-${want64} in
 789   *true*)
 790     wordsize=64
 791     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 792     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 793     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 794       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 795       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 796     fi
 797     if test -n "$GCC" ; then
 798        bad_64bit_gcc=no;
 799        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 800        # Add more tests for gcc versions with non-working 64-bit support here.
 801        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 802                     bad_64bit_gcc=yes;
 803                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 804                     AC_MSG_RESULT(no))
 805        if test $bad_64bit_gcc = yes ; then
 806          AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 807        fi
 808     fi
 809     ;;
 810   false-false-false)
 811     wordsize=32
 812     bfd_libs='$(BFD32_LIBS)'
 813     all_backends='$(BFD32_BACKENDS)'
 814     ;;
 815 esac
 816
 817 AC_SUBST(wordsize)
 818 AC_SUBST(bfd_libs)
 819 AC_SUBST(all_backends)
 820 AC_SUBST(bfd_backends)
 821 AC_SUBST(bfd_machines)
 822 AC_SUBST(bfd_default_target_size)
 823
 824 tdefaults=""
 825 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 826 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 827 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 828 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 829 AC_SUBST(tdefaults)
 830
 831 dnl AC_CHECK_HEADERS(sys/mman.h)
 832 AC_FUNC_MMAP
 833 AC_CHECK_FUNCS(madvise mprotect)
 834 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 835   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 836 esac
 837
 838 rm -f doc/config.status
 839 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 840 [sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
 841