bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55
  56 AM_CONFIG_HEADER(config.h:config.in)
  57
  58 if test -z "$target" ; then
  59     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  60 fi
  61
  62 AM_MAINTAINER_MODE
  63 AM_INSTALL_LIBBFD
  64 AC_EXEEXT
  65
  66 host64=false
  67 target64=false
  68 bfd_default_target_size=32
  69
  70 # host stuff:
  71
  72 AC_PROG_CC
  73
  74 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw"
  75 CY_GNU_GETTEXT
  76
  77 # Permit host specific settings.
  78 . ${srcdir}/configure.host
  79
  80 AC_SUBST(HDEFINES)
  81 AC_PROG_INSTALL
  82
  83 BFD_HOST_64BIT_LONG=0
  84 BFD_HOST_LONG_LONG=0
  85 BFD_HOST_64_BIT_DEFINED=0
  86 BFD_HOST_64_BIT=
  87 BFD_HOST_U_64_BIT=
  88
  89 AC_MSG_CHECKING([for long long])
  90 AC_CACHE_VAL(bfd_cv_has_long_long,
  91 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
  92 AC_MSG_RESULT($bfd_cv_has_long_long)
  93 if test $bfd_cv_has_long_long = yes; then
  94   BFD_HOST_LONG_LONG=1
  95   AC_COMPILE_CHECK_SIZEOF(long long)
  96 fi
  97
  98 AC_COMPILE_CHECK_SIZEOF(long)
  99 if test "x${ac_cv_sizeof_long}" = "x8"; then
 100   host64=true
 101   BFD_HOST_64BIT_LONG=1
 102   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 103   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 104 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 105   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 106   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 107 fi
 108
 109 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 110   BFD_HOST_64_BIT_DEFINED=1
 111   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 112   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 113 fi
 114
 115 AC_SUBST(BFD_HOST_64BIT_LONG)
 116 AC_SUBST(BFD_HOST_LONG_LONG)
 117 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 118 AC_SUBST(BFD_HOST_64_BIT)
 119 AC_SUBST(BFD_HOST_U_64_BIT)
 120
 121 BFD_CC_FOR_BUILD
 122
 123 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 124 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 125 AC_HEADER_TIME
 126 AC_HEADER_DIRENT
 127 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 128 AC_CHECK_FUNCS(strtoull)
 129
 130 AC_CHECK_DECLS(basename)
 131 AC_CHECK_DECLS(ftello)
 132 AC_CHECK_DECLS(ftello64)
 133 AC_CHECK_DECLS(fseeko)
 134 AC_CHECK_DECLS(fseeko64)
 135
 136 BFD_BINARY_FOPEN
 137
 138 AC_CHECK_DECLS(ffs)
 139 AC_CHECK_DECLS(free)
 140 AC_CHECK_DECLS(getenv)
 141 AC_CHECK_DECLS(malloc)
 142 AC_CHECK_DECLS(realloc)
 143 AC_CHECK_DECLS(stpcpy)
 144 AC_CHECK_DECLS(strstr)
 145
 146 # If we are configured native, pick a core file support file.
 147 COREFILE=
 148 COREFLAG=
 149 TRAD_HEADER=
 150 if test "${target}" = "${host}"; then
 151   case "${host}" in
 152   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 153         COREFILE=''
 154         ;;
 155   alpha*-*-linux-*)
 156         COREFILE=trad-core.lo
 157         TRAD_HEADER='"hosts/alphalinux.h"'
 158         ;;
 159   alpha*-*-netbsd* | alpha*-*-openbsd*)
 160         COREFILE=netbsd-core.lo
 161         ;;
 162   alpha*-*-*)           COREFILE=osf-core.lo ;;
 163   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 164                         COREFILE='' ;;
 165   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 166   arm-*-riscix)         COREFILE=trad-core.lo ;;
 167   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 168   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 169   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 170   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 171                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 172   hppa*-*-netbsd* | hppa*-*-openbsd*)
 173         COREFILE=netbsd-core.lo
 174         ;;
 175
 176   i370-*-*)
 177         COREFILE=trad-core.lo
 178         TRAD_HEADER='"hosts/i370linux.h"'
 179         ;;
 180
 181 changequote(,)dnl
 182   i[3-7]86-sequent-bsd*)
 183 changequote([,])dnl
 184         COREFILE=trad-core.lo
 185         TRAD_HEADER='"hosts/symmetry.h"'
 186         ;;
 187 changequote(,)dnl
 188   i[3-7]86-sequent-sysv4*) ;;
 189   i[3-7]86-sequent-sysv*)
 190 changequote([,])dnl
 191         COREFILE=trad-core.lo
 192         TRAD_HEADER='"hosts/symmetry.h"'
 193         ;;
 194 changequote(,)dnl
 195   i[3-7]86-*-bsdi)
 196 changequote([,])dnl
 197         COREFILE=
 198         ;;
 199 changequote(,)dnl
 200   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 201 changequote([,])dnl
 202         COREFILE=trad-core.lo
 203         TRAD_HEADER='"hosts/i386bsd.h"'
 204         ;;
 205 changequote(,)dnl
 206   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 207 changequote([,])dnl
 208         COREFILE=''
 209         TRAD_HEADER='"hosts/i386bsd.h"'
 210         ;;
 211 changequote(,)dnl
 212   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 213 changequote([,])dnl
 214         COREFILE=netbsd-core.lo
 215         ;;
 216 changequote(,)dnl
 217   i[3-7]86-esix-sysv3*)
 218 changequote([,])dnl
 219         COREFILE=trad-core.lo
 220         TRAD_HEADER='"hosts/esix.h"'
 221         ;;
 222 changequote(,)dnl
 223   i[3-7]86-*-sco3.2v5*)
 224 changequote([,])dnl
 225         COREFILE=sco5-core.lo
 226         ;;
 227 changequote(,)dnl
 228   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 229 changequote([,])dnl
 230         COREFILE=trad-core.lo
 231         TRAD_HEADER='"hosts/i386sco.h"'
 232         ;;
 233 changequote(,)dnl
 234   i[3-7]86-*-mach3*)
 235 changequote([,])dnl
 236         COREFILE=trad-core.lo
 237         TRAD_HEADER='"hosts/i386mach3.h"'
 238         ;;
 239 changequote(,)dnl
 240   i[3-7]86-*-linux-*)
 241 changequote([,])dnl
 242         COREFILE=trad-core.lo
 243         TRAD_HEADER='"hosts/i386linux.h"'
 244         ;;
 245 changequote(,)dnl
 246   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 247   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 248 changequote([,])dnl
 249   i860-*-mach3* | i860-*-osf1*)
 250         COREFILE=trad-core.lo
 251         TRAD_HEADER='"hosts/i860mach3.h"'
 252         ;;
 253   mips-*-netbsd* | mips*-*-openbsd*)
 254         COREFILE=netbsd-core.lo
 255         ;;
 256   mips-dec-*)
 257         COREFILE=trad-core.lo
 258         TRAD_HEADER='"hosts/decstation.h"'
 259         ;;
 260   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 261   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 262   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 263   mips-*-sysv4*)        ;;
 264   mips-*-sysv* | mips-*-riscos*)
 265         COREFILE=trad-core.lo
 266         TRAD_HEADER='"hosts/riscos.h"'
 267         ;;
 268   mips-sony-bsd*)
 269         COREFILE=trad-core.lo
 270         TRAD_HEADER='"hosts/news-mips.h"'
 271         ;;
 272   m68*-bull*-sysv*)
 273         COREFILE=trad-core.lo
 274         TRAD_HEADER='"hosts/dpx2.h"'
 275         ;;
 276   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 277   m68*-hp-bsd*)
 278         COREFILE=trad-core.lo
 279         TRAD_HEADER='"hosts/hp300bsd.h"'
 280         ;;
 281   m68*-*-linux-*)
 282         COREFILE=trad-core.lo
 283         TRAD_HEADER='"hosts/m68klinux.h"'
 284         ;;
 285   m68*-motorola-sysv*)
 286         COREFILE=trad-core.lo
 287         TRAD_HEADER='"hosts/delta68.h"'
 288         ;;
 289   m68*-sony-*)
 290         COREFILE=trad-core.lo
 291         TRAD_HEADER='"hosts/news.h"'
 292         ;;
 293   m68*-*-netbsd* | m68*-*-openbsd*)
 294         COREFILE=netbsd-core.lo
 295         ;;
 296   m68*-apple-aux*)
 297         COREFILE=trad-core.lo
 298         TRAD_HEADER='"hosts/m68kaux.h"'
 299         ;;
 300   m88*-*-sysv4*)
 301         ;;
 302   m88*-motorola-sysv*)
 303         COREFILE=ptrace-core.lo
 304         ;;
 305   m88*-*-mach3*)
 306         COREFILE=trad-core.lo
 307         TRAD_HEADER='"hosts/m88kmach3.h"'
 308         ;;
 309   m88*-*-openbsd*)
 310         COREFILE=netbsd-core.lo
 311         ;;
 312   ns32k-pc532-mach)
 313         COREFILE=trad-core.lo
 314         TRAD_HEADER='"hosts/pc532mach.h"'
 315         ;;
 316   ns32k-*-netbsd* | ns32k-*-openbsd*)
 317         COREFILE=netbsd-core.lo
 318         ;;
 319   rs6000-*-lynx*)
 320         COREFILE=lynx-core.lo
 321         ;;
 322   rs6000-*-aix5.* | powerpc-*-aix5.*)
 323         COREFILE=rs6000-core.lo
 324         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 325         ;;
 326 changequote(,)dnl
 327   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 328 changequote([,])dnl
 329         COREFILE=rs6000-core.lo
 330         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 331         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 332         # have c_impl as a member of struct core_dumpx
 333         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 334         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 335             [Define if struct core_dumpx has member c_impl])
 336           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 337         ;;
 338   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 339   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 340   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 341   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 342   powerpc-*-beos*)      ;;
 343   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 344                         COREFILE='' ;;
 345   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 346   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 347   s390*-*-*)            COREFILE=trad-core.lo ;;
 348   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 349   sparc-*-netbsd* | sparc*-*-openbsd*)
 350         COREFILE=netbsd-core.lo
 351         ;;
 352   tahoe-*-*)
 353         COREFILE=trad-core.lo
 354         TRAD_HEADER='"hosts/tahoe.h"'
 355         ;;
 356   vax-*-netbsd* | vax-*-openbsd*)
 357         COREFILE=netbsd-core.lo
 358         ;;
 359   vax-*-ultrix2*)
 360         COREFILE=trad-core.lo
 361         TRAD_HEADER='"hosts/vaxult2.h"'
 362         ;;
 363   vax-*-ultrix*)
 364         COREFILE=trad-core.lo
 365         TRAD_HEADER='"hosts/vaxult2.h"'
 366         ;;
 367   vax-*-linux-*)
 368         COREFILE=trad-core.lo
 369         TRAD_HEADER='"hosts/vaxlinux.h"'
 370         ;;
 371   vax-*-*)
 372         COREFILE=trad-core.lo
 373         TRAD_HEADER='"hosts/vaxbsd.h"'
 374         ;;
 375   x86_64-*-netbsd* | x86_64-*-openbsd*)
 376         COREFILE=netbsd-core.lo
 377         ;;
 378   esac
 379
 380   case "$COREFILE" in
 381   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 382   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 383   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 384   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 385   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 386   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 387   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 388   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 389   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 390   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 391   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 392   esac
 393
 394   # ELF corefile support has several flavors, but all of
 395   # them use something called <sys/procfs.h>
 396   AC_CHECK_HEADERS(sys/procfs.h)
 397   if test "$ac_cv_header_sys_procfs_h" = yes; then
 398     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 399     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 400     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 401     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 402     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 403     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 404     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 408     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 409     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 411     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 412     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 413     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 414   fi
 415 fi
 416 AC_SUBST(COREFILE)
 417 AC_SUBST(COREFLAG)
 418 if test -n "$TRAD_HEADER"; then
 419   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 420     [Name of host specific header file to include in trad-core.c.])
 421 fi
 422
 423 # Horrible hacks to build DLLs on Windows.
 424 WIN32LDFLAGS=
 425 WIN32LIBADD=
 426 case "${host}" in
 427 *-*-cygwin*)
 428   if test "$enable_shared" = "yes"; then
 429     WIN32LDFLAGS="-no-undefined"
 430     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 431   fi
 432   ;;
 433 *-*-linux*)
 434   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 435   # libiberty.a.
 436   case "${host}" in
 437   mips*-*-linux*)
 438     # Linux/MIPS uses PIC by default.
 439     if test "$enable_shared" = "yes"; then
 440       WIN32LIBADD="-L../libiberty -liberty"
 441     fi
 442     ;;
 443   *)
 444 changequote(,)dnl
 445     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 446 changequote([,])dnl
 447     if test -n "$x"; then
 448       WIN32LIBADD="-L../libiberty/pic -liberty"
 449     fi
 450   ;;
 451   esac
 452   ;;
 453 esac
 454 AC_SUBST(WIN32LDFLAGS)
 455 AC_SUBST(WIN32LIBADD)
 456
 457 # target stuff:
 458
 459 # Canonicalize the secondary target names.
 460 if test -n "$enable_targets" ; then
 461     for targ in `echo $enable_targets | sed 's/,/ /g'`
 462     do
 463         result=`$ac_config_sub $targ 2>/dev/null`
 464         if test -n "$result" ; then
 465             canon_targets="$canon_targets $result"
 466         else
 467             # Allow targets that config.sub doesn't recognize, like "all".
 468             canon_targets="$canon_targets $targ"
 469         fi
 470     done
 471 fi
 472
 473 all_targets=false
 474 defvec=
 475 selvecs=
 476 assocvecs=
 477 selarchs=
 478 TDEFINES=
 479 for targ in $target $canon_targets
 480 do
 481     if test "x$targ" = "xall"; then
 482         all_targets=true
 483         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 484     else
 485         . $srcdir/config.bfd
 486         if test "x$targ" = "x$target"; then
 487             defvec=$targ_defvec
 488         fi
 489         selvecs="$selvecs $targ_defvec $targ_selvecs"
 490         selarchs="$selarchs $targ_archs"
 491         TDEFINES="$TDEFINES $targ_cflags"
 492     fi
 493 done
 494 AC_SUBST(TDEFINES)
 495
 496 # This processing still needs to be done if we're to decide properly whether
 497 # 64-bit support needs to be compiled in.  Currently, it will be included if
 498 # the default or any other explicitly requested target requires it; it
 499 # will not be included on a 32-bit host if no 64-bit target is requested, and
 500 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 501 # used.
 502
 503 # uniq the default and selected vectors in all the configured targets.
 504 f=""
 505 for i in $selvecs ; do
 506     case " $f " in
 507     *" $i "*) ;;
 508     *) f="$f $i" ;;
 509     esac
 510 done
 511 selvecs="$f"
 512
 513
 514 # uniq the associated vectors in all the configured targets.
 515 f=""
 516 for i in $assocvecs ; do
 517     case " $f " in
 518     *" $i "*) ;;
 519     *) f="$f $i" ;;
 520     esac
 521 done
 522 assocvecs="$f"
 523
 524
 525 # uniq the architectures in all the configured targets.
 526 f=""
 527 for i in $selarchs ; do
 528     case " $f " in
 529     *" $i "*) ;;
 530     *) f="$f $i" ;;
 531     esac
 532 done
 533 selarchs="$f"
 534
 535 # Target backend .o files.
 536 tb=
 537
 538 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 539
 540 for vec in $selvecs
 541 do
 542     target_size=32
 543     case "$vec" in
 544     # This list is alphabetized to make it easy to compare
 545     # with the two vector lists in targets.c.  For the same reason,
 546     # use one entry per line, even though this leads to long lines.
 547     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 548     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 549     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 550     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 551     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 552     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 553     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 554     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 555     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 556     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 557     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 558     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 559     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 560     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 561     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 562     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 563     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 564     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 565     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 566     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 567     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 568     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 569     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 570     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 571     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 572     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 573     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 574     bfd_elf32_bigarm_symbian_vec)
 575                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 576     bfd_elf32_bigarm_vxworks_vec)
 577                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 578     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 579     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 580     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 581     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 582     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 583     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 584     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 585     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 586     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 587     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 588     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 589     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 590     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 591     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 592     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 593     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 594     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 595     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 596     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 597     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 598     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 599     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 600     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 601     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 602     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 603     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 604     bfd_elf32_littlearm_symbian_vec)
 605                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 606     bfd_elf32_littlearm_vxworks_vec)
 607                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 608     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 609     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 610     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 611     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 612     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 613     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 614     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 615     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 616     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 617     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 618     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 619     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 620     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 621     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 622     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 623     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 624     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 625     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 626     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 627     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 628     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 629     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 630     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 631     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 632     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 633     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 634     # FIXME: We include cofflink.lo not because it's needed for
 635     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 636     # which needs it but does not list it.  Should be fixed in right place.
 637     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 638     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 639     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 640     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 641     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 642     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 643     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 644     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 645     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 646     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 647     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 648     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 649     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 650     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
 651     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 652     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 653     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 654     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 655     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 656     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 657     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 658     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 659     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 660     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 661     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 662     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 663     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 664     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 665     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 666     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 667     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 668     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 669     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 670     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 671     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 672     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 673     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 674     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 675     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 676     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 677     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 678     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 679     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 680     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
 681     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 682     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 683     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 684     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 685     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 686     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 687     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 688     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 689     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 690     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 691     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 692     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 693     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 694     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 695     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 696     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 697     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 698     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 699     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 700     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 701     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 702     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 703     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 704     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 705     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 706     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 707     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 708     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 709     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 710     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 711     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 712     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 713     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 714     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 715     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 716     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 717     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 718     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 719     ieee_vec)                   tb="$tb ieee.lo" ;;
 720     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 721     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 722     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 723     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 724     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 725     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 726     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 727     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 728     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 729     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 730     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 731     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 732     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 733     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 734     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 735     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 736     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 737     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 738     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 739     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 740     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 741     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 742     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 743     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 744     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 745     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 746     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 747     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 748     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 749     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 750     pef_vec)                    tb="$tb pef.lo" ;;
 751     pef_xlib_vec)               tb="$tb pef.lo" ;;
 752     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 753     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 754     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 755     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 756     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 757     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 758     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 759     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 760     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 761     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 762     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 763     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 764     som_vec)                    tb="$tb som.lo" ;;
 765     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 766     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 767     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 768     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 769     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 770     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 771     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 772     sym_vec)                    tb="$tb xsym.lo" ;;
 773     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 774     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 775     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 776     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 777     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 778     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 779     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 780     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 781     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 782     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 783     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 784     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 785     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 786     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 787     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 788     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 789     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 790     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 791     versados_vec)               tb="$tb versados.lo" ;;
 792     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 793     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 794     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 795     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 796     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 797
 798     # These appear out of order in targets.c
 799     srec_vec)                   tb="$tb srec.lo" ;;
 800     symbolsrec_vec)             tb="$tb srec.lo" ;;
 801     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 802     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 803     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 804
 805     "")                 ;;
 806     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 807     esac
 808
 809     if test ${target_size} = 64; then
 810         target64=true
 811     fi
 812     if test x"${vec}" = x"${defvec}"; then
 813         bfd_default_target_size=${target_size}
 814     fi
 815 done
 816
 817 # Target architecture .o files.
 818 # A couple of CPUs use shorter file names to avoid problems on DOS
 819 # filesystems.
 820 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 821
 822 # Weed out duplicate .o files.
 823 f=""
 824 for i in $tb ; do
 825     case " $f " in
 826     *" $i "*) ;;
 827     *) f="$f $i" ;;
 828     esac
 829 done
 830 tb="$f"
 831
 832 f=""
 833 for i in $ta ; do
 834     case " $f " in
 835     *" $i "*) ;;
 836     *) f="$f $i" ;;
 837     esac
 838 done
 839 ta="$f"
 840
 841 bfd_backends="$tb"
 842 bfd_machines="$ta"
 843
 844 if test x${all_targets} = xtrue ; then
 845   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 846   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 847   selvecs=
 848   havevecs=
 849   selarchs=
 850   test -n "$assocvecs" &&
 851     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 852 else    # all_targets is true
 853   # Only set these if they will be nonempty, for the clever echo.
 854   havevecs=
 855   assocvecs=
 856   test -n "$selvecs" &&
 857     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 858   test -n "$selvecs" &&
 859     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 860   test -n "$selarchs" &&
 861     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 862 fi      # all_targets is true
 863
 864 case ${host64}-${target64}-${want64} in
 865   *true*)
 866     wordsize=64
 867     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 868     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 869     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 870       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 871       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 872     fi
 873     if test -n "$GCC" ; then
 874        bad_64bit_gcc=no;
 875        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 876        # Add more tests for gcc versions with non-working 64-bit support here.
 877        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 878                     bad_64bit_gcc=yes;
 879                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 880                     AC_MSG_RESULT(no))
 881        if test $bad_64bit_gcc = yes ; then
 882          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 883        fi
 884     fi
 885     ;;
 886   false-false-false)
 887     wordsize=32
 888     bfd_libs='$(BFD32_LIBS)'
 889     all_backends='$(BFD32_BACKENDS)'
 890     ;;
 891 esac
 892
 893 AC_SUBST(wordsize)
 894 AC_SUBST(bfd_libs)
 895 AC_SUBST(all_backends)
 896 AC_SUBST(bfd_backends)
 897 AC_SUBST(bfd_machines)
 898 AC_SUBST(bfd_default_target_size)
 899
 900 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 901 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 902 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 903 # Hopefully a reasonable assumption since fseeko et.al. should be
 904 # upward compatible.
 905 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 906 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 907     AC_COMPILE_CHECK_SIZEOF(off_t)
 908 fi
 909 AC_MSG_CHECKING([file_ptr type])
 910 bfd_file_ptr="long"
 911 bfd_ufile_ptr="unsigned long"
 912 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 913         -o x"${ac_cv_sizeof_off_t}" = x8; then
 914     bfd_file_ptr=BFD_HOST_64_BIT
 915     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 916 fi
 917 AC_MSG_RESULT($bfd_file_ptr)
 918 AC_SUBST(bfd_file_ptr)
 919 AC_SUBST(bfd_ufile_ptr)
 920
 921
 922 tdefaults=""
 923 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 924 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 925 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 926 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 927 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 928 AC_SUBST(tdefaults)
 929
 930 dnl AC_CHECK_HEADERS(sys/mman.h)
 931 AC_FUNC_MMAP
 932 AC_CHECK_FUNCS(madvise mprotect)
 933 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 934   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 935 esac
 936
 937 rm -f doc/config.status
 938 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 939 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 940 AC_OUTPUT
 941