configure.ac

   1 AC_PREREQ([2.50])
   2 m4_define([bt_version_major], [2])
   3 m4_define([bt_version_minor], [0])
   4 m4_define([bt_version_patch], [0])
   5 m4_define([bt_version_extra], [-pre])
   6 m4_define([bt_version], bt_version_major[.]bt_version_minor[.]bt_version_patch[]bt_version_extra)
   7 AC_INIT([babeltrace],bt_version,[jeremie dot galarneau at efficios dot com])
   8
   9 # Following the numbering scheme proposed by libtool for the library version
  10 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  11 AC_SUBST([BABELTRACE_LIBRARY_VERSION], bt_version_major[:]bt_version_minor[:]bt_version_patch)
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_AUX_DIR([config])
  15 AC_CONFIG_MACRO_DIR([m4])
  16
  17 AC_DEFINE([BT_VERSION_MAJOR], bt_version_major, [Babeltrace library major version])
  18 AC_DEFINE([BT_VERSION_MINOR], bt_version_minor, [Babeltrace library minor version])
  19 AC_DEFINE([BT_VERSION_PATCH], bt_version_patch, [Babeltrace library patch version])
  20 AC_DEFINE([BT_VERSION_EXTRA], ["]bt_version_extra["], [Babeltrace library extra version])
  21
  22 AC_CANONICAL_TARGET
  23 AC_CANONICAL_HOST
  24
  25 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  26 AM_MAINTAINER_MODE([enable])
  27
  28 # Enable silent rules if available (Introduced in AM 1.11)
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30
  31 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  32
  33 # Checks for C compiler
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PROG_CC
  37 AC_PROG_CC_STDC
  38
  39 # Checks for programs.
  40 AC_PROG_MAKE_SET
  41 LT_INIT
  42 AC_PROG_YACC
  43 AC_PROG_LEX
  44 AC_PROG_MKDIR_P
  45 AC_PROG_LN_S
  46
  47 AX_C___ATTRIBUTE__
  48 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  49         [:],
  50         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  51
  52 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  53 LIBS="$PTHREAD_LIBS $LIBS"
  54 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  55 CC="$PTHREAD_CC"
  56
  57 # Check linker option
  58 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  59 AC_SUBST([LD_NO_AS_NEEDED])
  60
  61 AC_HEADER_STDBOOL
  62 AC_CHECK_HEADERS([ \
  63         fcntl.h \
  64         float.h \
  65         libintl.h \
  66         limits.h \
  67         malloc.h \
  68         netdb.h \
  69         netinet/in.h \
  70         stddef.h \
  71         sys/socket.h \
  72 ])
  73
  74 if test ! -f "$srcdir/plugins/ctf/common/metadata/parser.h"; then
  75         if test x"$(basename "$YACC")" != "xbison -y"; then
  76                 AC_MSG_ERROR([[bison not found and is required when building from git.
  77                 Please install bison]])
  78         fi
  79         AC_PATH_PROG([BISON],[bison])
  80         AX_PROG_BISON_VERSION([2.4], [],[
  81                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  82         ])
  83 fi
  84
  85 if test ! -f "$srcdir/plugins/ctf/common/metadata/lexer.c"; then
  86         if test x"$LEX" != "xflex"; then
  87                 AC_MSG_ERROR([[flex not found and is required when building from git.
  88                 Please install flex]])
  89         fi
  90         AC_PATH_PROG([FLEX],[flex])
  91         AX_PROG_FLEX_VERSION([2.5.35], [],[
  92                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  93         ])
  94 fi
  95
  96
  97 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  98
  99 # Check what libraries are required on this platform to link sockets programs.
 100 AX_LIB_SOCKET_NSL
 101
 102 # Checks for typedefs, structures, and compiler characteristics.
 103 AC_C_INLINE
 104 AC_TYPE_PID_T
 105 AC_TYPE_SIZE_T
 106 AC_TYPE_INT16_T
 107 AC_TYPE_INT32_T
 108 AC_TYPE_INT64_T
 109 AC_TYPE_INT8_T
 110 AC_TYPE_OFF_T
 111 AC_TYPE_SSIZE_T
 112 AC_TYPE_UINT16_T
 113 AC_TYPE_UINT32_T
 114 AC_TYPE_UINT64_T
 115 AC_TYPE_UINT8_T
 116
 117 # Checks for library functions.
 118 AC_FUNC_ALLOCA
 119 AC_FUNC_FORK
 120 AC_FUNC_MALLOC
 121 AC_FUNC_MKTIME
 122 AC_FUNC_MMAP
 123 AC_FUNC_REALLOC
 124 AC_FUNC_STRERROR_R
 125 AC_CHECK_FUNCS([ \
 126         atexit \
 127         dirfd \
 128         dup2 \
 129         ftruncate \
 130         gethostbyname \
 131         gethostname \
 132         gettimeofday \
 133         localtime_r \
 134         memchr \
 135         memset \
 136         mkdir \
 137         mkdtemp \
 138         munmap \
 139         rmdir \
 140         setenv \
 141         socket \
 142         strchr \
 143         strdup \
 144         strerror \
 145         strndup \
 146         strnlen \
 147         strrchr \
 148         strtoul \
 149         strtoull \
 150         tzset \
 151         uname \
 152 ])
 153
 154 MINGW32=no
 155 DEFAULT_ENABLE_DEBUG_INFO=yes
 156 AS_CASE([$host_os],
 157   [solaris*|darwin*],
 158     [
 159         DEFAULT_ENABLE_DEBUG_INFO=no
 160     ],
 161   [mingw*],
 162     [
 163         MINGW32=yes
 164     ]
 165 )
 166
 167 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 168
 169 # Check for uuid in system libs
 170 AC_CHECK_FUNCS([uuid_generate],
 171 [
 172   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 173   link_with_libuuid=no
 174 ],
 175 [
 176   # First, check the pkg-config module is available, otherwise explicitly check
 177   # for libuuid, or uuid support in the C-library.
 178   PKG_CHECK_MODULES([UUID], [uuid],
 179   [
 180     LIBS="${UUID_LIBS} ${LIBS}"
 181     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 182     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 183     link_with_libuuid=yes
 184   ],
 185   [
 186     # Check for libuuid
 187     AC_CHECK_LIB([uuid], [uuid_generate],
 188     [
 189       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 190       link_with_libuuid=yes
 191     ],
 192     [
 193       # libuuid not found, check for uuid_create in libc.
 194       AC_CHECK_LIB([c], [uuid_create],
 195       [
 196         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 197         link_with_libc_uuid=yes
 198       ],
 199       [
 200         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 201         if test "x$MINGW32" = xno; then
 202           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 203         fi
 204       ])
 205     ])
 206   ])
 207 ])
 208
 209 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 210 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 211
 212 # Check for fmemopen
 213 AC_CHECK_LIB([c], [fmemopen],
 214 [
 215         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 216 ]
 217 )
 218
 219 # Check for open_memstream
 220 AC_CHECK_LIB([c], [open_memstream],
 221 [
 222         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 223 ]
 224 )
 225
 226 # Check for posix_fallocate
 227 AC_CHECK_LIB([c], [posix_fallocate],
 228 [
 229         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 230 ]
 231 )
 232
 233 # Check for faccessat
 234 AC_CHECK_LIB([c], [faccessat],
 235 [
 236         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 237 ]
 238 )
 239
 240 AC_CHECK_LIB([popt], [poptGetContext], [],
 241         [AC_MSG_ERROR([Cannot find popt.])]
 242 )
 243
 244 # Plugins
 245 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 246 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 247
 248 # For Python
 249 # SWIG version needed or newer:
 250 swig_version=2.0.0
 251
 252 AC_ARG_ENABLE([python-bindings],
 253               [AC_HELP_STRING([--enable-python-bindings],
 254                               [generate Python bindings])],
 255               [enable_python_bindings=yes], [enable_python_bindings=no])
 256
 257 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python_bindings:-yes}" = xyes])
 258
 259 AC_ARG_ENABLE(
 260         [python-plugins],
 261         [AC_HELP_STRING(
 262                 [--enable-python-plugins],
 263                 [add support for the Babeltrace library and converter to load Python plugins])
 264         ],
 265         [enable_python_plugins=yes],
 266         [enable_python_plugins=no]
 267 )
 268
 269 if test "x${enable_python_bindings:-yes}" = xyes; then
 270   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 271 else
 272     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 273 [if you want Python bindings.])
 274 fi
 275
 276 if test "x$enable_python_bindings" != xno || test "x$enable_python_plugins" != xno; then
 277   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 278
 279   AM_PATH_PYTHON_MODULES([PYTHON])
 280   # pythondir is the path where extra modules are to be installed
 281   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 282   # pyexecdir is the path that contains shared objects used by the extra modules
 283   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 284   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for Python, bypassing python-config])
 285   AC_ARG_VAR([PYTHON_LIBS], [Library flags for Python, bypassing python-config])
 286   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 287   AS_IF([test -z "$PYTHON_INCLUDE"], [
 288     AS_IF([test -z "$PYTHON_CONFIG"], [
 289       AC_PATH_PROGS([PYTHON_CONFIG],
 290                     [python$PYTHON_VERSION-config python-config],
 291                     [no],
 292                     [`dirname $PYTHON`])
 293       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 294     ])
 295     AC_MSG_CHECKING([Python include flags])
 296     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 297     AC_MSG_RESULT([$PYTHON_INCLUDE])
 298   ])
 299   AS_IF([test -z "$PYTHON_LIBS"], [
 300     AS_IF([test -z "$PYTHON_CONFIG"], [
 301       AC_PATH_PROGS([PYTHON_CONFIG],
 302                     [python$PYTHON_VERSION-config python-config],
 303                     [no],
 304                     [`dirname $PYTHON`])
 305       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 306     ])
 307     AC_MSG_CHECKING([Python library flags])
 308     PYTHON_LIBS=`$PYTHON_CONFIG --libs`
 309     AC_MSG_RESULT([$PYTHON_LIBS])
 310   ])
 311 fi
 312
 313 AM_CONDITIONAL([WITH_PYTHON_PLUGINS], [test "x$enable_python_plugins" != xno])
 314 AS_IF(
 315   [test "x$enable_python_plugins" != xno],
 316   AC_DEFINE_UNQUOTED([WITH_PYTHON_PLUGINS], [1], [Python plugin support.])
 317 )
 318
 319 AC_ARG_ENABLE([python-bindings-doc],
 320               [AC_HELP_STRING([--enable-python-bindings-doc],
 321                               [generate Python bindings documentation])],
 322               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 323
 324 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 325
 326 AC_ARG_ENABLE([python-bindings-tests],
 327               [AC_HELP_STRING([--enable-python-bindings-tests],
 328                               [test Python bindings])],
 329               [enable_python_bindings_tests=yes], [enable_python_bindings_tests=no])
 330
 331 AM_CONDITIONAL([ENABLE_PYTHON_BINDINGS_TESTS], [test "x${enable_python_bindings_tests:-yes}" = xyes])
 332
 333 if test "x${enable_python_bindings:-no}" = xno; then
 334   if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 335     AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 336   fi
 337
 338   if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 339     AC_MSG_ERROR([--enable-python-bindings-tests was specified without --enable-python-bindings])
 340   fi
 341 fi
 342
 343 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 344     AM_CHECK_PYTHON_SPHINX([PYTHON])
 345     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 346       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 347     )
 348 fi
 349
 350 if test "x${enable_python_bindings_tests:-yes}" = xyes; then
 351     AM_CHECK_PYTHON_TAPPY([PYTHON])
 352     AS_IF([test "x$PYTHON_TAPPY_EXISTS" = xno],
 353         AC_MSG_ERROR([You need the tappy Python project to test the Python bindings (see <https://github.com/python-tap/tappy>)])
 354     )
 355 fi
 356
 357 # Set default enable state for debug info.
 358 # The _enable_debug_info variable is prepended with an underscore to
 359 # avoid clashing with the one generated by AC_ARG_ENABLE.
 360 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 361
 362 # Optional debug info feature
 363 # Do _not_ indent the help string below (appears in the configure --help
 364 # output).
 365 AC_ARG_ENABLE([debug-info],
 366 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 367 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 368         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 369
 370 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 371 AC_DEFINE([BT_ENABLE_DEBUG_INFO], [1], [Enable debug info support])
 372
 373 AS_IF([test "x$_enable_debug_info" = xyes], [
 374             # Check if libelf and libdw are present
 375             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 376             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 377             BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 378             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 379 ], [])
 380
 381 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 382 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 383 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 384         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 385         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 386         built_in_plugins=yes
 387         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 388 ])
 389 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 390
 391 AC_ARG_VAR([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [Statically-link Python plugin support into the babeltrace binary])
 392 AS_IF([test "x$BUILT_IN_PYTHON_PLUGIN_SUPPORT" != x], [
 393 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 394   AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle Python plugin support in the babeltrace executable)])
 395   AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle Python plugin support in the babeltrace executable)])
 396   built_in_python_plugin_support=yes
 397   AC_DEFINE([BT_BUILT_IN_PYTHON_PLUGIN_SUPPORT], [1], [Define to 1 to register plug-in attributes in static executable sections])
 398 ])
 399 AM_CONDITIONAL([BUILT_IN_PYTHON_PLUGIN_SUPPORT], [test "x$built_in_python_plugin_support" = "xyes"])
 400
 401 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 402
 403 # Logging
 404 AC_ARG_VAR([BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level for Babeltrace program, library, and plugins (VERBOSE, DEBUG, INFO, WARN, ERROR (default), FATAL, or NONE)])
 405 AS_IF([test "x$BABELTRACE_MINIMAL_LOG_LEVEL" = "x"], [BABELTRACE_MINIMAL_LOG_LEVEL=DEBUG])
 406 AS_IF([test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "VERBOSE" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "DEBUG" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "INFO" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "WARN" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "ERROR" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "FATAL" && test "$BABELTRACE_MINIMAL_LOG_LEVEL" != "NONE"], [
 407         AC_MSG_ERROR([Invalid BABELTRACE_MINIMAL_LOG_LEVEL value ($BABELTRACE_MINIMAL_LOG_LEVEL): use VERBOSE, DEBUG, INFO, WARN, ERROR, FATAL, or NONE.])
 408 ])
 409 AC_DEFINE_UNQUOTED([BT_LOG_LEVEL], [BT_LOG_$BABELTRACE_MINIMAL_LOG_LEVEL], [Minimal log level])
 410
 411 LIBS="$LIBS $GMODULE_LIBS"
 412 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 413 AC_SUBST(PACKAGE_CFLAGS)
 414
 415 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 416 AC_SUBST(DEFAULT_INCLUDES)
 417
 418 babeltraceincludedir="${includedir}/babeltrace"
 419 AC_SUBST(babeltraceincludedir)
 420
 421 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 422 AC_SUBST(babeltracectfwriterincludedir)
 423
 424 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 425 AC_SUBST(babeltracectfincludedir)
 426
 427 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 428 AC_SUBST(babeltracectfirincludedir)
 429
 430 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 431 AC_SUBST(babeltracepluginincludedir)
 432
 433 babeltracegraphincludedir="${includedir}/babeltrace/graph"
 434 AC_SUBST(babeltracegraphincludedir)
 435
 436 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 437 AC_SUBST(program_transform_name)
 438
 439 # check for Doxygen
 440 AC_ARG_ENABLE(
 441   [api-doc],
 442   [AC_HELP_STRING(
 443     [--enable-api-doc],
 444     [generate and install HTML API documentation]
 445   )],
 446   [enable_api_doc=$enableval],
 447   [enable_api_doc=no]
 448 )
 449 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 450
 451 AS_IF([test "x$enable_api_doc" = "xyes"], [
 452   DX_DOXYGEN_FEATURE(ON)
 453   DX_DOT_FEATURE(OFF)
 454   DX_HTML_FEATURE(ON)
 455   DX_CHM_FEATURE(OFF)
 456   DX_CHI_FEATURE(OFF)
 457   DX_MAN_FEATURE(OFF)
 458   DX_RTF_FEATURE(OFF)
 459   DX_XML_FEATURE(OFF)
 460   DX_PDF_FEATURE(OFF)
 461   DX_PS_FEATURE(OFF)
 462   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 463 ])
 464
 465 AC_CONFIG_FILES([
 466         Makefile
 467         common/Makefile
 468         compat/Makefile
 469         cli/Makefile
 470         doc/Makefile
 471         doc/api/Makefile
 472         doc/api/Doxyfile
 473         doc/bindings/Makefile
 474         doc/bindings/python/Makefile
 475         doc/images/Makefile
 476         lib/Makefile
 477         lib/prio_heap/Makefile
 478         lib/plugin/Makefile
 479         lib/graph/Makefile
 480         lib/graph/notification/Makefile
 481         lib/ctf-ir/Makefile
 482         lib/ctf-writer/Makefile
 483         include/Makefile
 484         logging/Makefile
 485         bindings/Makefile
 486         bindings/python/Makefile
 487         bindings/python/babeltrace/Makefile
 488         bindings/python/bt2/Makefile
 489         bindings/python/bt2/__init__.py
 490         tests/Makefile
 491         tests/cli/Makefile
 492         tests/cli/intersection/Makefile
 493         tests/lib/Makefile
 494         tests/lib/writer/Makefile
 495         tests/lib/test-plugin-plugins/Makefile
 496         tests/utils/Makefile
 497         tests/utils/tap/Makefile
 498         tests/bindings/Makefile
 499         tests/bindings/python/Makefile
 500         tests/bindings/python/bt2/Makefile
 501         tests/plugins/Makefile
 502         extras/Makefile
 503         extras/valgrind/Makefile
 504         plugins/Makefile
 505         plugins/ctf/Makefile
 506         plugins/ctf/common/Makefile
 507         plugins/ctf/common/btr/Makefile
 508         plugins/ctf/common/metadata/Makefile
 509         plugins/ctf/common/notif-iter/Makefile
 510         plugins/ctf/fs-src/Makefile
 511         plugins/ctf/fs-sink/Makefile
 512         plugins/ctf/lttng-live/Makefile
 513         plugins/text/Makefile
 514         plugins/text/pretty/Makefile
 515         plugins/utils/Makefile
 516         plugins/utils/dummy/Makefile
 517         plugins/utils/trimmer/Makefile
 518         plugins/utils/muxer/Makefile
 519         python-plugin-provider/Makefile
 520         plugins/libctfcopytrace/Makefile
 521         plugins/lttng-utils/Makefile
 522         babeltrace.pc
 523         babeltrace-ctf.pc
 524 ])
 525
 526 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 527 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 528 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 529 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 530 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 531 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 532 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 533
 534 AC_CONFIG_FILES([tests/plugins/test-utils-muxer-complete], [chmod +x tests/plugins/test-utils-muxer-complete])
 535
 536 AC_CONFIG_FILES([tests/cli/test_trace_read], [chmod +x tests/cli/test_trace_read])
 537 AC_CONFIG_FILES([tests/cli/intersection/test_intersection], [chmod +x tests/cli/intersection/test_intersection])
 538 AC_CONFIG_FILES([tests/cli/intersection/bt_python_helper.py])
 539 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 540 AC_CONFIG_FILES([tests/cli/test_packet_seq_num], [chmod +x tests/cli/test_packet_seq_num])
 541
 542 AS_IF([test "x$enable_python" = "xyes"], [
 543         AC_CONFIG_FILES(
 544                 [tests/bindings/python/bt2/testall.sh],
 545                 [chmod +x tests/bindings/python/bt2/testall.sh]
 546         )
 547 ])
 548
 549 AC_OUTPUT
 550
 551 #
 552 # Mini-report on what will be built.
 553 #
 554
 555 PPRINT_INIT
 556 PPRINT_SET_INDENT(1)
 557 PPRINT_SET_TS(38)
 558
 559 AS_ECHO
 560 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 561 AS_ECHO
 562
 563 PPRINT_SUBTITLE([Features])
 564
 565 # Target architecture we're building for.
 566 target_arch=$host_cpu
 567 [
 568 for f in $CFLAGS; do
 569         if test $f = "-m32"; then
 570                 target_arch="32-bit"
 571         elif test $f = "-m64"; then
 572                 target_arch="64-bit"
 573         fi
 574 done
 575 ]
 576 PPRINT_PROP_STRING([Target architecture], $target_arch)
 577
 578 # Minimal log level
 579 PPRINT_PROP_STRING([Minimal log level], $BABELTRACE_MINIMAL_LOG_LEVEL)
 580
 581 # API doc
 582 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 583 PPRINT_PROP_BOOL([HTML API documentation], $value)
 584
 585 # python bindings enabled/disabled
 586 test "x$enable_python_bindings" = "xyes" && value=1 || value=0
 587 PPRINT_PROP_BOOL([Python bindings], $value)
 588
 589 # python bindings doc enabled/disabled
 590 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 591 PPRINT_PROP_BOOL([Python bindings doc], $value)
 592
 593 # python bindings tests enabled/disabled
 594 test "x$enable_python_bindings_tests" = "xyes" && value=1 || value=0
 595 PPRINT_PROP_BOOL([Python bindings tests], $value)
 596
 597 # python plugins enabled/disabled
 598 test "x$enable_python_plugins" = "xyes" && value=1 || value=0
 599 PPRINT_PROP_BOOL([Python plugin support], $value)
 600
 601 # built-in Python plugin support enabled/disabled
 602 test "x$built_in_python_plugin_support" = "xyes" && value=1 || value=0
 603 PPRINT_PROP_BOOL([Built-in Python plugin support], $value)
 604
 605 # debug info enabled/disabled
 606 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 607 PPRINT_PROP_BOOL([Debug information output], $value)
 608
 609 # built-in plug-ins enabled/disabled
 610 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 611 PPRINT_PROP_BOOL([Built-in plug-ins], $value)
 612
 613 report_bindir="`eval eval echo $bindir`"
 614 report_libdir="`eval eval echo $libdir`"
 615
 616 # Print the bindir and libdir this `make install' will install into.
 617 AS_ECHO
 618 PPRINT_SUBTITLE([Install directories])
 619 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 620 PPRINT_PROP_STRING([Libraries], [$report_libdir])