configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.8.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Checks for C compiler
  18 AC_USE_SYSTEM_EXTENSIONS
  19 AC_SYS_LARGEFILE
  20 AC_PROG_CC
  21 AC_PROG_CC_STDC
  22
  23 # Checks for programs.
  24 AC_PROG_GREP
  25 AC_PROG_LEX
  26 AC_PROG_MAKE_SET
  27 AC_PROG_SED
  28 AC_PROG_YACC
  29 LT_INIT
  30
  31 # Check for objcopy, required by the base address statedump and dynamic linker tests
  32 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  33 AS_IF([test "x$OBJCOPY" = xno],
  34         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  35 )
  36 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  37
  38 # Checks for typedefs, structures, and compiler characteristics.
  39 AC_C_INLINE
  40 AC_TYPE_INT32_T
  41 AC_TYPE_INT64_T
  42 AC_TYPE_MODE_T
  43 AC_TYPE_OFF_T
  44 AC_TYPE_PID_T
  45 AC_TYPE_SIZE_T
  46 AC_TYPE_SSIZE_T
  47 AC_TYPE_UID_T
  48 AC_TYPE_UINT16_T
  49 AC_TYPE_UINT32_T
  50 AC_TYPE_UINT64_T
  51 AC_TYPE_UINT8_T
  52
  53 AX_C___ATTRIBUTE__
  54 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  55         [:],
  56         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  57
  58 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  59 LIBS="$PTHREAD_LIBS $LIBS"
  60 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  61 CC="$PTHREAD_CC"
  62
  63 AX_LIB_SOCKET_NSL
  64
  65 # Compute minor/major/patchlevel version numbers
  66 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  67 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  68 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  69 AC_SUBST([MAJOR_VERSION], [$major_version])
  70 AC_SUBST([MINOR_VERSION], [$minor_version])
  71 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  72 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  73 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  74 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  75
  76 version_name="Herbe à Détourne"
  77 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  78 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  79
  80 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  81 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  82
  83 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  84 AC_ARG_ENABLE(libtool-linkdep-fixup,
  85         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  86                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  87         libtool_fixup=$enableval,
  88         libtool_fixup=yes)
  89
  90 AS_IF([test "x$libtool_fixup" = "xyes"],
  91             [
  92             libtool_m4="$srcdir/m4/libtool.m4"
  93             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  94             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  95             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  96             AS_IF([test $libtool_flag_pattern_count -ne 0],
  97             [
  98                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  99                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 100                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 101                   ],
 102                   [
 103                   AC_MSG_RESULT([none])
 104                   ])
 105             ])
 106
 107 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 108
 109 AC_CHECK_HEADERS([ \
 110         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 111         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 112         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 113         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 114         sys/mount.h sys/param.h sys/time.h
 115 ])
 116
 117 # Basic functions check
 118 AC_CHECK_FUNCS([ \
 119         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 120         gethostbyname gethostname getpagesize localtime_r memchr memset \
 121         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 122         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 123         strtoull dirfd gethostbyname2 getipnodebyname \
 124 ])
 125
 126 # Babeltrace viewer check
 127 AC_ARG_WITH([babeltrace-bin],
 128         AS_HELP_STRING([--with-babeltrace-bin],
 129         [Location of the babeltrace viewer executable (including the filename)]),
 130         [BABELTRACE_BIN="$withval"],
 131         [BABELTRACE_BIN=''])
 132 AC_SUBST([BABELTRACE_BIN])
 133
 134 # lttv-gui
 135 AC_ARG_WITH([lttv-gui-bin],
 136         AS_HELP_STRING([--with-lttv-gui-bin],
 137    [Location of the lttv GUI viewer executable (including the filename)]),
 138    [LTTV_GUI_BIN="$withval"],
 139    [LTTV_GUI_BIN=''])
 140 AC_SUBST([LTTV_GUI_BIN])
 141
 142 AC_ARG_WITH([consumerd32-bin],
 143         AS_HELP_STRING([--with-consumerd32-bin],
 144         [Location of the 32-bit consumerd executable (including the filename)]),
 145         [CONSUMERD32_BIN="$withval"],
 146         [CONSUMERD32_BIN=''])
 147 AC_SUBST([CONSUMERD32_BIN])
 148
 149 AC_ARG_WITH([consumerd64-bin],
 150         AS_HELP_STRING([--with-consumerd64-bin],
 151         [Location of the 64-bit consumerd executable (including the filename)]),
 152         [CONSUMERD64_BIN="$withval"],
 153         [CONSUMERD64_BIN=''])
 154 AC_SUBST([CONSUMERD64_BIN])
 155
 156 AC_ARG_WITH([consumerd32-libdir],
 157         AS_HELP_STRING([--with-consumerd32-libdir],
 158         [Directory containing the 32-bit consumerd libraries]),
 159         [CONSUMERD32_LIBDIR="$withval"],
 160         [CONSUMERD32_LIBDIR=''])
 161 AC_SUBST([CONSUMERD32_LIBDIR])
 162
 163 AC_ARG_WITH([consumerd64-libdir],
 164         AS_HELP_STRING([--with-consumerd64-libdir],
 165         [Directory containing the 64-bit consumerd libraries]),
 166         [CONSUMERD64_LIBDIR="$withval"],
 167         [CONSUMERD64_LIBDIR=''])
 168 AC_SUBST([CONSUMERD64_LIBDIR])
 169
 170 AC_ARG_WITH([sessiond-bin],
 171         AS_HELP_STRING([--with-sessiond-bin],
 172         [Location of the sessiond executable (including the filename)]),
 173         [SESSIOND_BIN="$withval"],
 174         [SESSIOND_BIN=''])
 175 AC_SUBST([SESSIOND_BIN])
 176
 177 AC_ARG_WITH([lttng-system-rundir],
 178         AS_HELP_STRING([--with-lttng-system-rundir],
 179         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 180         [LTTNG_SYSTEM_RUNDIR="$withval"],
 181         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 182 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 183
 184 AC_ARG_ENABLE([test-java-agent-jul],
 185         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 186         [test_java_agent_jul=$enableval],
 187         [test_java_agent_jul=no]
 188 )
 189
 190 AC_ARG_ENABLE([test-java-agent-log4j],
 191         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 192         [test_java_agent_log4j=$enableval],
 193         [test_java_agent_log4j=no]
 194 )
 195
 196 AC_ARG_ENABLE([test-java-agent-all],
 197         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 198         [test_java_agent_jul=$enableval
 199          test_java_agent_log4j=$enableval],
 200         [:]
 201 )
 202
 203 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 204 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 205 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 206 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 207 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 208 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 209 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 210 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 211
 212 if test "x$prefix" = "xNONE"; then
 213         prefix=$ac_default_prefix
 214 fi
 215 CONFDIR=`eval echo $sysconfdir`
 216 AC_SUBST(CONFDIR)
 217 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 218
 219 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 220
 221 #
 222 # Check for pthread
 223 AC_CHECK_LIB([pthread], [pthread_create], [],
 224         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 225 )
 226
 227 # Check libpopt
 228 PKG_CHECK_MODULES([POPT], [popt],
 229         [LIBS="$LIBS $POPT_LIBS"],
 230         [
 231                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 232                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 233                 AC_CHECK_LIB([popt],
 234                         [poptGetContext],
 235                         [],
 236                         [
 237                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 238                         ]
 239                 )
 240         ]
 241 )
 242
 243 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 244
 245 # Check for libuuid
 246 PKG_CHECK_MODULES([UUID], [uuid],
 247 [
 248         LIBS="$LIBS $UUID_LIBS"
 249         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 250         have_libuuid=yes
 251 ],
 252 [
 253         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 254         AC_MSG_WARN([Finding libuuid without pkg-config.])
 255         AC_CHECK_LIB([uuid],
 256                 [uuid_generate],
 257                 [
 258                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 259                         have_libuuid=yes
 260                 ],
 261                 [
 262                         # libuuid not found, check for uuid_create in libc.
 263                         AC_CHECK_LIB([c],
 264                                 [uuid_create],
 265                                 [
 266                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 267                                         have_libc_uuid=yes
 268                                 ],
 269                                 [
 270                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 271                                 ]
 272                         )
 273                 ]
 274         )
 275 ])
 276 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 277 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 278
 279 # URCU library version needed or newer
 280 liburcu_version=">= 0.8.0"
 281
 282 # Check liburcu needed function calls
 283 AC_CHECK_DECL([cds_list_add], [],
 284         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 285 )
 286 AC_CHECK_DECL([cds_wfcq_init], [],
 287         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 288 )
 289 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 290     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 291 )
 292 AC_CHECK_DECL([futex_async], [],
 293         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 294 )
 295 AC_CHECK_DECL([rcu_thread_offline], [],
 296         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 297 )
 298 AC_CHECK_DECL([rcu_thread_online], [],
 299         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 300 )
 301 AC_CHECK_DECL([caa_likely], [],
 302         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 303 )
 304 #Function added in urcu 0.7.0
 305 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 306         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 307 )
 308
 309 # Check kmod library
 310 AC_ARG_WITH(kmod-prefix,
 311   AS_HELP_STRING([--with-kmod-prefix=PATH],
 312                 [Specify the installation prefix of the kmod library.
 313                 Headers must be in PATH/include; libraries in PATH/lib.]),
 314                 [
 315                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 316                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 317                 ])
 318
 319 AC_ARG_ENABLE(kmod,
 320         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 321         kmod_support=zz$enableval, kmod_support=yes)
 322
 323 AS_IF([test "x$kmod_support" = "xyes"], [
 324         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 325                 [
 326                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 327                         LIBS="$LIBS -lkmod"
 328                         kmod_found=yes
 329                 ],
 330                 kmod_found=no
 331         )
 332 ])
 333 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 334
 335 AC_ARG_WITH(lttng-ust-prefix,
 336   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 337                  [Specify the installation prefix of the lttng-ust library.
 338                   Headers must be in PATH/include; libraries in PATH/lib.]),
 339                   [
 340                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 341                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 342                   ])
 343
 344 # Check liblttng-ust-ctl library
 345 AC_ARG_WITH(lttng-ust,
 346         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 347         lttng_ust_support=$withval, lttng_ust_support=yes)
 348
 349 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 350         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 351                 [
 352                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 353                         lttng_ust_ctl_found=yes
 354                 ],
 355                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 356                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 357         )
 358 ])
 359 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 360 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 361
 362 # check for dlopen
 363 AC_CHECK_LIB([dl], [dlopen],
 364 [
 365         have_libdl=yes
 366 ],
 367 [
 368         #libdl not found, check for dlopen in libc.
 369         AC_CHECK_LIB([c], [dlopen],
 370         [
 371                 have_libc_dl=yes
 372         ],
 373         [
 374                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 375         ])
 376 ])
 377 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 378 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 379
 380 # Check for fmemopen
 381 AC_CHECK_LIB([c], [fmemopen],
 382 [
 383         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 384 ]
 385 )
 386
 387 # Check for open_memstream
 388 AC_CHECK_LIB([c], [open_memstream],
 389 [
 390         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 391 ]
 392 )
 393
 394 AC_ARG_ENABLE([git-version],
 395               [AC_HELP_STRING([--disable-git-version],
 396                               [Do not use the git version for the build])],
 397               [have_git_version=$enableval], [have_git_version=yes]
 398 )
 399
 400 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 401         [test "x${have_git_version}" = "xyes"])
 402
 403 # For Python
 404 # SWIG version needed or newer:
 405 swig_version=2.0.0
 406
 407 AC_ARG_ENABLE([python-bindings],
 408               [AC_HELP_STRING([--enable-python-bindings],
 409                               [compile Python bindings])],
 410               [enable_python_binding=yes], [enable_python_binding=no])
 411
 412 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 413
 414 if test "x${enable_python_binding:-yes}" = xyes; then
 415   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 416   AM_PATH_PYTHON([3.0])
 417
 418   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 419   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 420   AS_IF([test -z "$PYTHON_INCLUDE"], [
 421     AS_IF([test -z "$PYTHON_CONFIG"], [
 422       AC_PATH_PROGS([PYTHON_CONFIG],
 423                     [python$PYTHON_VERSION-config python-config],
 424                     [no],
 425                     [`dirname $PYTHON`])
 426       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 427     ])
 428     AC_MSG_CHECKING([python include flags])
 429     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 430     AC_MSG_RESULT([$PYTHON_INCLUDE])
 431   ])
 432
 433 else
 434     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 435 [if you want Python bindings.])
 436
 437 fi
 438
 439 # Epoll check. If not present, the build will fallback on poll() API
 440 AX_HAVE_EPOLL(
 441         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 442         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 443 )
 444 AX_CONFIG_FEATURE(
 445         [epoll], [This platform supports epoll(7)],
 446         [HAVE_EPOLL], [This platform supports epoll(7).],
 447         [enable_epoll="yes"], [enable_epoll="no"]
 448 )
 449 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 450
 451 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 452 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 453
 454 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 455         AX_JAVA_OPTIONS
 456         AX_PROG_JAVAC
 457         AX_PROG_JAVA
 458         AX_PROG_JAR
 459
 460         AX_CHECK_CLASSPATH
 461
 462         # Check for Java UST agent common class first
 463         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 464         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 465                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 466         fi
 467
 468         if test "x$test_java_agent_jul" = "xyes"; then
 469                 # Check for JUL agent class
 470                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 471                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 472                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 473                 fi
 474         fi
 475
 476         if test "x$test_java_agent_log4j" = "xyes"; then
 477                 # Check for Log4j agent class
 478                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 479                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 480                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 481                 fi
 482
 483                 # Check for Log4j class
 484                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 485                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 486                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 487                 fi
 488         fi
 489 fi
 490
 491 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 492 # is not distributed in tarballs
 493 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 494 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 495
 496 # enable building man pages
 497 AC_ARG_ENABLE(
 498         build-man-pages,
 499         AS_HELP_STRING(
 500                 [--enable-build-man-pages],
 501                 [Build man pages (already built in a distributed tarball)]
 502         ),
 503         [enable_build_man_pages=yes],
 504         [enable_build_man_pages=no]
 505 )
 506
 507 # export man page build condition
 508 AM_CONDITIONAL([BUILD_MAN_PAGES], [test "x$enable_build_man_pages" != "xno"])
 509
 510 # check for asciidoc and xmlto if we enabled building the man pages
 511 AS_IF([test "x$enable_build_man_pages" = "xyes"], [
 512         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 513         AC_PATH_PROG([XMLTO], [xmlto], [no])
 514
 515         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 516                 AC_MSG_ERROR([Both asciidoc and xmlto are needed to build the LTTng man pages.])
 517         ])
 518 ])
 519
 520 # Python agent test
 521 UST_PYTHON_AGENT="lttngust"
 522
 523 AC_ARG_ENABLE(test-python2-agent,
 524         AS_HELP_STRING([--enable-test-python2-agent],
 525                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 526         ),[:],[test_python2_agent_autodetect=yes]
 527 )
 528
 529 AC_ARG_ENABLE(test-python3-agent,
 530         AS_HELP_STRING([--enable-test-python3-agent],
 531                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 532         ),[:],[test_python3_agent_autodetect=yes]
 533 )
 534
 535 AC_ARG_ENABLE(test-python-agent-all,
 536         AS_HELP_STRING([--enable-test-python-agent-all],
 537                 [enable test for all python{2/3} agent.]
 538         ),
 539 )
 540
 541 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 542        unset test_python2_agent_autodetect
 543        unset test_python3_agent_autodetect
 544 ])
 545
 546 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 547        enable_test_python2_agent=yes
 548        enable_test_python3_agent=yes
 549 ])
 550
 551 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 552        enable_test_python2_agent=no
 553        enable_test_python3_agent=no
 554 ])
 555
 556
 557 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 558         AS_IF([test -z "$PYTHON2"], [
 559                         PYTHON2=python2
 560                 ], [
 561                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 562         ])
 563
 564         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 565         AS_IF([test -z "$PYTHON2_BIN"], [
 566                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 567                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 568                 ])
 569         ], [
 570                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 571                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 572                         PYTHON2_AGENT=$PYTHON2_BIN
 573                         AC_MSG_RESULT([yes])
 574                         RUN_PYTHON_AGENT_TEST=yes
 575                 ], [
 576                         AC_MSG_RESULT([no])
 577                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 578                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 579                         ])
 580                 ])
 581
 582         ])
 583
 584 ])
 585
 586 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 587         AS_IF([test -z "$PYTHON3"], [
 588                 PYTHON3=python3
 589         ], [
 590                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 591         ])
 592
 593         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 594         AS_IF([test -z "$PYTHON3_BIN"], [
 595                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 596                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 597                 ])
 598         ], [
 599                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 600                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 601                         PYTHON3_AGENT=$PYTHON3_BIN
 602                         AC_MSG_RESULT([yes])
 603                         RUN_PYTHON_AGENT_TEST=yes
 604                 ], [
 605                         AC_MSG_RESULT([no])
 606                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 607                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 608                         ])
 609                 ])
 610
 611         ])
 612 ])
 613 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 614 AC_SUBST([PYTHON2_AGENT])
 615 AC_SUBST([PYTHON3_AGENT])
 616
 617 # Arguments for binaries build exclusion
 618 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 619 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 620               [Disable the build of lttng-consumerd binaries]))
 621 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 622 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 623               [Disable the build of lttng-relayd binaries]))
 624 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 625               [Disable the build of lttng-sessiond binaries]))
 626 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 627               [Disable the build of the extra components]))
 628
 629
 630 # Always build libconfig since it a dependency of libcommon
 631 build_lib_config=yes
 632
 633 build_lib_compat=no
 634 build_lib_consumer=no
 635 build_lib_hashtable=no
 636 build_lib_health=no
 637 build_lib_index=no
 638 build_lib_kernel_consumer=no
 639 build_lib_kernel_ctl=no
 640 build_lib_lttng_ctl=no
 641 build_lib_relayd=no
 642 build_lib_sessiond_comm=no
 643 build_lib_testpoint=no
 644 build_lib_ust_consumer=no
 645
 646 # There is an overlap for enabled dependencies, but this makes everything
 647 # simpler. libcommon and libconfig are always compiled so they are not repeated
 648 # here.
 649
 650 # Enable binary dependencies.
 651 AS_IF([test x$enable_bin_lttng != xno],
 652       [
 653        build_lib_lttng_ctl=yes
 654       ]
 655 )
 656
 657 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 658       [
 659        build_lib_consumer=yes
 660        build_lib_sessiond_comm=yes
 661        build_lib_index=yes
 662        build_lib_health=yes
 663        build_lib_testpoint=yes
 664       ]
 665 )
 666
 667 AS_IF([test x$enable_bin_lttng_crash != xno],
 668       # Do nothing since libconfig and libcommon are built by default.
 669       []
 670 )
 671
 672 AS_IF([test x$enable_bin_lttng_relayd != xno],
 673       [
 674        build_lib_lttng_ctl=yes
 675        build_lib_sessiond_comm=yes
 676        build_lib_hashtable=yes
 677        build_lib_compat=yes
 678        build_lib_index=yes
 679        build_lib_health=yes
 680        build_lib_testpoint=yes
 681       ]
 682 )
 683 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 684       [
 685        build_lib_lttng_ctl=yes
 686        build_lib_sessiond_comm=yes
 687        build_lib_kernel_ctl=yes
 688        build_lib_hashtable=yes
 689        build_lib_compat=yes
 690        build_lib_relayd=yes
 691        build_lib_testpoint=yes
 692        build_lib_health=yes
 693        build_lib_health=yes
 694       ]
 695 )
 696
 697 # Libraries dependencies enabling
 698 AS_IF([test x$build_lib_lttng_ctl = xyes],
 699       [
 700        build_lib_sessiond_comm=yes
 701        build_lib_hashtable=yes
 702       ]
 703 )
 704
 705 AS_IF([test x$build_lib_consumer = xyes],
 706       [
 707        build_lib_sessiond_comm=yes
 708        build_lib_kernel_consumer=yes
 709        build_lib_hashtable=yes
 710        build_lib_compat=yes
 711        build_lib_relayd=yes
 712        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 713       ]
 714 )
 715
 716 AS_IF([test x$build_lib_kernel_consumer = xyes],
 717       [
 718        build_lib_kernel_ctl=yes
 719        build_lib_relayd=yes
 720       ]
 721 )
 722
 723 AS_IF([test x$build_lib_relayd = xyes],
 724       [
 725        build_lib_sessiond_comm=yes
 726       ]
 727 )
 728
 729
 730 # Export binaries build conditions.
 731 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 732 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 733 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 734 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 735 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 736
 737 # Export the tests and extras build conditions.
 738 AS_IF([\
 739 test "x$enable_bin_lttng" != "xno" && \
 740 test "x$enable_bin_lttng_consumerd" != "xno" && \
 741 test "x$enable_bin_lttng_crash" != "xno" && \
 742 test "x$enable_bin_lttng_relayd" != "xno" && \
 743 test "x$enable_bin_lttng_sessiond" != "xno"],
 744 [build_tests=yes],
 745 [build_tests=no]
 746 )
 747
 748 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 749 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 750
 751 # Export libraries build conditions.
 752 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 753 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 754 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 755 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 756 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 757 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 758 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 759 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 760 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 761 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 762 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 763 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 764 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 765
 766 # check for pgrep
 767 AC_PATH_PROG([PGREP], [pgrep], [no])
 768 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 769
 770 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 771         if test x"$(basename "$YACC")" != "xbison -y"; then
 772                 AC_MSG_ERROR([[bison not found and is required when building from git.
 773                 Please install bison]])
 774         fi
 775         AC_PATH_PROG([BISON],[bison])
 776         AX_PROG_BISON_VERSION([2.4], [],[
 777                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 778         ])
 779 fi
 780
 781 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 782         if test x"$LEX" != "xflex"; then
 783                 AC_MSG_ERROR([[flex not found and is required when building from git.
 784                 Please install flex]])
 785         fi
 786         AC_PATH_PROG([FLEX],[flex])
 787         AX_PROG_FLEX_VERSION([2.5.35], [],[
 788                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 789         ])
 790 fi
 791
 792 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 793
 794 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 795
 796 lttngincludedir="${includedir}/lttng"
 797
 798 AC_SUBST(lttngincludedir)
 799 AC_SUBST(DEFAULT_INCLUDES)
 800
 801 lttnglibexecdir="${libdir}/lttng/libexec"
 802 AC_SUBST(lttnglibexecdir)
 803
 804 AC_CONFIG_FILES([
 805         Makefile
 806         doc/Makefile
 807         doc/man/Makefile
 808         include/Makefile
 809         extras/Makefile
 810         extras/bindings/Makefile
 811         extras/bindings/swig/Makefile
 812         extras/bindings/swig/python/Makefile
 813         extras/core-handler/Makefile
 814         src/Makefile
 815         src/common/Makefile
 816         src/common/kernel-ctl/Makefile
 817         src/common/kernel-consumer/Makefile
 818         src/common/consumer/Makefile
 819         src/common/ust-consumer/Makefile
 820         src/common/hashtable/Makefile
 821         src/common/sessiond-comm/Makefile
 822         src/common/compat/Makefile
 823         src/common/relayd/Makefile
 824         src/common/testpoint/Makefile
 825         src/common/index/Makefile
 826         src/common/health/Makefile
 827         src/common/config/Makefile
 828         src/lib/Makefile
 829         src/lib/lttng-ctl/Makefile
 830         src/lib/lttng-ctl/filter/Makefile
 831         src/lib/lttng-ctl/lttng-ctl.pc
 832         src/bin/Makefile
 833         src/bin/lttng-consumerd/Makefile
 834         src/bin/lttng-sessiond/Makefile
 835         src/bin/lttng-relayd/Makefile
 836         src/bin/lttng/Makefile
 837         src/bin/lttng-crash/Makefile
 838         tests/Makefile
 839         tests/destructive/Makefile
 840         tests/regression/Makefile
 841         tests/regression/kernel/Makefile
 842         tests/regression/tools/Makefile
 843         tests/regression/tools/streaming/Makefile
 844         tests/regression/tools/filtering/Makefile
 845         tests/regression/tools/health/Makefile
 846         tests/regression/tools/tracefile-limits/Makefile
 847         tests/regression/tools/snapshots/Makefile
 848         tests/regression/tools/live/Makefile
 849         tests/regression/tools/exclusion/Makefile
 850         tests/regression/tools/save-load/Makefile
 851         tests/regression/tools/mi/Makefile
 852         tests/regression/tools/wildcard/Makefile
 853         tests/regression/tools/crash/Makefile
 854         tests/regression/tools/metadata-regen/Makefile
 855         tests/regression/ust/Makefile
 856         tests/regression/ust/nprocesses/Makefile
 857         tests/regression/ust/high-throughput/Makefile
 858         tests/regression/ust/low-throughput/Makefile
 859         tests/regression/ust/before-after/Makefile
 860         tests/regression/ust/buffers-pid/Makefile
 861         tests/regression/ust/periodical-metadata-flush/Makefile
 862         tests/regression/ust/multi-session/Makefile
 863         tests/regression/ust/overlap/Makefile
 864         tests/regression/ust/overlap/demo/Makefile
 865         tests/regression/ust/linking/Makefile
 866         tests/regression/ust/daemon/Makefile
 867         tests/regression/ust/exit-fast/Makefile
 868         tests/regression/ust/fork/Makefile
 869         tests/regression/ust/libc-wrapper/Makefile
 870         tests/regression/ust/baddr-statedump/Makefile
 871         tests/regression/ust/ust-dl/Makefile
 872         tests/regression/ust/java-jul/Makefile
 873         tests/regression/ust/java-log4j/Makefile
 874         tests/regression/ust/python-logging/Makefile
 875         tests/regression/ust/getcpu-override/Makefile
 876         tests/regression/ust/clock-override/Makefile
 877         tests/regression/ust/type-declarations/Makefile
 878         tests/stress/Makefile
 879         tests/unit/Makefile
 880         tests/unit/ini_config/Makefile
 881         tests/utils/Makefile
 882         tests/utils/tap/Makefile
 883         tests/utils/testapp/Makefile
 884         tests/utils/testapp/gen-ust-events/Makefile
 885         tests/utils/testapp/gen-ust-nevents/Makefile
 886         tests/utils/testapp/gen-ust-tracef/Makefile
 887 ])
 888
 889 # Inject variable into python test script.
 890 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 891
 892 AC_OUTPUT
 893
 894 #
 895 # Mini-report on what will be built.
 896 #
 897 AS_ECHO()
 898
 899 AS_ECHO("Version name: $version_name")
 900 AS_ECHO("$version_description")
 901
 902 AS_ECHO()
 903
 904 # Target architecture we're building for.
 905 target_arch=$host_cpu
 906 [
 907 for f in $CFLAGS; do
 908         if test $f = "-m32"; then
 909                         target_arch="32-bit"
 910         elif test $f = "-m64"; then
 911                         target_arch="64-bit"
 912         fi
 913 done
 914 ]
 915 AS_ECHO_N("Target architecture: ")
 916 AS_ECHO($target_arch)
 917
 918 # kmod enabled/disabled
 919 AS_ECHO_N("libkmod support: ")
 920 AS_IF([test "x$kmod_found" = "xyes"],[
 921         AS_ECHO("Enabled")
 922 ],[
 923         AS_ECHO("Disabled")
 924 ])
 925
 926 # LTTng-UST enabled/disabled
 927 AS_ECHO_N("Lttng-UST support: ")
 928 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 929         AS_ECHO("Enabled")
 930 ],[
 931         AS_ECHO("Disabled")
 932 ])
 933
 934 AS_ECHO()
 935 AS_ECHO("Binaries:")
 936
 937 # List binaries to be built
 938 AS_ECHO_N("lttng: ")
 939 AS_IF([test x$enable_bin_lttng != xno],[
 940        AS_ECHO("Enabled")
 941 ],[
 942        AS_ECHO("Disabled")
 943 ])
 944
 945 AS_ECHO_N("lttng-consumerd: ")
 946 AS_IF([test x$enable_bin_lttng_consumerd != xno],[
 947        AS_ECHO("Enabled")
 948 ],[
 949        AS_ECHO("Disabled")
 950 ])
 951
 952 AS_ECHO_N("lttng-crash: ")
 953 AS_IF([test x$enable_bin_lttng_crash != xno],[
 954        AS_ECHO("Enabled")
 955 ],[
 956        AS_ECHO("Disabled")
 957 ])
 958
 959 AS_ECHO_N("lttng-relayd: ")
 960 AS_IF([test x$enable_bin_lttng_relayd != xno],[
 961        AS_ECHO("Enabled")
 962 ],[
 963        AS_ECHO("Disabled")
 964 ])
 965
 966 AS_ECHO_N("lttng-sessiond: ")
 967 AS_IF([test x$enable_bin_lttng_sessiond != xno],[
 968        AS_ECHO("Enabled")
 969 ],[
 970        AS_ECHO("Disabled")
 971 ])
 972
 973 AS_ECHO_N("Extras: ")
 974 AS_IF([test x$enable_extras != xno],[
 975        AS_ECHO("Enabled")
 976 ],[
 977        AS_ECHO("Disabled")
 978 ])
 979
 980 # Print the bindir and libdir this `make install' will install into.
 981 AS_ECHO()
 982 AS_ECHO_N("Binaries will be installed in:  ")
 983 AS_ECHO("`eval eval echo $bindir`")
 984 AS_ECHO_N("Libraries will be installed in: ")
 985 AS_ECHO("`eval eval echo $libdir`")
 986
 987
 988 AS_ECHO()
 989
 990 # Print clear message that tests won't be built
 991 AS_IF([test "x$build_tests" = "xno"],[
 992        AS_ECHO("WARNING: Tests won't be built since some binaries were disabled")
 993 ])
 994
 995 AS_ECHO("Tests:")
 996
 997 # LTTng UST Java agent JUL tests enabled/disabled
 998 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
 999 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
