binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 ACX_LARGEFILE
  20 LT_INIT
  21
  22 AC_ARG_ENABLE(targets,
  23 [  --enable-targets        alternative target configurations],
  24 [case "${enableval}" in
  25   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  26             ;;
  27   no)       enable_targets= ;;
  28   *)        enable_targets=$enableval ;;
  29 esac])dnl
  30
  31 AC_ARG_ENABLE(deterministic-archives,
  32 [AS_HELP_STRING([--enable-deterministic-archives],
  33                 [ar and ranlib default to -D behavior])], [
  34 if test "${enableval}" = no; then
  35   default_ar_deterministic=0
  36 else
  37   default_ar_deterministic=1
  38 fi], [default_ar_deterministic=0])
  39
  40 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  41                    [Should ar and ranlib use -D behavior by default?])
  42
  43 AM_BINUTILS_WARNINGS
  44
  45 AC_CONFIG_HEADERS(config.h:config.in)
  46
  47 if test -z "$target" ; then
  48     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  49 fi
  50 if test -z "$host" ; then
  51     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  52 fi
  53
  54 AC_PROG_YACC
  55 AM_PROG_LEX
  56
  57 ALL_LINGUAS="da es fi fr id ja ro ru rw sk sv tr uk vi zh_CN zh_TW bg"
  58 ZW_GNU_GETTEXT_SISTER_DIR
  59 AM_PO_SUBDIRS
  60
  61 AM_MAINTAINER_MODE
  62 AM_CONDITIONAL(GENINSRC_NEVER, false)
  63 AC_EXEEXT
  64 if test -n "$EXEEXT"; then
  65   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  66             [Does the platform use an executable suffix?])
  67 fi
  68 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  69                    [Suffix used for executables, if any.])
  70
  71 # host-specific stuff:
  72
  73 HDEFINES=
  74
  75 . ${srcdir}/../bfd/configure.host
  76
  77 AC_SUBST(HDEFINES)
  78 AR=${AR-ar}
  79 AC_SUBST(AR)
  80 AC_PROG_RANLIB
  81 AC_PROG_INSTALL
  82
  83 BFD_CC_FOR_BUILD
  84
  85 DEMANGLER_NAME=c++filt
  86 case "${host}" in
  87   *-*-go32* | *-*-msdos*)
  88     DEMANGLER_NAME=cxxfilt
  89 esac
  90 AC_SUBST(DEMANGLER_NAME)
  91
  92 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h sys/param.h)
  93 AC_HEADER_SYS_WAIT
  94 AC_FUNC_ALLOCA
  95 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  96 AC_CHECK_FUNC([mkstemp],
  97               AC_DEFINE([HAVE_MKSTEMP], 1,
  98               [Define to 1 if you have the `mkstemp' function.]))
  99 AC_CHECK_FUNC([mkdtemp],
 100               AC_DEFINE([HAVE_MKDTEMP], 1,
 101               [Define to 1 if you have the `mkdtemp' function.]))
 102
 103 # Some systems have frexp only in -lm, not in -lc.
 104 AC_SEARCH_LIBS(frexp, m)
 105
 106 AC_MSG_CHECKING(for time_t in time.h)
 107 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 108 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 109 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 110 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 111 if test $bu_cv_decl_time_t_time_h = yes; then
 112   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 113             [Is the type time_t defined in <time.h>?])
 114 fi
 115
 116 AC_MSG_CHECKING(for time_t in sys/types.h)
 117 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 118 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 119 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 120 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 121 if test $bu_cv_decl_time_t_types_h = yes; then
 122   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 123             [Is the type time_t defined in <sys/types.h>?])
 124 fi
 125
 126 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 127 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 128 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 129 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 130 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 131 if test $bu_cv_decl_getopt_unistd_h = yes; then
 132   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 133             [Is the prototype for getopt in <unistd.h> in the expected format?])
 134 fi
 135
 136 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 137 # by default.
 138 AC_MSG_CHECKING([for utime.h])
 139 AC_CACHE_VAL(bu_cv_header_utime_h,
 140 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 141 #ifdef HAVE_TIME_H
 142 #include <time.h>
 143 #endif
 144 #include <utime.h>],
 145 [struct utimbuf s;])],
 146 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 147 AC_MSG_RESULT($bu_cv_header_utime_h)
 148 if test $bu_cv_header_utime_h = yes; then
 149   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 150 fi
 151
 152 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 153                 snprintf, vsnprintf])
 154
 155 # Link in zlib if we can.  This allows us to read compressed debug
 156 # sections.  This is used only by readelf.c (objdump uses bfd for
 157 # reading compressed sections).
 158 AM_ZLIB
 159
 160 BFD_BINARY_FOPEN
 161
 162 # target-specific stuff:
 163
 164 # Canonicalize the secondary target names.
 165 if test -n "$enable_targets"; then
 166     for targ in `echo $enable_targets | sed 's/,/ /g'`
 167     do
 168         result=`$ac_config_sub $targ 2>/dev/null`
 169         if test -n "$result"; then
 170             canon_targets="$canon_targets $result"
 171         else
 172             # Allow targets that config.sub doesn't recognize, like "all".
 173             canon_targets="$canon_targets $targ"
 174         fi
 175     done
 176 fi
 177
 178 AC_CHECK_HEADER(iconv.h)
 179 AM_ICONV
 180
 181 all_targets=false
 182 BUILD_NLMCONV=
 183 NLMCONV_DEFS=
 184 BUILD_SRCONV=
 185 BUILD_DLLTOOL=
 186 DLLTOOL_DEFS=
 187 DLLTOOL_DEFAULT=
 188 BUILD_WINDRES=
 189 BUILD_WINDMC=
 190 BUILD_DLLWRAP=
 191 BUILD_MISC=
 192 BUILD_INSTALL_MISC=
 193 OBJDUMP_DEFS=
 194 OBJDUMP_PRIVATE_VECTORS=
 195 OBJDUMP_PRIVATE_OFILES=
 196 od_vectors=
 197
 198 for targ in $target $canon_targets
 199 do
 200     if test "x$targ" = "xall"; then
 201         all_targets=true
 202         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 203         BUILD_SRCONV='$(SRCONV_PROG)'
 204         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 205         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 206         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 207         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 208         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 209         if test -z "$DLLTOOL_DEFAULT"; then
 210           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 211         fi
 212         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 213         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 214         od_vectors="$od_vectors objdump_private_desc_xcoff"
 215     else
 216         case $targ in
 217 changequote(,)dnl
 218         i[3-7]86*-*-netware*)
 219 changequote([,])dnl
 220           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 221           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 222           ;;
 223         alpha*-*-netware*)
 224           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 225           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 226           ;;
 227         powerpc*-*-netware*)
 228           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 229           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 230           ;;
 231         sparc*-*-netware*)
 232           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 233           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 234           ;;
 235         esac
 236
 237         case $targ in
 238         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 239         esac
 240
 241         case $targ in
 242         arm-epoc-pe*)
 243           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 244           if test -z "$DLLTOOL_DEFAULT"; then
 245             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 246           fi
 247           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 248           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 249           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 250           ;;
 251         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 252           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 253           if test -z "$DLLTOOL_DEFAULT"; then
 254             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 255           fi
 256           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 257           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 258           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 259           ;;
 260         arm-*-pe*)
 261           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 262           if test -z "$DLLTOOL_DEFAULT"; then
 263             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 264           fi
 265           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 266           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 267           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 268           ;;
 269         x86_64-*-mingw*)
 270           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 271           if test -z "$DLLTOOL_DEFAULT"; then
 272             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 273           fi
 274           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 275           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 276           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 277           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 278           ;;
 279 changequote(,)dnl
 280         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 281 changequote([,])dnl
 282           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 283           if test -z "$DLLTOOL_DEFAULT"; then
 284             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 285           fi
 286           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 287           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 288           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 289           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 290           ;;
 291 changequote(,)dnl
 292         i[3-7]86-*-interix)
 293 changequote([,])dnl
 294           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 295           if test -z "$DLLTOOL_DEFAULT"; then
 296             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 297           fi
 298           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 299           ;;
 300 changequote(,)dnl
 301         powerpc*-aix5.[01])
 302 changequote([,])dnl
 303           ;;
 304 changequote(,)dnl
 305         powerpc*-aix[5-9].*)
 306 changequote([,])dnl
 307           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 308           ;;
 309         powerpc*-*-pe* | powerpc*-*-cygwin*)
 310           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 311           if test -z "$DLLTOOL_DEFAULT"; then
 312             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 313           fi
 314           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 315           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 316           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 317           ;;
 318         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 319           case "$BUILD_INSTALL_MISC" in
 320             *embedspu*) ;;
 321             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 322           esac
 323           ;;
 324         sh*-*-pe)
 325           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 326           if test -z "$DLLTOOL_DEFAULT"; then
 327             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 328           fi
 329           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 330           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 331           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 332           ;;
 333         spu-*-*)
 334           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 335           ;;
 336         mips*-*-pe)
 337           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 338           if test -z "$DLLTOOL_DEFAULT"; then
 339             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 340           fi
 341           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 342           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 343           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 344           ;;
 345         mcore-*-pe)
 346           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 347           if test -z "$DLLTOOL_DEFAULT"; then
 348             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 349           fi
 350           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 351           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 352           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 353           ;;
 354         mcore-*-elf)
 355           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 356           if test -z "$DLLTOOL_DEFAULT"; then
 357             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 358           fi
 359           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 360           ;;
 361         mep-*)
 362           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 363           ;;
 364         esac
 365
 366         # Add objdump private vectors.
 367         case $targ in
 368         powerpc-*-aix*)
 369           od_vectors="$od_vectors objdump_private_desc_xcoff"
 370           ;;
 371         *-*-darwin*)
 372           od_vectors="$od_vectors objdump_private_desc_mach_o"
 373           ;;
 374         esac
 375     fi
 376 done
 377
 378 # Uniq objdump private vector, build objdump target ofiles.
 379 od_files=
 380 f=""
 381 for i in $od_vectors ; do
 382     case " $f " in
 383     *" $i "*) ;;
 384     *)
 385         f="$f $i"
 386         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 387         case $i in
 388         objdump_private_desc_xcoff)
 389             od_files="$od_files od-xcoff" ;;
 390         objdump_private_desc_mach_o)
 391             od_files="$od_files od-macho" ;;
 392         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 393         esac
 394         ;;
 395     esac
 396 done
 397
 398 # Uniq objdump target ofiles
 399 f=""
 400 for i in $od_files ; do
 401     case " $f " in
 402     *" $i "*) ;;
 403     *)
 404         f="$f $i"
 405         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 406         ;;
 407     esac
 408 done
 409
 410 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 411
 412 if test "${with_windres+set}" = set; then
 413           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 414 fi
 415
 416 if test "${with_windmc+set}" = set; then
 417           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 418 fi
 419
 420 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 421
 422 AC_SUBST(NLMCONV_DEFS)
 423 AC_SUBST(BUILD_NLMCONV)
 424 AC_SUBST(BUILD_SRCONV)
 425 AC_SUBST(BUILD_DLLTOOL)
 426 AC_SUBST(DLLTOOL_DEFS)
 427 AC_SUBST(BUILD_WINDRES)
 428 AC_SUBST(BUILD_WINDMC)
 429 AC_SUBST(BUILD_DLLWRAP)
 430 AC_SUBST(BUILD_MISC)
 431 AC_SUBST(BUILD_INSTALL_MISC)
 432 AC_SUBST(OBJDUMP_DEFS)
 433 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 434
 435 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 436
 437 targ=$target
 438 . $srcdir/../bfd/config.bfd
 439 if test "x$targ_underscore" = "xyes"; then
 440     UNDERSCORE=1
 441 else
 442     UNDERSCORE=0
 443 fi
 444 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 445  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 446
 447 # Emulation
 448 targ=$target
 449 . ${srcdir}/configure.tgt
 450 EMULATION=$targ_emul
 451 EMULATION_VECTOR=$targ_emul_vector
 452
 453 AC_SUBST(EMULATION)
 454 AC_SUBST(EMULATION_VECTOR)
 455
 456 # Required for html and install-html
 457 AC_SUBST(datarootdir)
 458 AC_SUBST(docdir)
 459 AC_SUBST(htmldir)
 460 AC_SUBST(pdfdir)
 461
 462 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 463 AC_OUTPUT