binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2015 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 AC_ARG_ENABLE(targets,
  38 [  --enable-targets        alternative target configurations],
  39 [case "${enableval}" in
  40   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  41             ;;
  42   no)       enable_targets= ;;
  43   *)        enable_targets=$enableval ;;
  44 esac])dnl
  45
  46 AC_ARG_ENABLE(deterministic-archives,
  47 [AS_HELP_STRING([--enable-deterministic-archives],
  48                 [ar and ranlib default to -D behavior])], [
  49 if test "${enableval}" = no; then
  50   default_ar_deterministic=0
  51 else
  52   default_ar_deterministic=1
  53 fi], [default_ar_deterministic=0])
  54
  55 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  56                    [Should ar and ranlib use -D behavior by default?])
  57
  58 AC_ARG_ENABLE(default-strings-all,
  59 [AS_HELP_STRING([--disable-default-strings-all],
  60                 [strings defaults to --data behavior])], [
  61 if test "${enableval}" = no; then
  62   default_strings_all=0
  63 else
  64   default_strings_all=1
  65 fi], [default_strings_all=1])
  66
  67 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  68                    [Should strings use -a behavior by default?])
  69
  70 AM_BINUTILS_WARNINGS
  71
  72 AC_CONFIG_HEADERS(config.h:config.in)
  73
  74 AH_VERBATIM([00_CONFIG_H_CHECK],
  75 [/* Check that config.h is #included before system headers
  76    (this works only for glibc, but that should be enough).  */
  77 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  78 #  error config.h must be #included before system headers
  79 #endif
  80 #define __CONFIG_H__ 1])
  81
  82 if test -z "$target" ; then
  83     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  84 fi
  85 if test -z "$host" ; then
  86     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  87 fi
  88
  89 AC_PROG_YACC
  90 AM_PROG_LEX
  91
  92 ALL_LINGUAS="bg da es fi fr id it ja ro ru rw sk sv tr uk vi zh_CN zh_TW hr"
  93 ZW_GNU_GETTEXT_SISTER_DIR
  94 AM_PO_SUBDIRS
  95
  96 AM_MAINTAINER_MODE
  97 AM_CONDITIONAL(GENINSRC_NEVER, false)
  98 AC_EXEEXT
  99 if test -n "$EXEEXT"; then
 100   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 101             [Does the platform use an executable suffix?])
 102 fi
 103 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 104                    [Suffix used for executables, if any.])
 105
 106 # host-specific stuff:
 107
 108 HDEFINES=
 109
 110 . ${srcdir}/../bfd/configure.host
 111
 112 AC_SUBST(HDEFINES)
 113 AR=${AR-ar}
 114 AC_SUBST(AR)
 115 AC_PROG_RANLIB
 116 AC_PROG_INSTALL
 117
 118 BFD_CC_FOR_BUILD
 119
 120 DEMANGLER_NAME=c++filt
 121 case "${host}" in
 122   *-*-go32* | *-*-msdos*)
 123     DEMANGLER_NAME=cxxfilt
 124 esac
 125 AC_SUBST(DEMANGLER_NAME)
 126
 127 AC_CHECK_SIZEOF([long])
 128 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 129
 130 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h wchar.h)
 131 AC_HEADER_SYS_WAIT
 132 ACX_HEADER_STRING
 133 AC_FUNC_ALLOCA
 134 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
 135 AC_CHECK_FUNC([mkstemp],
 136               AC_DEFINE([HAVE_MKSTEMP], 1,
 137               [Define to 1 if you have the `mkstemp' function.]))
 138 AC_CHECK_FUNC([mkdtemp],
 139               AC_DEFINE([HAVE_MKDTEMP], 1,
 140               [Define to 1 if you have the `mkdtemp' function.]))
 141   AC_MSG_CHECKING([for mbstate_t])
 142   AC_TRY_COMPILE([#include <wchar.h>],
 143   [mbstate_t teststate;],
 144   have_mbstate_t=yes, have_mbstate_t=no)
 145   AC_MSG_RESULT($have_mbstate_t)
 146   if test x"$have_mbstate_t" = xyes; then
 147     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 148   fi
 149
 150 # Some systems have frexp only in -lm, not in -lc.
 151 AC_SEARCH_LIBS(frexp, m)
 152
 153 AM_LC_MESSAGES
 154
 155 AC_MSG_CHECKING(for time_t in time.h)
 156 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 157 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 158 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 159 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 160 if test $bu_cv_decl_time_t_time_h = yes; then
 161   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 162             [Is the type time_t defined in <time.h>?])
 163 fi
 164
 165 AC_MSG_CHECKING(for time_t in sys/types.h)
 166 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 167 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 168 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 169 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 170 if test $bu_cv_decl_time_t_types_h = yes; then
 171   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 172             [Is the type time_t defined in <sys/types.h>?])
 173 fi
 174
 175 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 176 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 177 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 178 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 179 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 180 if test $bu_cv_decl_getopt_unistd_h = yes; then
 181   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 182             [Is the prototype for getopt in <unistd.h> in the expected format?])
 183 fi
 184
 185 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 186 # by default.
 187 AC_MSG_CHECKING([for utime.h])
 188 AC_CACHE_VAL(bu_cv_header_utime_h,
 189 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 190 #ifdef HAVE_TIME_H
 191 #include <time.h>
 192 #endif
 193 #include <utime.h>],
 194 [struct utimbuf s;])],
 195 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 196 AC_MSG_RESULT($bu_cv_header_utime_h)
 197 if test $bu_cv_header_utime_h = yes; then
 198   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 199 fi
 200
 201 AC_CHECK_DECLS([environ, fprintf, getc_unlocked, getenv,
 202                 sbrk, snprintf, stpcpy, strnlen, strstr, vsnprintf])
 203
 204 # Use the system's zlib library.
 205 zlibdir=-L../zlib
 206 zlibinc="-I\$(srcdir)/../zlib"
 207 AC_ARG_WITH(system-zlib,
 208 [AS_HELP_STRING([--with-system-zlib], [use installed libz])],
 209 zlibdir=
 210 zlibinc=
 211 )
 212 AC_SUBST(zlibdir)
 213 AC_SUBST(zlibinc)
 214
 215 BFD_BINARY_FOPEN
 216
 217 # target-specific stuff:
 218
 219 # Canonicalize the secondary target names.
 220 if test -n "$enable_targets"; then
 221     for targ in `echo $enable_targets | sed 's/,/ /g'`
 222     do
 223         result=`$ac_config_sub $targ 2>/dev/null`
 224         if test -n "$result"; then
 225             canon_targets="$canon_targets $result"
 226         else
 227             # Allow targets that config.sub doesn't recognize, like "all".
 228             canon_targets="$canon_targets $targ"
 229         fi
 230     done
 231 fi
 232
 233 AC_CHECK_HEADER(iconv.h)
 234 AM_ICONV
 235
 236 all_targets=false
 237 BUILD_NLMCONV=
 238 NLMCONV_DEFS=
 239 BUILD_SRCONV=
 240 BUILD_DLLTOOL=
 241 DLLTOOL_DEFS=
 242 DLLTOOL_DEFAULT=
 243 BUILD_WINDRES=
 244 BUILD_WINDMC=
 245 BUILD_DLLWRAP=
 246 BUILD_MISC=
 247 BUILD_INSTALL_MISC=
 248 OBJDUMP_DEFS=
 249 OBJDUMP_PRIVATE_VECTORS=
 250 OBJDUMP_PRIVATE_OFILES=
 251 od_vectors=
 252
 253 for targ in $target $canon_targets
 254 do
 255     if test "x$targ" = "xall"; then
 256         all_targets=true
 257         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 258         BUILD_SRCONV='$(SRCONV_PROG)'
 259         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 260         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 261         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 262         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 263         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 264         if test -z "$DLLTOOL_DEFAULT"; then
 265           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 266         fi
 267         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 268         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 269         od_vectors="$od_vectors objdump_private_desc_xcoff"
 270     else
 271         case $targ in
 272 changequote(,)dnl
 273         i[3-7]86*-*-netware*)
 274 changequote([,])dnl
 275           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 276           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 277           ;;
 278         alpha*-*-netware*)
 279           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 280           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 281           ;;
 282         powerpc*-*-netware*)
 283           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 284           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 285           ;;
 286         sparc*-*-netware*)
 287           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 288           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 289           ;;
 290         esac
 291
 292         case $targ in
 293         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 294         esac
 295
 296         case $targ in
 297         arm-epoc-pe*)
 298           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 299           if test -z "$DLLTOOL_DEFAULT"; then
 300             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 301           fi
 302           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 303           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 304           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 305           ;;
 306         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 307           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 308           if test -z "$DLLTOOL_DEFAULT"; then
 309             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 310           fi
 311           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 312           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 313           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 314           ;;
 315         arm-*-pe*)
 316           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 317           if test -z "$DLLTOOL_DEFAULT"; then
 318             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 319           fi
 320           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 321           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 322           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 323           ;;
 324         x86_64-*-mingw* | x86_64-*-cygwin*)
 325           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 326           if test -z "$DLLTOOL_DEFAULT"; then
 327             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 328           fi
 329           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 330           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 331           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 332           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 333           ;;
 334 changequote(,)dnl
 335         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 336 changequote([,])dnl
 337           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 338           if test -z "$DLLTOOL_DEFAULT"; then
 339             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 340           fi
 341           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 342           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 343           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 344           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 345           ;;
 346 changequote(,)dnl
 347         i[3-7]86-*-interix)
 348 changequote([,])dnl
 349           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 350           if test -z "$DLLTOOL_DEFAULT"; then
 351             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 352           fi
 353           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 354           ;;
 355 changequote(,)dnl
 356         powerpc*-aix5.[01])
 357 changequote([,])dnl
 358           ;;
 359 changequote(,)dnl
 360         powerpc*-aix[5-9].*)
 361 changequote([,])dnl
 362           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 363           ;;
 364         powerpc*-*-pe* | powerpc*-*-cygwin*)
 365           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 366           if test -z "$DLLTOOL_DEFAULT"; then
 367             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 368           fi
 369           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 370           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 371           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 372           ;;
 373         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 374           case "$BUILD_INSTALL_MISC" in
 375             *embedspu*) ;;
 376             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 377           esac
 378           ;;
 379         sh*-*-pe)
 380           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 381           if test -z "$DLLTOOL_DEFAULT"; then
 382             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 383           fi
 384           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 385           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 386           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 387           ;;
 388         spu-*-*)
 389           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 390           ;;
 391         mips*-*-pe)
 392           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 393           if test -z "$DLLTOOL_DEFAULT"; then
 394             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 395           fi
 396           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 397           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 398           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 399           ;;
 400         mcore-*-pe)
 401           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 402           if test -z "$DLLTOOL_DEFAULT"; then
 403             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 404           fi
 405           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 406           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 407           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 408           ;;
 409         mcore-*-elf)
 410           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 411           if test -z "$DLLTOOL_DEFAULT"; then
 412             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 413           fi
 414           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 415           ;;
 416         mep-*)
 417           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 418           ;;
 419         esac
 420
 421         # Add objdump private vectors.
 422         case $targ in
 423         avr-*-*)
 424           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 425           ;;
 426         powerpc-*-aix*)
 427           od_vectors="$od_vectors objdump_private_desc_xcoff"
 428           ;;
 429         *-*-darwin*)
 430           od_vectors="$od_vectors objdump_private_desc_mach_o"
 431           ;;
 432         esac
 433     fi
 434 done
 435
 436 # Uniq objdump private vector, build objdump target ofiles.
 437 od_files=
 438 f=""
 439 for i in $od_vectors ; do
 440     case " $f " in
 441     *" $i "*) ;;
 442     *)
 443         f="$f $i"
 444         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 445         case $i in
 446         objdump_private_desc_elf32_avr)
 447             od_files="$od_files od-elf32_avr" ;;
 448         objdump_private_desc_xcoff)
 449             od_files="$od_files od-xcoff" ;;
 450         objdump_private_desc_mach_o)
 451             od_files="$od_files od-macho" ;;
 452         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 453         esac
 454         ;;
 455     esac
 456 done
 457
 458 # Uniq objdump target ofiles
 459 f=""
 460 for i in $od_files ; do
 461     case " $f " in
 462     *" $i "*) ;;
 463     *)
 464         f="$f $i"
 465         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 466         ;;
 467     esac
 468 done
 469
 470 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 471
 472 if test "${with_windres+set}" = set; then
 473           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 474 fi
 475
 476 if test "${with_windmc+set}" = set; then
 477           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 478 fi
 479
 480 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 481
 482 AC_SUBST(NLMCONV_DEFS)
 483 AC_SUBST(BUILD_NLMCONV)
 484 AC_SUBST(BUILD_SRCONV)
 485 AC_SUBST(BUILD_DLLTOOL)
 486 AC_SUBST(DLLTOOL_DEFS)
 487 AC_SUBST(BUILD_WINDRES)
 488 AC_SUBST(BUILD_WINDMC)
 489 AC_SUBST(BUILD_DLLWRAP)
 490 AC_SUBST(BUILD_MISC)
 491 AC_SUBST(BUILD_INSTALL_MISC)
 492 AC_SUBST(OBJDUMP_DEFS)
 493 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 494
 495 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 496
 497 targ=$target
 498 . $srcdir/../bfd/config.bfd
 499 if test "x$targ_underscore" = "xyes"; then
 500     UNDERSCORE=1
 501 else
 502     UNDERSCORE=0
 503 fi
 504 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 505  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 506
 507 # Emulation
 508 targ=$target
 509 . ${srcdir}/configure.tgt
 510 EMULATION=$targ_emul
 511 EMULATION_VECTOR=$targ_emul_vector
 512
 513 AC_SUBST(EMULATION)
 514 AC_SUBST(EMULATION_VECTOR)
 515
 516 # Required for html and install-html
 517 AC_SUBST(datarootdir)
 518 AC_SUBST(docdir)
 519 AC_SUBST(htmldir)
 520 AC_SUBST(pdfdir)
 521
 522 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 523 AC_OUTPUT