1000         AS_ECHO("Enabled")
1001 ],[
1002         AS_ECHO("Disabled")
1003 ])
1004
1005 # LTTng UST Java agent Log4j tests enabled/disabled
1006 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
1007 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
1008         AS_ECHO("Enabled")
1009 ],[
1010         AS_ECHO("Disabled")
1011 ])
1012
1013 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
1014 AS_IF([test ! -z "$PYTHON2_AGENT"],[
1015         AS_ECHO("Enabled")
1016 ],[
1017         AS_ECHO("Disabled")
1018 ])
1019
1020 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
1021 AS_IF([test ! -z "$PYTHON3_AGENT"],[
1022         AS_ECHO("Enabled")
1023 ],[
1024         AS_ECHO("Disabled")
1025 ])
1026
1027 AS_ECHO()
1028
1029 #Python binding enabled/disabled
1030 AS_ECHO_N("Python binding: ")
1031 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
1032         AS_ECHO("Enabled")
1033 ],[
1034         AS_ECHO("Disabled")
1035 ])
1036
1037 AS_ECHO()
1038
1039 # man pages build enabled/disabled
1040 AS_ECHO_N("Build man pages: ")
1041 AS_IF([test "x$enable_build_man_pages" = "xyes"], [
1042         AS_ECHO("Yes")
1043 ], [
1044         AS_IF([test "x$in_git_repo" = "xyes"], [
1045                 AS_ECHO("No")
1046         ], [
1047                 AS_ECHO("Already built")
1048         ])
1049 ])
1050
1051 # man pages install enabled/disabled (always true in tarball)
1052 AS_ECHO_N("Install man pages: ")
1053 AS_IF([test "x$enable_build_man_pages" = "xno" && test "x$in_git_repo" = "xyes"], [
1054         AS_ECHO("No")
1055 ], [
1056         AS_ECHO("Yes")
1057 ])
1058
1059 AS_ECHO()
1060
1061 # If we build the sessiond, print the paths it will use
1062 AS_ECHO_N("The lttng command will search for the lttng-sessiond executable at: ")
1063 AS_IF([test "$SESSIOND_BIN" = ""],[
1064         AS_ECHO_N("`eval eval echo $bindir`")
1065         AS_ECHO("/lttng-sessiond")
1066 ],[
1067         AS_ECHO("$SESSIOND_BIN")
1068 ])
1069
1070 AS_ECHO()
1071 AS_ECHO("The sessiond daemon will search the following directories: ")
1072 AS_ECHO_N("32-bit consumerd executable: ")
1073 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1074         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
1075         AS_ECHO("/lttng-consumerd")
1076 ],[
1077         AS_ECHO("$CONSUMERD32_BIN")
1078 ])
1079
1080 AS_ECHO_N("32-bit consumer libraries:   ")
1081 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1082         AS_ECHO("`eval eval echo $libdir`")
1083 ],[
1084         AS_ECHO("$CONSUMERD32_LIBDIR")
1085 ])
1086
1087 AS_ECHO_N("64-bit consumerd executable: ")
1088 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1089         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
1090         AS_ECHO("/lttng-consumerd")
1091 ],[
1092         AS_ECHO("$CONSUMERD64_BIN")
1093 ])
1094
1095 AS_ECHO_N("64-bit consumer libraries:   ")
1096 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1097         AS_ECHO("`eval eval echo $libdir`")
1098 ],[
1099         AS_ECHO("$CONSUMERD64_LIBDIR")
1100 ])
1101
1102 AS_ECHO()
1103