bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.17.50)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AC_PROG_CC
  23 AC_GNU_SOURCE
  24
  25 AC_PROG_LIBTOOL
  26
  27 AC_ARG_ENABLE(64-bit-bfd,
  28 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  29 [case "${enableval}" in
  30   yes)  want64=true  ;;
  31   no)   want64=false ;;
  32   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  33 esac],[want64=false])dnl
  34 AC_ARG_ENABLE(targets,
  35 [  --enable-targets        alternative target configurations],
  36 [case "${enableval}" in
  37   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  38             ;;
  39   no)       enable_targets= ;;
  40   *)        enable_targets=$enableval ;;
  41 esac])dnl
  42 AC_ARG_ENABLE(commonbfdlib,
  43 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  44 [case "${enableval}" in
  45   yes) commonbfdlib=true ;;
  46   no)  commonbfdlib=false ;;
  47   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  48 esac])dnl
  49 AC_ARG_WITH(mmap,
  50 [  --with-mmap             try using mmap for BFD input files if available],
  51 [case "${withval}" in
  52   yes)  want_mmap=true ;;
  53   no)   want_mmap=false ;;
  54   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  55 esac],[want_mmap=false])dnl
  56
  57 AC_ARG_ENABLE(secureplt,
  58 [  --enable-secureplt      Default to creating read-only plt entries],
  59 [case "${enableval}" in
  60   yes)  use_secureplt=true  ;;
  61   no)   use_secureplt=false ;;
  62   *)    AC_MSG_ERROR(bad value ${enableval} for secureplt option) ;;
  63 esac],[use_secureplt=false])dnl
  64 if test $use_secureplt = true; then
  65   AC_DEFINE(USE_SECUREPLT, 1,
  66     [Define if we should default to creating read-only plt entries])
  67 fi
  68
  69 DEBUGDIR=${libdir}/debug
  70
  71 AC_ARG_WITH(separate-debug-dir,
  72   AS_HELP_STRING([--with-separate-debug-dir=DIR],
  73                  [Look for global separate debug info in DIR [[default=LIBDIR/debug]]]),
  74 [DEBUGDIR="${withval}"])
  75 AC_SUBST(DEBUGDIR)
  76
  77 ACX_PKGVERSION([GNU Binutils])
  78 ACX_BUGURL([http://www.sourceware.org/bugzilla/])
  79
  80 AM_BINUTILS_WARNINGS
  81
  82 AM_CONFIG_HEADER(config.h:config.in)
  83
  84 if test -z "$target" ; then
  85     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  86 fi
  87
  88 AM_MAINTAINER_MODE
  89 AM_CONDITIONAL(GENINSRC_NEVER, false)
  90 AM_INSTALL_LIBBFD
  91 AC_EXEEXT
  92
  93 host64=false
  94 target64=false
  95 bfd_default_target_size=32
  96
  97 # host stuff:
  98
  99 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw vi"
 100 ZW_GNU_GETTEXT_SISTER_DIR
 101 AM_PO_SUBDIRS
 102
 103 # Permit host specific settings.
 104 . ${srcdir}/configure.host
 105
 106 AC_SUBST(HDEFINES)
 107 AC_PROG_INSTALL
 108
 109 BFD_HOST_64BIT_LONG=0
 110 BFD_HOST_LONG_LONG=0
 111 BFD_HOST_64_BIT_DEFINED=0
 112 BFD_HOST_64_BIT=
 113 BFD_HOST_U_64_BIT=
 114
 115 AC_MSG_CHECKING([for long long])
 116 AC_CACHE_VAL(bfd_cv_has_long_long,
 117 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 118 AC_MSG_RESULT($bfd_cv_has_long_long)
 119 if test $bfd_cv_has_long_long = yes; then
 120   BFD_HOST_LONG_LONG=1
 121   AC_CHECK_SIZEOF(long long)
 122 fi
 123
 124 AC_CHECK_SIZEOF(long)
 125 if test "x${ac_cv_sizeof_long}" = "x8"; then
 126   host64=true
 127   BFD_HOST_64BIT_LONG=1
 128   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 129   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 130 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 131   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 132   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 133 fi
 134
 135 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 136   BFD_HOST_64_BIT_DEFINED=1
 137   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 138   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 139 fi
 140
 141 AC_SUBST(BFD_HOST_64BIT_LONG)
 142 AC_SUBST(BFD_HOST_LONG_LONG)
 143 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 144 AC_SUBST(BFD_HOST_64_BIT)
 145 AC_SUBST(BFD_HOST_U_64_BIT)
 146
 147 BFD_CC_FOR_BUILD
 148
 149 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 150 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 151 GCC_HEADER_STDINT(bfd_stdint.h)
 152 AC_HEADER_TIME
 153 AC_HEADER_DIRENT
 154 ACX_HEADER_STRING
 155 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 156 AC_CHECK_FUNCS(strtoull)
 157
 158 AC_CHECK_DECLS(basename)
 159 AC_CHECK_DECLS(ftello)
 160 AC_CHECK_DECLS(ftello64)
 161 AC_CHECK_DECLS(fseeko)
 162 AC_CHECK_DECLS(fseeko64)
 163
 164 BFD_BINARY_FOPEN
 165
 166 AC_CHECK_DECLS(ffs)
 167 AC_CHECK_DECLS(free)
 168 AC_CHECK_DECLS(getenv)
 169 AC_CHECK_DECLS(malloc)
 170 AC_CHECK_DECLS(realloc)
 171 AC_CHECK_DECLS(stpcpy)
 172 AC_CHECK_DECLS(strstr)
 173 AC_CHECK_DECLS(snprintf)
 174 AC_CHECK_DECLS(vsnprintf)
 175
 176 # If we are configured native, pick a core file support file.
 177 COREFILE=
 178 COREFLAG=
 179 TRAD_HEADER=
 180 if test "${target}" = "${host}"; then
 181   case "${host}" in
 182   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 183         COREFILE=''
 184         ;;
 185   alpha*-*-linux-*)
 186         COREFILE=trad-core.lo
 187         TRAD_HEADER='"hosts/alphalinux.h"'
 188         ;;
 189   alpha*-*-netbsd* | alpha*-*-openbsd*)
 190         COREFILE=netbsd-core.lo
 191         ;;
 192   alpha*-*-*)           COREFILE=osf-core.lo ;;
 193   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 194                         COREFILE='' ;;
 195   arm-*-netbsd* | arm-*-openbsd*)
 196         COREFILE=netbsd-core.lo
 197         ;;
 198   arm-*-riscix)         COREFILE=trad-core.lo ;;
 199   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 200   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 201   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 202   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 203                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 204   hppa*-*-netbsd* | hppa*-*-openbsd*)
 205         COREFILE=netbsd-core.lo
 206         ;;
 207
 208   i370-*-*)
 209         COREFILE=trad-core.lo
 210         TRAD_HEADER='"hosts/i370linux.h"'
 211         ;;
 212
 213 changequote(,)dnl
 214   i[3-7]86-sequent-bsd*)
 215 changequote([,])dnl
 216         COREFILE=trad-core.lo
 217         TRAD_HEADER='"hosts/symmetry.h"'
 218         ;;
 219 changequote(,)dnl
 220   i[3-7]86-sequent-sysv4*) ;;
 221   i[3-7]86-sequent-sysv*)
 222 changequote([,])dnl
 223         COREFILE=trad-core.lo
 224         TRAD_HEADER='"hosts/symmetry.h"'
 225         ;;
 226 changequote(,)dnl
 227   i[3-7]86-*-bsdi)
 228 changequote([,])dnl
 229         COREFILE=
 230         ;;
 231 changequote(,)dnl
 232   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 233 changequote([,])dnl
 234         COREFILE=trad-core.lo
 235         TRAD_HEADER='"hosts/i386bsd.h"'
 236         ;;
 237 changequote(,)dnl
 238   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 239 changequote([,])dnl
 240         COREFILE=''
 241         TRAD_HEADER='"hosts/i386bsd.h"'
 242         ;;
 243 changequote(,)dnl
 244   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 245 changequote([,])dnl
 246         COREFILE=netbsd-core.lo
 247         ;;
 248 changequote(,)dnl
 249   i[3-7]86-esix-sysv3*)
 250 changequote([,])dnl
 251         COREFILE=trad-core.lo
 252         TRAD_HEADER='"hosts/esix.h"'
 253         ;;
 254 changequote(,)dnl
 255   i[3-7]86-*-sco3.2v5*)
 256 changequote([,])dnl
 257         COREFILE=sco5-core.lo
 258         ;;
 259 changequote(,)dnl
 260   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 261 changequote([,])dnl
 262         COREFILE=trad-core.lo
 263         TRAD_HEADER='"hosts/i386sco.h"'
 264         ;;
 265 changequote(,)dnl
 266   i[3-7]86-*-mach3*)
 267 changequote([,])dnl
 268         COREFILE=trad-core.lo
 269         TRAD_HEADER='"hosts/i386mach3.h"'
 270         ;;
 271 changequote(,)dnl
 272   i[3-7]86-*-linux-*)
 273 changequote([,])dnl
 274         COREFILE=trad-core.lo
 275         TRAD_HEADER='"hosts/i386linux.h"'
 276         ;;
 277 changequote(,)dnl
 278   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 279   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 280 changequote([,])dnl
 281   i860-*-mach3* | i860-*-osf1*)
 282         COREFILE=trad-core.lo
 283         TRAD_HEADER='"hosts/i860mach3.h"'
 284         ;;
 285   mips-*-netbsd* | mips*-*-openbsd*)
 286         COREFILE=netbsd-core.lo
 287         ;;
 288   mips-dec-*)
 289         COREFILE=trad-core.lo
 290         TRAD_HEADER='"hosts/decstation.h"'
 291         ;;
 292   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 293   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 294   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 295   mips-*-sysv4*)        ;;
 296   mips-*-sysv* | mips-*-riscos*)
 297         COREFILE=trad-core.lo
 298         TRAD_HEADER='"hosts/riscos.h"'
 299         ;;
 300   mips-sony-bsd*)
 301         COREFILE=trad-core.lo
 302         TRAD_HEADER='"hosts/news-mips.h"'
 303         ;;
 304   m68*-bull*-sysv*)
 305         COREFILE=trad-core.lo
 306         TRAD_HEADER='"hosts/dpx2.h"'
 307         ;;
 308   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 309   m68*-hp-bsd*)
 310         COREFILE=trad-core.lo
 311         TRAD_HEADER='"hosts/hp300bsd.h"'
 312         ;;
 313   m68*-*-linux-*)
 314         COREFILE=trad-core.lo
 315         TRAD_HEADER='"hosts/m68klinux.h"'
 316         ;;
 317   m68*-motorola-sysv*)
 318         COREFILE=trad-core.lo
 319         TRAD_HEADER='"hosts/delta68.h"'
 320         ;;
 321   m68*-sony-*)
 322         COREFILE=trad-core.lo
 323         TRAD_HEADER='"hosts/news.h"'
 324         ;;
 325   m68*-*-netbsd* | m68*-*-openbsd*)
 326         COREFILE=netbsd-core.lo
 327         ;;
 328   m68*-apple-aux*)
 329         COREFILE=trad-core.lo
 330         TRAD_HEADER='"hosts/m68kaux.h"'
 331         ;;
 332   m88*-*-sysv4*)
 333         ;;
 334   m88*-motorola-sysv*)
 335         COREFILE=ptrace-core.lo
 336         ;;
 337   m88*-*-mach3*)
 338         COREFILE=trad-core.lo
 339         TRAD_HEADER='"hosts/m88kmach3.h"'
 340         ;;
 341   m88*-*-openbsd*)
 342         COREFILE=netbsd-core.lo
 343         ;;
 344   ns32k-pc532-mach)
 345         COREFILE=trad-core.lo
 346         TRAD_HEADER='"hosts/pc532mach.h"'
 347         ;;
 348   ns32k-*-netbsd* | ns32k-*-openbsd*)
 349         COREFILE=netbsd-core.lo
 350         ;;
 351   rs6000-*-lynx*)
 352         COREFILE=lynx-core.lo
 353         ;;
 354   rs6000-*-aix5.* | powerpc-*-aix5.*)
 355         COREFILE=rs6000-core.lo
 356         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 357         ;;
 358 changequote(,)dnl
 359   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 360 changequote([,])dnl
 361         COREFILE=rs6000-core.lo
 362         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 363         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 364         # have c_impl as a member of struct core_dumpx
 365         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 366         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 367             [Define if struct core_dumpx has member c_impl])
 368           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 369         ;;
 370   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 371   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 372   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 373   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 374   powerpc-*-beos*)      ;;
 375   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 376                         COREFILE='' ;;
 377   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 378   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 379   s390*-*-*)            COREFILE=trad-core.lo ;;
 380   sh*-*-netbsd* | sh*-*-openbsd*)
 381         COREFILE=netbsd-core.lo
 382         ;;
 383   sparc-*-netbsd* | sparc*-*-openbsd*)
 384         COREFILE=netbsd-core.lo
 385         ;;
 386   tahoe-*-*)
 387         COREFILE=trad-core.lo
 388         TRAD_HEADER='"hosts/tahoe.h"'
 389         ;;
 390   vax-*-netbsd* | vax-*-openbsd*)
 391         COREFILE=netbsd-core.lo
 392         ;;
 393   vax-*-ultrix2*)
 394         COREFILE=trad-core.lo
 395         TRAD_HEADER='"hosts/vaxult2.h"'
 396         ;;
 397   vax-*-ultrix*)
 398         COREFILE=trad-core.lo
 399         TRAD_HEADER='"hosts/vaxult2.h"'
 400         ;;
 401   vax-*-linux-*)
 402         COREFILE=trad-core.lo
 403         TRAD_HEADER='"hosts/vaxlinux.h"'
 404         ;;
 405   vax-*-*)
 406         COREFILE=trad-core.lo
 407         TRAD_HEADER='"hosts/vaxbsd.h"'
 408         ;;
 409   x86_64-*-netbsd* | x86_64-*-openbsd*)
 410         COREFILE=netbsd-core.lo
 411         ;;
 412   esac
 413
 414   case "$COREFILE" in
 415   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 416   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 417   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 418   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 419   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 420   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 421   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 422   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 423   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 424   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 425   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 426   esac
 427
 428   # ELF corefile support has several flavors, but all of
 429   # them use something called <sys/procfs.h>
 430   AC_CHECK_HEADERS(sys/procfs.h)
 431   if test "$ac_cv_header_sys_procfs_h" = yes; then
 432     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 433     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 434     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 435     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 436     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 437     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 438     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 439     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 440     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 441     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 442     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 443     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 444     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 445     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 446     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 447     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 448   fi
 449 fi
 450 AC_SUBST(COREFILE)
 451 AC_SUBST(COREFLAG)
 452 if test -n "$TRAD_HEADER"; then
 453   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 454     [Name of host specific header file to include in trad-core.c.])
 455 fi
 456
 457 # Horrible hacks to build DLLs on Windows.
 458 WIN32LDFLAGS=
 459 WIN32LIBADD=
 460 case "${host}" in
 461 *-*-cygwin*)
 462   if test "$enable_shared" = "yes"; then
 463     WIN32LDFLAGS="-no-undefined"
 464     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 465   fi
 466   ;;
 467 *-*-linux*)
 468   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 469   # libiberty.a.
 470   case "${host}" in
 471   mips*-*-linux*)
 472     # Linux/MIPS uses PIC by default.
 473     if test "$enable_shared" = "yes"; then
 474       WIN32LIBADD="-L../libiberty -liberty"
 475     fi
 476     ;;
 477   *)
 478 changequote(,)dnl
 479     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 480 changequote([,])dnl
 481     if test -n "$x"; then
 482       WIN32LIBADD="-L../libiberty/pic -liberty"
 483     fi
 484   ;;
 485   esac
 486   ;;
 487 esac
 488 AC_SUBST(WIN32LDFLAGS)
 489 AC_SUBST(WIN32LIBADD)
 490
 491 # target stuff:
 492
 493 # Canonicalize the secondary target names.
 494 if test -n "$enable_targets" ; then
 495     for targ in `echo $enable_targets | sed 's/,/ /g'`
 496     do
 497         result=`$ac_config_sub $targ 2>/dev/null`
 498         if test -n "$result" ; then
 499             canon_targets="$canon_targets $result"
 500         else
 501             # Allow targets that config.sub doesn't recognize, like "all".
 502             canon_targets="$canon_targets $targ"
 503         fi
 504     done
 505 fi
 506
 507 all_targets=false
 508 defvec=
 509 selvecs=
 510 assocvecs=
 511 selarchs=
 512 TDEFINES=
 513 for targ in $target $canon_targets
 514 do
 515     if test "x$targ" = "xall"; then
 516         all_targets=true
 517         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 518     else
 519         . $srcdir/config.bfd
 520         if test "x$targ" = "x$target"; then
 521             defvec=$targ_defvec
 522         fi
 523         selvecs="$selvecs $targ_defvec $targ_selvecs"
 524         selarchs="$selarchs $targ_archs"
 525         TDEFINES="$TDEFINES $targ_cflags"
 526     fi
 527 done
 528 AC_SUBST(TDEFINES)
 529
 530 # This processing still needs to be done if we're to decide properly whether
 531 # 64-bit support needs to be compiled in.  Currently, it will be included if
 532 # the default or any other explicitly requested target requires it; it
 533 # will not be included on a 32-bit host if no 64-bit target is requested, and
 534 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 535 # used.
 536
 537 # uniq the default and selected vectors in all the configured targets.
 538 f=""
 539 for i in $selvecs ; do
 540     case " $f " in
 541     *" $i "*) ;;
 542     *) f="$f $i" ;;
 543     esac
 544 done
 545 selvecs="$f"
 546
 547
 548 # uniq the associated vectors in all the configured targets.
 549 f=""
 550 for i in $assocvecs ; do
 551     case " $f " in
 552     *" $i "*) ;;
 553     *) f="$f $i" ;;
 554     esac
 555 done
 556 assocvecs="$f"
 557
 558
 559 # uniq the architectures in all the configured targets.
 560 f=""
 561 for i in $selarchs ; do
 562     case " $f " in
 563     *" $i "*) ;;
 564     *) f="$f $i" ;;
 565     esac
 566 done
 567 selarchs="$f"
 568
 569 # Target backend .o files.
 570 tb=
 571
 572 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 573
 574 for vec in $selvecs
 575 do
 576     target_size=32
 577     case "$vec" in
 578     # This list is alphabetized to make it easy to compare
 579     # with the two vector lists in targets.c.  For the same reason,
 580     # use one entry per line, even though this leads to long lines.
 581     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 582     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 583     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 584     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 585     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 586     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 587     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 588     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 589     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 590     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 591     arm_wince_pe_big_vec)       tb="$tb pe-arm-wince.lo pe-arm.lo peigen.lo cofflink.lo " ;;
 592     arm_wince_pe_little_vec)    tb="$tb pe-arm-wince.lo pe-arm.lo peigen.lo cofflink.lo " ;;
 593     arm_wince_pei_big_vec)      tb="$tb pei-arm-wince.lo pei-arm.lo peigen.lo cofflink.lo " ;;
 594     arm_wince_pei_little_vec)   tb="$tb pei-arm-wince.lo pei-arm.lo peigen.lo cofflink.lo " ;;
 595     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 596     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 597     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 598     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 599     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 600     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 601     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 602     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 603     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 604     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 605     bfd_efi_app_x86_64_vec)     tb="$tb efi-app-x86_64.lo pex64igen.lo cofflink.lo" ;target_size=64;;
 606     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 607     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 608     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 609     bfd_elf32_bfin_vec)         tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 610     bfd_elf32_bfinfdpic_vec)    tb="$tb elf32-bfin.lo elf32.lo $elf" ;;
 611     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 612     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 613     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 614     bfd_elf32_bigarm_symbian_vec)
 615                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 616     bfd_elf32_bigarm_vxworks_vec)
 617                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 618     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 619     bfd_elf32_bigmips_vxworks_vec)
 620                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 621     bfd_elf32_cr16_vec)         tb="$tb elf32-cr16.lo elf32.lo $elf" ;;
 622     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 623     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 624     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 625     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 626     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 627     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 628     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 629     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 630     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 631     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 632     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 633     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 634     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 635     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 636     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 637     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 638     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 639     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 640     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 641     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 642     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 643     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 644     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 645     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 646     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 647     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 648     bfd_elf32_littlearm_symbian_vec)
 649                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 650     bfd_elf32_littlearm_vxworks_vec)
 651                                 tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 652     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo elf-vxworks.lo $elf" ;;
 653     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 654     bfd_elf32_littlemips_vxworks_vec)
 655                                 tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 656     bfd_elf32_m32c_vec)         tb="$tb elf32-m32c.lo elf32.lo $elf" ;;
 657     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 658     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 659     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 660     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 661     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 662     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 663     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 664     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 665     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 666     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 667     bfd_elf32_mep_vec)          tb="$tb elf32-mep.lo elf32.lo $elf" ;;
 668     bfd_elf32_mep_little_vec)   tb="$tb elf32-mep.lo elf32.lo $elf" ;;
 669     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 670     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 671     bfd_elf32_mt_vec)           tb="$tb elf32-mt.lo elf32.lo $elf" ;;
 672     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 673     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 674     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 675     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 676     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 677     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 678     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 679     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 680     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 681     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 682     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 683     bfd_elf32_powerpc_vxworks_vec) tb="$tb elf32-ppc.lo elf-vxworks.lo elf32.lo $elf" ;;
 684     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 685     bfd_elf32_bigscore_vec)     tb="$tb elf32-score.lo elf32.lo $elf" ;;
 686     bfd_elf32_littlescore_vec)  tb="$tb elf32-score.lo elf32.lo $elf" ;;
 687     # FIXME: We include cofflink.lo not because it's needed for
 688     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 689     # which needs it but does not list it.  Should be fixed in right place.
 690     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 691     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 692     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 693     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 694     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" ;;
 695     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf cofflink.lo" ;;
 696     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 697     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 698     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 699     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 700     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 701     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 702     bfd_elf32_shlvxworks_vec)   tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 703     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 704     bfd_elf32_shvxworks_vec)    tb="$tb elf32-sh.lo elf-vxworks.lo elf32.lo $elf coff-sh.lo" ;;
 705     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 706     bfd_elf32_sparc_vxworks_vec) tb="$tb elf32-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf32.lo $elf" ;;
 707     bfd_elf32_spu_vec)          tb="$tb elf32-spu.lo elf32.lo $elf" ;;
 708     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 709     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo" ;;
 710     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 711     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 712     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 713     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 714     bfd_elf32_xc16x_vec)                tb="$tb elf32-xc16x.lo elf32.lo $elf" ;;
 715     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 716     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 717     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 718     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 719     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 720     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 721     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 722     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 723     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 724     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 725     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 726     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 727     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 728     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 729     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 730     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 731     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 732     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 733     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 734     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 735     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 736     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 737     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 738     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf64.lo $elf"; target_size=64 ;;
 739     bfd_elf64_sparc_freebsd_vec) tb="$tb elf64-sparc.lo elfxx-sparc.lo elf-vxworks.lo elf64.lo $elf"; target_size=64 ;;
 740     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 741     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf-vxworks.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 742     bfd_elf64_x86_64_freebsd_vec) tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 743     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 744     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 745     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 746     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 747     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 748     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 749     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 750     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 751     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 752     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 753     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 754     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 755     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 756     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 757     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 758     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 759     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 760     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 761     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 762     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 763     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 764     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 765     x86_64coff_vec)             tb="$tb coff-x86_64.lo cofflink.lo"; target_size=64 ;;
 766     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 767     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 768     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 769     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 770     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 771     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 772     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 773     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 774     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 775     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 776     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 777     x86_64pe_vec)               tb="$tb pe-x86_64.lo pex64igen.lo cofflink.lo"; target_size=64 ;;
 778     x86_64pei_vec)              tb="$tb pei-x86_64.lo pex64igen.lo cofflink.lo"; target_size=64 ;;
 779     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 780     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 781     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 782     ieee_vec)                   tb="$tb ieee.lo" ;;
 783     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 784     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 785     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 786     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 787     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 788     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 789     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 790     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 791     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 792     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 793     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 794     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 795     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 796     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 797     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 798     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 799     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 800     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 801     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 802     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 803     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 804     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 805     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 806     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 807     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 808     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 809     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 810     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 811     pef_vec)                    tb="$tb pef.lo" ;;
 812     pef_xlib_vec)               tb="$tb pef.lo" ;;
 813     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 814     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 815     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 816     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 817     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 818     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 819     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 820     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 821     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 822     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 823     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 824     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 825     som_vec)                    tb="$tb som.lo" ;;
 826     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 827     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 828     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 829     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 830     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 831     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 832     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 833     sym_vec)                    tb="$tb xsym.lo" ;;
 834     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 835     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 836     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 837     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 838     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 839     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 840     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 841     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 842     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 843     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 844     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 845     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 846     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 847     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 848     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 849     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 850     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 851     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 852     versados_vec)               tb="$tb versados.lo" ;;
 853     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 854     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 855     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 856     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 857     z80coff_vec)                tb="$tb coff-z80.lo reloc16.lo" ;;
 858     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo cofflink.lo" ;;
 859
 860     # These appear out of order in targets.c
 861     srec_vec)                   tb="$tb srec.lo" ;;
 862     symbolsrec_vec)             tb="$tb srec.lo" ;;
 863     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 864     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 865     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 866
 867     "")                 ;;
 868     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 869     esac
 870
 871     if test ${target_size} = 64; then
 872         target64=true
 873     fi
 874     if test x"${vec}" = x"${defvec}"; then
 875         bfd_default_target_size=${target_size}
 876     fi
 877 done
 878
 879 # Target architecture .o files.
 880 # A couple of CPUs use shorter file names to avoid problems on DOS
 881 # filesystems.
 882 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 883
 884 # Weed out duplicate .o files.
 885 f=""
 886 for i in $tb ; do
 887     case " $f " in
 888     *" $i "*) ;;
 889     *) f="$f $i" ;;
 890     esac
 891 done
 892 tb="$f"
 893
 894 f=""
 895 for i in $ta ; do
 896     case " $f " in
 897     *" $i "*) ;;
 898     *) f="$f $i" ;;
 899     esac
 900 done
 901 ta="$f"
 902
 903 bfd_backends="$tb"
 904 bfd_machines="$ta"
 905
 906 if test x${all_targets} = xtrue ; then
 907   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 908   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 909   selvecs=
 910   havevecs=
 911   selarchs=
 912   test -n "$assocvecs" &&
 913     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 914 else    # all_targets is true
 915   # Only set these if they will be nonempty, for the clever echo.
 916   havevecs=
 917   assocvecs=
 918   test -n "$selvecs" &&
 919     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 920   test -n "$selvecs" &&
 921     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 922   test -n "$selarchs" &&
 923     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 924 fi      # all_targets is true
 925
 926 case ${host64}-${target64}-${want64} in
 927   *true*)
 928     wordsize=64
 929     bfd64_libs='$(BFD64_LIBS)'
 930     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 931     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 932       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 933       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 934     fi
 935     if test -n "$GCC" ; then
 936        bad_64bit_gcc=no;
 937        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 938        # Add more tests for gcc versions with non-working 64-bit support here.
 939        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 940                     bad_64bit_gcc=yes;
 941                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 942                     AC_MSG_RESULT(no))
 943        if test $bad_64bit_gcc = yes ; then
 944          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 945        fi
 946     fi
 947     ;;
 948   false-false-false)
 949     wordsize=32
 950     all_backends='$(BFD32_BACKENDS)'
 951     ;;
 952 esac
 953
 954 AC_SUBST(wordsize)
 955 AC_SUBST(bfd64_libs)
 956 AC_SUBST(all_backends)
 957 AC_SUBST(bfd_backends)
 958 AC_SUBST(bfd_machines)
 959 AC_SUBST(bfd_default_target_size)
 960
 961 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 962 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 963 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 964 # Hopefully a reasonable assumption since fseeko et.al. should be
 965 # upward compatible.
 966 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64 fopen64)
 967 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 968     AC_CHECK_SIZEOF(off_t)
 969 fi
 970 AC_MSG_CHECKING([file_ptr type])
 971 bfd_file_ptr="long"
 972 bfd_ufile_ptr="unsigned long"
 973 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 974         -o x"${ac_cv_sizeof_off_t}" = x8; then
 975     bfd_file_ptr=BFD_HOST_64_BIT
 976     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 977 fi
 978 AC_MSG_RESULT($bfd_file_ptr)
 979 AC_SUBST(bfd_file_ptr)
 980 AC_SUBST(bfd_ufile_ptr)
 981
 982
 983 tdefaults=""
 984 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 985 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 986 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 987 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 988 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 989 AC_SUBST(tdefaults)
 990
 991 dnl AC_CHECK_HEADERS(sys/mman.h)
 992 AC_FUNC_MMAP
 993 AC_CHECK_FUNCS(madvise mprotect)
 994 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 995   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 996 esac
 997
 998 rm -f doc/config.status
 999 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
1000
1001 dnl We need this duplication, even though we use AM_PO_SUBDIRS, because of
1002 dnl our two separate POTFILES.  Yuck.
1003 AC_CONFIG_COMMANDS([default],
1004 [[
1005 case "$srcdir" in
1006   .) srcdirpre= ;;
1007   *) srcdirpre='$(srcdir)/' ;;
1008 esac
1009 POFILES=
1010 GMOFILES=
1011 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
1012   if test $lang != dummy; then
1013     POFILES="$POFILES $srcdirpre$lang.po"
1014     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
1015   fi
1016 done
1017 sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' \
1018     -e '/BLD-POTFILES =/r po/BLD-POTFILES' \
1019     -e "s,@POFILES@,$POFILES," \
1020     -e "s,@GMOFILES@,$GMOFILES," \
1021     po/Makefile.in > po/Makefile]],[[]])
1022
1023 dnl Required by html and install-html
1024 AC_SUBST(datarootdir)
1025 AC_SUBST(docdir)
1026 AC_SUBST(htmldir)
1027
1028 AC_OUTPUT
1029