configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 # Checks for C compiler
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_SYS_LARGEFILE
  24 AC_PROG_CC
  25 AC_PROG_CC_STDC
  26
  27 # Checks for programs.
  28 AC_PROG_MAKE_SET
  29 LT_INIT
  30 AC_PROG_YACC
  31 AC_PROG_LEX
  32 AC_PROG_MKDIR_P
  33 AC_PROG_LN_S
  34
  35 AX_C___ATTRIBUTE__
  36 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  37         [:],
  38         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  41 LIBS="$PTHREAD_LIBS $LIBS"
  42 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  43 CC="$PTHREAD_CC"
  44
  45 # Check linker option
  46 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  47 AC_SUBST([LD_NO_AS_NEEDED])
  48
  49 AC_HEADER_STDBOOL
  50 AC_CHECK_HEADERS([ \
  51         fcntl.h \
  52         float.h \
  53         libintl.h \
  54         limits.h \
  55         malloc.h \
  56         netdb.h \
  57         netinet/in.h \
  58         stddef.h \
  59         sys/socket.h \
  60 ])
  61
  62 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  63         if test x"$(basename "$YACC")" != "xbison -y"; then
  64                 AC_MSG_ERROR([[bison not found and is required when building from git.
  65                 Please install bison]])
  66         fi
  67         AC_PATH_PROG([BISON],[bison])
  68         AX_PROG_BISON_VERSION([2.4], [],[
  69                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  70         ])
  71 fi
  72
  73 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  74         if test x"$LEX" != "xflex"; then
  75                 AC_MSG_ERROR([[flex not found and is required when building from git.
  76                 Please install flex]])
  77         fi
  78         AC_PATH_PROG([FLEX],[flex])
  79         AX_PROG_FLEX_VERSION([2.5.35], [],[
  80                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  81         ])
  82 fi
  83
  84
  85 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  86
  87 # Checks for typedefs, structures, and compiler characteristics.
  88 AC_C_INLINE
  89 AC_TYPE_PID_T
  90 AC_TYPE_SIZE_T
  91 AC_TYPE_INT16_T
  92 AC_TYPE_INT32_T
  93 AC_TYPE_INT64_T
  94 AC_TYPE_INT8_T
  95 AC_TYPE_OFF_T
  96 AC_TYPE_SSIZE_T
  97 AC_TYPE_UINT16_T
  98 AC_TYPE_UINT32_T
  99 AC_TYPE_UINT64_T
 100 AC_TYPE_UINT8_T
 101
 102 # Checks for library functions.
 103 AC_FUNC_ALLOCA
 104 AC_FUNC_FORK
 105 AC_FUNC_MALLOC
 106 AC_FUNC_MKTIME
 107 AC_FUNC_MMAP
 108 AC_FUNC_REALLOC
 109 AC_FUNC_STRERROR_R
 110 AC_CHECK_FUNCS([ \
 111         atexit \
 112         dirfd \
 113         dup2 \
 114         ftruncate \
 115         gethostbyname \
 116         gethostname \
 117         gettimeofday \
 118         localtime_r \
 119         memchr \
 120         memset \
 121         mkdir \
 122         mkdtemp \
 123         munmap \
 124         rmdir \
 125         setenv \
 126         socket \
 127         strchr \
 128         strdup \
 129         strerror \
 130         strndup \
 131         strnlen \
 132         strrchr \
 133         strtoul \
 134         strtoull \
 135         tzset \
 136         uname \
 137 ])
 138
 139 # Check for MinGW32.
 140 MINGW32=no
 141 case $host in
 142   *-*-mingw*)
 143         MINGW32=yes;;
 144 esac
 145
 146 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 147
 148 # Check what libraries are required on this platform to link sockets programs.
 149 AX_LIB_SOCKET_NSL
 150
 151 # Check for libuuid
 152 AC_CHECK_LIB([uuid], [uuid_generate],
 153 [
 154         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 155         have_libuuid=yes
 156 ],
 157 [
 158         # libuuid not found, check for uuid_create in libc.
 159         AC_CHECK_LIB([c], [uuid_create],
 160         [
 161                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 162                 have_libc_uuid=yes
 163         ],
 164         [
 165                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 166                 if test "x$MINGW32" = xno; then
 167                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 168                 fi
 169         ])
 170 ]
 171 )
 172 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 173 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 174
 175 # Check for fmemopen
 176 AC_CHECK_LIB([c], [fmemopen],
 177 [
 178         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 179 ]
 180 )
 181
 182 # Check for open_memstream
 183 AC_CHECK_LIB([c], [open_memstream],
 184 [
 185         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 186 ]
 187 )
 188
 189 # Check for posix_fallocate
 190 AC_CHECK_LIB([c], [posix_fallocate],
 191 [
 192         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 193 ]
 194 )
 195
 196 # Check for faccessat
 197 AC_CHECK_LIB([c], [faccessat],
 198 [
 199         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 200 ]
 201 )
 202
 203 AC_CHECK_LIB([popt], [poptGetContext], [],
 204         [AC_MSG_ERROR([Cannot find popt.])]
 205 )
 206
 207 # For Python
 208 # SWIG version needed or newer:
 209 swig_version=2.0.0
 210
 211 AC_ARG_ENABLE([python-bindings],
 212               [AC_HELP_STRING([--enable-python-bindings],
 213                               [generate Python bindings])],
 214               [enable_python=yes], [enable_python=no])
 215
 216 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 217
 218 AC_ARG_ENABLE([python-bindings-doc],
 219               [AC_HELP_STRING([--enable-python-bindings-doc],
 220                               [generate Python bindings documentation])],
 221               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 222
 223 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 224   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 225 fi
 226
 227 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 228
 229 if test "x${enable_python:-yes}" = xyes; then
 230   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 231   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 232
 233   AM_PATH_PYTHON_MODULES([PYTHON])
 234   # pythondir is the path where extra modules are to be installed
 235   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 236   # pyexecdir is the path that contains shared objects used by the extra modules
 237   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 238   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 239   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 240   AS_IF([test -z "$PYTHON_INCLUDE"], [
 241     AS_IF([test -z "$PYTHON_CONFIG"], [
 242       AC_PATH_PROGS([PYTHON_CONFIG],
 243                     [python$PYTHON_VERSION-config python-config],
 244                     [no],
 245                     [`dirname $PYTHON`])
 246       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 247     ])
 248     AC_MSG_CHECKING([python include flags])
 249     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 250     AC_MSG_RESULT([$PYTHON_INCLUDE])
 251   ])
 252 else
 253     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 254 [if you want Python bindings.])
 255
 256 fi
 257
 258 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 259     AM_CHECK_PYTHON_SPHINX([PYTHON])
 260     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 261       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 262     )
 263 fi
 264
 265 pkg_modules="gmodule-2.0 >= 2.0.0"
 266 PKG_CHECK_MODULES(GMODULE, [$pkg_modules])
 267 AC_SUBST(PACKAGE_LIBS)
 268
 269 LIBS="$LIBS $GMODULE_LIBS"
 270 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 271 AC_SUBST(PACKAGE_CFLAGS)
 272
 273 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 274 AC_SUBST(DEFAULT_INCLUDES)
 275
 276 babeltraceincludedir="${includedir}/babeltrace"
 277 AC_SUBST(babeltraceincludedir)
 278
 279 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 280 AC_SUBST(babeltracectfincludedir)
 281
 282 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 283 AC_SUBST(babeltracectfwriterincludedir)
 284
 285 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 286 AC_SUBST(babeltracectfirincludedir)
 287
 288 AC_CONFIG_FILES([
 289         Makefile
 290         types/Makefile
 291         compat/Makefile
 292         formats/Makefile
 293         formats/ctf/Makefile
 294         formats/ctf/types/Makefile
 295         formats/ctf-text/Makefile
 296         formats/ctf-text/types/Makefile
 297         formats/ctf-metadata/Makefile
 298         formats/bt-dummy/Makefile
 299         formats/lttng-live/Makefile
 300         formats/ctf/metadata/Makefile
 301         formats/ctf/writer/Makefile
 302         formats/ctf/ir/Makefile
 303         converter/Makefile
 304         doc/Makefile
 305         doc/bindings/Makefile
 306         doc/bindings/python/Makefile
 307         doc/images/Makefile
 308         lib/Makefile
 309         lib/prio_heap/Makefile
 310         include/Makefile
 311         bindings/Makefile
 312         bindings/python/Makefile
 313         tests/Makefile
 314         tests/bin/Makefile
 315         tests/lib/Makefile
 316         tests/utils/Makefile
 317         tests/utils/tap/Makefile
 318         extras/Makefile
 319         extras/valgrind/Makefile
 320         babeltrace.pc
 321         babeltrace-ctf.pc
 322 ])
 323 AC_OUTPUT