binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_ENABLE(targets,
  17 [  --enable-targets        alternative target configurations],
  18 [case "${enableval}" in
  19   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  20             ;;
  21   no)       enable_targets= ;;
  22   *)        enable_targets=$enableval ;;
  23 esac])dnl
  24 AC_ARG_ENABLE(commonbfdlib,
  25 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  26 [case "${enableval}" in
  27   yes) commonbfdlib=true ;;
  28   no)  commonbfdlib=false ;;
  29   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  30 esac])dnl
  31
  32 AM_BINUTILS_WARNINGS
  33
  34 AM_CONFIG_HEADER(config.h:config.in)
  35
  36 if test -z "$target" ; then
  37     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  38 fi
  39 if test -z "$host" ; then
  40     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  41 fi
  42
  43 AC_PROG_CC
  44 AC_GNU_SOURCE
  45
  46 AC_PROG_YACC
  47 AM_PROG_LEX
  48
  49 ALL_LINGUAS="fr tr ja es sv da zh_CN ru ro rw zh_TW"
  50 CY_GNU_GETTEXT
  51
  52 AM_MAINTAINER_MODE
  53 AC_EXEEXT
  54 if test -n "$EXEEXT"; then
  55   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  56             [Does the platform use an executable suffix?])
  57 fi
  58 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  59                    [Suffix used for executables, if any.])
  60
  61 # host-specific stuff:
  62
  63 HDEFINES=
  64
  65 . ${srcdir}/../bfd/configure.host
  66
  67 AC_SUBST(HDEFINES)
  68 AR=${AR-ar}
  69 AC_SUBST(AR)
  70 AC_PROG_RANLIB
  71 AC_PROG_INSTALL
  72
  73 BFD_CC_FOR_BUILD
  74
  75 DEMANGLER_NAME=c++filt
  76 case "${host}" in
  77   *-*-go32* | *-*-msdos*)
  78     DEMANGLER_NAME=cxxfilt
  79 esac
  80 AC_SUBST(DEMANGLER_NAME)
  81
  82 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h)
  83 AC_HEADER_SYS_WAIT
  84 AC_FUNC_ALLOCA
  85 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  86
  87 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  88 # needs to be defined for it
  89 AC_MSG_CHECKING([for fopen64])
  90 AC_CACHE_VAL(bu_cv_have_fopen64,
  91 [AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
  92 bu_cv_have_fopen64=yes,
  93 [saved_CPPFLAGS=$CPPFLAGS
  94  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
  95  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
  96 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
  97 bu_cv_have_fopen64=no)
  98  CPPFLAGS=$saved_CPPFLAGS])])
  99 AC_MSG_RESULT($bu_cv_have_fopen64)
 100 if test "$bu_cv_have_fopen64" != no; then
 101   AC_DEFINE([HAVE_FOPEN64], 1,
 102             [Is fopen64 available?])
 103 fi
 104 AC_MSG_CHECKING([for stat64])
 105 AC_CACHE_VAL(bu_cv_have_stat64,
 106 [AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 107 bu_cv_have_stat64=yes,
 108 [saved_CPPFLAGS=$CPPFLAGS
 109  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 110  AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 111 bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 112 bu_cv_have_stat64=no)
 113  CPPFLAGS=$saved_CPPFLAGS])])
 114 AC_MSG_RESULT($bu_cv_have_stat64)
 115 if test "$bu_cv_have_stat64" != no; then
 116   AC_DEFINE([HAVE_STAT64], 1,
 117             [Is stat64 available?])
 118 fi
 119 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 120    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 121   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 122             [Enable LFS])
 123   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 124 fi
 125
 126 # Some systems have frexp only in -lm, not in -lc.
 127 AC_SEARCH_LIBS(frexp, m)
 128
 129 AC_MSG_CHECKING(for time_t in time.h)
 130 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 131 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
 132 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 133 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 134 if test $bu_cv_decl_time_t_time_h = yes; then
 135   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 136             [Is the type time_t defined in <time.h>?])
 137 fi
 138
 139 AC_MSG_CHECKING(for time_t in sys/types.h)
 140 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 141 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
 142 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 143 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 144 if test $bu_cv_decl_time_t_types_h = yes; then
 145   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 146             [Is the type time_t defined in <sys/types.h>?])
 147 fi
 148
 149 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 150 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 151 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 152 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 153 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 154 if test $bu_cv_decl_getopt_unistd_h = yes; then
 155   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 156             [Is the prototype for getopt in <unistd.h> in the expected format?])
 157 fi
 158
 159 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 160 # by default.
 161 AC_MSG_CHECKING([for utime.h])
 162 AC_CACHE_VAL(bu_cv_header_utime_h,
 163 [AC_TRY_COMPILE([#include <sys/types.h>
 164 #ifdef HAVE_TIME_H
 165 #include <time.h>
 166 #endif
 167 #include <utime.h>],
 168 [struct utimbuf s;],
 169 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 170 AC_MSG_RESULT($bu_cv_header_utime_h)
 171 if test $bu_cv_header_utime_h = yes; then
 172   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 173 fi
 174
 175 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked])
 176
 177 BFD_BINARY_FOPEN
 178
 179 # target-specific stuff:
 180
 181 # Canonicalize the secondary target names.
 182 if test -n "$enable_targets"; then
 183     for targ in `echo $enable_targets | sed 's/,/ /g'`
 184     do
 185         result=`$ac_config_sub $targ 2>/dev/null`
 186         if test -n "$result"; then
 187             canon_targets="$canon_targets $result"
 188         else
 189             # Allow targets that config.sub doesn't recognize, like "all".
 190             canon_targets="$canon_targets $targ"
 191         fi
 192     done
 193 fi
 194
 195 all_targets=false
 196 BUILD_NLMCONV=
 197 NLMCONV_DEFS=
 198 BUILD_SRCONV=
 199 BUILD_DLLTOOL=
 200 DLLTOOL_DEFS=
 201 BUILD_WINDRES=
 202 BUILD_DLLWRAP=
 203 BUILD_MISC=
 204 OBJDUMP_DEFS=
 205
 206 for targ in $target $canon_targets
 207 do
 208     if test "x$targ" = "xall"; then
 209         all_targets=true
 210         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 211         BUILD_SRCONV='$(SRCONV_PROG)'
 212         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 213     else
 214         case $targ in
 215 changequote(,)dnl
 216         i[3-7]86*-*-netware*)
 217 changequote([,])dnl
 218           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 219           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 220           ;;
 221         alpha*-*-netware*)
 222           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 223           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 224           ;;
 225         powerpc*-*-netware*)
 226           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 227           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 228           ;;
 229         sparc*-*-netware*)
 230           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 231           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 232           ;;
 233         esac
 234         case $targ in
 235         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 236         esac
 237         case $targ in
 238         arm-epoc-pe*)
 239           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 240           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 241           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 242           ;;
 243         arm-*-pe* | arm-*-wince)
 244           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 245           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 246           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 247           ;;
 248         thumb-*-pe*)
 249           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 250           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 251           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 252           ;;
 253         arm*-* | xscale-* | strongarm-* | d10v-*)
 254           OBJDUMP_DEFS="-DDISASSEMBLER_NEEDS_RELOCS"
 255           ;;
 256 changequote(,)dnl
 257         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 258 changequote([,])dnl
 259           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 260           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 261           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 262           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 263           ;;
 264 changequote(,)dnl
 265         i[3-7]86-*-interix)
 266 changequote([,])dnl
 267           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 268           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 269           ;;
 270 changequote(,)dnl
 271         powerpc*-aix5.[01])
 272 changequote([,])dnl
 273           ;;
 274         powerpc*-aix5.*)
 275           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 276           ;;
 277         powerpc*-*-pe* | powerpc*-*-cygwin*)
 278           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 279           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 280           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 281           ;;
 282         sh*-*-pe)
 283           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 284           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 285           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 286           ;;
 287         mips*-*-pe)
 288           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 289           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 290           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 291           ;;
 292         mcore-*-pe)
 293           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 294           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 295           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 296           ;;
 297         mcore-*-elf)
 298           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 299           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 300           ;;
 301         esac
 302     fi
 303 done
 304
 305 if test "${with_windres+set}" = set; then
 306           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 307 fi
 308
 309 AC_SUBST(NLMCONV_DEFS)
 310 AC_SUBST(BUILD_NLMCONV)
 311 AC_SUBST(BUILD_SRCONV)
 312 AC_SUBST(BUILD_DLLTOOL)
 313 AC_SUBST(DLLTOOL_DEFS)
 314 AC_SUBST(BUILD_WINDRES)
 315 AC_SUBST(BUILD_DLLWRAP)
 316 AC_SUBST(BUILD_MISC)
 317 AC_SUBST(OBJDUMP_DEFS)
 318
 319 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 320
 321 targ=$target
 322 . $srcdir/../bfd/config.bfd
 323 if test "x$targ_underscore" = "xyes"; then
 324     UNDERSCORE=1
 325 else
 326     UNDERSCORE=0
 327 fi
 328 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 329  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 330
 331 # Emulation
 332 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 333 do
 334   # Canonicalize the secondary target names.
 335  result=`$ac_config_sub $targ_alias 2>/dev/null`
 336  if test -n "$result"; then
 337    targ=$result
 338  else
 339    targ=$targ_alias
 340  fi
 341
 342  . ${srcdir}/configure.tgt
 343
 344   EMULATION=$targ_emul
 345   EMULATION_VECTOR=$targ_emul_vector
 346 done
 347
 348 AC_SUBST(EMULATION)
 349 AC_SUBST(EMULATION_VECTOR)
 350
 351 AC_OUTPUT(Makefile doc/Makefile po/Makefile.in:po/Make-in,
 352 [
 353 case "x$CONFIG_FILES" in
 354 *) sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile ;;
 355 esac
 356 ])