configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl Copyright (c) 2017 EfficiOS, Inc.
   4 dnl
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a copy
   6 dnl of this software and associated documentation files (the "Software"), to deal
   7 dnl in the Software without restriction, including without limitation the rights
   8 dnl to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 dnl copies of the Software, and to permit persons to whom the Software is
  10 dnl furnished to do so, subject to the following conditions:
  11 dnl
  12 dnl The above copyright notice and this permission notice shall be included in
  13 dnl all copies or substantial portions of the Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 dnl AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 dnl OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 dnl SOFTWARE.
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.50])
  28
  29 m4_define([bt_version_major], [2])
  30 m4_define([bt_version_minor], [0])
  31 m4_define([bt_version_patch], [0])
  32 m4_define([bt_version_extra], [-pre6])
  33 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
  34
  35 AC_INIT([babeltrace], bt_version, [jeremie dot galarneau at efficios dot com], [], [https://efficios.com/babeltrace/])
  36
  37 # Following the numbering scheme proposed by libtool for the library version
  38 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  39 m4_define([bt_lib_version_current], [0])
  40 m4_define([bt_lib_version_revision], [0])
  41 m4_define([bt_lib_version_age], [0])
  42 m4_define([bt_lib_version], bt_lib_version_current[:]bt_lib_version_revision[:]bt_lib_version_age)
  43
  44 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_lib_version)
  45
  46 AC_CONFIG_HEADERS([src/common/config.h])
  47 AC_CONFIG_AUX_DIR([config])
  48 AC_CONFIG_MACRO_DIR([m4])
  49
  50 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace major version])
  51 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace minor version])
  52 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace patch version])
  53 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace extra version])
  54
  55 AC_CANONICAL_TARGET
  56 AC_CANONICAL_HOST
  57
  58
  59 ##                     ##
  60 ## Automake base setup ##
  61 ##                     ##
  62
  63 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  64 AM_MAINTAINER_MODE([enable])
  65
  66 # Enable silent rules if available (Introduced in AM 1.11)
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69
  70 ##                      ##
  71 ## OS specific defaults ##
  72 ##                      ##
  73
  74 MINGW32=no
  75 DEFAULT_ENABLE_DEBUG_INFO=yes
  76 LT_NO_UNDEFINED=""
  77 AS_CASE([$host_os],
  78   [solaris*|darwin*],
  79     [
  80         DEFAULT_ENABLE_DEBUG_INFO=no
  81     ],
  82   [cygwin*],
  83     [
  84         DEFAULT_ENABLE_DEBUG_INFO=no
  85         LT_NO_UNDEFINED="-no-undefined"
  86     ],
  87   [mingw*],
  88     [
  89         MINGW32=yes
  90         DEFAULT_ENABLE_DEBUG_INFO=no
  91         LT_NO_UNDEFINED="-no-undefined"
  92     ]
  93 )
  94
  95 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
  96 AC_SUBST(LT_NO_UNDEFINED)
  97
  98
  99 ##                   ##
 100 ## C compiler checks ##
 101 ##                   ##
 102
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Choose the c compiler
 107 AC_PROG_CC
 108
 109 # Make sure the c compiler supports C99
 110 AC_PROG_CC_C99([], [AC_MSG_ERROR([The compiler does not support C99])])
 111
 112 # Make sure the c compiler supports __attributes__
 113 AX_C___ATTRIBUTE__
 114 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 115   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 116
 117 # Make sur we have pthread support
 118 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 119
 120 # Checks for typedefs, structures, and compiler characteristics.
 121 AC_C_INLINE
 122 AC_C_TYPEOF
 123 AC_TYPE_PID_T
 124 AC_TYPE_SIZE_T
 125 AC_TYPE_INT16_T
 126 AC_TYPE_INT32_T
 127 AC_TYPE_INT64_T
 128 AC_TYPE_INT8_T
 129 AC_TYPE_OFF_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UINT16_T
 132 AC_TYPE_UINT32_T
 133 AC_TYPE_UINT64_T
 134 AC_TYPE_UINT8_T
 135 AC_CHECK_TYPES([ptrdiff_t])
 136
 137
 138 ##               ##
 139 ## Header checks ##
 140 ##               ##
 141
 142 AC_HEADER_STDBOOL
 143 AC_CHECK_HEADERS([ \
 144         fcntl.h \
 145         float.h \
 146         ftw.h \
 147         libintl.h \
 148         limits.h \
 149         malloc.h \
 150         netdb.h \
 151         netinet/in.h \
 152         stddef.h \
 153         sys/socket.h \
 154         sys/time.h
 155 ])
 156
 157
 158 ##               ##
 159 ## Linker checks ##
 160 ##               ##
 161
 162 # Check if the linker supports no-as-needed
 163 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
 164 AC_SUBST([LD_NO_AS_NEEDED])
 165
 166 # Check if the linker supports whole-archive
 167 AX_CHECK_LINK_FLAG([-Wl,--whole-archive,--no-whole-archive],
 168   [
 169     AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,--whole-archive,])
 170     AC_SUBST([LD_NO_WHOLE_ARCHIVE], [,--no-whole-archive])
 171   ],[
 172     # Fallback to force_load for the macOS linker
 173     AX_CHECK_LINK_FLAG([-Wl,-force_load],
 174       [
 175         AC_SUBST([LD_WHOLE_ARCHIVE], [-Wl,-force_load,])
 176         AC_SUBST([LD_NO_WHOLE_ARCHIVE], [])
 177       ],[
 178         AC_MSG_WARN([Can't find a linker option to force the inclusion of the static plugin archive objects.])
 179       ]
 180     )
 181   ]
 182 )
 183
 184 # Initialize and configure libtool
 185 LT_INIT([win32-dll])
 186
 187
 188 ##                 ##
 189 ## Programs checks ##
 190 ##                 ##
 191
 192 AC_PROG_MAKE_SET
 193 AC_PROG_MKDIR_P
 194 AC_PROG_LN_S
 195
 196 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 197 # is not distributed in tarballs
 198 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 199 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 200
 201 # check for bison
 202 AC_PROG_YACC
 203 AX_PROG_BISON_VERSION([2.5], [have_bison=yes])
 204
 205 AS_IF([test "x$have_bison" != "xyes"], [
 206   AS_IF([test "x$in_git_repo" = "xyes"], [
 207     AC_MSG_FAILURE([dnl
 208 Bison >= 2.4 is required when building from the Git repository. You can
 209 set the YACC variable to override automatic detection.
 210     ])
 211   ], [
 212     AC_MSG_WARN([dnl
 213 Missing Bison >= 2.4. Note that the parser files are already built in
 214 this distribution tarball, so Bison is only needed if you intend to
 215 modify their sources. You can set the YACC variable to override automatic
 216 detection.
 217     ])
 218   ])
 219 ])
 220 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 221
 222 # check for flex
 223 AC_PROG_LEX
 224 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 225
 226 AS_IF([test "x$have_flex" != "xyes"], [
 227   AS_IF([test "x$in_git_repo" = "xyes"], [
 228     AC_MSG_FAILURE([dnl
 229 Flex >= 2.5.35 is required when building from the Git repository. You can
 230 set the LEX variable to override automatic detection.
 231     ])
 232   ], [
 233     AC_MSG_WARN([dnl
 234 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 235 this distribution tarball, so Flex is only needed if you intend to
 236 modify their sources. You can set the LEX variable to override automatic
 237 detection.
 238     ])
 239   ])
 240 ])
 241 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 242
 243
 244 ##                ##
 245 ## Library checks ##
 246 ##                ##
 247
 248 # Check what libraries are required on this platform to link sockets programs.
 249 AX_LIB_SOCKET_NSL
 250
 251 # Check for glib >= 2.22 with gmodule support
 252 AM_PATH_GLIB_2_0([2.22.0], [],
 253   AC_MSG_ERROR([glib >= 2.22 is required - download it from ftp://ftp.gtk.org/pub/gtk]),
 254   [gmodule-no-export]
 255 )
 256
 257 # Checks for library functions.
 258 AC_FUNC_ALLOCA
 259 AC_FUNC_FORK
 260 AC_FUNC_MKTIME
 261 AC_FUNC_MMAP
 262 AC_FUNC_STRERROR_R
 263 AC_FUNC_STRNLEN
 264 AC_CHECK_FUNCS([ \
 265         atexit \
 266         dup2 \
 267         ftruncate \
 268         gethostbyname \
 269         gettimeofday \
 270         localtime_r \
 271         memchr \
 272         memset \
 273         mkdir \
 274         mkdtemp \
 275         munmap \
 276         rmdir \
 277         setenv \
 278         socket \
 279         strchr \
 280         strdup \
 281         strerror \
 282         strndup \
 283         strnlen \
 284         strrchr \
 285         strstr \
 286         strtoul \
 287         strtoull \
 288         tzset \
 289 ])
 290
 291 # AC_FUNC_MALLOC causes problems when cross-compiling.
 292 #AC_FUNC_MALLOC
 293 #AC_FUNC_REALLOC
 294
 295 # Check for fmemopen
 296 AC_CHECK_LIB([c], [fmemopen],
 297   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])]
 298 )
 299
 300 # Check for open_memstream
 301 AC_CHECK_LIB([c], [open_memstream],
 302   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])]
 303 )
 304
 305 # Check for posix_fallocate
 306 AC_CHECK_LIB([c], [posix_fallocate],
 307   [AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])]
 308 )
 309
 310 ##                 ##
 311 ## User variables  ##
 312 ##                 ##
 313
 314 AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 315 AC_ARG_VAR([PYTHON_LDFLAGS], [Linker flags for Python, bypassing python-config])
 316 AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 317
 318 # BABELTRACE_PLUGINS_DIR: Plugins directory
 319 AC_ARG_VAR([BABELTRACE_PLUGINS_DIR], [built-in plugins install directory [LIBDIR/babeltrace2/plugins]])
 320 AS_IF([test "x$BABELTRACE_PLUGINS_DIR" = x], [BABELTRACE_PLUGINS_DIR='${libdir}/babeltrace2/plugins'])
 321
 322 # BABELTRACE_PLUGIN_PROVIDERS_DIR: Plugin providers directory
 323 AC_ARG_VAR([BABELTRACE_PLUGIN_PROVIDERS_DIR], [built-in plugin providers install directory [LIBDIR/babeltrace2/plugin-providers]])
 324 AS_IF([test "x$BABELTRACE_PLUGIN_PROVIDERS_DIR" = x], [BABELTRACE_PLUGIN_PROVIDERS_DIR='${libdir}/babeltrace2/plugin-providers'])
 325
 326 # BABELTRACE_MINIMAL_LOG_LEVEL:
 327 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (TRACE, DEBUG (default), or INFO)])
 328 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = x], [BABELTRACE_MINIMAL_LOG_LEVEL="DEBUG"])
 329 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "TRACE" && \
 330        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && \
 331        test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO"],
 332   [AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use TRACE, DEBUG, or INFO.])]
 333 )
 334 AC_DEFINE_UNQUOTED([BT_MINIMAL_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 335
 336 # BABELTRACE_DEV_MODE:
 337 AC_ARG_VAR([BABELTRACE_DEV_MODE], [Set to 1 to enable the Babeltrace developer mode (enables run-time checks for plugin developers)])
 338 AS_IF([test "x$BABELTRACE_DEV_MODE" = x1], [
 339         AC_DEFINE([BT_DEV_MODE], 1, [Babeltrace developer mode])
 340 ], [BABELTRACE_DEV_MODE=0])
 341
 342 # BABELTRACE_DEBUG_MODE:
 343 AC_ARG_VAR([BABELTRACE_DEBUG_MODE], [Set to 1 to enable the Babeltrace debug mode (enables internal assertions for Babeltrace maintainers)])
 344 AS_IF([test "x$BABELTRACE_DEBUG_MODE" = x1], [
 345         AC_DEFINE([BT_DEBUG_MODE], 1, [Babeltrace debug mode])
 346 ], [BABELTRACE_DEBUG_MODE=0])
 347
 348
 349 ##                              ##
 350 ## Optionnal features selection ##
 351 ##                              ##
 352
 353 # Python bindings
 354 # Disabled by default
 355 AC_ARG_ENABLE([python-bindings],
 356   [AC_HELP_STRING([--enable-python-bindings], [build the Python bindings])],
 357   [], dnl AC_ARG_ENABLE will fill enable_python_bindings with the user choice
 358   [enable_python_bindings=no]
 359 )
 360
 361 # Python bindings documentation
 362 # Disabled by default
 363 AC_ARG_ENABLE([python-bindings-doc],
 364   [AC_HELP_STRING([--enable-python-bindings-doc], [build the Python bindings documentation])],
 365   [], dnl AC_ARG_ENABLE will fill enable_python_bindings_doc with the user choice
 366   [enable_python_bindings_doc=no]
 367 )
 368
 369 # Python plugins
 370 # Disabled by default
 371 AC_ARG_ENABLE([python-plugins],
 372   [AC_HELP_STRING([--enable-python-plugins], [enable the Python plugins support for the library and converter])],
 373   [], dnl AC_ARG_ENABLE will fill enable_python_plugins with the user choice
 374   [enable_python_plugins=no]
 375 )
 376
 377 # Debug info
 378 # Enabled by default, except on some platforms
 379 AC_ARG_ENABLE([debug-info],
 380   [AC_HELP_STRING([--disable-debug-info], [disable the debug info support (default on macOS, Solaris and Windows)])],
 381   [], dnl AC_ARG_ENABLE will fill enable_debug_info with the user choice
 382   [enable_debug_info="$DEFAULT_ENABLE_DEBUG_INFO"]
 383 )
 384
 385 # API documentation
 386 # Disabled by default
 387 AC_ARG_ENABLE([api-doc],
 388   [AC_HELP_STRING([--enable-api-doc], [build the HTML API documentation])],
 389   [enable_api_doc=$enableval],
 390   [enable_api_doc=no]
 391 )
 392
 393 # Built-in plugins
 394 # Disabled by default
 395 AC_ARG_ENABLE([built-in-plugins],
 396   [AC_HELP_STRING([--enable-built-in-plugins], [Statically-link in-tree plug-ins into the babeltrace2 executable])],
 397   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 398   [enable_built_in_plugins=no]
 399 )
 400
 401 # Built-in python plugin support
 402 # Disabled by default
 403 AC_ARG_ENABLE([built-in-python-plugin-support],
 404   [AC_HELP_STRING([--enable-built-in-python-plugin-support], [Statically-link Python plugin support into the babeltrace library])],
 405   [], dnl AC_ARG_ENABLE will fill enable_built_in_python_plugin_support with the user choice
 406   [enable_built_in_python_plugin_support=no]
 407 )
 408
 409 # Man pages
 410 # Enabled by default
 411 AC_ARG_ENABLE([man-pages],
 412   [AS_HELP_STRING([--disable-man-pages], [Do not build and install man pages (already built in a distributed tarball])],
 413   [], dnl AC_ARG_ENABLE will fill enable_built_in_plugins with the user choice
 414   [enable_man_pages=yes]
 415 )
 416
 417
 418 # Set automake variables for optionnal feature conditionnals in Makefile.am
 419 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS], [test "x$enable_python_bindings" = xyes])
 420 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_DOC], [test "x$enable_python_bindings_doc" = xyes])
 421 AM_CONDITIONAL([ENABLE_PYTHON_PLUGINS], [test "x$enable_python_plugins" = xyes])
 422 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$enable_debug_info" = xyes])
 423 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = xyes])
 424 AM_CONDITIONAL([ENABLE_BUILT_IN_PLUGINS], [test "x$enable_built_in_plugins" = xyes])
 425 AM_CONDITIONAL([ENABLE_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$enable_built_in_python_plugin_support" = xyes])
 426 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$enable_man_pages" = xyes])
 427 AM_CONDITIONAL([ENABLE_PYTHON_COMMON_DEPS], [test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes])
 428
 429 # Set defines for optionnal features conditionnals in the source code
 430
 431 ## jgalar: still used?
 432 AS_IF([test "x$enable_python_plugins" = xyes],
 433   [AC_DEFINE([PYTHON_PLUGINS], [1], [Python plugin support.])]
 434 )
 435
 436 AS_IF([test "x$enable_debug_info" = xyes],
 437   [AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])]
 438 )
 439
 440 AS_IF([test "x$enable_built_in_plugins" = xyes],
 441   [AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 442 )
 443
 444 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 445   [AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])]
 446 )
 447
 448 AS_IF([test "x$enable_debug_info" = xyes],
 449   [ENABLE_DEBUG_INFO_VAL=1],
 450   [ENABLE_DEBUG_INFO_VAL=0]
 451 )
 452
 453 AC_SUBST([ENABLE_DEBUG_INFO_VAL])
 454
 455
 456 # Check for conflicting optional features user choices
 457
 458 AS_IF([test "x$enable_python_bindings" = xno],
 459   [
 460     AS_IF([test "x$enable_python_bindings_doc" = xyes], [AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])])
 461   ]
 462 )
 463
 464 AS_IF([test "x$enable_built_in_plugins" = xyes],
 465   [
 466     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 467     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace2 executable)])
 468     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace2 executable)])
 469   ]
 470 )
 471
 472 AS_IF([test "x$enable_built_in_python_plugin_support" = xyes],
 473   [
 474     AS_IF([test "x$enable_python_plugins" = xno], [AC_MSG_ERROR([--enable-python-plugins must be used to bundle Python plugin support in the babeltrace2 executable])])
 475     # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 476     AS_IF([test "x$enable_static" != xyes], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace2 executable)])
 477     AS_IF([test "x$enable_shared" = xyes], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace2 executable)])
 478   ]
 479 )
 480
 481
 482 # Check for optionnal features dependencies
 483
 484 AS_IF([test "x$enable_python_bindings" = xyes],
 485   [AX_PKG_SWIG(2.0.0, [], [AC_MSG_ERROR([SWIG 2.0.0 or newer is required to build the python bindings])])]
 486 )
 487
 488 AM_PATH_PYTHON([3.0], [
 489   AM_PATH_PYTHON_MODULES([PYTHON])
 490
 491   # pythondir is the path where extra modules are to be installed
 492   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 493
 494   # pyexecdir is the path that contains shared objects used by the extra modules
 495   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 496
 497   AS_IF([test -z "$PYTHON_CONFIG"], [
 498     AC_PATH_PROGS([PYTHON_CONFIG],
 499                   [python$PYTHON_VERSION-config python-config],
 500                   [],
 501                   [`dirname $PYTHON`])
 502   ])
 503
 504   AS_IF([test -n "$PYTHON_CONFIG"], [
 505     AS_IF([test -z "$PYTHON_INCLUDE"], [
 506       AC_MSG_CHECKING([Python include flags])
 507       PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 508       AC_MSG_RESULT([$PYTHON_INCLUDE])
 509     ])
 510
 511     AS_IF([test -z "$PYTHON_LDFLAGS"], [
 512       AC_MSG_CHECKING([Python library flags])
 513       PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 514       AC_MSG_RESULT([$PYTHON_LDFLAGS])
 515     ])
 516   ])
 517 ], [:])
 518
 519 AS_IF([test "$PYTHON" != :], [have_python=yes], [have_python=no])
 520 AS_IF([test -n "$PYTHON_CONFIG"], [have_python_dev=yes], [have_python_dev=no])
 521
 522 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = xyes])
 523 AM_CONDITIONAL([HAVE_PYTHON_DEV], [test "x$have_python_dev" = xyes])
 524
 525 AS_IF([test "x$enable_python_bindings" = xyes || test "x$enable_python_plugins" = xyes], [
 526   AS_IF([test "x$have_python_dev" = xno], [
 527     AC_MSG_ERROR([Cannot find a suitable python-config. You can override the python-config path with the PYTHON_CONFIG environment variable.])
 528   ])
 529 ])
 530
 531 AS_IF([test "x$enable_python_bindings_doc" = xyes],
 532   [
 533     AM_CHECK_PYTHON_SPHINX([PYTHON])
 534     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 535       [AC_MSG_ERROR([The Sphinx package for Python 3 is required to build the Python bindings documentation])]
 536     )
 537   ]
 538 )
 539
 540 AS_IF([test "x$enable_debug_info" = xyes],
 541   [
 542     # Check if libelf and libdw are present
 543     AC_CHECK_LIB([elf], [elf_version], [:], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 544     AC_CHECK_LIB([dw], [dwarf_begin], [:], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 545     BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 546     ELFUTILS_LIBS="-lelf -ldw"
 547   ]
 548 )
 549 AC_SUBST([ELFUTILS_LIBS])
 550
 551 AS_IF([test "x$enable_api_doc" = "xyes"],
 552   [
 553     DX_DOXYGEN_FEATURE(ON)
 554     DX_DOT_FEATURE(OFF)
 555     DX_HTML_FEATURE(ON)
 556     DX_CHM_FEATURE(OFF)
 557     DX_CHI_FEATURE(OFF)
 558     DX_MAN_FEATURE(OFF)
 559     DX_RTF_FEATURE(OFF)
 560     DX_XML_FEATURE(OFF)
 561     DX_PDF_FEATURE(OFF)
 562     DX_PS_FEATURE(OFF)
 563     DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 564     AS_IF([test -z "$DX_DOXYGEN"],
 565           [AC_MSG_ERROR([You need doxygen to enable the API documentation])]
 566     )
 567   ]
 568 )
 569
 570 have_asciidoc_xmlto=no
 571 warn_prebuilt_man_pages=no
 572
 573 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 574 AC_PATH_PROG([XMLTO], [xmlto], [no])
 575
 576 AS_IF([test "x$enable_man_pages" = "xyes"], [
 577   AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 578     AS_IF([test "x$in_git_repo" = "xyes"], [
 579       # this is an error because we're in the Git repo, which
 580       # means the man pages are not already generated for us,
 581       # thus asciixmlto are required because we were asked
 582       # to build the man pages
 583       AC_MSG_ERROR([
 584 You need asciidoc and xmlto to build the Babeltrace man pages. Use
 585 --disable-man-pages to disable building the man pages, in which case
 586 they will not be installed.
 587       ])
 588     ], [
 589       # only warn here: since we're in the tarball, the man
 590       # pages should already be generated at this point, thus
 591       # asciidoc/xmlto are not strictly required
 592       warn_prebuilt_man_pages=yes
 593     ])
 594   ], [
 595     have_asciidoc_xmlto=yes
 596   ])
 597 ])
 598
 599 # export AsciiDoc and xmlto existence
 600 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 601
 602 # a wonderful hack that seems necessary because $libdir is
 603 # literally `${exec_prefix}/lib`, and $exec_prefix is set to `NONE`
 604 # by autoconf when it's not specified by the user
 605 AS_IF([test "x$exec_prefix" = xNONE], [
 606   AS_IF([test "x$prefix" = xNONE], [
 607     PREFIX="$ac_default_prefix"
 608   ], [
 609     PREFIX="$prefix"
 610   ])
 611
 612   LIBDIR="$PREFIX/lib"
 613 ], [
 614   LIBDIR="$libdir"
 615 ])
 616
 617 AC_SUBST(LIBDIR)
 618
 619
 620 # Set global CFLAGS in AM_CFLAGS
 621 AM_CFLAGS="-Wall -Wformat -Werror=implicit-function-declaration $PTHREAD_CFLAGS $GLIB_CFLAGS"
 622 AC_SUBST(AM_CFLAGS)
 623
 624 # Set global CPPFLAGS in AM_CPPFLAGS
 625 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 626 AC_SUBST(AM_CPPFLAGS)
 627
 628 # Add glib to global link libs
 629 LIBS="$LIBS $GLIB_LIBS"
 630
 631 # Check that the current size_t matches the size that glib thinks it should
 632 # be. This catches problems on multi-arch where people try to do a 32-bit
 633 # build while pointing at 64-bit glib headers. This is a common error because
 634 # glib.h is not platform specific but it includes glibconfig.h which is and
 635 # is usually installed in a non-standard path.
 636
 637 # Older versions of the pkg-config macros disallows PKG_* in the autoconf
 638 # output. Specifically allow pkg_config_libdir to be able to print the
 639 # error message.
 640 m4_pattern_allow([PKG_CONFIG_LIBDIR])
 641
 642 save_CFLAGS=${CFLAGS}
 643 CFLAGS="${CFLAGS} ${AM_CFLAGS}"
 644 AC_COMPILE_IFELSE([
 645   AC_LANG_PROGRAM([dnl
 646 #include <glib.h>
 647 #include <unistd.h>
 648   ], [dnl
 649 G_STATIC_ASSERT(sizeof(size_t) == GLIB_SIZEOF_SIZE_T);
 650   ])
 651 ],[:],[
 652   AC_MSG_ERROR([dnl
 653 sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T. You probably need to set
 654 PKG_CONFIG_LIBDIR to point to the right pkg-config files for your build
 655 target.
 656   ])
 657 ])
 658 CFLAGS=${save_CFLAGS}
 659
 660 # Abuse autoconf's AC_ARG_PROGRAM output variable 'program_transform_name'
 661 # to rename babeltrace2.bin to babeltrace2 at install time.
 662 program_transform_name="s&babeltrace2\.bin&babeltrace2&;$program_transform_name"
 663 AC_SUBST(program_transform_name)
 664
 665 AC_CONFIG_FILES([
 666         doc/api/Doxyfile
 667         doc/api/Makefile
 668         doc/bindings/Makefile
 669         doc/bindings/python/Makefile
 670         doc/contributing-images/Makefile
 671         doc/Makefile
 672         doc/man/asciidoc-attrs.conf
 673         doc/man/Makefile
 674         include/Makefile
 675         Makefile
 676         src/argpar/Makefile
 677         src/autodisc/Makefile
 678         src/babeltrace2-ctf-writer.pc
 679         src/babeltrace2.pc
 680         src/bindings/Makefile
 681         src/bindings/python/bt2/bt2/version.py
 682         src/bindings/python/bt2/Makefile
 683         src/bindings/python/bt2/setup.py
 684         src/bindings/python/Makefile
 685         src/cli/Makefile
 686         src/common/Makefile
 687         src/compat/Makefile
 688         src/ctfser/Makefile
 689         src/ctf-writer/Makefile
 690         src/fd-cache/Makefile
 691         src/lib/graph/Makefile
 692         src/lib/graph/message/Makefile
 693         src/lib/Makefile
 694         src/lib/plugin/Makefile
 695         src/lib/prio-heap/Makefile
 696         src/lib/trace-ir/Makefile
 697         src/logging/Makefile
 698         src/Makefile
 699         src/plugins/common/Makefile
 700         src/plugins/common/muxing/Makefile
 701         src/plugins/ctf/common/bfcr/Makefile
 702         src/plugins/ctf/common/Makefile
 703         src/plugins/ctf/common/metadata/Makefile
 704         src/plugins/ctf/common/msg-iter/Makefile
 705         src/plugins/ctf/fs-sink/Makefile
 706         src/plugins/ctf/fs-src/Makefile
 707         src/plugins/ctf/lttng-live/Makefile
 708         src/plugins/ctf/Makefile
 709         src/plugins/lttng-utils/debug-info/Makefile
 710         src/plugins/lttng-utils/Makefile
 711         src/plugins/Makefile
 712         src/plugins/text/dmesg/Makefile
 713         src/plugins/text/Makefile
 714         src/plugins/text/pretty/Makefile
 715         src/plugins/text/details/Makefile
 716         src/plugins/utils/counter/Makefile
 717         src/plugins/utils/dummy/Makefile
 718         src/plugins/utils/Makefile
 719         src/plugins/utils/muxer/Makefile
 720         src/plugins/utils/trimmer/Makefile
 721         src/py-common/Makefile
 722         src/python-plugin-provider/Makefile
 723         tests/bitfield/Makefile
 724         tests/ctf-writer/Makefile
 725         tests/argpar/Makefile
 726         tests/lib/Makefile
 727         tests/lib/test-plugin-plugins/Makefile
 728         tests/Makefile
 729         tests/plugins/Makefile
 730         tests/plugins/src.ctf.fs/Makefile
 731         tests/plugins/src.ctf.fs/succeed/Makefile
 732         tests/plugins/sink.ctf.fs/Makefile
 733         tests/plugins/sink.ctf.fs/succeed/Makefile
 734         tests/plugins/flt.lttng-utils.debug-info/Makefile
 735         tests/plugins/flt.utils.muxer/Makefile
 736         tests/plugins/flt.utils.muxer/succeed/Makefile
 737         tests/plugins/flt.utils.trimmer/Makefile
 738         tests/utils/Makefile
 739         tests/utils/tap/Makefile
 740 ])
 741
 742 AC_OUTPUT
 743
 744 #
 745 # Mini-report on what will be built.
 746 #
 747
 748 PPRINT_INIT
 749 PPRINT_SET_INDENT(1)
 750 PPRINT_SET_TS(38)
 751
 752 AS_ECHO
 753 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 754 AS_ECHO
 755
 756 PPRINT_SUBTITLE([System])
 757
 758 # Target architecture we're building for.
 759 target_arch=$host_cpu
 760 [
 761 for f in $CFLAGS; do
 762         if test $f = "-m32"; then
 763                 target_arch="32-bit"
 764         elif test $f = "-m64"; then
 765                 target_arch="64-bit"
 766         fi
 767 done
 768 ]
 769
 770 PPRINT_PROP_STRING([Target architecture], $target_arch)
 771
 772 AS_ECHO
 773 PPRINT_SUBTITLE([Python 3 language support])
 774 test "x$have_python" = "xyes" && value=1 || value=0
 775 PPRINT_PROP_BOOL([Have Python interpreter], $value)
 776 test "x$have_python_dev" = "xyes" && value=1 || value=0
 777 PPRINT_PROP_BOOL([Have Python development libraries], $value)
 778 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 779 PPRINT_PROP_BOOL([Python bindings], $value)
 780 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 781 PPRINT_PROP_BOOL([Python plugin support], $value)
 782 AS_IF([test "x$have_python" = "xyes"], [
 783   PPRINT_PROP_STRING([Python interpreter path], [$PYTHON])
 784 ])
 785 AS_IF([test "x$have_python_dev" = "xyes"], [
 786   PPRINT_PROP_STRING([python-config path], [$PYTHON_CONFIG])
 787   PPRINT_PROP_STRING([Python include paths], [$PYTHON_INCLUDE])
 788   PPRINT_PROP_STRING([Python linker flags], [$PYTHON_LDFLAGS])
 789 ])
 790 AS_IF([test "x$enable_python_bindings" = "xyes"], [
 791   PPRINT_PROP_STRING([SWIG executable], [$SWIG])
 792   PPRINT_PROP_STRING([SWIG library], [$SWIG_LIB])
 793 ])
 794
 795 AS_ECHO
 796 PPRINT_SUBTITLE([Plugins])
 797 PPRINT_PROP_BOOL(['ctf' plugin], 1)
 798 test "x$enable_debug_info" = "xyes" && value=1 || value=0
 799 PPRINT_PROP_BOOL(['lttng-utils' plugin], $value)
 800 PPRINT_PROP_BOOL(['text' plugin], 1)
 801 PPRINT_PROP_BOOL(['utils' plugin], 1)
 802
 803 AS_ECHO
 804 PPRINT_SUBTITLE([Built-in features])
 805 test "x$enable_built_in_plugins" = "xyes" && value=1 || value=0
 806 PPRINT_PROP_BOOL([Built-in plugins], $value)
 807 test "x$enable_built_in_python_plugin_support" = "xyes" && value=1 || value=0
 808 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 809
 810 AS_ECHO
 811 PPRINT_SUBTITLE([Documentation])
 812
 813 # man pages build enabled/disabled
 814 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 815
 816 AS_IF([test "x$enable_man_pages" != "xno"], [
 817   AS_IF([test "x$in_git_repo" = "xyes"], [
 818     PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 819   ], [
 820     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 821       PPRINT_PROP_BOOL([build_man_pages_msg], 1)
 822     ], [
 823       PPRINT_PROP_STRING([build_man_pages_msg],
 824         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 825         $PPRINT_COLOR_SUBTITLE)
 826     ])
 827   ])
 828 ], [
 829   PPRINT_PROP_BOOL([build_man_pages_msg], 0)
 830 ])
 831
 832 m4_popdef([build_man_pages_msg])
 833
 834 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 835 PPRINT_PROP_BOOL([HTML API documentation], $value)
 836 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 837 PPRINT_PROP_BOOL([Python bindings documentation], $value)
 838
 839 AS_ECHO
 840 PPRINT_SUBTITLE([Logging])
 841 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 842
 843 AS_ECHO
 844 PPRINT_SUBTITLE([Special build modes])
 845 PPRINT_PROP_BOOL([Debug mode], $BABELTRACE_DEBUG_MODE)
 846 PPRINT_PROP_BOOL([Developer mode], $BABELTRACE_DEV_MODE)
 847
 848 report_bindir="`eval eval echo $bindir`"
 849 report_libdir="`eval eval echo $libdir`"
 850 report_sysconfdif="`eval eval echo $sysconfdir`"
 851 report_pluginsdir="`eval eval eval echo $BABELTRACE_PLUGINS_DIR`"
 852 report_pluginprovidersdir="`eval eval eval echo $BABELTRACE_PLUGIN_PROVIDERS_DIR`"
 853
 854 # Print the bindir and libdir this `make install' will install into.
 855 AS_ECHO
 856 PPRINT_SUBTITLE([Install directories])
 857 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 858 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 859 PPRINT_PROP_STRING([Plugins], [$report_pluginsdir])
 860 PPRINT_PROP_STRING([Plugin providers], [$report_pluginprovidersdir])
 861 PPRINT_PROP_STRING([Configuration], [$report_sysconfdif])