configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.4.0],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
   3 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   4
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 AC_PROG_CC_STDC
  25
  26 # Checks for programs.
  27 AC_PROG_MAKE_SET
  28 LT_INIT
  29 AC_PROG_YACC
  30 AC_PROG_LEX
  31 AC_PROG_MKDIR_P
  32 AC_PROG_LN_S
  33
  34 AX_C___ATTRIBUTE__
  35 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  36         [:],
  37         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  38
  39 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  40 LIBS="$PTHREAD_LIBS $LIBS"
  41 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  42 CC="$PTHREAD_CC"
  43
  44 # Check linker option
  45 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  46 AC_SUBST([LD_NO_AS_NEEDED])
  47
  48 AC_HEADER_STDBOOL
  49 AC_CHECK_HEADERS([ \
  50         fcntl.h \
  51         float.h \
  52         libintl.h \
  53         limits.h \
  54         malloc.h \
  55         netdb.h \
  56         netinet/in.h \
  57         stddef.h \
  58         sys/socket.h \
  59 ])
  60
  61 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  62         if test x"$(basename "$YACC")" != "xbison -y"; then
  63                 AC_MSG_ERROR([[bison not found and is required when building from git.
  64                 Please install bison]])
  65         fi
  66         AC_PATH_PROG([BISON],[bison])
  67         AX_PROG_BISON_VERSION([2.4], [],[
  68                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  69         ])
  70 fi
  71
  72 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  73         if test x"$LEX" != "xflex"; then
  74                 AC_MSG_ERROR([[flex not found and is required when building from git.
  75                 Please install flex]])
  76         fi
  77         AC_PATH_PROG([FLEX],[flex])
  78         AX_PROG_FLEX_VERSION([2.5.35], [],[
  79                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  80         ])
  81 fi
  82
  83 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  84
  85 # Check what libraries are required on this platform to link sockets programs.
  86 AX_LIB_SOCKET_NSL
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_INLINE
  90 AC_TYPE_PID_T
  91 AC_TYPE_SIZE_T
  92
  93 # Checks for library functions.
  94 AC_FUNC_ALLOCA
  95 AC_FUNC_FORK
  96 AC_FUNC_MALLOC
  97 AC_FUNC_MKTIME
  98 AC_FUNC_MMAP
  99 AC_FUNC_REALLOC
 100 AC_FUNC_STRERROR_R
 101 AC_CHECK_FUNCS([ \
 102         atexit \
 103         dirfd \
 104         dup2 \
 105         ftruncate \
 106         gethostbyname \
 107         gethostname \
 108         gettimeofday \
 109         localtime_r \
 110         memchr \
 111         memset \
 112         mkdir \
 113         mkdtemp \
 114         munmap \
 115         rmdir \
 116         setenv \
 117         socket \
 118         strchr \
 119         strdup \
 120         strerror \
 121         strndup \
 122         strnlen \
 123         strrchr \
 124         strtoul \
 125         strtoull \
 126         tzset \
 127         uname \
 128 ])
 129
 130 MINGW32=no
 131 DEFAULT_ENABLE_DEBUG_INFO=yes
 132 AS_CASE([$host_os],
 133   [solaris*|darwin*],
 134     [
 135         DEFAULT_ENABLE_DEBUG_INFO=no
 136     ],
 137   [mingw*],
 138     [
 139         MINGW32=yes
 140     ]
 141 )
 142
 143 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 144
 145 # Check what libraries are required on this platform to link sockets programs.
 146 AX_LIB_SOCKET_NSL
 147
 148 # Check for uuid in system libs
 149 AC_CHECK_FUNCS([uuid_generate],
 150 [
 151   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 152   link_with_libuuid=no
 153 ],
 154 [
 155   # First, check the pkg-config module is available, otherwise explicitly check
 156   # for libuuid, or uuid support in the C-library.
 157   PKG_CHECK_MODULES([UUID], [uuid],
 158   [
 159     LIBS="${UUID_LIBS} ${LIBS}"
 160     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 161     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 162     link_with_libuuid=yes
 163   ],
 164   [
 165     # Check for libuuid
 166     AC_CHECK_LIB([uuid], [uuid_generate],
 167     [
 168       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 169       link_with_libuuid=yes
 170     ],
 171     [
 172       # libuuid not found, check for uuid_create in libc.
 173       AC_CHECK_LIB([c], [uuid_create],
 174       [
 175         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 176         link_with_libc_uuid=yes
 177       ],
 178       [
 179         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 180         if test "x$MINGW32" = xno; then
 181           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 182         fi
 183       ])
 184     ])
 185   ])
 186 ])
 187
 188 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 189 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 190
 191 # Check for fmemopen
 192 AC_CHECK_LIB([c], [fmemopen],
 193 [
 194         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 195 ]
 196 )
 197
 198 # Check for open_memstream
 199 AC_CHECK_LIB([c], [open_memstream],
 200 [
 201         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 202 ]
 203 )
 204
 205 # Check for posix_fallocate
 206 AC_CHECK_LIB([c], [posix_fallocate],
 207 [
 208         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 209 ]
 210 )
 211
 212 # Check for faccessat
 213 AC_CHECK_LIB([c], [faccessat],
 214 [
 215         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 216 ]
 217 )
 218
 219 AC_CHECK_LIB([popt], [poptGetContext], [],
 220         [AC_MSG_ERROR([Cannot find popt.])]
 221 )
 222
 223 # For Python
 224 # SWIG version needed or newer:
 225 swig_version=2.0.0
 226
 227 AC_ARG_ENABLE([python-bindings],
 228               [AC_HELP_STRING([--enable-python-bindings],
 229                               [generate Python bindings])],
 230               [enable_python=yes], [enable_python=no])
 231
 232 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 233
 234 if test "x${enable_python:-yes}" = xyes; then
 235   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 236   AM_PATH_PYTHON
 237
 238   AM_PATH_PYTHON_MODULES([PYTHON])
 239   # pythondir is the path where extra modules are to be installed
 240   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 241   # pyexecdir is the path that contains shared objects used by the extra modules
 242   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 243   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 244   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 245   AS_IF([test -z "$PYTHON_INCLUDE"], [
 246     AS_IF([test -z "$PYTHON_CONFIG"], [
 247       AC_PATH_PROGS([PYTHON_CONFIG],
 248                     [python$PYTHON_VERSION-config python-config],
 249                     [no],
 250                     [`dirname $PYTHON`])
 251       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 252     ])
 253     AC_MSG_CHECKING([python include flags])
 254     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 255     AC_MSG_RESULT([$PYTHON_INCLUDE])
 256   ])
 257
 258 else
 259     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 260 [if you want Python bindings.])
 261
 262 fi
 263
 264 # Set default enable state for debug info.
 265 # The _enable_debug_info variable is prepended with an underscore to
 266 # avoid clashing with the one generated by AC_ARG_ENABLE.
 267 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 268
 269 # Optional debug info feature
 270 # Do _not_ indent the help string below (appears in the configure --help
 271 # output).
 272 AC_ARG_ENABLE([debug-info],
 273 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 274 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 275         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 276
 277 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 278 AS_IF([test "x$_enable_debug_info" = xyes], [
 279             # Check if libelf and libdw are present
 280             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 281             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 282             AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 283             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 284 ], [])
 285
 286 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 287 AC_SUBST(PACKAGE_LIBS)
 288
 289 LIBS="$LIBS $GMODULE_LIBS"
 290 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 291 AC_SUBST(PACKAGE_CFLAGS)
 292
 293 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 294 AC_SUBST(DEFAULT_INCLUDES)
 295
 296 babeltraceincludedir="${includedir}/babeltrace"
 297 AC_SUBST(babeltraceincludedir)
 298
 299 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 300 AC_SUBST(babeltracectfincludedir)
 301
 302 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 303 AC_SUBST(babeltracectfwriterincludedir)
 304
 305 AC_CONFIG_FILES([
 306         Makefile
 307         types/Makefile
 308         compat/Makefile
 309         formats/Makefile
 310         formats/ctf/Makefile
 311         formats/ctf/types/Makefile
 312         formats/ctf-text/Makefile
 313         formats/ctf-text/types/Makefile
 314         formats/ctf-metadata/Makefile
 315         formats/bt-dummy/Makefile
 316         formats/lttng-live/Makefile
 317         formats/ctf/metadata/Makefile
 318         formats/ctf/writer/Makefile
 319         converter/Makefile
 320         doc/Makefile
 321         lib/Makefile
 322         lib/prio_heap/Makefile
 323         include/Makefile
 324         bindings/Makefile
 325         bindings/python/Makefile
 326         bindings/python/babeltrace/Makefile
 327         tests/Makefile
 328         tests/bin/Makefile
 329         tests/bin/intersection/Makefile
 330         tests/lib/Makefile
 331         tests/utils/Makefile
 332         tests/utils/tap/Makefile
 333         extras/Makefile
 334         extras/valgrind/Makefile
 335         babeltrace.pc
 336         babeltrace-ctf.pc
 337 ])
 338
 339 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 340 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 341 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 342 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 343 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 344
 345 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 346 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 347 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 348 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 349
 350 AC_OUTPUT
 351
 352 #
 353 # Mini-report on what will be built.
 354 #
 355
 356 PPRINT_INIT
 357 PPRINT_SET_INDENT(1)
 358 PPRINT_SET_TS(38)
 359
 360 AS_ECHO
 361 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 362 AS_ECHO
 363
 364 PPRINT_SUBTITLE([Features])
 365
 366 # Target architecture we're building for.
 367 target_arch=$host_cpu
 368 [
 369 for f in $CFLAGS; do
 370         if test $f = "-m32"; then
 371                 target_arch="32-bit"
 372         elif test $f = "-m64"; then
 373                 target_arch="64-bit"
 374         fi
 375 done
 376 ]
 377 PPRINT_PROP_STRING([Target architecture], $target_arch)
 378
 379 # python bindings enabled/disabled
 380 test "x$enable_python" = "xyes" && value=1 || value=0
 381 PPRINT_PROP_BOOL([Python bindings], $value)
 382
 383 # python bindings doc enabled/disabled
 384 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 385 PPRINT_PROP_BOOL([Python bindings doc], $value)
 386
 387 # debug info enabled/disabled
 388 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 389 PPRINT_PROP_BOOL([Debug information output], $value)
 390
 391
 392 report_bindir="`eval eval echo $bindir`"
 393 report_libdir="`eval eval echo $libdir`"
 394
 395 # Print the bindir and libdir this `make install' will install into.
 396 AS_ECHO
 397 PPRINT_SUBTITLE([Install directories])
 398 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 399 PPRINT_PROP_STRING([Libraries], [$report_libdir])